data/qcsrc/client/shownames.qc

   1 // self.isactive = player is in range and coordinates/status (health and armor) are up to date
   2 // self.origin = player origin TODO: should maybe move this so it's the origin of the shownames tag already in SSQC for culling?
   3 // self.healthvalue
   4 // self.armorvalue
   5 // self.eaten
   6 //
   7 const float SHOWNAMES_FADESPEED = 4;
   8 void Draw_ShowNames(entity ent)
   9 {
  10         if(!cvar("hud_shownames"))
  11                 return;
  12
  13         if(ent.sv_entnum == player_localentnum && !cvar("chase_active"))
  14                 return;
  15
  16         float sameteam;
  17         if(teamplay && (GetPlayerColor(player_localentnum - 1) == GetPlayerColor(ent.sv_entnum - 1)))
  18                 sameteam = TRUE;
  19
  20         if(sameteam || (!sameteam && cvar("hud_shownames") > 1))
  21         {
  22                 ent.origin_z += cvar("hud_shownames_offset");
  23
  24                 // offset the name by player scale, decided by health
  25                 if(g_healthsize)
  26                         ent.origin_z -= (g_healthsize - bound(g_healthsize_min, ent.healthvalue, g_healthsize_max)) * cvar("hud_shownames_offset_healthsize");
  27
  28                 traceline(ent.origin, view_origin, 1, ent);
  29
  30                 vector o, eo;
  31                 o = project_3d_to_2d(ent.origin);
  32                 float overlap;
  33
  34                 if(cvar("hud_shownames_antioverlap"))
  35                 {
  36                         // fade tag out if another tag that is closer to you overlaps
  37                         entity e;
  38                         for(e = world; (e = find(e, classname, "shownames_tag")); )
  39                         {
  40                                 if(e == ent)
  41                                         continue;
  42                                 eo = project_3d_to_2d(e.origin);
  43                                 if not(eo_z < 0 || eo_x < 0 || eo_y < 0 || eo_x > vid_conwidth || eo_y > vid_conheight)
  44                                 {
  45                                         eo_z = 0;
  46                                         if(vlen(('1 0 0' * o_x + '0 1 0' * o_y) - eo) < cvar("hud_shownames_antioverlap_distance") && vlen(ent.origin - view_origin) > vlen(e.origin - view_origin))
  47                                         {
  48                                                 overlap = TRUE;
  49                                                 break;
  50                                         }
  51                                 }
  52                         }
  53                 }
  54
  55                 if(trace_endpos != view_origin) // out of view, fade out
  56                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * frametime);
  57                 else if(ent.healthvalue < 1) // dead player, fade out slowly
  58                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * 0.25 * frametime);
  59                 else if(overlap) // tag overlap detected, fade out
  60                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * frametime);
  61                 else // fade in
  62                         ent.alpha = min(1, ent.alpha + SHOWNAMES_FADESPEED * frametime);
  63
  64                 if(!ent.alpha)
  65                         return;
  66
  67                 float dist;
  68                 dist = vlen(ent.origin - view_origin);
  69
  70                 float a;
  71                 a = cvar("hud_shownames_alpha");
  72                 a *= ent.alpha;
  73                 if(cvar("hud_shownames_maxdistance"))
  74                 {
  75                         if(dist >= cvar("hud_shownames_maxdistance"))
  76                                 return;
  77                         a *= ((cvar("hud_shownames_maxdistance") - cvar("hud_shownames_mindistance")) - max(0, dist - cvar("hud_shownames_mindistance"))) / (cvar("hud_shownames_maxdistance") - cvar("hud_shownames_mindistance"));
  78                 }
  79
  80                 if(!a)
  81                         return;
  82
  83                 float resize;
  84                 resize = 1;
  85                 if(cvar("hud_shownames_resize")) // limit resize so its never smaller than 0.5... gets unreadable
  86                         resize = 0.5 + 0.5 * ((cvar("hud_shownames_maxdistance") - cvar("hud_shownames_mindistance")) - max(0, dist - cvar("hud_shownames_mindistance"))) / (cvar("hud_shownames_maxdistance") - cvar("hud_shownames_mindistance"));
  87
  88                 // draw the sprite image
  89                 if not(o_z < 0 || o_x < 0 || o_y < 0 || o_x > vid_conwidth || o_y > vid_conheight)
  90                 {
  91                         o_z = 0;
  92
  93                         vector myPos, mySize;
  94                         mySize = ('1 0 0' * cvar("hud_shownames_aspect") + '0 1 0') * cvar("hud_shownames_fontsize");
  95                         myPos = o - '0.5 0 0' * mySize_x - '0 1 0' * mySize_y;
  96
  97                         // size scaling
  98                         mySize_x *= resize;
  99                         mySize_y *= resize;
 100
 101                         myPos_x += 0.5 * (mySize_x / resize - mySize_x);
 102                         myPos_y += (mySize_y / resize - mySize_y);
 103
 104                         vector namepos; // this is where the origin of the string
 105                         float namewidth;
 106
 107                         namepos = myPos;
 108                         namewidth = mySize_x;
 109
 110                         string s;
 111                         s = GetPlayerName(ent.sv_entnum-1);
 112                         if((cvar("hud_shownames_decolorize") == 1 && teamplay) || cvar("hud_shownames_decolorize") == 2)
 113                                 s = playername(s, GetPlayerColor(ent.sv_entnum-1));
 114
 115                         drawfontscale = '1 1 0' * resize;
 116                         s = textShortenToWidth(s, namewidth, '1 1 0' * cvar("hud_shownames_fontsize"), stringwidth_colors);
 117
 118                         if(sameteam && ent.healthvalue > 0)
 119                         {
 120                                 if(cvar("hud_shownames_status") > 2 && ent.armorvalue)
 121                                         s = strcat(s, "^7 (^1+", ftos(ent.healthvalue), "^7|^2*", ftos(ent.armorvalue), "^7)");
 122                                 else if(cvar("hud_shownames_status") > 1)
 123                                         s = strcat(s, "^7 (^1+", ftos(ent.healthvalue), "^7)");
 124
 125                                 // if team healing is enabled, mark the team mate as possible to heal
 126                                 if(cvar("hud_shownames_status") && ent.healthvalue < teamheal_max)
 127                                         s = strcat(s, "^7 [^5HEAL^7]");
 128                         }
 129
 130                         float width;
 131                         width = stringwidth(s, TRUE, '1 1 0' * cvar("hud_shownames_fontsize"));
 132
 133                         if (width != namewidth)
 134                                 namepos_x += (namewidth - width) / 2;
 135                         drawcolorcodedstring(namepos, s, '1 1 0' * cvar("hud_shownames_fontsize"), a, DRAWFLAG_NORMAL);
 136                         drawfontscale = '1 1 0';
 137                 }
 138         }
 139 }
 140
 141 entity shownames_ent[255];
 142 void Draw_ShowNames_All()
 143 {
 144         float i;
 145         for(i = 0; i < maxclients; ++i)
 146         {
 147                 float t;
 148                 t = GetPlayerColor(i);
 149                 if(t == COLOR_SPECTATOR)
 150                         continue;
 151
 152                 entity e;
 153                 e = shownames_ent[i];
 154                 if(!e)
 155                 {
 156                         e = spawn();
 157                         e.classname = "shownames_tag";
 158                         e.sv_entnum = i+1;
 159                         shownames_ent[i] = e;
 160                 }
 161
 162                 entity entcs;
 163                 entcs = entcs_receiver[i];
 164                 if(entcs)
 165                 {
 166                         e.healthvalue = entcs.healthvalue;
 167                         e.armorvalue = entcs.armorvalue;
 168                 }
 169                 else
 170                 {
 171                         e.healthvalue = 2342;
 172                         e.armorvalue = 0;
 173                 }
 174
 175                 e.origin = getplayerorigin(i);
 176                 if(e.origin == GETPLAYERORIGIN_ERROR)
 177                         continue;
 178
 179                 Draw_ShowNames(e);
 180         }
 181 }