Make bots much smarter :)
[voretournament/voretournament.git] / data / qcsrc / server / bot / havocbot / vore_ai.qc
1 .float status_teamhealing; // 0 = can't team heal, 1 = can team heal, 2 = team healing right now
2 .float hold_BUTTON_ATCK; // marks the bot holding the fire button after having decided on his prey
3
4 float Swallow_condition_check_bot(entity prey)
5 {
6         // checks the necessary conditions for a bot to swallow a player
7
8         float kick_dmg;
9         if(cvar("g_vore_kick") && skill >= 7)
10         {
11                 kick_dmg = cvar("g_balance_vore_kick_damage");
12                 if(cvar("g_healthsize"))
13                         kick_dmg *= pow(prey.scale / self.scale, cvar("g_balance_vore_kick_scalediff")); // based on the damage the prey can do to us at his size
14         }
15
16         if(Swallow_condition_check(prey)) // check the normal conditions of the vore system
17         if(time >= prey.spawnshieldtime) // spawn shield means you are invincible
18         if not(prey.BUTTON_CHAT) // don't eat players who are chatting
19         if(self.health > kick_dmg)
20                 return TRUE;
21         return FALSE;
22 }
23
24 .float decide_swallow, decide_pred, decide_prey;
25 void Vore_AI_Teamheal(entity prey)
26 {
27         // allows bots to use the teamheal feature and heal damaged team mates
28         // the prey entity is only used when it's available (a player is detected in range)
29
30         entity head;
31
32         if not(teams_matter && cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))
33                 return;
34         if(self.deadflag != DEAD_NO || self.stat_eaten || self.flagcarried || self.digesting) // a flag carrier can't waste time on team healing
35         {
36                 self.status_teamhealing = 0;
37                 return;
38         }
39
40         // if a teamheal is ongoing, decide whether or not to abandon it when seeing a foe we can attack
41         // this only causes the bot to regurgitate their team mate when seeing an enemy, with the hope that our enemy will still be there once we can swallow
42         // the higher the skill, the greater the chance a bot will abandon a team heal for an enemy
43         if(self.status_teamhealing > 1)
44         if(Swallow_condition_check_bot(prey))
45         if(prey.team != self.team)
46         if(random() * 10 < cvar("bot_ai_vore_teamhealabandon") * skill / self.bot_voreteamheal) // there are 10 bot skill steps
47                 self.BUTTON_REGURGITATE = TRUE; // release the team mate
48
49         // decide if we can teamheal or not
50         if(self.stomach_load)
51         {
52                 self.status_teamhealing = 2; // consider a team mate is in our stomach and we are teamhealing, until proven otherwise below
53
54                 FOR_EACH_PLAYER(head)
55                 {
56                         if(head.predator == self)
57                         if(head.team != self.team)
58                         {
59                                 self.status_teamhealing = 0; // there's a foe in our stomach, we can't teamheal now
60                                 return;
61                         }
62                 }
63         }
64         else
65                 self.status_teamhealing = 1; // if our stomach is empty, it means we can decide to teamheal
66
67         // now that we're decided if we can teamheal or not, lets go ahead and do so
68
69         // if we are holding a team mate that's been healed to the limit, we can release them
70         if not(cvar("bot_ai_vore_keepinstomach"))
71         FOR_EACH_PLAYER(head)
72         {
73                 if(head.predator == self) // head is automatically a team mate, or we wouldn't be reaching this part of the code
74                 if(head.health >= cvar("g_balance_vore_teamheal_stable"))
75                         self.BUTTON_REGURGITATE = TRUE; // release the team mate
76         }
77
78         // check if we can heal a team mate we come across, and if so swallow them
79         if(prey.team == self.team)
80         if(Swallow_condition_check_bot(prey))
81         if(prey.health < cvar("g_balance_vore_teamheal_stable"))
82         if not(prey.digesting) // if our team mate is digesting someone, he likely wouldn't want us ruining his frag
83         if not(prey.flagcarried) // don't eat the flag carrier and ruin his job
84         if not(prey.BUTTON_ATCK || prey.BUTTON_ATCK2) // our team mate wouldn't want us eating him while he's firing
85         {
86                 if(time > self.decide_swallow)
87                 {
88                         // base the decision around HOW damaged the team mate is, centered around 100 health
89                         if(skill * (100 / prey.health) >= random() * 10) // there are 10 bot skill steps
90                                 self.hold_BUTTON_ATCK = TRUE; // swallow the team mate
91                         self.decide_swallow = time + cvar("bot_ai_vore_decide_swallow") / self.bot_vorethinkpred; // this is needed to take a proper decision, otherwise the code would execute each frame and return TRUE quickly
92                 }
93         }
94         else
95                 self.hold_BUTTON_ATCK = FALSE;
96 }
97
98 void Vore_AI()
99 {
100         // main vore AI code
101
102         if(!cvar("g_vore")) // the vore system is disabled
103                 return;
104         if(self.deadflag != DEAD_NO || cvar("bot_nofire") || !skill || (g_rpg && cvar("g_rpg_botattack") < 1))
105                 return;
106
107         float randomtry;
108         randomtry = random() * 10; // there are 10 bot skill steps
109
110 // --------------------------------
111 // Predator bot behavior:
112 // --------------------------------
113
114         if(!self.stat_eaten)
115         {
116                 // finding and swallowing a player
117
118                 // aim toward the nearest possible victim. The greater the skill, the quicker the aim
119                 // this only does the aiming, checking and swallowing is handled below
120                 entity head;
121                 head = findradius(self.origin, cvar("g_balance_vore_swallow_range"));
122                 while(head)
123                 {
124                         if(Swallow_condition_check_bot(head))
125                                 bot_aimdir(head.origin + head.view_ofs - self.origin - self.view_ofs, -1);
126                         head = head.chain;
127                 }
128
129                 // now do the actual checking and swallowing
130                 entity prey;
131                 float decide_pred_time, fear;
132
133                 prey = Swallow_player_check();
134                 fear = 1;
135
136                 // check if we should run the Teamhealing AI rather than continuing with the normal vore AI
137                 Vore_AI_Teamheal(prey);
138                 if(self.status_teamhealing > 1) // if we are teamhealing, there's nothing to do from here on
139                         return;
140
141                 if(!cvar("g_vore_reversescoring")) // when reverse scoring is on, it's in the interest of the prey to get eaten, so the predator has nothing to fear
142                 {
143                         if(skill >= 3) // make bots aware of this from skill 3 and up
144                                 fear *= 1 + self.stomach_load; // the bigger our stomach, the less we want to put someone else in there
145                         if(skill >= 5) // make bots aware of this from skill 5 and up
146                                 fear *= 1 + prey.stomach_load; // predators fear prey that have a large stomach
147
148                         if(cvar("g_healthsize"))
149                                 fear *= (prey.scale / self.scale); // predators fear larger prey and are courageous toward smaller prey
150                         if(prey.items & IT_STRENGTH) // avoid eating bots that have the Strenght powerup
151                                 fear *= 2;
152                         if(prey.items & IT_INVINCIBLE) // avoid eating bots that have the Invincible powerup
153                                 fear *= 2;
154
155                         // when a bot is being swallowed, he will try to swallow the enemy back in defense, forgetting about fear
156                         if(self.swallow_progress_prey)
157                                 fear /= self.swallow_progress_prey * skill;
158
159                         fear *= cvar("bot_ai_vore_fear") * self.bot_vorefear;
160                 }
161
162                 decide_pred_time = cvar("bot_ai_vore_decide_pred") / skill / self.bot_vorethinkpred;
163
164                 if(Swallow_condition_check_bot(prey))
165                 {
166                         if(time > self.decide_swallow)
167                         {
168                                 // the greater the skill, the higher the chance bots will swallow someone each attempt
169                                 if(skill / fear >= randomtry)
170                                 if not(teams_matter && prey.team == self.team)
171                                 {
172                                         self.hold_BUTTON_ATCK = TRUE; // swallow
173                                         self.decide_pred = time + decide_pred_time; // time before the bot decides what to do with his prey
174                                 }
175                                 self.decide_swallow = time + cvar("bot_ai_vore_decide_swallow") / self.bot_vorethinkpred; // this is needed to take a proper decision, otherwise the code would execute each frame and return TRUE quickly
176                         }
177                 }
178                 else
179                         self.hold_BUTTON_ATCK = FALSE;
180
181                 // if the bot is holding the firing button, apply that to the actual fire key
182                 if(self.hold_BUTTON_ATCK)
183                         self.BUTTON_ATCK = TRUE;
184
185                 // deciding what to do with a victim:
186
187                 if(self.stomach_load && time > self.decide_pred)
188                 {
189                         // if the predator's health is smaller than the damage a stomach kick can do, regurgitate the player(s)
190                         // otherwise the predator is putting himself at risk by keeping you inside
191                         float kick_dmg;
192                         if(cvar("g_vore_kick") && skill >= 7) // such awareness comes from skill level 7 and up
193                         {
194                                 kick_dmg = cvar("g_balance_vore_kick_damage");
195                                 if(cvar("g_healthsize"))
196                                 {
197                                         entity e;
198                                         FOR_EACH_PLAYER(e) // count the size of all players in the stomach for accounting the danger level
199                                         {
200                                                 if(e.predator == self)
201                                                 if not(teamplay && e.team == self.team) // don't count team mates
202                                                         kick_dmg *= pow(e.scale / self.scale, cvar("g_balance_vore_kick_scalediff")); // based on the damage the prey can do to us at his size
203                                         }
204                                 }
205                         }
206                         if(self.health <= kick_dmg)
207                                 self.BUTTON_REGURGITATE = TRUE;
208
209                         else if(!self.digesting && cvar("g_vore_digestion"))
210                         {
211                                 // the higher the skill, the faster bots will start to digest
212                                 if not(g_rpg && cvar("g_rpg_botattack") < 2)
213                                 if(skill >= randomtry)
214                                         self.BUTTON_DIGEST = TRUE; // digest
215
216                                 self.decide_pred = time + decide_pred_time; // time before the bot decides what to do with his prey
217                         }
218                 }
219         }
220
221 // --------------------------------
222 // Prey bot behavior:
223 // --------------------------------
224
225         if(cvar("g_vore_reversescoring")) // if reverse scoring is on, it's in the interest of the prey to get eaten, so don't fight back
226                 return;
227
228         // while being swallowed, smart bots know to keep jumping to make it harder to be caught
229         // TODO: Don't do this if the predator is a team mate
230         if(self.swallow_progress_prey)
231         if(self.swallow_progress_prey * 10 >= 10 - skill) // 10 skill steps
232                 self.BUTTON_JUMP = TRUE;
233
234         if(self.stat_eaten && time > self.decide_prey)
235         {
236                 // all we can do in the stomach is kick and do some damage / try to escape, or leave if the circumstances allow it and we should
237
238                 float decide_prey_time;
239                 decide_prey_time = cvar("bot_ai_vore_decide_prey") / skill / self.bot_vorethinkprey;
240
241                 if(cvar("g_vore_kick"))
242                 if not(g_rpg && cvar("g_rpg_botattack") < 2)
243                 if not(teams_matter && self.team == self.predator.team)
244                 {
245                         // the higher the skill, the more the bot will kick in your stomack
246                         if(skill >= randomtry)
247                         if not(teams_matter && self.team == self.predator.team) // if someone from the same team is in the belly, don't kick the predator
248                                 self.BUTTON_ATCK = TRUE; // kick
249                 }
250
251                 // if a bot can willingly leave the predator, do so unless there's a reason not to
252                 if(self.stat_canleave)
253                 {
254                         if(self.predator.digesting) // our predator is digesting, so get out of him regardless of who he is
255                                 self.BUTTON_JUMP = TRUE; // leave
256                         else if not((g_rpg && cvar("g_rpg_botattack") < 2) || !cvar("g_vore_digestion")) // don't leave when gentle vore is enabled
257                         {
258                                 if not(teams_matter && self.team == self.predator.team && cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable")) // we are being team healed, don't leave
259                                 if not(teams_matter && self.team == self.predator.team && cvar("bot_ai_vore_stayinstomach")) // bots are not supposed to leave a team mate's stomach automatically
260                                         self.BUTTON_JUMP = TRUE; // leave
261                         }
262                 }
263
264                 self.decide_prey = time + decide_prey_time; // time before the bot decides what to do with their predator
265         }
266 }