a468fd7f52dffd90d08c45c474f611bc5bfd216b
[voretournament/voretournament.git] / data / qcsrc / server / bot / havocbot / vore_ai.qc
1 .float status_teamhealing; // 0 = can't team heal, 1 = can team heal, 2 = team healing right now
2 .float hold_BUTTON_ATCK; // marks the bot holding the fire button after having decided on his prey
3
4 float Swallow_condition_check_bot(entity prey)
5 {
6         // checks the necessary conditions for a bot to swallow a player
7
8         if(Swallow_condition_check(prey)) // check the normal conditions of the vore system
9         if(time >= prey.spawnshieldtime) // spawn shield means you are invincible
10         if not(prey.BUTTON_CHAT) // don't eat players who are chatting
11         if(self.health > cvar("g_balance_vore_kick_damage") && skill >= 5) // explained below
12                 return TRUE;
13         return FALSE;
14 }
15
16 .float decide_swallow, decide_pred, decide_prey;
17 void Vore_AI_Teamheal(entity prey)
18 {
19         // allows bots to use the teamheal feature and heal damaged team mates
20         // the prey entity is only used when it's available (a player is detected in range)
21
22         entity head;
23
24         if not(teams_matter && cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))
25                 return;
26         if(self.deadflag != DEAD_NO || self.stat_eaten || self.flagcarried || self.digesting) // a flag carrier can't waste time on team healing
27         {
28                 self.status_teamhealing = 0;
29                 return;
30         }
31
32         // if a teamheal is ongoing, decide whether or not to abandon it when seeing a foe we can attack
33         // this only causes the bot to regurgitate their team mate when seeing an enemy, with the hope that our enemy will still be there once we can swallow
34         // the higher the skill, the greater the chance a bot will abandon a team heal for an enemy
35         if(self.status_teamhealing > 1)
36         if(Swallow_condition_check_bot(prey))
37         if(prey.team != self.team)
38         if(random() * 10 < cvar("bot_ai_vore_teamhealabandon") * skill / self.bot_voreteamheal) // there are 10 bot skill steps
39                 self.BUTTON_REGURGITATE = TRUE; // release the team mate
40
41         // decide if we can teamheal or not
42         if(self.stomach_load)
43         {
44                 self.status_teamhealing = 2; // consider a team mate is in our stomach and we are teamhealing, until proven otherwise below
45
46                 FOR_EACH_PLAYER(head)
47                 {
48                         if(head.predator == self)
49                         if(head.team != self.team)
50                         {
51                                 self.status_teamhealing = 0; // there's a foe in our stomach, we can't teamheal now
52                                 return;
53                         }
54                 }
55         }
56         else
57                 self.status_teamhealing = 1; // if our stomach is empty, it means we can decide to teamheal
58
59         // now that we're decided if we can teamheal or not, lets go ahead and do so
60
61         // if we are holding a team mate that's been healed to the limit, we can release them
62         if not(cvar("bot_ai_vore_keepinstomach"))
63         FOR_EACH_PLAYER(head)
64         {
65                 if(head.predator == self) // head is automatically a team mate, or we wouldn't be reaching this part of the code
66                 if(head.health >= cvar("g_balance_vore_teamheal_stable"))
67                         self.BUTTON_REGURGITATE = TRUE; // release the team mate
68         }
69
70         // check if we can heal a team mate we come across, and if so swallow them
71         if(prey.team == self.team)
72         if(Swallow_condition_check_bot(prey))
73         if(prey.health < cvar("g_balance_vore_teamheal_stable"))
74         if not(prey.digesting) // if our team mate is digesting someone, he likely wouldn't want us ruining his frag
75         if not(prey.flagcarried) // don't eat the flag carrier and ruin his job
76         if not(prey.BUTTON_ATCK || prey.BUTTON_ATCK2) // our team mate wouldn't want us eating him while he's firing
77         {
78                 if(time > self.decide_swallow)
79                 {
80                         // base the decision around HOW damaged the team mate is, centered around 100 health
81                         if(skill * (100 / prey.health) >= random() * 10) // there are 10 bot skill steps
82                                 self.hold_BUTTON_ATCK = TRUE; // swallow the team mate
83                         self.decide_swallow = time + cvar("bot_ai_vore_decide_swallow") / self.bot_vorethinkpred; // this is needed to take a proper decision, otherwise the code would execute each frame and return TRUE quickly
84                 }
85         }
86         else
87                 self.hold_BUTTON_ATCK = FALSE;
88 }
89
90 void Vore_AI()
91 {
92         // main vore AI code
93
94         if(!cvar("g_vore")) // the vore system is disabled
95                 return;
96         if(self.deadflag != DEAD_NO || cvar("bot_nofire") || !skill || (g_rpg && cvar("g_rpg_botattack") < 1))
97                 return;
98
99         float randomtry;
100         randomtry = random() * 10; // there are 10 bot skill steps
101
102 // --------------------------------
103 // Predator bot behavior:
104 // --------------------------------
105
106         if(!self.stat_eaten)
107         {
108                 // finding and swallowing a player
109
110                 // aim toward the nearest possible victim. The greater the skill, the quicker the aim
111                 // this only does the aiming, checking and swallowing is handled below
112                 entity head;
113                 head = findradius(self.origin, cvar("g_balance_vore_swallow_range"));
114                 while(head)
115                 {
116                         if(Swallow_condition_check_bot(head))
117                                 bot_aimdir(head.origin + head.view_ofs - self.origin - self.view_ofs, -1);
118                         head = head.chain;
119                 }
120
121                 // now do the actual checking and swallowing
122                 entity prey;
123                 float decide_pred_time, fear;
124
125                 prey = Swallow_player_check();
126                 fear = 1;
127
128                 // check if we should run the Teamhealing AI rather than continuing with the normal vore AI
129                 Vore_AI_Teamheal(prey);
130                 if(self.status_teamhealing > 1) // if we are teamhealing, there's nothing to do from here on
131                         return;
132
133                 if(!cvar("g_vore_reversescoring")) // when reverse scoring is on, it's in the interest of the prey to get eaten, so the predator has nothing to fear
134                 {
135                         if(prey.items & IT_STRENGTH) // avoid eating bots that have the Strenght powerup
136                                 fear += cvar("bot_ai_vore_fear") * self.bot_vorefear;
137                         if(prey.items & IT_INVINCIBLE) // avoid eating bots that have the Invincible powerup
138                                 fear += cvar("bot_ai_vore_fear") * self.bot_vorefear;
139                         fear += self.stomach_load; // the bigger our stomach, the less we want to put someone else in there
140                         if(cvar("g_healthsize"))
141                                 fear *= (prey.scale / self.scale); // predators fear larger prey and are courageous toward smaller prey
142                         if(prey.stomach_load)
143                                 fear *= prey.stomach_load; // predators fear prey that have a large stomach
144
145                         // when a bot is being swallowed, he will try to swallow the enemy back in defense, forgetting about fear
146                         if(self.swallow_progress_prey)
147                                 fear /= self.swallow_progress_prey * skill;
148                 }
149
150                 decide_pred_time = cvar("bot_ai_vore_decide_pred") / skill / self.bot_vorethinkpred;
151
152                 if(Swallow_condition_check_bot(prey))
153                 {
154                         if(time > self.decide_swallow)
155                         {
156                                 // the greater the skill, the higher the chance bots will swallow someone each attempt
157                                 if(skill / fear >= randomtry)
158                                 if not(teams_matter && prey.team == self.team)
159                                 {
160                                         self.hold_BUTTON_ATCK = TRUE; // swallow
161                                         self.decide_pred = time + decide_pred_time; // time before the bot decides what to do with his prey
162                                 }
163                                 self.decide_swallow = time + cvar("bot_ai_vore_decide_swallow") / self.bot_vorethinkpred; // this is needed to take a proper decision, otherwise the code would execute each frame and return TRUE quickly
164                         }
165                 }
166                 else
167                         self.hold_BUTTON_ATCK = FALSE;
168
169                 // if the bot is holding the firing button, apply that to the actual fire key
170                 if(self.hold_BUTTON_ATCK)
171                         self.BUTTON_ATCK = TRUE;
172
173                 // deciding what to do with a victim:
174
175                 if(self.stomach_load && time > self.decide_pred)
176                 {
177                         // if the predator's health is smaller than the damage a stomach kick can do, regurgitate the player(s)
178                         // otherwise the predator is putting himself at risk by keeping you inside
179                         if(self.health <= cvar("g_balance_vore_kick_damage") && skill >= 5) // such awareness comes from skill 5 and up
180                                 self.BUTTON_REGURGITATE = TRUE;
181
182                         else if(!self.digesting && cvar("g_vore_digestion"))
183                         {
184                                 // the higher the skill, the faster bots will start to digest
185                                 if not(g_rpg && cvar("g_rpg_botattack") < 2)
186                                 if(skill >= randomtry)
187                                         self.BUTTON_DIGEST = TRUE; // digest
188
189                                 self.decide_pred = time + decide_pred_time; // time before the bot decides what to do with his prey
190                         }
191                 }
192         }
193
194 // --------------------------------
195 // Prey bot behavior:
196 // --------------------------------
197
198         if(cvar("g_vore_reversescoring")) // if reverse scoring is on, it's in the interest of the prey to get eaten, so don't fight back
199                 return;
200
201         // while being swallowed, smart bots know to keep jumping to make it harder to be caught
202         // TODO: Don't do this if the predator is a team mate
203         if(self.swallow_progress_prey)
204         if(self.swallow_progress_prey * 10 >= 10 - skill) // 10 skill steps
205                 self.BUTTON_JUMP = TRUE;
206
207         if(self.stat_eaten && time > self.decide_prey)
208         {
209                 // all we can do in the stomach is kick and do some damage / try to escape, or leave if the circumstances allow it and we should
210
211                 float decide_prey_time;
212                 decide_prey_time = cvar("bot_ai_vore_decide_prey") / skill / self.bot_vorethinkprey;
213
214                 if(cvar("g_vore_kick"))
215                 if not(g_rpg && cvar("g_rpg_botattack") < 2)
216                 if not(teams_matter && self.team == self.predator.team)
217                 {
218                         // the higher the skill, the more the bot will kick in your stomack
219                         if(skill >= randomtry)
220                         if not(teams_matter && self.team == self.predator.team) // if someone from the same team is in the belly, don't kick the predator
221                                 self.BUTTON_ATCK = TRUE; // kick
222                 }
223
224                 // if a bot can willingly leave the predator, do so unless there's a reason not to
225                 if(self.stat_canleave)
226                 {
227                         if(self.predator.digesting) // our predator is digesting, so get out of him regardless of who he is
228                                 self.BUTTON_JUMP = TRUE; // leave
229                         else if not((g_rpg && cvar("g_rpg_botattack") < 2) || !cvar("g_vore_digestion")) // don't leave when gentle vore is enabled
230                         {
231                                 if not(teams_matter && self.team == self.predator.team && cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable")) // we are being team healed, don't leave
232                                 if not(teams_matter && self.team == self.predator.team && cvar("bot_ai_vore_stayinstomach")) // bots are not supposed to leave a team mate's stomach automatically
233                                         self.BUTTON_JUMP = TRUE; // leave
234                         }
235                 }
236
237                 self.decide_prey = time + decide_prey_time; // time before the bot decides what to do with their predator
238         }
239 }