data/qcsrc/server/bot/havocbot/vore_ai.qc

   1 .float status_teamhealing; // 0 = can't team heal, 1 = can team heal, 2 = team healing currently
   2
   3 entity Swallow_distance_check_bot(entity e)
   4 {
   5         // check if we can swallow a player instead of firing our weapon
   6         vector w_shotorg, w_shotdir;
   7         w_shotorg = self.origin + self.view_ofs;
   8         w_shotdir = v_forward;
   9
  10         WarpZone_traceline_antilag(e, w_shotorg, w_shotorg + w_shotdir * cvar("g_balance_vore_swallow_range"), FALSE, e, ANTILAG_LATENCY(e));
  11         if(trace_fraction < 1)
  12         if(trace_ent.classname == "player")
  13                 return trace_ent;
  14         return world;
  15 }
  16
  17 float Swallow_condition_check_bot(entity prey)
  18 {
  19         // checks the necessary conditions for a bot to swallow another player
  20         if(prey != self && prey.classname == "player" && prey.eater.classname != "player" && prey.deadflag == DEAD_NO && !prey.BUTTON_CHAT) // we can't swallow someone who's already in someone else's stomach
  21         if(self.eater.classname != "player" && self.stomach_load < cvar("g_balance_vore_swallow_limit") && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves
  22         if not(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)
  23         if(self.health > cvar("g_balance_vore_kick_damage_max")) // explained below
  24                 return TRUE;
  25         return FALSE;
  26 }
  27
  28 void Vore_AI_Teamheal(entity prey)
  29 {
  30         // allows bots to take advantage of the teamheal feature in team games, and use this feature to heal damaged team mates
  31
  32         if not(teamplay)
  33                 return;
  34
  35         self.status_teamhealing = 1; // start from the premise we can teamheal until proven otherwise
  36         if(self.deadflag != DEAD_NO || self.eater.classname == "player")
  37                 self.status_teamhealing = 0;
  38
  39         // if we are holding a team mate that's been healed to the max, we can release them
  40         // also use this check to not go any further if someone from the enemy team is in our stomach
  41         entity head;
  42         if(self.stomach_load)
  43         {
  44                 FOR_EACH_PLAYER(head)
  45                 {
  46                         if(head.eater.classname == "player")
  47                         {
  48                                 if(head.team == self.team)
  49                                 {
  50                                         if(head.health >= cvar("g_balance_vore_teamheal_stable"))
  51                                                 self.BUTTON_REGURGITATE = TRUE; // release the team mate
  52                                 }
  53                                 else
  54                                 {
  55                                         self.status_teamhealing = 0; // someone from the enemy team is in our belly, which means we can't be teamhealing any more
  56                                         return;
  57                                 }
  58                         }
  59                 }
  60         }
  61
  62         // check if we can heal a damaged team mate we came across, and if so swallow them
  63         if(self.status_teamhealing)
  64         if(prey.classname == "player" && prey.team == self.team)
  65         if not(prey.flagcarried) // don't eat the flag carrier and ruin his job
  66         if(Swallow_condition_check_bot(prey))
  67         if(prey.health < cvar("g_balance_vore_teamheal_stable"))
  68         {
  69                 self.BUTTON_ATCK = TRUE; // swallow
  70                 self.status_teamhealing = 2;
  71         }
  72 }
  73
  74 .float swallow_retry, decide_delay1, decide_delay2;
  75 void Vore_AI()
  76 {
  77         if(cvar("bot_nofire") || !skill)
  78                 return;
  79
  80 // --------------------------------
  81 // Predator bot behavior:
  82 // --------------------------------
  83
  84         // finding and swallowing a victim:
  85
  86         // aim toward the nearest possible victim. The greater the skill the quicker the aim. This only does the aiming, checking and swallowing is handled below
  87         entity scan;
  88         scan = findradius(self.origin, cvar("g_balance_vore_swallow_range"));
  89         if(Swallow_condition_check_bot(scan))
  90                 bot_aimdir(scan.origin + scan.view_ofs - self.origin - self.view_ofs, -1);
  91
  92         // now do the actual checking and swallowing
  93         entity prey;
  94         float random_try;
  95         float decide_prey, decide_pred;
  96
  97         prey = Swallow_distance_check_bot(self);
  98         random_try = random() * 10; // there are 10 bot skill steps
  99         if(prey.items & IT_STRENGTH) // avoid eating bots that have the Strenght powerup
 100                 random_try /= cvar("bot_ai_vore_decide_fear");
 101         if(prey.items & IT_INVINCIBLE) // avoid eating bots that have the Invincible powerup
 102                 random_try /= cvar("bot_ai_vore_decide_fear");
 103         decide_prey = cvar("bot_ai_vore_decide_prey") / (skill * 2 + 1);
 104         decide_pred = cvar("bot_ai_vore_decide_pred") / (skill * 2 + 1);
 105
 106         if(time > self.swallow_retry)
 107         if(Swallow_condition_check_bot(prey))
 108         {
 109                 // the greater the skill, the higher the chance bots will swallow someone each attempt
 110                 if(skill >= random_try)
 111                 if not(teamplay && prey.team == self.team)
 112                 {
 113                         self.BUTTON_ATCK = TRUE; // swallow
 114                         self.decide_delay1 = time + decide_pred; // time before the bot decides what to do with their prey
 115                 }
 116                 self.swallow_retry = time + 0.5; // bots retry swallowing every 0.5 seconds, otherwise each frame would be random chance
 117         }
 118
 119         Vore_AI_Teamheal(prey);
 120         if(self.status_teamhealing > 1) // if we are teamhealing, there's nothing to do from here on
 121                 return;
 122
 123         // deciding what to do with a victim:
 124
 125         if(self.stomach_load > 0 && time > self.decide_delay1)
 126         {
 127                 // if the predator's health is smaller than the maximum amount of damage a stomach kick can do, regurgitate the player(s)
 128                 // otherwise the predator is putting himself at risk by keeping someone inside
 129                 if(self.health <= cvar("g_balance_vore_kick_damage_max"))
 130                         self.BUTTON_REGURGITATE = TRUE;
 131
 132                 else if(!self.digesting)
 133                 {
 134                         // the higher the skill, the faster bots will start to digest you
 135                         if(skill >= random_try)
 136                                 self.BUTTON_DIGEST = TRUE; // digest
 137
 138                         self.decide_delay1 = time + decide_pred; // time before the bot decides what to do with their prey
 139                 }
 140         }
 141
 142 // --------------------------------
 143 // Prey bot behavior:
 144 // --------------------------------
 145
 146         // all we can do in the stomach is kick and do some damage / try to escape
 147         if(self.eater.classname == "player" && time > self.decide_delay2)
 148         {
 149                 // the higher the skill, the more the bot will kick in your stomack
 150                 if(skill >= random_try)
 151                 if not(teamplay && prey.team == self.team) // if someone from the same team somehow made it in the belly, don't kick the eater
 152                         self.BUTTON_ATCK = TRUE; // kick
 153
 154                 self.decide_delay2 = time + decide_prey; // time before the bot decides what to do with their predator
 155         }
 156 }