data/qcsrc/server/bot/havocbot/vore_ai.qc

   1 .float status_teamhealing; // 0 = can't team heal, 1 = can team heal, 2 = team healing right now
   2
   3 float Swallow_condition_check_bot(entity prey)
   4 {
   5         // checks the necessary conditions for a bot to swallow a player
   6
   7         if(Swallow_condition_check(prey)) // check the normal conditions of the vore system
   8         if(time >= prey.spawnshieldtime) // spawn shield means you are invincible
   9         if not(prey.BUTTON_CHAT) // don't eat players who are chatting
  10         if(self.health > cvar("g_balance_vore_kick_damage_max")) // explained below
  11                 return TRUE;
  12         return FALSE;
  13 }
  14
  15 .float decide_swallow, decide_pred, decide_prey;
  16 void Vore_AI_Teamheal(entity prey)
  17 {
  18         // allows bots to use the teamheal feature and heal damaged team mates
  19         // the prey entity is only used when it's available (a player is detected in range)
  20
  21         entity head;
  22
  23         if not(teams_matter && cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))
  24                 return;
  25         if(self.deadflag != DEAD_NO || self.predator.classname == "player" || self.flagcarried || self.digesting) // a flag carrier can't waste time on team healing
  26         {
  27                 self.status_teamhealing = 0;
  28                 return;
  29         }
  30
  31         // if a teamheal is ongoing, decide whether or not to abandon it when seeing a foe we can attack
  32         // this only causes the bot to regurgitate their team mate when seeing an enemy, with the hope that our enemy will still be there once we can swallow
  33         // the higher the skill, the greater the chance a bot will abandon a team heal for an enemy
  34         if(self.status_teamhealing > 1)
  35         if(Swallow_condition_check_bot(prey))
  36         if(prey.team != self.team)
  37         if(random() * 10 < cvar("bot_ai_vore_teamhealabandon") * skill / self.bot_voreteamheal) // there are 10 bot skill steps
  38                 self.BUTTON_REGURGITATE = TRUE; // release the team mate
  39
  40         // decide if we can teamheal or not
  41         if(self.stomach_load)
  42         {
  43                 self.status_teamhealing = 2; // consider a team mate is in our stomach and we are teamhealing, until proven otherwise below
  44
  45                 FOR_EACH_PLAYER(head)
  46                 {
  47                         if(head.predator == self)
  48                         if(head.team != self.team)
  49                         {
  50                                 self.status_teamhealing = 0; // there's a foe in our stomach, we can't teamheal now
  51                                 return;
  52                         }
  53                 }
  54         }
  55         else
  56                 self.status_teamhealing = 1; // if our stomach is empty, it means we can decide to teamheal
  57
  58         // now that we're decided if we can teamheal or not, lets go ahead and do so
  59
  60         // if we are holding a team mate that's been healed to the limit, we can release them
  61         if not(cvar("bot_ai_vore_keepinstomach"))
  62         FOR_EACH_PLAYER(head)
  63         {
  64                 if(head.predator == self) // head is automatically a team mate, or we wouldn't be reaching this part of the code
  65                 if(head.health >= cvar("g_balance_vore_teamheal_stable"))
  66                         self.BUTTON_REGURGITATE = TRUE; // release the team mate
  67         }
  68
  69         // check if we can heal a team mate we come across, and if so swallow them
  70         if(prey.team == self.team)
  71         if(Swallow_condition_check_bot(prey))
  72         if(prey.health < cvar("g_balance_vore_teamheal_stable"))
  73         if not(prey.digesting) // if our team mate is digesting someone, he likely wouldn't want us ruining his frag
  74         if not(prey.flagcarried) // don't eat the flag carrier and ruin his job
  75         if not(prey.BUTTON_ATCK || prey.BUTTON_ATCK2) // our team mate wouldn't want us eating him while he's firing
  76         if(time > self.decide_swallow)
  77         {
  78                 if(skill >= random() * 10) // there are 10 bot skill steps
  79                         self.BUTTON_ATCK = TRUE; // swallow the team mate
  80                 self.decide_swallow = time + cvar("bot_ai_vore_decide_swallow") / self.bot_vorethinkpred; // this is needed to take a proper decision, otherwise the code would execute each frame and return TRUE quickly
  81         }
  82 }
  83
  84 void Vore_AI()
  85 {
  86         // main vore AI code
  87
  88         if(!cvar("g_vore")) // the vore system is disabled
  89                 return;
  90         if(cvar("bot_nofire") || !skill || (g_rpg && cvar("g_rpg_botattack") < 1))
  91                 return;
  92
  93         float randomtry;
  94         randomtry = random() * 10; // there are 10 bot skill steps
  95
  96 // --------------------------------
  97 // Predator bot behavior:
  98 // --------------------------------
  99
 100         if(self.predator.classname != "player")
 101         {
 102                 // finding and swallowing a player
 103
 104                 // aim toward the nearest possible victim. The greater the skill, the quicker the aim
 105                 // this only does the aiming, checking and swallowing is handled below
 106                 entity head;
 107                 head = findradius(self.origin, cvar("g_balance_vore_swallow_range"));
 108                 while(head)
 109                 {
 110                         if(Swallow_condition_check_bot(head))
 111                                 bot_aimdir(head.origin + head.view_ofs - self.origin - self.view_ofs, -1);
 112                         head = head.chain;
 113                 }
 114
 115                 // now do the actual checking and swallowing
 116                 entity prey;
 117                 float decide_pred_time, fear;
 118
 119                 prey = Swallow_player_check();
 120                 fear = 1;
 121
 122                 // check if we should run the Teamhealing AI rather than continuing with the normal vore AI
 123                 Vore_AI_Teamheal(prey);
 124                 if(self.status_teamhealing > 1) // if we are teamhealing, there's nothing to do from here on
 125                         return;
 126
 127                 if(prey.items & IT_STRENGTH) // avoid eating bots that have the Strenght powerup
 128                         fear += cvar("bot_ai_vore_fear") * self.bot_vorefear;
 129                 if(prey.items & IT_INVINCIBLE) // avoid eating bots that have the Invincible powerup
 130                         fear += cvar("bot_ai_vore_fear") * self.bot_vorefear;
 131                 fear += self.stomach_load; // the bigger our stomach, the less we want to put someone else in there
 132                 decide_pred_time = cvar("bot_ai_vore_decide_pred") / skill / self.bot_vorethinkpred;
 133
 134                 if(time > self.decide_swallow && cvar("g_vore_digestion"))
 135                 if(Swallow_condition_check_bot(prey))
 136                 {
 137                         // the greater the skill, the higher the chance bots will swallow someone each attempt
 138                         if(skill / fear >= randomtry)
 139                         if not(teams_matter && prey.team == self.team)
 140                         {
 141                                 self.BUTTON_ATCK = TRUE; // swallow
 142                                 self.decide_pred = time + decide_pred_time; // time before the bot decides what to do with his prey
 143                         }
 144                         self.decide_swallow = time + cvar("bot_ai_vore_decide_swallow") / self.bot_vorethinkpred; // this is needed to take a proper decision, otherwise the code would execute each frame and return TRUE quickly
 145                 }
 146
 147                 // deciding what to do with a victim:
 148
 149                 if(self.stomach_load && time > self.decide_pred)
 150                 {
 151                         // if the predator's health is smaller than the maximum damage a stomach kick can do, regurgitate the player(s)
 152                         // otherwise the predator is putting himself at risk by keeping you inside
 153                         if(self.health <= cvar("g_balance_vore_kick_damage_max"))
 154                                 self.BUTTON_REGURGITATE = TRUE;
 155
 156                         else if(!self.digesting && cvar("g_vore_digestion"))
 157                         {
 158                                 // the higher the skill, the faster bots will start to digest
 159                                 if not(g_rpg && cvar("g_rpg_botattack") < 2)
 160                                 if(skill >= randomtry)
 161                                         self.BUTTON_DIGEST = TRUE; // digest
 162
 163                                 self.decide_pred = time + decide_pred_time; // time before the bot decides what to do with his prey
 164                         }
 165                 }
 166         }
 167
 168 // --------------------------------
 169 // Prey bot behavior:
 170 // --------------------------------
 171
 172         if(self.predator.classname == "player" && time > self.decide_prey)
 173         {
 174                 // all we can do in the stomach is kick and do some damage / try to escape, or leave if the circumstances allow it and we should
 175
 176                 float decide_prey_time;
 177                 decide_prey_time = cvar("bot_ai_vore_decide_prey") / skill / self.bot_vorethinkprey;
 178
 179                 if(cvar("g_vore_kick"))
 180                 if not(g_rpg && cvar("g_rpg_botattack") < 2)
 181                 if not(teams_matter && self.team == self.predator.team)
 182                 {
 183                         // the higher the skill, the more the bot will kick in your stomack
 184                         if(skill >= randomtry)
 185                         if not(teams_matter && self.team == self.predator.team) // if someone from the same team is in the belly, don't kick the predator
 186                                 self.BUTTON_ATCK = TRUE; // kick
 187                 }
 188
 189                 // if a bot can willingly leave the predator, do so unless there's a reason not to
 190                 if(self.stat_canleave)
 191                 {
 192                         if(self.predator.digesting) // our predator is digesting, so get out of him regardless of who he is
 193                                 self.BUTTON_JUMP = TRUE; // leave
 194                         else if not(g_rpg && cvar("g_rpg_botattack") < 2)
 195                         {
 196                                 if not(teams_matter && self.team == self.predator.team && cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable")) // we are being team healed, don't leave
 197                                 if not(teams_matter && self.team == self.predator.team && cvar("bot_ai_vore_stayinstomach")) // bots are not supposed to leave a team mate's stomach automatically
 198                                         self.BUTTON_JUMP = TRUE; // leave
 199                         }
 200                 }
 201
 202                 self.decide_prey = time + decide_prey_time; // time before the bot decides what to do with their predator
 203         }
 204 }