data/qcsrc/server/bot/havocbot/vore_ai.qc

   1 entity Swallow_distance_check_bot(entity e)
   2 {
   3         // check if we can swallow a player instead of firing our weapon
   4         vector w_shotorg, w_shotdir;
   5         w_shotorg = self.origin + self.view_ofs;
   6         w_shotdir = v_forward;
   7
   8         WarpZone_traceline_antilag(e, w_shotorg, w_shotorg + w_shotdir * cvar("g_balance_vore_swallow_range"), FALSE, e, ANTILAG_LATENCY(e));
   9         if(trace_fraction < 1)
  10         if(trace_ent.classname == "player")
  11                 return trace_ent;
  12         return world;
  13 }
  14
  15 float Swallow_condition_check_bot(entity prey)
  16 {
  17         // checks the necessary conditions for a bot to swallow another player
  18         if(prey != self && prey.classname == "player" && prey.eater.classname != "player" && prey.deadflag == DEAD_NO && !prey.BUTTON_CHAT) // we can't swallow someone who's already in someone else's stomach
  19         if(self.eater.classname != "player" && self.stomach_load < cvar("g_balance_vore_swallow_limit") && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves
  20         if not(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)
  21         if(self.health > cvar("g_balance_vore_kick_damage_max")) // explained below
  22         if not(prey.team == self.team && teamplay)
  23                 return TRUE;
  24         return FALSE;
  25 }
  26
  27 .float swallow_retry, decide_delay1, decide_delay2;
  28 void Vore_AI()
  29 {
  30         if(cvar("bot_nofire") || !skill)
  31                 return;
  32
  33 // --------------------------------
  34 // Predator bot behavior:
  35 // --------------------------------
  36
  37         // finding and swallowing a victim:
  38
  39         // aim toward the nearest possible victim. The greater the skill the quicker the aim. This only does the aiming, checking and swallowing is handled below
  40         entity scan;
  41         scan = findradius(self.origin, cvar("g_balance_vore_swallow_range"));
  42         if(Swallow_condition_check_bot(scan))
  43                 bot_aimdir(scan.origin + scan.view_ofs - self.origin - self.view_ofs, -1);
  44
  45         // now do the actual checking and swallowing
  46         entity prey;
  47         float random_try;
  48         float decide_prey, decide_pred;
  49
  50         prey = Swallow_distance_check_bot(self);
  51         random_try = random() * 10; // there are 10 bot skill steps
  52         if(prey.items & IT_STRENGTH) // avoid eating bots that have the Strenght powerup
  53                 random_try /= cvar("bot_ai_vore_decide_fear");
  54         if(prey.items & IT_INVINCIBLE) // avoid eating bots that have the Invincible powerup
  55                 random_try /= cvar("bot_ai_vore_decide_fear");
  56         decide_prey = cvar("bot_ai_vore_decide_prey") / (skill * 2 + 1);
  57         decide_pred = cvar("bot_ai_vore_decide_pred") / (skill * 2 + 1);
  58
  59         if(Swallow_condition_check_bot(prey))
  60         if(time > self.swallow_retry)
  61         {
  62                 // the greater the skill, the higher the chance bots will swallow someone each attempt
  63                 if(skill >= random_try)
  64                 {
  65                         self.BUTTON_ATCK = TRUE; // swallow
  66                         self.decide_delay1 = time + decide_pred; // time before the bot decides what to do with their prey
  67                 }
  68                 self.swallow_retry = time + 0.5; // bots retry swallowing every 0.5 seconds, otherwise each frame would be random chance
  69         }
  70
  71         // deciding what to do with a victim:
  72
  73         if(self.stomach_load > 0 && time > self.decide_delay1)
  74         {
  75                 // if the predator's health is smaller than the maximum amount of damage a stomach kick can do, regurgitate the player(s)
  76                 // otherwise the predator is putting himself at risk by keeping someone inside
  77                 if(self.health <= cvar("g_balance_vore_kick_damage_max"))
  78                         self.BUTTON_REGURGITATE = TRUE;
  79
  80                 else if(!self.digesting)
  81                 {
  82                         // the higher the skill, the faster bots will start to digest you
  83                         if(skill >= random_try)
  84                                 self.BUTTON_DIGEST = TRUE; // digest
  85
  86                         self.decide_delay1 = time + decide_pred; // time before the bot decides what to do with their prey
  87                 }
  88         }
  89
  90 // --------------------------------
  91 // Prey bot behavior:
  92 // --------------------------------
  93
  94         // all we can do in the stomach is kick and do some damage / try to escape
  95         if(self.eater.classname == "player" && time > self.decide_delay2)
  96         {
  97                 // the higher the skill, the more the bot will kick in your stomack
  98                 if(skill >= random_try)
  99                 if not(teams_matter && self.team == self.eater.team) // if someone from the same team somehow made it in the belly, don't kick the eater
 100                         self.BUTTON_ATCK = TRUE; // kick
 101
 102                 self.decide_delay2 = time + decide_prey; // time before the bot decides what to do with their predator
 103         }
 104 }