#define RACER_MIN '-120 -120 -40'
#define RACER_MAX '120 120 40'
#define RACER_TICRATE 0.05

void racer_exit(float eject);
void racer_enter();

// Auto cvars
float autocvar_g_vehicle_racer_speed_afterburn;
float autocvar_g_vehicle_racer_afterburn_cost;

float autocvar_g_vehicle_racer_anglestabilizer;
float autocvar_g_vehicle_racer_downforce;

float autocvar_g_vehicle_racer_speed_forward;
float autocvar_g_vehicle_racer_speed_strafe;
float autocvar_g_vehicle_racer_springlength;
float autocvar_g_vehicle_racer_upforcedamper;

float autocvar_g_vehicle_racer_hovertype;
float autocvar_g_vehicle_racer_hoverpower;

float autocvar_g_vehicle_racer_turnroll;
float autocvar_g_vehicle_racer_turnspeed;
float autocvar_g_vehicle_racer_pitchspeed;

float autocvar_g_vehicle_racer_energy;
float autocvar_g_vehicle_racer_energy_regen;
float autocvar_g_vehicle_racer_energy_regen_pause;

float autocvar_g_vehicle_racer_health;
float autocvar_g_vehicle_racer_health_regen;
float autocvar_g_vehicle_racer_health_regen_pause;

float autocvar_g_vehicle_racer_shield;
float autocvar_g_vehicle_racer_shield_regen;
float autocvar_g_vehicle_racer_shield_regen_pause;

float autocvar_g_vehicle_racer_laser_cost;
float autocvar_g_vehicle_racer_laser_damage;
float autocvar_g_vehicle_racer_laser_radius;
float autocvar_g_vehicle_racer_laser_refire;
float autocvar_g_vehicle_racer_laser_speed;

float autocvar_g_vehicle_racer_rocket_accel;
float autocvar_g_vehicle_racer_rocket_damage;
float autocvar_g_vehicle_racer_rocket_radius;
float autocvar_g_vehicle_racer_rocket_refire;
float autocvar_g_vehicle_racer_rocket_speed;
float autocvar_g_vehicle_racer_rocket_turnrate;

float autocvar_g_vehicle_racer_rocket_locktarget;
float autocvar_g_vehicle_racer_rocket_locking_time;
float autocvar_g_vehicle_racer_rocket_locking_releasetime;
float autocvar_g_vehicle_racer_rocket_locked_time;


float autocvar_g_vehicle_racer_respawntime;
float autocvar_g_vehicle_racer_collision_multiplier;

var vector racer_force_from_tag(string tag_name, float spring_length, float max_power);

void racer_align4point()
{
    vector push_vector, v_add;
    float fl_push, fr_push, bl_push, br_push;

    push_vector  = racer_force_from_tag("tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
    fr_push      = force_fromtag_normpower;
    vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);

    push_vector += racer_force_from_tag("tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
    fl_push      = force_fromtag_normpower;
    vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);

    push_vector += racer_force_from_tag("tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
    br_push      = force_fromtag_normpower;
    vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);

    push_vector += racer_force_from_tag("tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
    bl_push      = force_fromtag_normpower;
    vehicles_sweap_collision(force_fromtag_origin, self.velocity, frametime, v_add, autocvar_g_vehicle_racer_collision_multiplier);

    self.velocity += (push_vector * frametime);

    // Anti ocilation
    if(self.velocity_z  > 0)
        self.velocity_z  *= autocvar_g_vehicle_racer_upforcedamper;

    self.velocity += v_add;
    self.velocity_z -= autocvar_sv_gravity * frametime;

    push_vector_x =  (fl_push - bl_push);
    push_vector_x += (fr_push - br_push);
    push_vector_x *= 360;

    push_vector_z = (fr_push - fl_push);
    push_vector_z += (br_push - bl_push);
    push_vector_z *= 360;

    // Apply angle diffrance
    self.angles_z += push_vector_z * frametime;
    self.angles_x += push_vector_x * frametime;
    // Apply stabilizer
    self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * frametime);
    self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * frametime);
}

void racer_rocket_explode()
{
	PROJECTILE_TOUCH;
    if(other.owner == self.owner)
        return;

	self.event_damage = SUB_Null;

    sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
    pointparticles(particleeffectnum("rocket_explode"), findbetterlocation (self.origin, 16), '0 0 0', 1);
    RadiusDamage (self, self.realowner ,autocvar_g_vehicle_racer_rocket_damage, 0, autocvar_g_vehicle_racer_rocket_radius, world, 150, DEATH_WAKIROCKET, world);

    remove (self);
}

void racer_bolt_explode()
{
	PROJECTILE_TOUCH;
    pointparticles(particleeffectnum("wakizashi_gun_impact"), findbetterlocation (self.origin, 8), trace_plane_normal * 1000, 1);
    RadiusDamage (self, self.realowner, autocvar_g_vehicle_racer_laser_damage, 0, autocvar_g_vehicle_racer_laser_radius, world, 150, DEATH_WAKIGUN, world);
    sound (self, CHAN_PROJECTILE, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM);
    remove (self);
}

void racer_fire_cannon(string tagname)
{
    entity bolt;
    vector v;

    bolt = spawn();
    sound (self, CHAN_WEAPON, "weapons/lasergun_fire.wav", VOL_BASE, ATTN_NORM);

    setorigin(bolt, gettaginfo(self, gettagindex(self, tagname)));
    PROJECTILE_MAKETRIGGER(bolt);

    bolt.movetype        = MOVETYPE_FLYMISSILE;
    bolt.flags           = FL_PROJECTILE | FL_NOTARGET;
    bolt.owner           = self;
    bolt.realowner       = self.owner;
    bolt.touch           = racer_bolt_explode;
    bolt.think           = racer_bolt_explode;
    bolt.nextthink       = time + 9;

    bolt.bot_dodge       = TRUE;
    bolt.bot_dodgerating = autocvar_g_vehicle_racer_laser_damage;

	// Fix z-aim (for chase mode)
    v = normalize(trace_endpos - bolt.origin);
    v_forward_z = v_z * 0.5;

    bolt.velocity = v_forward * autocvar_g_vehicle_racer_laser_speed;

    pointparticles(particleeffectnum("wakizashi_gun_muzzleflash"), bolt.origin, bolt.velocity, 1);

    CSQCProjectile(bolt, TRUE, PROJECTILE_LASER, TRUE);
}

void racer_rocket_groundhugger()
{
    vector olddir, newdir;
    float oldvel, newvel;

    self.nextthink  = time;

    if ((self.owner.deadflag != DEAD_NO) || (self.cnt < time))
    {
        racer_rocket_explode();
        return;
    }

    if not (self.realowner.vehicle)
    {
        UpdateCSQCProjectile(self);
        return;
    }

    olddir = normalize(self.velocity);
    oldvel = vlen(self.velocity);
    newvel = oldvel + self.lip;

    tracebox(self.origin, self.mins, self.maxs, self.origin + olddir * 64, MOVE_WORLDONLY,self);
    if(trace_fraction <= 0.5)
    {
        // Hitting somethign soon, just speed ahead
        self.velocity = olddir * newvel;
        UpdateCSQCProjectile(self);
        return;
    }

    if(self.enemy != world)
        newdir = normalize(self.enemy.origin - self.origin);

    traceline(trace_endpos, trace_endpos - '0 0 64', MOVE_NORMAL, self);
    if(trace_fraction != 1.0)
    {
        newdir += normalize(trace_endpos + '0 0 64' - self.origin);
        self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_racer_rocket_turnrate) * newvel;
    }
    else
    {
        self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_racer_rocket_turnrate) * newvel;
        self.velocity_z -= 1600 * sys_frametime; // 2x grav looks better for this one
    }

    UpdateCSQCProjectile(self);
    return;
}

void racer_fire_rocket(string tagname, entity trg)
{
    entity rocket;

    sound (self, CHAN_WEAPON, "weapons/rocket_fire.wav", VOL_BASE, ATTN_NORM);

    rocket = spawn();
    setsize (rocket, '-1 -1 -1', '1 1 1');
    setorigin(rocket, gettaginfo(self, gettagindex(self, tagname)));

    rocket.lip              = autocvar_g_vehicle_racer_rocket_accel * sys_frametime;
    rocket.wait             = autocvar_g_vehicle_racer_rocket_turnrate;
    rocket.solid            = SOLID_BBOX;
    rocket.movetype         = MOVETYPE_FLYMISSILE;
    rocket.flags            = FL_PROJECTILE;
    rocket.owner            = self;
    rocket.realowner        = self.owner;
    rocket.touch            = racer_rocket_explode;
    rocket.bot_dodge        = TRUE;
    rocket.bot_dodgerating  = autocvar_g_vehicle_racer_rocket_damage;
    rocket.cnt              = time + 9;
    rocket.velocity         = v_forward * autocvar_g_vehicle_racer_rocket_speed;
    rocket.think            = racer_rocket_groundhugger;
    rocket.nextthink        = time + 0.5;
    rocket.enemy            = trg;

    CSQCProjectile(rocket, TRUE, PROJECTILE_ROCKET, TRUE);
}

.float fire1_waspressed;
.float fire2_waspressed;
float racer_frame()
{
    entity player, racer;
    float ftmp, ftmp2;
    vector df;

    player          = self;
    racer           = self.vehicle;

    player.BUTTON_ZOOM = player.BUTTON_CROUCH = 0;

    self = racer;

    if(player.BUTTON_USE)
    {
        vehicles_exit(VHEF_NORMAL);
        self = player;
        return 0;
    }

    if(racer.deadflag != DEAD_NO)
    {
        self = player;
        player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
        return 1;
    }

    racer_align4point();
    // Move abt crosshir insted of v_angle. this allows custom chase camera.
    crosshair_trace(player);
    racer.angles_x *= -1;
    df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
    if(df_x > 180)  df_x -= 360;
    if(df_x < -180) df_x += 360;
    if(df_y > 180)  df_y -= 360;
    if(df_y < -180) df_y += 360;

    // Yaw
    ftmp = autocvar_g_vehicle_racer_turnspeed * sys_frametime;
    ftmp2 = ftmp * -1;

    ftmp = bound(ftmp2, shortangle_f(df_y - racer.angles_y, racer.angles_y), ftmp);
    ftmp2 = anglemods(racer.angles_y + ftmp);

    // Roll
    ftmp = bound(-45, shortangle_f(df_z + ((racer.angles_y - ftmp2) * autocvar_g_vehicle_racer_turnroll), racer.angles_z), 45);
    ftmp = anglemods(racer.angles_z + ftmp) * frametime;
    racer.angles_z = bound(-65, racer.angles_z + ftmp, 65);

    // Turn
    racer.angles_y = ftmp2;

    // Pitch Body
    ftmp = autocvar_g_vehicle_racer_pitchspeed * sys_frametime;
    ftmp2 = ftmp * -1;

    ftmp = bound(ftmp2, shortangle_f(player.v_angle_x - racer.angles_x, racer.angles_x), ftmp);
    racer.angles_x = anglemods(racer.angles_x + ftmp);

    makevectors(racer.angles);
    racer.angles_x *= -1;

    df = racer.velocity * -0.5;

    if(player.movement_x != 0)
    {
        if(player.movement_x > 0)
            df += v_forward  * autocvar_g_vehicle_racer_speed_forward;
        else if(player.movement_x < 0)
            df -= v_forward  * autocvar_g_vehicle_racer_speed_forward;
    }

    if(player.movement_y != 0)
    {
        if(player.movement_y < 0)
            df -= v_right * autocvar_g_vehicle_racer_speed_strafe;
        else if(player.movement_y > 0)
            df += v_right * autocvar_g_vehicle_racer_speed_strafe;
    }

    // limit _z to avoid flying on normal thrust
    if(df_z > 0)
        df_z = min(df_z, 700);

    // Afterburn
    if (player.BUTTON_JUMP)
    if(racer.vehicle_energy >= (autocvar_g_vehicle_racer_afterburn_cost * frametime))
    {
        racer.wait = time;
        racer.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * frametime;
        df += (v_forward * autocvar_g_vehicle_racer_speed_afterburn);
        self.owner.vehicle_energy = racer.vehicle_energy / autocvar_g_vehicle_racer_energy;
    }

    racer.velocity  += df * frametime;

    df = (vlen(racer.velocity) * autocvar_g_vehicle_racer_downforce * v_up) * frametime;
    racer.velocity  = racer.velocity - df;
    player.movement = racer.velocity;

    if(player.BUTTON_ATCK)
    if(time > racer.attack_finished_single)
    if(racer.vehicle_energy >= autocvar_g_vehicle_racer_laser_cost)
    {
        racer.vehicle_energy -= autocvar_g_vehicle_racer_laser_cost;
        racer.wait = time;

        crosshair_trace(player);
        if(racer.cnt)
        {
            racer_fire_cannon("tag_fire1");
            racer.cnt = 0;
        }
        else
        {
            racer_fire_cannon("tag_fire2");
            racer.cnt = 1;
        }
        racer.attack_finished_single = time + autocvar_g_vehicle_racer_laser_refire;
        self.owner.vehicle_energy = racer.vehicle_energy / autocvar_g_vehicle_racer_energy;
    }

    if(autocvar_g_vehicle_racer_rocket_locktarget)
    {
        vehicles_locktarget2((1 / autocvar_g_vehicle_racer_rocket_locking_time) * frametime,
                         (1 / autocvar_g_vehicle_racer_rocket_locking_releasetime) * frametime,
                         autocvar_g_vehicle_racer_rocket_locked_time);

        if(self.lock_target)
        {
            if(racer.lock_strength == 1)
                UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '1 0 0', 0);
            else if(self.lock_strength > 0.5)
                UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 1 0', 0);
            else if(self.lock_strength < 0.5)
                UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 0 1', 0);
        }
    }

    if(time > racer.delay)
    if(player.BUTTON_ATCK2)
    {
        racer_fire_rocket("tag_rocket_r", ((self.lock_strength == 1 && self.lock_target) ? self.lock_target : world));
        racer_fire_rocket("tag_rocket_l", ((self.lock_strength == 1 && self.lock_target) ? self.lock_target : world));

        self.lock_strength  = 0;
        self.lock_target    = world;

        racer.delay = time + autocvar_g_vehicle_racer_rocket_refire;
        racer.lip = time;
    }

    player.fire2_waspressed = player.BUTTON_ATCK2;

    player.vehicle_reload1 = (time - racer.lip) / (racer.delay - racer.lip);

    if(self.vehicle_flags  & VHF_SHIELDREGEN)
        vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, frametime);

    if(self.vehicle_flags  & VHF_HEALTHREGEN)
        vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, frametime);

    if(self.vehicle_flags  & VHF_ENERGYREGEN)
        vehicles_regen(wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, frametime);


    VEHICLE_UPDATE_PLAYER(health, racer);

    if(self.vehicle_flags & VHF_HASSHIELD)
        VEHICLE_UPDATE_PLAYER(shield, racer);


    player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
    setorigin(player,racer.origin + '0 0 32');
    player.velocity = racer.velocity;

    self = player;
    return 1;
}

void racer_think()
{
    float a, b, c;

    self.nextthink = time;

    a = autocvar_g_vehicle_racer_anglestabilizer;
    b = autocvar_g_vehicle_racer_springlength;
    c = autocvar_g_vehicle_racer_hoverpower;

    autocvar_g_vehicle_racer_anglestabilizer = 36;
    autocvar_g_vehicle_racer_springlength = 96;
    autocvar_g_vehicle_racer_hoverpower = 300;

    racer_align4point();

    if(self.velocity_z < 0)
        self.velocity_z *= 0.95;

    autocvar_g_vehicle_racer_anglestabilizer = a;
    autocvar_g_vehicle_racer_springlength = b;
    autocvar_g_vehicle_racer_hoverpower = c;

    self.velocity_x *= 0.95;
    self.velocity_y *= 0.95;
}

void racer_enter()
{
    self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_racer_health);
    self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_racer_shield);
}

void racer_spawn();

void racer_exit(float eject)
{
    vehicles_setreturn(autocvar_g_vehicle_racer_respawntime, racer_spawn);

    self.think      = racer_think;
    self.nextthink  = time;

    if not (self.owner)
        return;

	makevectors(self.angles);
	if(eject)
	{
	    setorigin(self.owner, self.origin + v_forward * 100 + v_up * 32);
	    self.owner.velocity = (v_up + v_forward * 0.25) * 750;
	}
	else
	{
	    setorigin(self.owner, self.origin - v_forward * 100 + v_up * 32);
	    self.owner.velocity = v_forward * -150;
	}
    self.owner = world;
}

void racer_touch()
{
    if(self.owner)
    {
        //self.velocity = 0.999 * self.velocity;
        // TO-DO Impact reaction (crush players, damage self on high speed impact etc)
        return;
    }

    if(other.classname != "player")
        return;

    if(other.deadflag != DEAD_NO)
        return;

    if(other.vehicle != world)
        return;

    vehicles_enter();
}

void racer_spawn()
{
    self.think = racer_think;
    self.nextthink = time;

    self.flags      = FL_NOTARGET;
    self.effects   = 0;

    self.vehicle_health = autocvar_g_vehicle_racer_health;
    self.vehicle_shield = autocvar_g_vehicle_racer_shield;

    self.event_damage = vehicles_damage;
    self.touch      = racer_touch;

    self.iscreature = TRUE;
    self.scale      = 0.5;
    self.movetype   = MOVETYPE_BOUNCEMISSILE;
    self.solid      = SOLID_SLIDEBOX;
    self.takedamage = DAMAGE_AIM;

    self.alpha      = 1;
	self.colormap   = 1024;
	self.deadflag   = DEAD_NO;
    self.bot_attack = TRUE;

    self.vehicle_energy = 1;
    self.vehicle_hudmodel.viewmodelforclient = self;

    setorigin(self, self.pos1);
    self.angles = self.pos2;

    setsize(self, RACER_MIN * 0.5, RACER_MAX * 0.5);
    pointparticles(particleeffectnum("teleport"), self.origin + '0 0 64', '0 0 0', 1);
    self.delay = time;

    vehicles_common_spawn();
}

void racer_blowup()
{

    sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
    pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);

    self.deadflag    = DEAD_DEAD;
    self.vehicle_exit(VHEF_NORMAL);

    // FIXME dont use hardcoded damage/force
    RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_WAKIBLOWUP, world);

    self.alpha = -1;
    self.nextthink  = time + autocvar_g_vehicle_racer_respawntime;
    self.think      = racer_spawn;
    self.movetype   = MOVETYPE_NONE;
    self.effects    = EF_NODRAW;

    self.colormod  = '0 0 0';
    self.avelocity = '0 0 0';
    self.velocity  = '0 0 0';

    setorigin(self, self.pos1);
}

void racer_deadtouch()
{
    self.avelocity_x *= 0.7;
    self.cnt -= 1;
    if(self.cnt <= 0)
        racer_blowup();
}

void racer_die()
{
    self.health       = 0;
    self.event_damage = SUB_Null;
    self.iscreature   = FALSE;
    self.solid        = SOLID_CORPSE;
    self.takedamage   = DAMAGE_NO;
    self.deadflag     = DEAD_DYING;
    self.movetype     = MOVETYPE_BOUNCE;
    self.wait         = time;
    self.cnt          = 1 + random() * 3;
    self.touch        = racer_deadtouch;

    pointparticles(particleeffectnum("rocket_explode"), findbetterlocation (self.origin, 16), '0 0 0', 1);

    self.velocity     += '0 0 700';

    if(random() < 0.5)
        self.avelocity_z  = 16;
    else
        self.avelocity_z  = -16;

    self.avelocity_x = -vlen(self.velocity) * 0.2;

    self.colormod = '-0.5 -0.5 -0.5';

	self.think     = racer_blowup;
	self.nextthink = 2 + time + random() * 3;
}

void racer_dinit()
{
    if not (vehicle_initialize(
             "Wakizashi",
             "models/vehicles/wakizashi.dpm",
             "",
             "models/vehicles/wakizashi_cockpit.dpm",
             "", "", "tag_viewport",
             HUD_WAKIZASHI,
             0.5 * RACER_MIN, 0.5 * RACER_MAX,
             FALSE,
             racer_spawn, racer_frame,
             racer_enter, racer_exit,
             racer_die,   racer_think))
    {
        remove(self);
        return;
    }

    if(autocvar_g_vehicle_racer_hovertype != 0)
        racer_force_from_tag = vehicles_force_fromtag_maglev;
    else
        racer_force_from_tag = vehicles_force_fromtag_hover;

    // FIXME: this be hakkz, fix the models insted (scale body, add tag_viewport to the hudmodel).
    self.scale = 0.5;
    setattachment(self.vehicle_hudmodel, self, "");
    setattachment(self.vehicle_viewport, self, "tag_viewport");
}

void spawnfunc_vehicle_racer()
{

    precache_sound ("weapons/laserimpact.wav");
    precache_sound ("weapons/lasergun_fire.wav");
    precache_sound ("weapons/rocket_fire.wav");
    precache_sound ("weapons/rocket_impact.wav");

    precache_model ("models/vhshield.md3");
    precache_model ("models/vehicles/wakizashi.dpm");
    precache_model ("models/vehicles/wakizashi_cockpit.dpm");


    vehicles_configcheck("vehicle_racer.cfg", autocvar_g_vehicle_racer_health);
    if(autocvar_g_vehicle_racer_energy)
        if(autocvar_g_vehicle_racer_energy_regen)
            self.vehicle_flags |= VHF_ENERGYREGEN;

    if(autocvar_g_vehicle_racer_shield)
        self.vehicle_flags |= VHF_HASSHIELD;

    if(autocvar_g_vehicle_racer_shield_regen)
        self.vehicle_flags |= VHF_SHIELDREGEN;

    if(autocvar_g_vehicle_racer_health_regen)
        self.vehicle_flags |= VHF_HEALTHREGEN;

    self.think = racer_dinit;
    self.nextthink = time + 1;
}