data/qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------\r
   2 // BEGIN REQUIRED CSQC FUNCTIONS\r
   3 //include "main.qh"\r
   4 \r
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
   6 \r
   7 void cvar_clientsettemp(string cv, string val)\r
   8 {\r
   9         entity e;\r
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )\r
  11                 if(e.netname == cv)\r
  12                         goto saved;\r
  13         e = spawn();\r
  14         e.classname = "saved_cvar_value";\r
  15         e.netname = strzone(cv);\r
  16         e.message = strzone(cvar_string(cv));\r
  17 :saved\r
  18         cvar_set(cv, val);\r
  19 }\r
  20 \r
  21 void cvar_clientsettemp_restore()\r
  22 {\r
  23         entity e;\r
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )\r
  25                         cvar_set(e.netname, e.message);\r
  26 }\r
  27 \r
  28 void() menu_show_error =\r
  29 {\r
  30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);\r
  31 };\r
  32 \r
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)\r
  34 // Useful for precaching things\r
  35 \r
  36 float(float, float, float) menu_sub_null_float = { };\r
  37 void () menu_sub_null_void  = { };\r
  38 \r
  39 #ifdef USE_FTE\r
  40 float __engine_check;\r
  41 #endif\r
  42 \r
  43 string forcefog;\r
  44 string cl_announcer_prev;\r
  45 void WaypointSprite_Load();\r
  46 void CSQC_Init(void)\r
  47 {\r
  48 #ifdef USE_FTE\r
  49 #pragma target ID\r
  50         __engine_check = checkextension("DP_SV_WRITEPICTURE");\r
  51         if(!__engine_check)\r
  52         {\r
  53                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");\r
  54                 localcmd("\ndisconnect\n");\r
  55                 return;\r
  56         }\r
  57 #pragma target FTE\r
  58 #endif\r
  59         \r
  60         check_unacceptable_compiler_bugs();\r
  61 \r
  62         float i;\r
  63         CSQC_CheckEngine();\r
  64 \r
  65         binddb = db_create();\r
  66         tempdb = db_create();\r
  67         ClientProgsDB = db_load("client.db");\r
  68         compressShortVector_init();\r
  69 \r
  70         drawfont = FONT_USER+1;\r
  71         menu_visible = FALSE;\r
  72         menu_show = menu_show_error;\r
  73         menu_action = menu_sub_null_float;\r
  74 \r
  75         for(i = 0; i < 255; ++i)\r
  76                 if(getplayerkey(i, "viewentity") == "")\r
  77                         break;\r
  78         maxclients = i;\r
  79 \r
  80         //ctf_temp_1 = "";\r
  81         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used\r
  82         //registercmd("ctf_menu");\r
  83         registercmd("ons_map");\r
  84         //registercmd("menu_action");\r
  85 \r
  86         registercmd("+button3");\r
  87         registercmd("-button3");\r
  88         registercmd("+button4");\r
  89         registercmd("-button4");\r
  90         registercmd("+button6");\r
  91         registercmd("-button6");\r
  92         registercmd("+showaccuracy");registercmd("-showaccuracy");\r
  93 \r
  94 #ifndef CAMERATEST\r
  95         if(isdemo())\r
  96         {\r
  97 #endif\r
  98                 registercmd("+forward");registercmd("-forward");\r
  99                 registercmd("+back");registercmd("-back");\r
 100                 registercmd("+moveup");registercmd("-moveup");\r
 101                 registercmd("+movedown");registercmd("-movedown");\r
 102                 registercmd("+moveright");registercmd("-moveright");\r
 103                 registercmd("+moveleft");registercmd("-moveleft");\r
 104                 registercmd("+roll_right");registercmd("-roll_right");\r
 105                 registercmd("+roll_left");registercmd("-roll_left");\r
 106 #ifndef CAMERATEST\r
 107         }\r
 108 #endif\r
 109         registercvar("sbar_usecsqc", "1");\r
 110         registercvar("sbar_columns", "default", CVAR_SAVE);\r
 111 \r
 112         gametype = 0;\r
 113 \r
 114         // sbar_fields uses strunzone on the titles!\r
 115         for(i = 0; i < MAX_SBAR_FIELDS; ++i)\r
 116                 sbar_title[i] = strzone("(null)");\r
 117 \r
 118         postinit = false;\r
 119 \r
 120         calledhooks = 0;\r
 121 \r
 122         teams = Sort_Spawn();\r
 123         players = Sort_Spawn();\r
 124 \r
 125         GetTeam(COLOR_SPECTATOR, true); // add specs first\r
 126 \r
 127         cvar_clientsettemp("_supports_weaponpriority", "1");\r
 128 \r
 129         RegisterWeapons();\r
 130 \r
 131         WaypointSprite_Load();\r
 132 \r
 133         // precaches\r
 134         Projectile_Precache();\r
 135         GibSplash_Precache();\r
 136         Casings_Precache();\r
 137         DamageInfo_Precache();\r
 138         if(cvar_string("cl_announcer") != cl_announcer_prev) {\r
 139                 Announcer_Precache();\r
 140                 if(cl_announcer_prev)\r
 141                         strunzone(cl_announcer_prev);\r
 142                 cl_announcer_prev = strzone(cvar_string("cl_announcer"));\r
 143         }\r
 144 \r
 145         if(cvar("cl_reticle_item_normal")) precache_pic("gfx/reticle_normal");\r
 146         if(cvar("cl_reticle_item_nex")) precache_pic("gfx/reticle_nex");\r
 147 \r
 148 #ifdef UID\r
 149         {\r
 150                 // find the user ID\r
 151                 string uid;\r
 152                 registercvar("_cl_userid", "", CVAR_SAVE);\r
 153                 uid = cvar_string("_cl_userid");\r
 154                 if(strlen(uid) < 16)\r
 155                 {\r
 156                         uid = "";\r
 157                         for(i = 0; i < 4; ++i)\r
 158                                 uid = strcat(uid, substring(ftos(floor(10000 + random() * 10000)), 1, -1));\r
 159                 }\r
 160                 cvar_set("_cl_userid", uid);\r
 161                 localcmd(strcat("\ncmd uid ", uid, "\n"));\r
 162         }\r
 163 #endif\r
 164 \r
 165         get_mi_min_max_texcoords(1); // try the CLEVER way first\r
 166         minimapname = strcat("gfx/radar/", mi_shortname, "_radar.tga");\r
 167         shortmapname = mi_shortname;\r
 168 \r
 169         if(precache_pic(minimapname) == "")\r
 170         {\r
 171                 // but maybe we have a non-clever minimap\r
 172                 minimapname = strcat("gfx/radar/", mi_shortname, "_mini.tga");\r
 173                 if(precache_pic(minimapname) == "")\r
 174                         minimapname = ""; // FAIL\r
 175                 else\r
 176                         get_mi_min_max_texcoords(0); // load new texcoords\r
 177         }\r
 178 \r
 179         precache_pic(strcat("gfx/hud/", cvar_string("hud_style"), "/bg_radar.tga"));\r
 180         precache_pic(strcat("gfx/hud/", cvar_string("hud_style"), "/fg_radar.tga"));\r
 181         precache_pic(strcat("gfx/hud/", cvar_string("hud_style"), "/fg_radar_team.tga"));\r
 182 \r
 183         mi_center = (mi_min + mi_max) * 0.5;\r
 184         mi_scale = mi_max - mi_min;\r
 185         minimapname = strzone(minimapname);\r
 186 \r
 187         WarpZone_Init();\r
 188 \r
 189         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));\r
 190 }\r
 191 \r
 192 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)\r
 193 void CSQC_Shutdown(void)\r
 194 {\r
 195 #ifdef USE_FTE\r
 196 #pragma TARGET id\r
 197         if(!__engine_check)\r
 198                 return 0;\r
 199 #pragma TARGET fte\r
 200 #endif\r
 201 \r
 202         WarpZone_Shutdown();\r
 203 \r
 204         remove(teams);\r
 205         remove(players);\r
 206         db_close(binddb);\r
 207         db_close(tempdb);\r
 208         db_save(ClientProgsDB, "client.db");\r
 209         db_close(ClientProgsDB);\r
 210 \r
 211         cvar_clientsettemp_restore();\r
 212 \r
 213         if(camera_active)\r
 214                 cvar_set("chase_active",ftos(chase_active_backup));\r
 215 \r
 216         // unset the event chasecam's chase_active\r
 217         if(cvar("chase_active") < 0)\r
 218                 cvar_set("chase_active", "0");\r
 219 \r
 220         if not(isdemo())\r
 221         {\r
 222                 if not(calledhooks & HOOK_START)\r
 223                 {\r
 224                         localcmd("\n_cl_hook_gamestart nop;");\r
 225                         if(g_campaign) // this is a server cvar used in the client code, but g_campaign is always local, so it should be safe\r
 226                                 localcmd("\n_cl_hook_campaign_gamestart nop;");\r
 227                 }\r
 228                 if not(calledhooks & HOOK_END)\r
 229                 {\r
 230                         localcmd("\ncl_hook_gameend;");\r
 231                         if(g_campaign)\r
 232                                 localcmd("\ncl_hook_campaign_gameend;");\r
 233                 }\r
 234         }\r
 235 }\r
 236 \r
 237 .float has_team;\r
 238 float SetTeam(entity o, float Team)\r
 239 {\r
 240         entity tm;\r
 241         if(teamplay)\r
 242         {\r
 243                 switch(Team)\r
 244                 {\r
 245                         case -1:\r
 246                         case COLOR_TEAM1:\r
 247                         case COLOR_TEAM2:\r
 248                         case COLOR_TEAM3:\r
 249                         case COLOR_TEAM4:\r
 250                                 break;\r
 251                         default:\r
 252                                 if(GetTeam(Team, false) == NULL)\r
 253                                 {\r
 254                                         print("trying to switch to unsupported team ", ftos(Team), "\n");\r
 255                                         Team = COLOR_SPECTATOR;\r
 256                                 }\r
 257                                 break;\r
 258                 }\r
 259         }\r
 260         else\r
 261         {\r
 262                 switch(Team)\r
 263                 {\r
 264                         case -1:\r
 265                         case 0:\r
 266                                 break;\r
 267                         default:\r
 268                                 if(GetTeam(Team, false) == NULL)\r
 269                                 {\r
 270                                         print("trying to switch to unsupported team ", ftos(Team), "\n");\r
 271                                         Team = COLOR_SPECTATOR;\r
 272                                 }\r
 273                                 break;\r
 274                 }\r
 275         }\r
 276         if(Team == -1) // leave\r
 277         {\r
 278                 if(o.has_team)\r
 279                 {\r
 280                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");\r
 281                         tm = GetTeam(o.team, false);\r
 282                         tm.team_size -= 1;\r
 283                         o.has_team = 0;\r
 284                         return TRUE;\r
 285                 }\r
 286         }\r
 287         else\r
 288         {\r
 289                 if not(o.has_team)\r
 290                 {\r
 291                         //print("(CONNECT) enter team ", ftos(o.team), "\n");\r
 292                         o.team = Team;\r
 293                         tm = GetTeam(Team, true);\r
 294                         tm.team_size += 1;\r
 295                         o.has_team = 1;\r
 296                         return TRUE;\r
 297                 }\r
 298                 else if(Team != o.team)\r
 299                 {\r
 300                         //print("(CHANGE) leave team ", ftos(o.team), "\n");\r
 301                         tm = GetTeam(o.team, false);\r
 302                         tm.team_size -= 1;\r
 303                         o.team = Team;\r
 304                         //print("(CHANGE) enter team ", ftos(o.team), "\n");\r
 305                         tm = GetTeam(Team, true);\r
 306                         tm.team_size += 1;\r
 307                         return TRUE;\r
 308                 }\r
 309         }\r
 310         return FALSE;\r
 311 }\r
 312 \r
 313 void Playerchecker_Think()\r
 314 {\r
 315         float i;\r
 316         entity e;\r
 317         for(i = 0; i < maxclients; ++i)\r
 318         {\r
 319                 e = playerslots[i];\r
 320                 if(GetPlayerName(i) == "")\r
 321                 {\r
 322                         if(e.sort_prev)\r
 323                         {\r
 324                                 //print("playerchecker: KILL KILL KILL\n");\r
 325                                 // player disconnected\r
 326                                 SetTeam(e, -1);\r
 327                                 RemovePlayer(e);\r
 328                                 e.sort_prev = world;\r
 329                                 //e.gotscores = 0;\r
 330                         }\r
 331                 }\r
 332                 else\r
 333                 {\r
 334                         if not(e.sort_prev)\r
 335                         {\r
 336                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");\r
 337                                 // player connected\r
 338                                 if not(e)\r
 339                                         playerslots[i] = e = spawn();\r
 340                                 e.sv_entnum = i;\r
 341                                 e.ping = 0;\r
 342                                 e.ping_packetloss = 0;\r
 343                                 e.ping_movementloss = 0;\r
 344                                 \r
 345                                 //e.gotscores = 0; // we might already have the scores...\r
 346                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with Sbar_UpdatePlayerTeams\r
 347                                 RegisterPlayer(e);\r
 348                                 Sbar_UpdatePlayerPos(e);\r
 349                         }\r
 350                 }\r
 351         }\r
 352         self.nextthink = time + 0.2;\r
 353 }\r
 354 \r
 355 void Porto_Init();\r
 356 void TrueAim_Init();\r
 357 void PostInit(void)\r
 358 {\r
 359         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));\r
 360         localcmd(strcat("\nsbar_columns_set ", cvar_string("sbar_columns"), ";\n"));\r
 361 \r
 362         entity playerchecker;\r
 363         playerchecker = spawn();\r
 364         playerchecker.think = Playerchecker_Think;\r
 365         playerchecker.nextthink = time + 0.2;\r
 366 \r
 367         Porto_Init();\r
 368         TrueAim_Init();\r
 369 \r
 370         postinit = true;\r
 371 }\r
 372 \r
 373 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function\r
 374 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.\r
 375 float button_zoom;\r
 376 void Cmd_Sbar_SetFields(float);\r
 377 void Cmd_Sbar_Help(float);\r
 378 float CSQC_ConsoleCommand(string strMessage)\r
 379 {\r
 380         float argc;\r
 381         // Tokenize String\r
 382         //argc = tokenize(strMessage);\r
 383         argc = tokenize_console(strMessage);\r
 384 \r
 385         // Acquire Command\r
 386         local string strCmd;\r
 387         strCmd = argv(0);\r
 388 \r
 389         if(strCmd == "+button4") { // zoom\r
 390                 // return false, because the message shall be sent to the server anyway (for demos/speccing)\r
 391                 if(ignore_plus_zoom)\r
 392                 {\r
 393                         --ignore_plus_zoom;\r
 394                         return false;\r
 395                 }\r
 396                 button_zoom = 1;\r
 397                 return true;\r
 398         } else if(strCmd == "-button4") { // zoom\r
 399                 if(ignore_minus_zoom)\r
 400                 {\r
 401                         --ignore_minus_zoom;\r
 402                         return false;\r
 403                 }\r
 404                 button_zoom = 0;\r
 405                 return true;\r
 406         } else if(strCmd == "+button3") { // secondary\r
 407                 button_attack2 = 1;\r
 408                 return false;\r
 409         } else if(strCmd == "-button3") { // secondary\r
 410                 button_attack2 = 0;\r
 411                 return false;\r
 412         } else if(strCmd == "+button6") { // secondary\r
 413                 button_jetpack = 1;\r
 414                 return false;\r
 415         } else if(strCmd == "-button6") { // secondary\r
 416                 button_jetpack = 0;\r
 417                 return false;\r
 418         } else if(strCmd == "+showscores") {\r
 419                 sb_showscores = true;\r
 420                 return true;\r
 421         } else if(strCmd == "-showscores") {\r
 422                 sb_showscores = false;\r
 423                 return true;\r
 424         } else if(strCmd == "+showaccuracy") {\r
 425                 sb_showaccuracy = true;\r
 426                 return true;\r
 427         } else if(strCmd == "-showaccuracy") {\r
 428                 sb_showaccuracy = false;\r
 429                 return true;\r
 430         }\r
 431 \r
 432         if(camera_active)\r
 433         if(strCmd == "+forward" || strCmd == "-back") {\r
 434                 ++camera_direction_x;\r
 435                 return true;\r
 436         } else if(strCmd == "-forward" || strCmd == "+back") {\r
 437                 --camera_direction_x;\r
 438                 return true;\r
 439         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {\r
 440                 --camera_direction_y;\r
 441                 return true;\r
 442         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {\r
 443                 ++camera_direction_y;\r
 444                 return true;\r
 445         } else if(strCmd == "+moveup" || strCmd == "-movedown") {\r
 446                 ++camera_direction_z;\r
 447                 return true;\r
 448         } else if(strCmd == "-moveup" || strCmd == "+movedown") {\r
 449                 --camera_direction_z;\r
 450                 return true;\r
 451         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {\r
 452                 ++camera_roll;\r
 453                 return true;\r
 454         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {\r
 455                 --camera_roll;\r
 456                 return true;\r
 457         }\r
 458 \r
 459         return false;\r
 460 }\r
 461 \r
 462 .vector view_ofs;\r
 463 entity debug_shotorg;\r
 464 void ShotOrg_Draw()\r
 465 {\r
 466         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;\r
 467         self.angles = view_angles;\r
 468         self.angles_x = -self.angles_x;\r
 469         if not(self.cnt)\r
 470                 R_AddEntity(self);\r
 471 }\r
 472 void ShotOrg_Draw2D()\r
 473 {\r
 474         vector coord2d_topleft, coord2d_topright, coord2d;\r
 475         string s;\r
 476         vector fs;\r
 477 \r
 478         s = vtos(self.view_ofs);\r
 479         s = substring(s, 1, strlen(s) - 2);\r
 480         if(tokenize_console(s) == 3)\r
 481                 s = strcat(argv(0), " ", argv(1), " ", argv(2));\r
 482 \r
 483         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);\r
 484         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);\r
 485 \r
 486         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));\r
 487 \r
 488         coord2d = coord2d_topleft;\r
 489         if(fs_x < 8)\r
 490         {\r
 491                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;\r
 492                 fs = '8 8 0';\r
 493         }\r
 494         coord2d_y -= fs_y;\r
 495         coord2d_z = 0;\r
 496         drawstring(coord2d, s, fs, '1 1 1', 1, 0);\r
 497 }\r
 498 \r
 499 void ShotOrg_Spawn()\r
 500 {\r
 501         debug_shotorg = spawn();\r
 502         debug_shotorg.draw = ShotOrg_Draw;\r
 503         debug_shotorg.draw2d = ShotOrg_Draw2D;\r
 504         debug_shotorg.renderflags = RF_VIEWMODEL;\r
 505         debug_shotorg.effects = EF_FULLBRIGHT;\r
 506         precache_model("models/shotorg_adjuster.md3");\r
 507         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");\r
 508         debug_shotorg.scale = 2;\r
 509         debug_shotorg.view_ofs = '25 8 -8';\r
 510 }\r
 511 \r
 512 void DrawDebugModel()\r
 513 {\r
 514         if(time - floor(time) > 0.5)\r
 515         {\r
 516                 PolyDrawModel(self);\r
 517         }\r
 518         else\r
 519         {\r
 520                 self.renderflags = 0;\r
 521                 R_AddEntity(self);\r
 522         }\r
 523 }\r
 524 \r
 525 void GameCommand(string msg)\r
 526 {\r
 527         string s;\r
 528         float argc;\r
 529         entity e;\r
 530         argc = tokenize_console(msg);\r
 531 \r
 532         if(argv(0) == "help" || argc == 0)\r
 533         {\r
 534                 print("Usage: cl_cmd COMMAND..., where possible commands are:\n");\r
 535                 print("  settemp cvar value\n");\r
 536                 print("  radar\n");\r
 537                 print("  sbar_columns_set ...\n");\r
 538                 print("  sbar_columns_help\n");\r
 539                 GameCommand_Generic("help");\r
 540                 return;\r
 541         }\r
 542 \r
 543         if(GameCommand_Generic(msg))\r
 544                 return;\r
 545 \r
 546         string cmd;\r
 547         cmd = argv(0);\r
 548         if(cmd == "mv_download") {\r
 549                 Cmd_MapVote_MapDownload(argc);\r
 550         }\r
 551         else if(cmd == "settemp") {\r
 552                 cvar_clientsettemp(argv(1), argv(2));\r
 553         }\r
 554         else if(cmd == "radar") {\r
 555                 showmap = !showmap;\r
 556         }\r
 557         else if(cmd == "sbar_columns_set") {\r
 558                 Cmd_Sbar_SetFields(argc);\r
 559         }\r
 560         else if(cmd == "sbar_columns_help") {\r
 561                 Cmd_Sbar_Help(argc);\r
 562         }\r
 563 #ifdef BLURTEST\r
 564         else if(cmd == "blurtest") {\r
 565                 blurtest_time0 = time;\r
 566                 blurtest_time1 = time + stof(argv(1));\r
 567                 blurtest_radius = stof(argv(2));\r
 568                 blurtest_power = stof(argv(3));\r
 569         }\r
 570 #endif\r
 571         else if(cmd == "shotorg_move") {\r
 572                 if(!debug_shotorg)\r
 573                         ShotOrg_Spawn();\r
 574                 else\r
 575                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));\r
 576                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");\r
 577         }\r
 578         else if(cmd == "shotorg_movez") {\r
 579                 if(!debug_shotorg)\r
 580                         ShotOrg_Spawn();\r
 581                 else\r
 582                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos\r
 583                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");\r
 584         }\r
 585         else if(cmd == "shotorg_set") {\r
 586                 if(!debug_shotorg)\r
 587                         ShotOrg_Spawn();\r
 588                 else\r
 589                         debug_shotorg.view_ofs = stov(argv(1));\r
 590                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");\r
 591         }\r
 592         else if(cmd == "shotorg_setz") {\r
 593                 if(!debug_shotorg)\r
 594                         ShotOrg_Spawn();\r
 595                 else\r
 596                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos\r
 597                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");\r
 598         }\r
 599         else if(cmd == "shotorg_toggle_hide") {\r
 600                 if(debug_shotorg)\r
 601                 {\r
 602                         debug_shotorg.cnt = !debug_shotorg.cnt;\r
 603                 }\r
 604         }\r
 605         else if(cmd == "shotorg_end") {\r
 606                 if(debug_shotorg)\r
 607                 {\r
 608                         print(vtos(debug_shotorg.view_ofs), "\n");\r
 609                         remove(debug_shotorg);\r
 610                         debug_shotorg = world;\r
 611                 }\r
 612                 localcmd("sv_cmd debug_shotorg\n");\r
 613         }\r
 614         else if(cmd == "sendcvar") {\r
 615                 s = cvar_string(argv(1));\r
 616                 if(argv(1) == "cl_weaponpriority")\r
 617                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);\r
 618                 else if(substring(argv(1), 0, 17) == "cl_weaponpriority" && strlen(argv(1)) == 18)\r
 619                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);\r
 620                 localcmd("cmd sentcvar ", argv(1), " \"", s, "\"\n");\r
 621         }\r
 622         else if(cmd == "spawn") {\r
 623                 s = argv(1);\r
 624                 e = spawn();\r
 625                 precache_model(s);\r
 626                 setmodel(e, s);\r
 627                 setorigin(e, view_origin);\r
 628                 e.angles = view_angles;\r
 629                 e.draw = DrawDebugModel;\r
 630                 e.classname = "debugmodel";\r
 631         }\r
 632         else\r
 633         {\r
 634                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");\r
 635         }\r
 636 \r
 637         return;\r
 638 }\r
 639 \r
 640 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.\r
 641 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.\r
 642 // All keys are in ascii.\r
 643 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.\r
 644 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.\r
 645 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.\r
 646 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)\r
 647 {\r
 648         local float bSkipKey;\r
 649         bSkipKey = false;\r
 650 \r
 651         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))\r
 652                 return true;\r
 653 \r
 654         if(menu_visible)\r
 655                 if(menu_action(bInputType, nPrimary, nSecondary))\r
 656                         return TRUE;\r
 657         return bSkipKey;\r
 658 }\r
 659 \r
 660 // END REQUIRED CSQC FUNCTIONS\r
 661 // --------------------------------------------------------------------------\r
 662 \r
 663 // --------------------------------------------------------------------------\r
 664 // BEGIN OPTIONAL CSQC FUNCTIONS\r
 665 void Ent_RemoveEntCS()\r
 666 {\r
 667         entcs_receiver[self.sv_entnum] = world;\r
 668 }\r
 669 void Ent_ReadEntCS()\r
 670 {\r
 671         float sf;\r
 672         InterpolateOrigin_Undo();\r
 673 \r
 674         self.classname = "entcs_receiver";\r
 675         sf = ReadByte();\r
 676 \r
 677         if(sf & 1)\r
 678                 self.sv_entnum = ReadByte();\r
 679         if(sf & 2)\r
 680         {\r
 681                 self.origin_x = ReadShort();\r
 682                 self.origin_y = ReadShort();\r
 683                 self.origin_z = ReadShort();\r
 684         }\r
 685         if(sf & 4)\r
 686         {\r
 687                 self.angles_y = ReadByte() * 360.0 / 256;\r
 688                 self.angles_x = self.angles_z = 0;\r
 689         }\r
 690         if(sf & 8)\r
 691                 self.healthvalue = ReadShort();\r
 692         if(sf & 16)\r
 693                 self.armorvalue = ReadShort();\r
 694         if(sf & 32)\r
 695                 self.eaten = ReadByte();\r
 696 \r
 697         entcs_receiver[self.sv_entnum] = self;\r
 698         self.entremove = Ent_RemoveEntCS;\r
 699 \r
 700         InterpolateOrigin_Note();\r
 701 }\r
 702 \r
 703 void Ent_Remove();\r
 704 \r
 705 void Ent_RemovePlayerScore()\r
 706 {\r
 707         float i;\r
 708 \r
 709         if(self.owner)\r
 710         {\r
 711                 SetTeam(self.owner, -1);\r
 712                 self.owner.gotscores = 0;\r
 713                 for(i = 0; i < MAX_SCORE; ++i)\r
 714                         self.owner.(scores[i]) = 0; // clear all scores\r
 715         }\r
 716 }\r
 717 \r
 718 void Ent_ReadPlayerScore()\r
 719 {\r
 720         float i, n;\r
 721         float isNew;\r
 722         entity o;\r
 723 \r
 724         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN\r
 725         // (no I've never heard of M-x replace-string, sed, or anything like that)\r
 726         isNew = !self.owner; // workaround for DP bug\r
 727         n = ReadByte()-1;\r
 728 \r
 729 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 730         if(!isNew && n != self.sv_entnum)\r
 731         {\r
 732                 print("A CSQC entity changed its owner!\n");\r
 733                 isNew = true;\r
 734                 Ent_Remove();\r
 735                 self.enttype = ENT_CLIENT_SCORES;\r
 736         }\r
 737 #endif\r
 738 \r
 739         self.sv_entnum = n;\r
 740 \r
 741         if not(playerslots[self.sv_entnum])\r
 742                 playerslots[self.sv_entnum] = spawn();\r
 743         o = self.owner = playerslots[self.sv_entnum];\r
 744         o.sv_entnum = self.sv_entnum;\r
 745         o.gotscores = 1;\r
 746 \r
 747         //if not(o.sort_prev)\r
 748         //      RegisterPlayer(o);\r
 749         //playerchecker will do this for us later, if it has not already done so\r
 750 \r
 751         float sf, lf;\r
 752 #if MAX_SCORE <= 8\r
 753         sf = ReadByte();\r
 754         lf = ReadByte();\r
 755 #else\r
 756         sf = ReadShort();\r
 757         lf = ReadShort();\r
 758 #endif\r
 759         float p;\r
 760         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)\r
 761                 if(sf & p)\r
 762                 {\r
 763                         if(lf & p)\r
 764                                 o.(scores[i]) = ReadInt24_t();\r
 765                         else\r
 766                                 o.(scores[i]) = ReadChar();\r
 767                 }\r
 768 \r
 769         if(o.sort_prev)\r
 770                 Sbar_UpdatePlayerPos(o); // if not registered, we cannot do this yet!\r
 771 \r
 772         self.entremove = Ent_RemovePlayerScore;\r
 773 }\r
 774 \r
 775 void Ent_ReadTeamScore()\r
 776 {\r
 777         float i;\r
 778         entity o;\r
 779 \r
 780         self.team = ReadByte();\r
 781         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted\r
 782 \r
 783         float sf, lf;\r
 784 #if MAX_TEAMSCORE <= 8\r
 785         sf = ReadByte();\r
 786         lf = ReadByte();\r
 787 #else\r
 788         sf = ReadShort();\r
 789         lf = ReadShort();\r
 790 #endif\r
 791         float p;\r
 792         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)\r
 793                 if(sf & p)\r
 794                 {\r
 795                         if(lf & p)\r
 796                                 o.(teamscores[i]) = ReadInt24_t();\r
 797                         else\r
 798                                 o.(teamscores[i]) = ReadChar();\r
 799                 }\r
 800 \r
 801         Sbar_UpdateTeamPos(o);\r
 802 }\r
 803 \r
 804 void Net_Reset()\r
 805 {\r
 806 }\r
 807 \r
 808 void Ent_ClientData()\r
 809 {\r
 810         float f;\r
 811         float newspectatee_status;\r
 812 \r
 813         f = ReadByte();\r
 814 \r
 815         sb_showscores_force = (f & 1);\r
 816 \r
 817         if(f & 2)\r
 818         {\r
 819                 newspectatee_status = ReadByte();\r
 820                 if(newspectatee_status == player_localentnum)\r
 821                         newspectatee_status = -1; // observing\r
 822         }\r
 823         else\r
 824                 newspectatee_status = 0;\r
 825 \r
 826         spectatorbutton_zoom = (f & 4);\r
 827 \r
 828         if(f & 8)\r
 829         {\r
 830                 angles_held_status = 1;\r
 831                 angles_held_x = ReadAngle();\r
 832                 angles_held_y = ReadAngle();\r
 833                 angles_held_z = 0;\r
 834         }\r
 835         else\r
 836                 angles_held_status = 0;\r
 837 \r
 838         if(newspectatee_status != spectatee_status)\r
 839         {\r
 840                 float i;\r
 841                 // clear the weapon accuracy stats\r
 842                 for(i = WEP_FIRST; i <= WEP_LAST; ++i) {\r
 843                         weapon_hits[i] = 0;\r
 844                         weapon_fired[i] = 0;\r
 845                 }\r
 846 \r
 847                 // clear race stuff\r
 848                 race_laptime = 0;\r
 849                 race_checkpointtime = 0;\r
 850         }\r
 851         spectatee_status = newspectatee_status;\r
 852 }\r
 853 \r
 854 void Ent_Nagger()\r
 855 {\r
 856         float nags, i, j, b, f;\r
 857 \r
 858         nags = ReadByte();\r
 859 \r
 860         if(nags & 128)\r
 861         {\r
 862                 if(vote_called_vote)\r
 863                         strunzone(vote_called_vote);\r
 864                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));\r
 865         }\r
 866 \r
 867         if(nags & 1)\r
 868         {\r
 869                 for(j = 0; j < maxclients; ++j)\r
 870                         if(playerslots[j])\r
 871                                 playerslots[j].ready = 1;\r
 872                 for(i = 1; i <= maxclients; i += 8)\r
 873                 {\r
 874                         f = ReadByte();\r
 875                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)\r
 876                                 if not(f & b)\r
 877                                         if(playerslots[j])\r
 878                                                 playerslots[j].ready = 0;\r
 879                 }\r
 880         }\r
 881 \r
 882         ready_waiting = (nags & 1);\r
 883         ready_waiting_for_me = (nags & 2);\r
 884         vote_waiting = (nags & 4);\r
 885         vote_waiting_for_me = (nags & 8);\r
 886         warmup_stage = (nags & 16);\r
 887 }\r
 888 \r
 889 void Ent_RandomSeed()\r
 890 {\r
 891         float s;\r
 892         prandom_debug();\r
 893         s = ReadShort();\r
 894         psrandom(s);\r
 895 }\r
 896 \r
 897 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.\r
 898 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.\r
 899 void Ent_RadarLink();\r
 900 void Ent_Init();\r
 901 void Ent_ScoresInfo();\r
 902 void(float bIsNewEntity) CSQC_Ent_Update =\r
 903 {\r
 904         float t;\r
 905         float savetime;\r
 906         t = ReadByte();\r
 907 \r
 908         // set up the "time" global for received entities to be correct for interpolation purposes\r
 909         savetime = time;\r
 910         if(servertime)\r
 911         {\r
 912                 time = servertime;\r
 913         }\r
 914         else\r
 915         {\r
 916                 serverprevtime = time;\r
 917                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);\r
 918                 time = serverprevtime + serverdeltatime;\r
 919         }\r
 920 \r
 921 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 922         if(self.enttype)\r
 923                 if(t != self.enttype)\r
 924                 {\r
 925                         print("A CSQC entity changed its type!\n");\r
 926                         Ent_Remove();\r
 927                         bIsNewEntity = 1;\r
 928                 }\r
 929 #endif\r
 930         self.enttype = t;\r
 931         switch(t)\r
 932         {\r
 933                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;\r
 934                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;\r
 935                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;\r
 936                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;\r
 937                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;\r
 938                 case ENT_CLIENT_LASER: Ent_Laser(); break;\r
 939                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;\r
 940                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;\r
 941                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;\r
 942                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;\r
 943                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;\r
 944                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;\r
 945                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;\r
 946                 case ENT_CLIENT_INIT: Ent_Init(); break;\r
 947                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;\r
 948                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;\r
 949                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;\r
 950                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;\r
 951                 case ENT_CLIENT_WALL: Ent_Wall(); break;\r
 952                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;\r
 953                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;\r
 954                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;\r
 955                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;\r
 956                 case ENT_CLIENT_PORTRAIT: Ent_ReadPortrait(); break;\r
 957                 default:\r
 958                         error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));\r
 959                         break;\r
 960         }\r
 961 \r
 962         time = savetime;\r
 963 };\r
 964 // Destructor, but does NOT deallocate the entity by calling remove(). Also\r
 965 // used when an entity changes its type. For an entity that someone interacts\r
 966 // with others, make sure it can no longer do so.\r
 967 void Ent_Remove()\r
 968 {\r
 969         if(self.entremove)\r
 970                 self.entremove();\r
 971 \r
 972         self.enttype = 0;\r
 973         self.classname = "";\r
 974         self.draw = menu_sub_null_void;\r
 975         self.entremove = menu_sub_null_void;\r
 976         // TODO possibly set more stuff to defaults\r
 977 }\r
 978 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.\r
 979 void CSQC_Ent_Remove()\r
 980 {\r
 981         if(self.enttype)\r
 982                 Ent_Remove();\r
 983         remove(self);\r
 984 }\r
 985 \r
 986 void Gamemode_Init()\r
 987 {\r
 988         if(gametype == GAME_ONSLAUGHT)\r
 989                 print(strcat("Using ", minimapname, " as minimap.\n"));\r
 990 \r
 991         if not(isdemo())\r
 992         {\r
 993                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), ";");\r
 994                 if(g_campaign)\r
 995                         localcmd("\n_cl_hook_campaign_gamestart ", GametypeNameFromType(gametype), ";");\r
 996                 calledhooks |= HOOK_START;\r
 997         }\r
 998 }\r
 999 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.\r
1000 void CSQC_Parse_StuffCmd(string strMessage)\r
1001 {\r
1002         localcmd(strMessage);\r
1003 }\r
1004 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.\r
1005 void CSQC_Parse_Print(string strMessage)\r
1006 {\r
1007         print(ColorTranslateRGB(strMessage));\r
1008 }\r
1009 \r
1010 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.\r
1011 void CSQC_Parse_CenterPrint(string strMessage)\r
1012 {\r
1013         centerprint(strMessage);\r
1014 }\r
1015 \r
1016 string notranslate_fogcmd1 = "\nfog ";\r
1017 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";\r
1018 void Fog_Force()\r
1019 {\r
1020         // TODO somehow thwart prvm_globalset client ...\r
1021 \r
1022         if(forcefog != "")\r
1023                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));\r
1024 }\r
1025 \r
1026 void Gamemode_Init();\r
1027 void Ent_ScoresInfo()\r
1028 {\r
1029         float i;\r
1030         self.classname = "ent_client_scores_info";\r
1031         gametype = ReadByte();\r
1032         for(i = 0; i < MAX_SCORE; ++i)\r
1033         {\r
1034                 scores_label[i] = strzone(ReadString());\r
1035                 scores_flags[i] = ReadByte();\r
1036         }\r
1037         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
1038         {\r
1039                 teamscores_label[i] = strzone(ReadString());\r
1040                 teamscores_flags[i] = ReadByte();\r
1041         }\r
1042         Sbar_InitScores();\r
1043         Gamemode_Init();\r
1044 }\r
1045 \r
1046 void Ent_Init()\r
1047 {\r
1048         self.classname = "ent_client_init";\r
1049 \r
1050         grabber_shotorigin_x = ReadCoord();\r
1051         grabber_shotorigin_y = ReadCoord();\r
1052         grabber_shotorigin_z = ReadCoord();\r
1053 \r
1054         if(forcefog)\r
1055                 strunzone(forcefog);\r
1056         forcefog = strzone(ReadString());\r
1057 \r
1058         g_campaign = ReadShort();\r
1059 \r
1060         armorblockpercent = ReadByte() / 255.0;\r
1061 \r
1062         g_weaponswitchdelay = ReadByte() / 255.0;\r
1063 \r
1064         g_vore = ReadShort();\r
1065         g_healthsize_center = ReadShort();\r
1066         g_healthsize_min = ReadShort();\r
1067         g_healthsize_max = ReadShort();\r
1068 \r
1069         armor_max = ReadCoord();\r
1070         teamheal_max = ReadCoord();\r
1071 \r
1072         g_power = ReadShort();\r
1073         g_power_reboot = ReadShort();\r
1074         g_power_reboot_spawn = ReadByte();\r
1075 \r
1076         if(!postinit)\r
1077                 PostInit();\r
1078 }\r
1079 \r
1080 void Net_ReadRace()\r
1081 {\r
1082         float b;\r
1083 \r
1084         b = ReadByte();\r
1085 \r
1086         switch(b)\r
1087         {\r
1088                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:\r
1089                         race_checkpoint = ReadByte();\r
1090                         race_time = ReadInt24_t();\r
1091                         race_previousbesttime = ReadInt24_t();\r
1092                         if(race_previousbestname)\r
1093                                 strunzone(race_previousbestname);\r
1094                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));\r
1095 \r
1096                         race_checkpointtime = time;\r
1097 \r
1098                         if(race_checkpoint == 0 || race_checkpoint == 254)\r
1099                         {\r
1100                                 race_penaltyaccumulator = 0;\r
1101                                 race_laptime = time; // valid\r
1102                         }\r
1103 \r
1104                         break;\r
1105 \r
1106                 case RACE_NET_CHECKPOINT_CLEAR:\r
1107                         race_laptime = 0;\r
1108                         race_checkpointtime = 0;\r
1109                         break;\r
1110 \r
1111                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:\r
1112                         race_laptime = ReadCoord();\r
1113                         race_checkpointtime = -99999;\r
1114                         // fall through\r
1115                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:\r
1116                         race_nextcheckpoint = ReadByte();\r
1117 \r
1118                         race_nextbesttime = ReadInt24_t();\r
1119                         if(race_nextbestname)\r
1120                                 strunzone(race_nextbestname);\r
1121                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));\r
1122                         break;\r
1123 \r
1124                 case RACE_NET_CHECKPOINT_HIT_RACE:\r
1125                         race_mycheckpoint = ReadByte();\r
1126                         race_mycheckpointtime = time;\r
1127                         race_mycheckpointdelta = ReadInt24_t();\r
1128                         race_mycheckpointlapsdelta = ReadByte();\r
1129                         if(race_mycheckpointlapsdelta >= 128)\r
1130                                 race_mycheckpointlapsdelta -= 256;\r
1131                         if(race_mycheckpointenemy)\r
1132                                 strunzone(race_mycheckpointenemy);\r
1133                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));\r
1134                         break;\r
1135 \r
1136                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:\r
1137                         race_othercheckpoint = ReadByte();\r
1138                         race_othercheckpointtime = time;\r
1139                         race_othercheckpointdelta = ReadInt24_t();\r
1140                         race_othercheckpointlapsdelta = ReadByte();\r
1141                         if(race_othercheckpointlapsdelta >= 128)\r
1142                                 race_othercheckpointlapsdelta -= 256;\r
1143                         if(race_othercheckpointenemy)\r
1144                                 strunzone(race_othercheckpointenemy);\r
1145                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));\r
1146                         break;\r
1147 \r
1148                 case RACE_NET_PENALTY_RACE:\r
1149                         race_penaltyeventtime = time;\r
1150                         race_penaltytime = ReadShort();\r
1151                         //race_penaltyaccumulator += race_penaltytime;\r
1152                         if(race_penaltyreason)\r
1153                                 strunzone(race_penaltyreason);\r
1154                         race_penaltyreason = strzone(ReadString());\r
1155                         break;\r
1156 \r
1157                 case RACE_NET_PENALTY_QUALIFYING:\r
1158                         race_penaltyeventtime = time;\r
1159                         race_penaltytime = ReadShort();\r
1160                         race_penaltyaccumulator += race_penaltytime;\r
1161                         if(race_penaltyreason)\r
1162                                 strunzone(race_penaltyreason);\r
1163                         race_penaltyreason = strzone(ReadString());\r
1164                         break;\r
1165 \r
1166                 case RACE_NET_SERVER_RECORD:\r
1167                         race_server_record = ReadInt24_t();\r
1168                         break;\r
1169                 case RACE_NET_SPEED_AWARD:\r
1170                         race_speedaward = ReadInt24_t();\r
1171                         if(race_speedaward_holder)\r
1172                                 strunzone(race_speedaward_holder);\r
1173                         race_speedaward_holder = strzone(ReadString());\r
1174                         break;\r
1175                 case RACE_NET_SPEED_AWARD_BEST:\r
1176                         race_speedaward_alltimebest = ReadInt24_t();\r
1177                         if(race_speedaward_alltimebest_holder)\r
1178                                 strunzone(race_speedaward_alltimebest_holder);\r
1179                         race_speedaward_alltimebest_holder = strzone(ReadString());\r
1180                         break;\r
1181                 case RACE_NET_SERVER_RANKINGS:\r
1182                         float pos, prevpos, del;\r
1183                         pos = ReadShort();\r
1184                         prevpos = ReadShort();\r
1185                         del = ReadShort();\r
1186 \r
1187                         // move other rankings out of the way\r
1188                         float i;\r
1189                         if (prevpos) {\r
1190                                 for (i=prevpos-1;i>pos-1;--i) {\r
1191                                         grecordtime[i] = grecordtime[i-1];\r
1192                                         if(grecordholder[i])\r
1193                                                 strunzone(grecordholder[i]);\r
1194                                         grecordholder[i] = strzone(grecordholder[i-1]);\r
1195                                 }\r
1196                         } else if (del) { // a record has been deleted by the admin\r
1197                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {\r
1198                                         if (i == RANKINGS_CNT-1) { // clear out last record\r
1199                                                 grecordtime[i] = 0;\r
1200                                                 if (grecordholder[i])\r
1201                                                         strunzone(grecordholder[i]);\r
1202                                                 grecordholder[i] = string_null;\r
1203                                         }\r
1204                                         else {\r
1205                                                 grecordtime[i] = grecordtime[i+1];\r
1206                                                 if (grecordholder[i])\r
1207                                                         strunzone(grecordholder[i]);\r
1208                                                 grecordholder[i] = strzone(grecordholder[i+1]);\r
1209                                         }\r
1210                                 }\r
1211                         } else { // player has no ranked record yet\r
1212                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {\r
1213                                         grecordtime[i] = grecordtime[i-1];\r
1214                                         if(grecordholder[i])\r
1215                                                 strunzone(grecordholder[i]);\r
1216                                         grecordholder[i] = strzone(grecordholder[i-1]);\r
1217                                 }\r
1218                         }\r
1219 \r
1220                         // store new ranking\r
1221                         if(grecordholder[pos-1] != "")\r
1222                                 strunzone(grecordholder[pos-1]);\r
1223                         grecordholder[pos-1] = strzone(ReadString());\r
1224                         grecordtime[pos-1] = ReadInt24_t();\r
1225                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))\r
1226                                 race_myrank = pos;\r
1227                         break;\r
1228                 case RACE_NET_SERVER_STATUS:\r
1229                         race_status = ReadShort();\r
1230                         if(race_status_name)\r
1231                                 strunzone(race_status_name);\r
1232                         race_status_name = strzone(ReadString());\r
1233         }\r
1234 }\r
1235 \r
1236 void Net_ReadSpawn()\r
1237 {\r
1238         zoomin_effect = 1;\r
1239         current_viewzoom = 0.6;\r
1240 }\r
1241 \r
1242 void Net_TeamNagger()\r
1243 {\r
1244         teamnagger = 1;\r
1245 }\r
1246 \r
1247 void Net_ReadPingPLReport()\r
1248 {\r
1249         float e, pi, pl, ml;\r
1250         e = ReadByte();\r
1251         pi = ReadShort();\r
1252         pl = ReadByte();\r
1253         ml = ReadByte();\r
1254         if not(playerslots[e])\r
1255                 return;\r
1256         playerslots[e].ping = pi;\r
1257         playerslots[e].ping_packetloss = pl / 255.0;\r
1258         playerslots[e].ping_movementloss = ml / 255.0;\r
1259 }\r
1260 \r
1261 void Net_ReadOtherPLReport()\r
1262 {\r
1263         float e, ph, pn;\r
1264         e = ReadByte();\r
1265         ph = ReadShort(); // not ReadByte because we show minus health too\r
1266         pn = ReadByte();\r
1267         if not(playerslots[e])\r
1268                 return;\r
1269         playerslots[e].plhealth = ph;\r
1270         playerslots[e].plpredator = pn;\r
1271 }\r
1272 \r
1273 void Net_VoteDialog(float highlight) {\r
1274         if(highlight) {\r
1275                 vote_highlighted = ReadShort();\r
1276                 return;\r
1277         }\r
1278 \r
1279         vote_yescount = ReadShort();\r
1280         vote_nocount = ReadShort();\r
1281         vote_needed = ReadShort();\r
1282         vote_active = 1;\r
1283 }\r
1284 \r
1285 void Net_VoteDialogReset() {\r
1286         vote_active = 0;\r
1287 }\r
1288 \r
1289 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.\r
1290 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.\r
1291 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.\r
1292 float CSQC_Parse_TempEntity()\r
1293 {\r
1294         local float bHandled;\r
1295                 bHandled  = true;\r
1296         // Acquire TE ID\r
1297         local float nTEID;\r
1298                 nTEID = ReadByte();\r
1299 \r
1300                 // NOTE: Could just do return instead of break...\r
1301         switch(nTEID)\r
1302         {\r
1303                 case TE_CSQC_TARGET_MUSIC:\r
1304                         Net_TargetMusic();\r
1305                         bHandled = true;\r
1306                         break;\r
1307                 case TE_CSQC_PICTURE:\r
1308                         Net_MapVote_Picture();\r
1309                         bHandled = true;\r
1310                         break;\r
1311                 case TE_CSQC_RACE:\r
1312                         Net_ReadRace();\r
1313                         bHandled = true;\r
1314                         break;\r
1315                 case 13: // TE_BEAM\r
1316                         Net_Grabber();\r
1317                         bHandled = true;\r
1318                         break;\r
1319                 case TE_CSQC_SPAWN:\r
1320                         Net_ReadSpawn();\r
1321                         bHandled = true;\r
1322                         break;\r
1323                 case TE_CSQC_ZCURVEPARTICLES:\r
1324                         Net_ReadZCurveParticles();\r
1325                         bHandled = true;\r
1326                         break;\r
1327                 case TE_CSQC_TEAMNAGGER:\r
1328                         Net_TeamNagger();\r
1329                         bHandled = true;\r
1330                         break;\r
1331                 case TE_CSQC_VOTE:\r
1332                         Net_VoteDialog(ReadByte());\r
1333                         bHandled = true;\r
1334                         break;\r
1335                 case TE_CSQC_VOTERESET:\r
1336                         Net_VoteDialogReset();\r
1337                         bHandled = true;\r
1338                         break;\r
1339                 case TE_CSQC_LIGHTNINGARC:\r
1340                         Net_ReadLightningarc();\r
1341                         bHandled = true;\r
1342                         break;\r
1343                 case TE_CSQC_PINGPLREPORT:\r
1344                         Net_ReadPingPLReport();\r
1345                         bHandled = true;\r
1346                         break;\r
1347                 case TE_CSQC_OTHERPLREPORT:\r
1348                         Net_ReadOtherPLReport();\r
1349                         bHandled = true;\r
1350                         break;\r
1351                 case TE_CSQC_ANNOUNCE:\r
1352                         announce_snd = strzone(ReadString());\r
1353                         bHandled = true;\r
1354                         break;\r
1355                 default:\r
1356                         // No special logic for this temporary entity; return 0 so the engine can handle it\r
1357                         bHandled = false;\r
1358                         break;\r
1359         }\r
1360 \r
1361         return bHandled;\r
1362 }\r
1363 \r
1364 string getcommandkey(string text, string command)\r
1365 {\r
1366         string keys;\r
1367         float n, j, k, l;\r
1368 \r
1369         if (!sbar_showbinds)\r
1370                 return text;\r
1371 \r
1372         keys = db_get(binddb, command);\r
1373         if (!keys)\r
1374         {\r
1375                 n = tokenize(findkeysforcommand(command)); // uses '...' strings\r
1376                 for(j = 0; j < n; ++j)\r
1377                 {\r
1378                         k = stof(argv(j));\r
1379                         if(k != -1)\r
1380                         {\r
1381                                 if ("" == keys)\r
1382                                         keys = keynumtostring(k);\r
1383                                 else\r
1384                                         keys = strcat(keys, ", ", keynumtostring(k));\r
1385 \r
1386                                 ++l;\r
1387                                 if (sbar_showbinds_limit > 0 && sbar_showbinds_limit >= l) break;\r
1388                         }\r
1389 \r
1390                 }\r
1391                 db_put(binddb, command, keys);\r
1392         }\r
1393 \r
1394         if ("" == keys) {\r
1395                 if (sbar_showbinds > 1)\r
1396                         return strcat(text, " (not bound)");\r
1397                 else\r
1398                         return text;\r
1399         }\r
1400         else if (sbar_showbinds > 1)\r
1401                 return strcat(text, " (", keys, ")");\r
1402         else\r
1403                 return keys;\r
1404 }\r