data/qcsrc/client/mapvoting.qc

   1 float mv_num_maps;\r
   2 \r
   3 float mv_active;\r
   4 string mv_maps[MAPVOTE_COUNT];\r
   5 string mv_pics[MAPVOTE_COUNT];\r
   6 string mv_pk3[MAPVOTE_COUNT];\r
   7 float mv_preview[MAPVOTE_COUNT];\r
   8 float mv_votes[MAPVOTE_COUNT];\r
   9 entity mv_pk3list;\r
  10 float mv_abstain;\r
  11 float mv_ownvote;\r
  12 float mv_detail;\r
  13 float mv_timeout;\r
  14 float mv_maps_mask;\r
  15 \r
  16 vector mv_mousepos;\r
  17 float mv_selection;\r
  18 \r
  19 string MapVote_FormatMapItem(float id, string map, float count, float maxwidth, vector fontsize)\r
  20 {\r
  21         string pre, post;\r
  22         pre = strcat(ftos(id+1), ". ");\r
  23         if(mv_detail)\r
  24         {\r
  25                 if(count == 1)\r
  26                         post = strcat(" (1 vote)");\r
  27                 else\r
  28                         post = strcat(" (", ftos(count), " votes)");\r
  29         }\r
  30         else\r
  31                 post = "";\r
  32         maxwidth -= stringwidth(pre, FALSE, fontsize) + stringwidth(post, FALSE, fontsize);\r
  33         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);\r
  34         return strcat(pre, map, post);\r
  35 }\r
  36 \r
  37 vector MapVote_RGB(float id)\r
  38 {\r
  39         if(id == mv_ownvote)\r
  40                 return '0 1 0';\r
  41         else if (id == mv_selection)\r
  42                 return '1 1 0';\r
  43         else\r
  44                 return '1 1 1';\r
  45 }\r
  46 \r
  47 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float count, float id)\r
  48 {\r
  49         vector img_size;\r
  50         vector rgb;\r
  51         string label;\r
  52         float text_size;\r
  53         \r
  54         isize -= sbar_fontsize_y; // respect the text when calculating the image size\r
  55 \r
  56         rgb = MapVote_RGB(id);\r
  57         \r
  58         img_size_y = isize;\r
  59         img_size_x = isize / 0.75; // 4:3 x can be stretched easily, height is defined in isize\r
  60 \r
  61         drawfont = sbar_font;\r
  62         pos_y = pos_y + img_size_y;\r
  63         \r
  64         label = MapVote_FormatMapItem(id, map, count, tsize, sbar_fontsize);\r
  65 \r
  66         text_size = stringwidth(label, false, sbar_fontsize);\r
  67         \r
  68         pos_x -= text_size*0.5;\r
  69         drawstring(pos, label, sbar_fontsize, rgb, 1, DRAWFLAG_NORMAL);\r
  70         \r
  71         pos_x = pos_x + text_size*0.5 - img_size_x*0.5;\r
  72         pos_y = pos_y - img_size_y;\r
  73 \r
  74         pos += sbar_border_thickness * '1 1 0';\r
  75         img_size -= (sbar_border_thickness * 2) * '1 1 0';\r
  76         if(pic == "")\r
  77         {\r
  78                 drawfill(pos, img_size, '.5 .5 .5', .7, DRAWFLAG_NORMAL);\r
  79         }\r
  80         else\r
  81         {\r
  82                 drawpic(pos, pic, img_size, '1 1 1', 1, DRAWFLAG_NORMAL);\r
  83         }\r
  84         \r
  85         drawstring(pos + '2 0 0', ftos(id+1), (img_size_y / 5) * '1 1 0', '1 1 1', 0.6, DRAWFLAG_NORMAL);\r
  86 \r
  87         if(id == mv_ownvote || pic == "")\r
  88         {\r
  89                 drawborderlines(sbar_border_thickness, pos, img_size, rgb, 1, DRAWFLAG_NORMAL);\r
  90                 drawstring(pos + '2 0 0', ftos(id+1), (img_size_y / 5) * '1 1 0', rgb, 0.6, DRAWFLAG_NORMAL);\r
  91         }\r
  92         else\r
  93         {\r
  94                 drawborderlines(sbar_border_thickness, pos, img_size, '0 0 0', 1, DRAWFLAG_NORMAL);\r
  95                 drawstring(pos + '2 0 0', ftos(id+1), (img_size_y / 5) * '1 1 0', '1 1 1', 0.6, DRAWFLAG_NORMAL);\r
  96         }\r
  97 }\r
  98 \r
  99 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float count, float id)\r
 100 {\r
 101         vector rgb;\r
 102         float text_size;\r
 103         string label;\r
 104         \r
 105         rgb = MapVote_RGB(id);\r
 106 \r
 107         drawfont = sbar_font;\r
 108         pos_y = pos_y + sbar_fontsize_y;\r
 109         \r
 110         label = MapVote_FormatMapItem(id, "Don't care", count, tsize, sbar_fontsize);\r
 111 \r
 112         text_size = stringwidth(label, false, sbar_fontsize);\r
 113         \r
 114         pos_x -= text_size*0.5;\r
 115         drawstring(pos, label, sbar_fontsize, rgb, 1, DRAWFLAG_NORMAL);\r
 116 }\r
 117 \r
 118 vector MapVote_GridVec(vector gridspec, float i, float m)\r
 119 {\r
 120         float r;\r
 121         r = mod(i, m);\r
 122         return\r
 123                 '1 0 0' * (gridspec_x * r)\r
 124                 +\r
 125                 '0 1 0' * (gridspec_y * (i - r) / m);\r
 126 }\r
 127 \r
 128 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)\r
 129 {\r
 130         float cell;\r
 131         float c, r;\r
 132 \r
 133         cell = -1;\r
 134 \r
 135         for (r = 0; r < rows; ++r)\r
 136                 for (c = 0; c < columns; ++c)\r
 137                 {\r
 138                         if (mv_mousepos_x >= topleft_x + cellsize_x *  c &&\r
 139                                 mv_mousepos_x <= topleft_x + cellsize_x * (c + 1) &&\r
 140                                 mv_mousepos_y >= topleft_y + cellsize_y *  r &&\r
 141                                 mv_mousepos_y <= topleft_y + cellsize_y * (r + 1))\r
 142                         {\r
 143                                 cell = r * columns + c;\r
 144                                 break;\r
 145                         }\r
 146                 }\r
 147 \r
 148         if (cell >= mv_num_maps)\r
 149                 cell = -1;\r
 150 \r
 151         if (mv_abstain && cell < 0)\r
 152                 return mv_num_maps;\r
 153 \r
 154         return cell;\r
 155 }\r
 156 \r
 157 void MapVote_Draw()\r
 158 {\r
 159         string map;\r
 160         float i, tmp;\r
 161         vector pos;\r
 162         float isize;\r
 163         float center;\r
 164         float columns, rows;\r
 165         float tsize;\r
 166         vector dist;\r
 167 \r
 168         if(!mv_active)\r
 169                 return;\r
 170         \r
 171         mv_mousepos = mv_mousepos + getmousepos();\r
 172 \r
 173         mv_mousepos_x = bound(0, mv_mousepos_x, vid_conwidth);\r
 174         mv_mousepos_y = bound(0, mv_mousepos_y, vid_conheight);\r
 175 \r
 176         center = (vid_conwidth - 1)/2;\r
 177         xmin = vid_conwidth*0.05; // 5% border must suffice\r
 178         xmax = vid_conwidth - xmin;\r
 179         ymin = 20;\r
 180         i = cvar("con_chatpos"); //*cvar("con_chatsize");\r
 181         if(i < 0)\r
 182                 ymax = vid_conheight + (i - cvar("con_chat")) * cvar("con_chatsize");\r
 183         if(i >= 0 || ymax < (vid_conheight*0.5))\r
 184                 ymax = vid_conheight - ymin;\r
 185 \r
 186         drawfont = sbar_bigfont;\r
 187         sbar_fontsize = Sbar_GetFontsize("sbar_fontsize");\r
 188 \r
 189         pos_y = ymin;\r
 190         pos_z = 0;\r
 191         //pos_x = center - stringwidth("Vote for a map", false) * 0.5 * 24;\r
 192         pos_x = center - stringwidth("Vote for a map", false, '12 0 0');\r
 193         drawstring(pos, "Vote for a map", '24 24 0', '1 1 1', 1, DRAWFLAG_NORMAL);\r
 194         pos_y += 26;\r
 195 \r
 196         i = ceil(max(0, mv_timeout - time));\r
 197         map = strcat(ftos(i), " seconds left");\r
 198         //pos_x = center - stringwidth(map, false) * 0.5 * 16;\r
 199         pos_x = center - stringwidth(map, false, '8 0 0');\r
 200         drawstring(pos, map, '16 16 0', '0 1 0', 1, DRAWFLAG_NORMAL);\r
 201         pos_y += 22;\r
 202         pos_x = xmin;\r
 203 \r
 204         drawfont = sbar_font;\r
 205         \r
 206         // base for multi-column stuff...\r
 207         ymin = pos_y;\r
 208         if(mv_abstain)\r
 209                 mv_num_maps -= 1;\r
 210         \r
 211         if(mv_num_maps > 3)\r
 212         {\r
 213                 columns = 3;\r
 214         } else {\r
 215                 columns = mv_num_maps;\r
 216         }\r
 217         rows = ceil(mv_num_maps / columns);\r
 218 \r
 219         dist_x = (xmax - xmin) / columns;\r
 220         dist_y = (ymax - pos_y) / rows;\r
 221         tsize = dist_x - 10;\r
 222         isize = min(dist_y - 10, 0.75 * tsize);\r
 223 \r
 224         mv_selection = MapVote_Selection(pos, dist, rows, columns);\r
 225 \r
 226         pos_x += (xmax - xmin) / (2 * columns);\r
 227         pos_y += (dist_y - isize) / 2;\r
 228         ymax -= isize;\r
 229 \r
 230         for(i = 0; i < mv_num_maps; ++i)\r
 231         {\r
 232                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up\r
 233                 if(tmp < 0)\r
 234                         continue;\r
 235                 map = mv_maps[i];\r
 236                 if(mv_preview[i])\r
 237                         MapVote_DrawMapItem(pos + MapVote_GridVec(dist, i, columns), isize, tsize, map, mv_pics[i], tmp, i);\r
 238                 else\r
 239                         MapVote_DrawMapItem(pos + MapVote_GridVec(dist, i, columns), isize, tsize, map, "", tmp, i);\r
 240         }\r
 241 \r
 242         if(mv_abstain)\r
 243                 ++mv_num_maps;\r
 244         \r
 245         if(mv_abstain && i < mv_num_maps) {\r
 246                 tmp = mv_votes[i];\r
 247                 pos_y = ymax + isize - sbar_fontsize_y;\r
 248                 pos_x = (xmax+xmin)*0.5;\r
 249                 MapVote_DrawAbstain(pos, isize, xmax - xmin, tmp, i);\r
 250         }\r
 251 \r
 252         drawpic(mv_mousepos, strcat("gfx/menu/", cvar_string("menu_skin"), "/cursor.tga"), '32 32 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);\r
 253 }\r
 254 \r
 255 void Cmd_MapVote_MapDownload(float argc)\r
 256 {\r
 257         float id;\r
 258         entity pak;\r
 259 \r
 260         if(argc != 2 || !mv_pk3list)\r
 261         {\r
 262                 print("mv_mapdownload: ^3You're not supposed to use this command on your own!\n");\r
 263                 return;\r
 264         }\r
 265         \r
 266         id = stof(argv(1));\r
 267         for(pak = mv_pk3list; pak; pak = pak.chain)\r
 268                 if(pak.sv_entnum == id)\r
 269                         break;\r
 270         \r
 271         if(!pak || pak.sv_entnum != id) {\r
 272                 print("^1Error:^7 Couldn't find pak index.\n");\r
 273                 return;\r
 274         }\r
 275 \r
 276         //print(strcat("^3Adding: ", ftos(id), " - ", pak.message, " - "));\r
 277         \r
 278         if(PreviewExists(pak.message))\r
 279         {\r
 280                 mv_preview[id] = true;\r
 281                 //print("^2Found...\n");\r
 282                 return;\r
 283         } else {\r
 284                 print("Requesting preview...\n");\r
 285                 localcmd(strcat("\ncmd mv_getpic ", ftos(id), "\n"));\r
 286         }\r
 287 }\r
 288 \r
 289 void MapVote_CheckPK3(string pic, string pk3, float id)\r
 290 {\r
 291         entity pak;\r
 292         pak = spawn();\r
 293         pak.netname = pk3;\r
 294         pak.message = pic;\r
 295         pak.sv_entnum = id;\r
 296         \r
 297         pak.chain = mv_pk3list;\r
 298         mv_pk3list = pak;\r
 299         \r
 300         if(pk3 != "")\r
 301         {\r
 302                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));\r
 303         }\r
 304         else\r
 305         {\r
 306                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));\r
 307         }\r
 308 }\r
 309 \r
 310 void MapVote_CheckPic(string pic, string pk3, float id)\r
 311 {\r
 312         // never try to retrieve a pic for the "don't care" 'map'\r
 313         if(mv_abstain && id == mv_num_maps - 1)\r
 314                 return;\r
 315 \r
 316         if(PreviewExists(pic))\r
 317         {\r
 318                 mv_preview[id] = true;\r
 319                 return;\r
 320         }\r
 321         MapVote_CheckPK3(pic, pk3, id);\r
 322 }\r
 323 \r
 324 #define NUM_SSDIRS 4\r
 325 string ssdirs[NUM_SSDIRS];\r
 326 float n_ssdirs;\r
 327 void MapVote_Init()\r
 328 {\r
 329         float i, j, power;\r
 330         string map, pk3, s;\r
 331 \r
 332         precache_sound ("misc/invshot.wav");\r
 333 \r
 334         registercmd("+showscores");\r
 335         registercmd("-showscores");\r
 336 \r
 337         mv_active = 1;\r
 338 \r
 339         mv_mousepos = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;\r
 340         mv_selection = -1;\r
 341 \r
 342         for(n_ssdirs = 0; ; ++n_ssdirs)\r
 343         {\r
 344                 s = ReadString();\r
 345                 if(s == "")\r
 346                         break;\r
 347                 if(n_ssdirs < NUM_SSDIRS)\r
 348                         ssdirs[n_ssdirs] = s;\r
 349         }\r
 350         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);\r
 351 \r
 352         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());\r
 353         mv_abstain = ReadByte();\r
 354         if(mv_abstain)\r
 355                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier\r
 356         mv_detail = ReadByte();\r
 357 \r
 358         mv_ownvote = -1;\r
 359         mv_timeout = ReadCoord();\r
 360 \r
 361         if(mv_num_maps <= 8)\r
 362                 mv_maps_mask = ReadByte();\r
 363         else\r
 364                 mv_maps_mask = ReadShort();\r
 365         \r
 366         // Assume mv_pk3list is NULL, there should only be 1 mapvote per round\r
 367         mv_pk3list = NULL; // I'm still paranoid!\r
 368         \r
 369         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)\r
 370         {\r
 371                 mv_votes[i] = 0;\r
 372 \r
 373                 if(mv_maps_mask & power)\r
 374                 {\r
 375                         map = strzone(ReadString());\r
 376                         pk3 = strzone(ReadString());\r
 377                         j = bound(0, ReadByte(), n_ssdirs - 1);\r
 378         \r
 379                         mv_maps[i] = map;\r
 380                         mv_pk3[i] = pk3;\r
 381                         map = strzone(strcat(ssdirs[j], "/", map));\r
 382                         mv_pics[i] = map;\r
 383 \r
 384                         mv_preview[i] = false;\r
 385 \r
 386                         //print(strcat("RECV: ", map, " in ", pk3, "\n"));\r
 387                         MapVote_CheckPic(map, pk3, i);\r
 388                 }\r
 389                 else\r
 390                 {\r
 391                         mv_maps[i] = strzone("if-you-see-this-the-code-is-broken");\r
 392                         mv_pk3[i] = strzone("if-you-see-this-the-code-is-broken");\r
 393                         mv_pics[i] = strzone("if-you-see-this-the-code-is-broken");\r
 394                         mv_preview[i] = false;\r
 395                 }\r
 396         }\r
 397 \r
 398         for(i = 0; i < n_ssdirs; ++i)\r
 399                 ssdirs[n_ssdirs] = string_null;\r
 400         n_ssdirs = 0;\r
 401 }\r
 402 \r
 403 float MapVote_InputEvent(float bInputType, float nPrimary, float nSecondary)\r
 404 {\r
 405         float imp;\r
 406 \r
 407         if (!mv_active)\r
 408                 return false;\r
 409 \r
 410         if (bInputType != 0)\r
 411                 return false;\r
 412 \r
 413         if ('0' <= nPrimary && nPrimary <= '9')\r
 414         {\r
 415                 imp = nPrimary - '0';\r
 416                 if (imp == 0) imp = 10;\r
 417                 localcmd(strcat("\nimpulse ", ftos(imp), "\n"));\r
 418                 return true;\r
 419         }\r
 420 \r
 421         if (nPrimary == K_MOUSE1)\r
 422                 if (mv_selection >= 0)\r
 423                 {\r
 424                         imp = min(mv_selection + 1, mv_num_maps);\r
 425                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));\r
 426                         return true;\r
 427                 }\r
 428 \r
 429         return false;\r
 430 }\r
 431 \r
 432 void MapVote_UpdateMask()\r
 433 {\r
 434         float i, power;\r
 435         float oldmask;\r
 436 \r
 437         oldmask = mv_maps_mask;\r
 438         if(mv_num_maps <= 8)\r
 439                 mv_maps_mask = ReadByte();\r
 440         else\r
 441                 mv_maps_mask = ReadShort();\r
 442 \r
 443         if(oldmask & mv_maps_mask != oldmask)\r
 444                 if(oldmask & mv_maps_mask == mv_maps_mask)\r
 445                          sound(world, CHAN_AUTO, "misc_invshot.wav", VOL_BASE, ATTN_NONE);\r
 446 \r
 447         // remove votes that no longer apply\r
 448         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)\r
 449                 if not(mv_maps_mask & power)\r
 450                         mv_votes[i] = -1;\r
 451 }\r
 452 \r
 453 void MapVote_UpdateVotes()\r
 454 {\r
 455         float i, power;\r
 456         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)\r
 457         {\r
 458                 if(mv_maps_mask & power)\r
 459                 {\r
 460                         if(mv_detail)\r
 461                                 mv_votes[i] = ReadByte();\r
 462                         else\r
 463                                 mv_votes[i] = 0;\r
 464                 }\r
 465                 else\r
 466                         mv_votes[i] = -1;\r
 467         }\r
 468 \r
 469         mv_ownvote = ReadByte()-1;\r
 470 }\r
 471 \r
 472 void Ent_MapVote()\r
 473 {\r
 474         float sf;\r
 475 \r
 476         sf = ReadByte();\r
 477 \r
 478         if(sf & 1)\r
 479                 MapVote_Init();\r
 480 \r
 481         if(sf & 2)\r
 482                 MapVote_UpdateMask();\r
 483 \r
 484         if(sf & 4)\r
 485                 MapVote_UpdateVotes();\r
 486 }\r
 487 \r
 488 void Net_MapVote_Picture()\r
 489 {\r
 490         float type;\r
 491         type = ReadByte();\r
 492         mv_preview[type] = true;\r
 493         mv_pics[type] = strzone(ReadPicture());\r
 494 }\r