Add symbols for health and armor
[voretournament/voretournament.git] / data / qcsrc / client / shownames.qc
1 // self.isactive = player is in range and coordinates/status (health and armor) are up to date
2 // self.origin = player origin TODO: should maybe move this so it's the origin of the shownames tag already in SSQC for culling?
3 // self.healthvalue
4 // self.armorvalue
5 // self.eaten
6 //
7 const float SHOWNAMES_FADESPEED = 4;
8 void Draw_ShowNames(entity ent)
9 {
10         if(!cvar("hud_shownames"))
11                 return;
12
13         if(ent.sv_entnum == player_localentnum && !cvar("chase_active"))
14                 return;
15
16         if(ent.predator) // don't show names for prey
17                 return;
18
19         float sameteam;
20         if(teamplay && (GetPlayerColor(player_localentnum - 1) == GetPlayerColor(ent.sv_entnum - 1)))
21                 sameteam = TRUE;
22
23         if(sameteam || (!sameteam && cvar("hud_shownames_enemies")))
24         {
25                 ent.origin_z += cvar("hud_shownames_offset");
26
27                 // offset the name by player scale, decided by health
28                 if(g_healthsize)
29                         ent.origin_z -= (g_healthsize - ent.healthvalue) * cvar("hud_shownames_offset_healthsize");
30
31                 if(!sameteam)
32                 {
33                         /* WIP, why does trace_ent != ent not work as intended here?
34                            if(cvar("hud_shownames_enemies") != 2) // player has to point at enemy if so
35                            {
36                            traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, MOVETYPE_FLY, world);
37                            print("trace_endpos: ", vtos(trace_endpos), " view_origin: ", vtos(view_origin), "\n");
38                            if(trace_ent != ent)
39                            return;
40                            }*/
41
42                         traceline(ent.origin, view_origin, 1, ent);
43                 }
44
45                 vector o, eo;
46                 o = project_3d_to_2d(ent.origin);
47                 float overlap;
48
49                 if(cvar("hud_shownames_antioverlap"))
50                 {
51                         // fade tag out if another tag that is closer to you overlaps
52                         entity e;
53                         for(e = world; (e = find(e, classname, "shownames_tag")); )
54                         {
55                                 if(e == ent)
56                                         continue;
57                                 eo = project_3d_to_2d(e.origin);
58                                 if not(eo_z < 0 || eo_x < 0 || eo_y < 0 || eo_x > vid_conwidth || eo_y > vid_conheight)
59                                 {
60                                         eo_z = 0;
61                                         if(vlen(('1 0 0' * o_x + '0 1 0' * o_y) - eo) < cvar("hud_shownames_antioverlap_distance") && vlen(ent.origin - view_origin) > vlen(e.origin - view_origin))
62                                         {
63                                                 overlap = TRUE;
64                                                 break;
65                                         }
66                                 }
67                         }
68                 }
69
70                 if(!sameteam && trace_endpos != view_origin) // out of view, fade out
71                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * frametime);
72                 else if(ent.healthvalue < 1) // dead player, fade out slowly
73                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * 0.25 * frametime);
74                 else if(overlap) // tag overlap detected, fade out
75                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * frametime);
76                 else // fade in
77                         ent.alpha = min(1, ent.alpha + SHOWNAMES_FADESPEED * frametime);
78
79                 if(!ent.alpha)
80                         return;
81
82                 float dist;
83                 dist = vlen(ent.origin - view_origin);
84
85                 float a;
86                 a = cvar("hud_shownames_alpha");
87                 a *= ent.alpha;
88                 if(cvar("hud_shownames_maxdistance"))
89                 {
90                         if(dist >= cvar("hud_shownames_maxdistance"))
91                                 return;
92                         a *= ((cvar("hud_shownames_maxdistance") - cvar("hud_shownames_mindistance")) - max(0, dist - cvar("hud_shownames_mindistance"))) / (cvar("hud_shownames_maxdistance") - cvar("hud_shownames_mindistance"));
93                 }
94
95                 if(!a)
96                         return;
97
98                 float resize;
99                 resize = 1;
100                 if(cvar("hud_shownames_resize")) // limit resize so its never smaller than 0.5... gets unreadable
101                         resize = 0.5 + 0.5 * ((cvar("hud_shownames_maxdistance") - cvar("hud_shownames_mindistance")) - max(0, dist - cvar("hud_shownames_mindistance"))) / (cvar("hud_shownames_maxdistance") - cvar("hud_shownames_mindistance"));
102
103                 // draw the sprite image
104                 if not(o_z < 0 || o_x < 0 || o_y < 0 || o_x > vid_conwidth || o_y > vid_conheight)
105                 {
106                         o_z = 0;
107
108                         vector myPos, mySize;
109                         mySize = ('1 0 0' * cvar("hud_shownames_aspect") + '0 1 0') * cvar("hud_shownames_fontsize");
110                         myPos = o - '0.5 0 0' * mySize_x - '0 1 0' * mySize_y;
111
112                         // size scaling
113                         mySize_x *= resize;
114                         mySize_y *= resize;
115
116                         myPos_x += 0.5 * (mySize_x / resize - mySize_x);
117                         myPos_y += (mySize_y / resize - mySize_y);
118
119                         vector namepos; // this is where the origin of the string
120                         float namewidth;
121
122                         namepos = myPos;
123                         namewidth = mySize_x;
124
125                         string s;
126                         s = GetPlayerName(ent.sv_entnum-1);
127                         if((cvar("hud_shownames_decolorize") == 1 && teamplay) || cvar("hud_shownames_decolorize") == 2)
128                                 s = playername(s, GetPlayerColor(ent.sv_entnum-1));
129
130                         drawfontscale = '1 1 0' * resize;
131                         s = textShortenToWidth(s, namewidth, '1 1 0' * cvar("hud_shownames_fontsize"), stringwidth_colors);
132
133                         if(cvar("hud_shownames_status"))
134                         if(sameteam && ent.healthvalue > 0)
135                         {
136                                 if(ent.armorvalue)
137                                         s = strcat(s, "^7 (^1+", ftos(ent.healthvalue), "^7|^2*", ftos(ent.armorvalue), "^7)");
138                                 else
139                                         s = strcat(s, "^7 (^1+", ftos(ent.healthvalue), "^7)");
140
141                                 // if team healing is enabled, mark the team mate as possible to heal
142                                 if(ent.healthvalue < teamheal_max)
143                                         s = strcat(s, "^7 [^5HEAL^7]");
144                         }
145
146                         float width;
147                         width = stringwidth(s, TRUE, '1 1 0' * cvar("hud_shownames_fontsize"));
148
149                         if (width != namewidth)
150                                 namepos_x += (namewidth - width) / 2;
151                         drawcolorcodedstring(namepos, s, '1 1 0' * cvar("hud_shownames_fontsize"), a, DRAWFLAG_NORMAL);
152                         drawfontscale = '1 1 0';
153                 }
154         }
155 }
156
157 entity shownames_ent[255];
158 void Draw_ShowNames_All()
159 {
160         float i;
161         for(i = 0; i < maxclients; ++i)
162         {
163                 float t;
164                 t = GetPlayerColor(i);
165                 if(t == COLOR_SPECTATOR)
166                         continue;
167
168                 entity e;
169                 e = shownames_ent[i];
170                 if(!e)
171                 {
172                         e = spawn();
173                         e.classname = "shownames_tag";
174                         e.sv_entnum = i+1;
175                         shownames_ent[i] = e;
176                 }
177
178                 entity entcs;
179                 entcs = entcs_receiver[i];
180                 if(entcs)
181                 {
182                         e.healthvalue = entcs.healthvalue;
183                         e.armorvalue = entcs.armorvalue;
184                         e.predator = entcs.predator;
185                 }
186                 else
187                 {
188                         e.healthvalue = 2342;
189                         e.armorvalue = 0;
190                         e.predator = 0;
191                 }
192
193                 e.origin = getplayerorigin(i);
194                 if(e.origin == GETPLAYERORIGIN_ERROR)
195                         continue;
196
197                 Draw_ShowNames(e);
198         }
199 }