data/qcsrc/client/shownames.qc

   1 // self.isactive = player is in range and coordinates/status (health and armor) are up to date
   2 // self.origin = player origin TODO: should maybe move this so it's the origin of the shownames tag already in SSQC for culling?
   3 // self.healthvalue
   4 // self.armorvalue
   5 // self.eaten
   6 //
   7 const float SHOWNAMES_FADESPEED = 4;
   8 void Draw_ShowNames(entity ent)
   9 {
  10         if(!cvar("hud_shownames"))
  11                 return;
  12
  13         if(ent.sv_entnum == player_localentnum && !cvar("chase_active"))
  14                 return;
  15
  16         if(ent.predator) // don't show names for prey
  17                 return;
  18
  19         float sameteam;
  20         if(teamplay && (GetPlayerColor(player_localentnum - 1) == GetPlayerColor(ent.sv_entnum - 1)))
  21                 sameteam = TRUE;
  22
  23         if(sameteam || (!sameteam && cvar("hud_shownames") > 1))
  24         {
  25                 ent.origin_z += cvar("hud_shownames_offset");
  26
  27                 // offset the name by player scale, decided by health
  28                 if(g_healthsize)
  29                         ent.origin_z -= (g_healthsize - ent.healthvalue) * cvar("hud_shownames_offset_healthsize");
  30
  31                 traceline(ent.origin, view_origin, 1, ent);
  32
  33                 vector o, eo;
  34                 o = project_3d_to_2d(ent.origin);
  35                 float overlap;
  36
  37                 if(cvar("hud_shownames_antioverlap"))
  38                 {
  39                         // fade tag out if another tag that is closer to you overlaps
  40                         entity e;
  41                         for(e = world; (e = find(e, classname, "shownames_tag")); )
  42                         {
  43                                 if(e == ent)
  44                                         continue;
  45                                 eo = project_3d_to_2d(e.origin);
  46                                 if not(eo_z < 0 || eo_x < 0 || eo_y < 0 || eo_x > vid_conwidth || eo_y > vid_conheight)
  47                                 {
  48                                         eo_z = 0;
  49                                         if(vlen(('1 0 0' * o_x + '0 1 0' * o_y) - eo) < cvar("hud_shownames_antioverlap_distance") && vlen(ent.origin - view_origin) > vlen(e.origin - view_origin))
  50                                         {
  51                                                 overlap = TRUE;
  52                                                 break;
  53                                         }
  54                                 }
  55                         }
  56                 }
  57
  58                 if(trace_endpos != view_origin) // out of view, fade out
  59                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * frametime);
  60                 else if(ent.healthvalue < 1) // dead player, fade out slowly
  61                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * 0.25 * frametime);
  62                 else if(overlap) // tag overlap detected, fade out
  63                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * frametime);
  64                 else // fade in
  65                         ent.alpha = min(1, ent.alpha + SHOWNAMES_FADESPEED * frametime);
  66
  67                 if(!ent.alpha)
  68                         return;
  69
  70                 float dist;
  71                 dist = vlen(ent.origin - view_origin);
  72
  73                 float a;
  74                 a = cvar("hud_shownames_alpha");
  75                 a *= ent.alpha;
  76                 if(cvar("hud_shownames_maxdistance"))
  77                 {
  78                         if(dist >= cvar("hud_shownames_maxdistance"))
  79                                 return;
  80                         a *= ((cvar("hud_shownames_maxdistance") - cvar("hud_shownames_mindistance")) - max(0, dist - cvar("hud_shownames_mindistance"))) / (cvar("hud_shownames_maxdistance") - cvar("hud_shownames_mindistance"));
  81                 }
  82
  83                 if(!a)
  84                         return;
  85
  86                 float resize;
  87                 resize = 1;
  88                 if(cvar("hud_shownames_resize")) // limit resize so its never smaller than 0.5... gets unreadable
  89                         resize = 0.5 + 0.5 * ((cvar("hud_shownames_maxdistance") - cvar("hud_shownames_mindistance")) - max(0, dist - cvar("hud_shownames_mindistance"))) / (cvar("hud_shownames_maxdistance") - cvar("hud_shownames_mindistance"));
  90
  91                 // draw the sprite image
  92                 if not(o_z < 0 || o_x < 0 || o_y < 0 || o_x > vid_conwidth || o_y > vid_conheight)
  93                 {
  94                         o_z = 0;
  95
  96                         vector myPos, mySize;
  97                         mySize = ('1 0 0' * cvar("hud_shownames_aspect") + '0 1 0') * cvar("hud_shownames_fontsize");
  98                         myPos = o - '0.5 0 0' * mySize_x - '0 1 0' * mySize_y;
  99
 100                         // size scaling
 101                         mySize_x *= resize;
 102                         mySize_y *= resize;
 103
 104                         myPos_x += 0.5 * (mySize_x / resize - mySize_x);
 105                         myPos_y += (mySize_y / resize - mySize_y);
 106
 107                         vector namepos; // this is where the origin of the string
 108                         float namewidth;
 109
 110                         namepos = myPos;
 111                         namewidth = mySize_x;
 112
 113                         string s;
 114                         s = GetPlayerName(ent.sv_entnum-1);
 115                         if((cvar("hud_shownames_decolorize") == 1 && teamplay) || cvar("hud_shownames_decolorize") == 2)
 116                                 s = playername(s, GetPlayerColor(ent.sv_entnum-1));
 117
 118                         drawfontscale = '1 1 0' * resize;
 119                         s = textShortenToWidth(s, namewidth, '1 1 0' * cvar("hud_shownames_fontsize"), stringwidth_colors);
 120
 121                         if(sameteam && ent.healthvalue > 0)
 122                         {
 123                                 if(cvar("hud_shownames_status") > 2 && ent.armorvalue)
 124                                         s = strcat(s, "^7 (^1+", ftos(ent.healthvalue), "^7|^2*", ftos(ent.armorvalue), "^7)");
 125                                 else if(cvar("hud_shownames_status") > 1)
 126                                         s = strcat(s, "^7 (^1+", ftos(ent.healthvalue), "^7)");
 127
 128                                 // if team healing is enabled, mark the team mate as possible to heal
 129                                 if(cvar("hud_shownames_status") && ent.healthvalue < teamheal_max)
 130                                         s = strcat(s, "^7 [^5HEAL^7]");
 131                         }
 132
 133                         float width;
 134                         width = stringwidth(s, TRUE, '1 1 0' * cvar("hud_shownames_fontsize"));
 135
 136                         if (width != namewidth)
 137                                 namepos_x += (namewidth - width) / 2;
 138                         drawcolorcodedstring(namepos, s, '1 1 0' * cvar("hud_shownames_fontsize"), a, DRAWFLAG_NORMAL);
 139                         drawfontscale = '1 1 0';
 140                 }
 141         }
 142 }
 143
 144 entity shownames_ent[255];
 145 void Draw_ShowNames_All()
 146 {
 147         float i;
 148         for(i = 0; i < maxclients; ++i)
 149         {
 150                 float t;
 151                 t = GetPlayerColor(i);
 152                 if(t == COLOR_SPECTATOR)
 153                         continue;
 154
 155                 entity e;
 156                 e = shownames_ent[i];
 157                 if(!e)
 158                 {
 159                         e = spawn();
 160                         e.classname = "shownames_tag";
 161                         e.sv_entnum = i+1;
 162                         shownames_ent[i] = e;
 163                 }
 164
 165                 entity entcs;
 166                 entcs = entcs_receiver[i];
 167                 if(entcs)
 168                 {
 169                         e.healthvalue = entcs.healthvalue;
 170                         e.armorvalue = entcs.armorvalue;
 171                         e.predator = entcs.predator;
 172                 }
 173                 else
 174                 {
 175                         e.healthvalue = 2342;
 176                         e.armorvalue = 0;
 177                         e.predator = 0;
 178                 }
 179
 180                 e.origin = getplayerorigin(i);
 181                 if(e.origin == GETPLAYERORIGIN_ERROR)
 182                         continue;
 183
 184                 Draw_ShowNames(e);
 185         }
 186 }