qcsrc/server/w_hlac.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(HLAC, w_hlac, IT_CELLS, 6, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "hlac", "hlac", _("Heavy Laser Assault Cannon"))
   3 #else
   4 #ifdef SVQC
   5
   6 void W_HLAC_Touch (void)
   7 {
   8         PROJECTILE_TOUCH;
   9
  10         self.event_damage = SUB_Null;
  11
  12         if(self.projectiledeathtype & HITTYPE_SECONDARY)
  13                 RadiusDamage (self, self.owner, autocvar_g_balance_hlac_secondary_damage, autocvar_g_balance_hlac_secondary_edgedamage, autocvar_g_balance_hlac_secondary_radius, world, autocvar_g_balance_hlac_secondary_force, self.projectiledeathtype, other);
  14         else
  15                 RadiusDamage (self, self.owner, autocvar_g_balance_hlac_primary_damage, autocvar_g_balance_hlac_primary_edgedamage, autocvar_g_balance_hlac_primary_radius, world, autocvar_g_balance_hlac_primary_force, self.projectiledeathtype, other);
  16
  17         remove (self);
  18 }
  19
  20 void W_HLAC_Attack (void)
  21 {
  22         local entity missile;
  23     float spread;
  24
  25         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
  26         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  27         {
  28                 if(autocvar_g_balance_hlac_reload_ammo)
  29                 {
  30                         self.clip_load -= autocvar_g_balance_hlac_primary_ammo;
  31                         self.weapon_load[WEP_HLAC] = self.clip_load;
  32                 }
  33                 else
  34                         self.ammo_cells -= autocvar_g_balance_hlac_primary_ammo;
  35         }
  36
  37     spread = autocvar_g_balance_hlac_primary_spread_min + (autocvar_g_balance_hlac_primary_spread_add * self.misc_bulletcounter);
  38     spread = min(spread,autocvar_g_balance_hlac_primary_spread_max);
  39     if(self.crouch)
  40         spread = spread * autocvar_g_balance_hlac_primary_spread_crouchmod;
  41
  42         W_SetupShot (self, FALSE, 3, "weapons/lasergun_fire.wav", CHAN_WEAPON, autocvar_g_balance_hlac_primary_damage);
  43         pointparticles(particleeffectnum("laser_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  44         if (!g_norecoil)
  45         {
  46                 self.punchangle_x = random () - 0.5;
  47                 self.punchangle_y = random () - 0.5;
  48         }
  49
  50         missile = spawn ();
  51         missile.owner = self;
  52         missile.classname = "hlacbolt";
  53         missile.bot_dodge = TRUE;
  54
  55     missile.bot_dodgerating = autocvar_g_balance_hlac_primary_damage;
  56
  57         missile.movetype = MOVETYPE_FLY;
  58         PROJECTILE_MAKETRIGGER(missile);
  59
  60         setorigin (missile, w_shotorg);
  61         setsize(missile, '0 0 0', '0 0 0');
  62
  63         W_SetupProjectileVelocity(missile, autocvar_g_balance_hlac_primary_speed, spread);
  64         //missile.angles = vectoangles (missile.velocity); // csqc
  65
  66         missile.touch = W_HLAC_Touch;
  67         missile.think = SUB_Remove;
  68
  69     missile.nextthink = time + autocvar_g_balance_hlac_primary_lifetime;
  70
  71         missile.flags = FL_PROJECTILE;
  72         missile.projectiledeathtype = WEP_HLAC;
  73
  74         CSQCProjectile(missile, TRUE, PROJECTILE_HLAC, TRUE);
  75
  76         other = missile; MUTATOR_CALLHOOK(EditProjectile);
  77 }
  78
  79 void W_HLAC_Attack2f (void)
  80 {
  81         local entity missile;
  82     float spread;
  83
  84     spread = autocvar_g_balance_hlac_secondary_spread;
  85
  86
  87     if(self.crouch)
  88         spread = spread * autocvar_g_balance_hlac_secondary_spread_crouchmod;
  89
  90         W_SetupShot (self, FALSE, 3, "weapons/lasergun_fire.wav", CHAN_WEAPON, autocvar_g_balance_hlac_secondary_damage);
  91         pointparticles(particleeffectnum("laser_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  92
  93         missile = spawn ();
  94         missile.owner = self;
  95         missile.classname = "hlacbolt";
  96         missile.bot_dodge = TRUE;
  97
  98     missile.bot_dodgerating = autocvar_g_balance_hlac_secondary_damage;
  99
 100         missile.movetype = MOVETYPE_FLY;
 101         PROJECTILE_MAKETRIGGER(missile);
 102
 103         setorigin (missile, w_shotorg);
 104         setsize(missile, '0 0 0', '0 0 0');
 105
 106         W_SetupProjectileVelocity(missile, autocvar_g_balance_hlac_secondary_speed, spread);
 107         //missile.angles = vectoangles (missile.velocity); // csqc
 108
 109         missile.touch = W_HLAC_Touch;
 110         missile.think = SUB_Remove;
 111
 112     missile.nextthink = time + autocvar_g_balance_hlac_secondary_lifetime;
 113
 114         missile.flags = FL_PROJECTILE;
 115         missile.projectiledeathtype = WEP_HLAC | HITTYPE_SECONDARY;
 116
 117         CSQCProjectile(missile, TRUE, PROJECTILE_HLAC, TRUE);
 118
 119         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 120 }
 121
 122 void W_HLAC_Attack2 (void)
 123 {
 124     float i;
 125
 126         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 127         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 128         {
 129                 if(autocvar_g_balance_hlac_reload_ammo)
 130                 {
 131                         self.clip_load -= autocvar_g_balance_hlac_secondary_ammo;
 132                         self.weapon_load[WEP_HLAC] = self.clip_load;
 133                 }
 134                 else
 135                         self.ammo_cells -= autocvar_g_balance_hlac_secondary_ammo;
 136         }
 137
 138     for(i=autocvar_g_balance_hlac_secondary_shots;i>0;--i)
 139         W_HLAC_Attack2f();
 140
 141         if (!g_norecoil)
 142         {
 143                 self.punchangle_x = random () - 0.5;
 144                 self.punchangle_y = random () - 0.5;
 145         }
 146 }
 147
 148 // weapon frames
 149 void HLAC_fire1_02()
 150 {
 151         if(self.weapon != self.switchweapon) // abort immediately if switching
 152         {
 153                 w_ready();
 154                 return;
 155         }
 156
 157         if (self.BUTTON_ATCK)
 158         {
 159                 if (!weapon_action(self.weapon, WR_CHECKAMMO1))
 160                 {
 161                         W_SwitchWeapon_Force(self, w_getbestweapon(self));
 162                         w_ready();
 163                         return;
 164                 }
 165
 166                 ATTACK_FINISHED(self) = time + autocvar_g_balance_hlac_primary_refire * W_WeaponRateFactor();
 167                 W_HLAC_Attack();
 168                 self.misc_bulletcounter = self.misc_bulletcounter + 1;
 169         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_hlac_primary_refire, HLAC_fire1_02);
 170         }
 171         else
 172         {
 173                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_hlac_primary_animtime, w_ready);
 174         }
 175 };
 176
 177 void spawnfunc_weapon_hlac (void)
 178 {
 179         weapon_defaultspawnfunc(WEP_HLAC);
 180 }
 181
 182 float w_hlac(float req)
 183 {
 184         float ammo_amount;
 185         if (req == WR_AIM)
 186         self.BUTTON_ATCK = bot_aim(autocvar_g_balance_hlac_primary_speed, 0, autocvar_g_balance_hlac_primary_lifetime, FALSE);
 187         else if (req == WR_THINK)
 188         {
 189                 if(autocvar_g_balance_hlac_reload_ammo && self.clip_load < min(autocvar_g_balance_hlac_primary_ammo, autocvar_g_balance_hlac_secondary_ammo)) // forced reload
 190                         weapon_action(self.weapon, WR_RELOAD);
 191                 else if (self.BUTTON_ATCK)
 192                 {
 193                         if (weapon_prepareattack(0, autocvar_g_balance_hlac_primary_refire))
 194                         {
 195                                 self.misc_bulletcounter = 0;
 196                                 W_HLAC_Attack();
 197                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_hlac_primary_refire, HLAC_fire1_02);
 198                         }
 199                 }
 200
 201                 else if (self.BUTTON_ATCK2 && autocvar_g_balance_hlac_secondary)
 202                 {
 203                         if (weapon_prepareattack(1, autocvar_g_balance_hlac_secondary_refire))
 204                         {
 205                                 W_HLAC_Attack2();
 206                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hlac_secondary_animtime, w_ready);
 207                         }
 208                 }
 209         }
 210         else if (req == WR_PRECACHE)
 211         {
 212         precache_model ("models/weapons/g_hlac.md3");
 213                 precache_model ("models/weapons/v_hlac.md3");
 214                 precache_model ("models/weapons/h_hlac.iqm");
 215                 precache_sound ("weapons/lasergun_fire.wav");
 216                 precache_sound ("weapons/reload.wav");
 217
 218         }
 219         else if (req == WR_SETUP)
 220         {
 221                 weapon_setup(WEP_HLAC);
 222         }
 223         else if (req == WR_CHECKAMMO1)
 224         {
 225                 ammo_amount = self.ammo_cells >= autocvar_g_balance_hlac_primary_ammo;
 226                 ammo_amount += self.weapon_load[WEP_HLAC] >= autocvar_g_balance_hlac_primary_ammo;
 227                 return ammo_amount;
 228         }
 229         else if (req == WR_CHECKAMMO2)
 230         {
 231                 ammo_amount = self.ammo_cells >= autocvar_g_balance_hlac_secondary_ammo;
 232                 ammo_amount += self.weapon_load[WEP_HLAC] >= autocvar_g_balance_hlac_secondary_ammo;
 233                 return ammo_amount;
 234         }
 235         else if (req == WR_RELOAD)
 236         {
 237                 W_Reload(ammo_cells, min(autocvar_g_balance_hlac_primary_ammo, autocvar_g_balance_hlac_secondary_ammo), autocvar_g_balance_hlac_reload_ammo, autocvar_g_balance_hlac_reload_time, "weapons/reload.wav");
 238         }
 239         return TRUE;
 240 };
 241 #endif
 242 #ifdef CSQC
 243 float w_hlac(float req)
 244 {
 245         if(req == WR_IMPACTEFFECT)
 246         {
 247                 vector org2;
 248                 org2 = w_org + w_backoff * 6;
 249                 pointparticles(particleeffectnum("laser_impact"), org2, w_backoff * 1000, 1);
 250                 if(!w_issilent)
 251                         sound(self, CHAN_PROJECTILE, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM);
 252         }
 253         else if(req == WR_PRECACHE)
 254         {
 255                 precache_sound("weapons/laserimpact.wav");
 256         }
 257         else if (req == WR_SUICIDEMESSAGE)
 258                 w_deathtypestring = _("%s should have used a smaller gun");
 259         else if (req == WR_KILLMESSAGE)
 260                 w_deathtypestring = _("%s was cut down by %s");
 261         return TRUE;
 262 }
 263 #endif
 264 #endif