data/qcsrc/server/cheats.qc

   1 void CopyBody(float keepvelocity);
   2
   3 #ifdef NOCHEATS
   4
   5 float CheatImpulse(float i) { return 0; }
   6 float CheatCommand(float argc) { return 0; }
   7 float CheatFrame() { return 0; }
   8 void CheatInit() { cheatcount_total = world.cheatcount; }
   9 void CheatShutdown() { }
  10 void CheatInitClient() { }
  11 void CheatShutdownClient() { }
  12 void Drag_MoveDrag(entity from, entity to) { }
  13
  14 #else
  15
  16 .float maycheat;
  17 float sv_cheats;
  18 float autocvar_sv_cheats;
  19
  20 #define CHIMPULSE_SPEEDRUN_INIT 30
  21 #define CHIMPULSE_GIVE_ALL 99
  22 #define CHIMPULSE_CLONE_MOVING 140
  23 #define CHIMPULSE_SPEEDRUN 141
  24 #define CHIMPULSE_CLONE_STANDING 142
  25 #define CHIMPULSE_TELEPORT 143
  26 #define CHIMPULSE_R00T 148
  27
  28 #define CHRAME_DRAG 8
  29
  30 void CheatInit()
  31 {
  32         sv_cheats = cvar("sv_cheats");
  33 }
  34
  35 void CheatShutdown()
  36 {
  37 }
  38
  39 void CheatInitClient()
  40 {
  41 }
  42
  43 void CheatShutdownClient()
  44 {
  45 }
  46
  47 float CheatsAllowed(float i, float argc, float fr) // the cheat gets passed as argument for possible future ACL checking
  48 {
  49         // dead people cannot cheat
  50         if(self.deadflag != DEAD_NO)
  51                 return 0;
  52         if(self.classname != "player")
  53                 return 0;
  54
  55         // sv_clones
  56         if(i == CHIMPULSE_CLONE_MOVING || i == CHIMPULSE_CLONE_STANDING)
  57                 if(self.lip < sv_clones)
  58                         return 1;
  59
  60         // haha
  61         if(self.maycheat)
  62                 return 1;
  63
  64         // sv_cheats
  65         if(sv_cheats && autocvar_sv_cheats)
  66                 return 1;
  67
  68         // if we get here, player is not allowed to cheat. Log it.
  69         if(i)
  70                 bprint(sprintf("Player %s^7 tried to use cheat 'impulse %d'\n", self.netname, i));
  71         else if(argc)
  72                 bprint(sprintf("Player %s^7 tried to use cheat '%s'\n", self.netname, argv(0)));
  73         else if(fr)
  74                 bprint(sprintf("Player %s^7 tried to use cheat frame %d\n", self.netname, fr));
  75         else
  76                 bprint(sprintf("Player %s^7 tried to use an unknown cheat\n", self.netname));
  77
  78         return 0;
  79 }
  80
  81 #define BEGIN_CHEAT_FUNCTION() \
  82         float cheating, attempting; \
  83         cheating = 0; attempting = 0
  84 #define DID_CHEAT() \
  85         ++cheating
  86 #define ADD_CHEATS(e,n) \
  87         cheatcount_total += n; \
  88         e.cheatcount += n
  89 #define END_CHEAT_FUNCTION() \
  90         ADD_CHEATS(self,cheating); \
  91         return attempting
  92 #define IS_CHEAT(i,argc,fr) \
  93         ++attempting; \
  94         if(!CheatsAllowed(i,argc,fr)) \
  95                 break
  96
  97 float CheatImpulse(float i)
  98 {
  99         BEGIN_CHEAT_FUNCTION();
 100         switch(i)
 101         {
 102                 entity e, e2;
 103                 vector org;
 104
 105                 case CHIMPULSE_SPEEDRUN_INIT: // deploy personal waypoint
 106                         // shared with regular waypoint init, so this is not a cheat by itself
 107                         if(!self.personal)
 108                         {
 109                                 self.personal = spawn();
 110                                 self.personal.classname = "personal_wp";
 111                         }
 112                         self.personal.origin = self.origin;
 113                         self.personal.v_angle = self.v_angle;
 114                         self.personal.velocity = self.velocity;
 115                         self.personal.ammo_fuel = self.ammo_fuel;
 116                         self.personal.health = self.health;
 117                         self.personal.armorvalue = self.armorvalue;
 118                         self.personal.weapons = self.weapons;
 119                         self.personal.items = self.items;
 120                         self.personal.pauserotarmor_finished = self.pauserotarmor_finished;
 121                         self.personal.pauserothealth_finished = self.pauserothealth_finished;
 122                         self.personal.pauserotfuel_finished = self.pauserotfuel_finished;
 123                         self.personal.pauseregen_finished = self.pauseregen_finished;
 124                         self.personal.strength_finished = self.strength_finished;
 125                         self.personal.invincible_finished = self.invincible_finished;
 126                         self.personal.teleport_time = time;
 127                         break; // this part itself doesn't cheat, so let's not count this
 128                 case CHIMPULSE_CLONE_MOVING:
 129                         IS_CHEAT(i, 0, 0);
 130                         makevectors (self.v_angle);
 131                         self.velocity = self.velocity + v_forward * 300;
 132                         CopyBody(1);
 133                         self.lip += 1;
 134                         self.velocity = self.velocity - v_forward * 300;
 135                         DID_CHEAT();
 136                         break;
 137                 case CHIMPULSE_CLONE_STANDING:
 138                         IS_CHEAT(i, 0, 0);
 139                         CopyBody(0);
 140                         self.lip += 1;
 141                         DID_CHEAT();
 142                         break;
 143                 case CHIMPULSE_GIVE_ALL:
 144                         IS_CHEAT(i, 0, 0);
 145                         CheatCommand(tokenize_console("give all"));
 146                         break; // already counted as cheat
 147                 case CHIMPULSE_SPEEDRUN:
 148                         IS_CHEAT(i, 0, 0);
 149                         if(self.personal)
 150                         {
 151                                 self.speedrunning = TRUE;
 152                                 tracebox(self.personal.origin, self.mins, self.maxs, self.personal.origin, MOVE_WORLDONLY, self);
 153                                 if(trace_startsolid)
 154                                 {
 155                                         sprint(self, "Cannot move there, cheater - only waypoints set using g_waypointsprite_personal work\n");
 156                                 }
 157                                 else
 158                                 {
 159                                         // Abort speedrun, teleport back
 160                                         setorigin(self, self.personal.origin);
 161                                         self.oldvelocity = self.velocity = self.personal.velocity;
 162                                         self.angles = self.personal.v_angle;
 163                                         self.fixangle = TRUE;
 164                                         if(self.flagcarried)
 165                                         {
 166                                                 bprint("The ", self.flagcarried.netname, " was returned to base by its carrier\n");
 167                                                 ReturnFlag(self.flagcarried);
 168                                         }
 169                                 }
 170                                 if(g_ctf)
 171                                 {
 172                                         self.ammo_fuel = 999;
 173                                         self.health = start_health;
 174                                         self.armorvalue = start_armorvalue;
 175                                         self.weapons |= weaponsInMap;
 176                                         self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 177                                         self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 178                                         self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 179                                         self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 180                                         self.strength_finished = 0;
 181                                         self.invincible_finished = 0;
 182                                 }
 183                                 else
 184                                 {
 185                                         self.ammo_fuel = self.personal.ammo_fuel;
 186                                         self.health = self.personal.health;
 187                                         self.armorvalue = self.personal.armorvalue;
 188                                         self.weapons = self.personal.weapons;
 189                                         self.items = self.personal.items;
 190                                         self.pauserotarmor_finished = time + self.personal.pauserotarmor_finished - self.personal.teleport_time;
 191                                         self.pauserothealth_finished = time + self.personal.pauserothealth_finished - self.personal.teleport_time;
 192                                         self.pauserotfuel_finished = time + self.personal.pauserotfuel_finished - self.personal.teleport_time;
 193                                         self.pauseregen_finished = time + self.personal.pauseregen_finished - self.personal.teleport_time;
 194                                         self.strength_finished = time + self.personal.strength_finished - self.personal.teleport_time;
 195                                         self.invincible_finished = time + self.personal.invincible_finished - self.personal.teleport_time;
 196                                 }
 197                                 DID_CHEAT();
 198                                 break;
 199                         }
 200                         if(self.deadflag != DEAD_NO)
 201                                 sprint(self, "UR DEAD AHAHAH))\n");
 202                         else
 203                                 sprint(self, "No waypoint set, cheater (use g_waypointsprite_personal to set one)\n");
 204                         break;
 205                 case CHIMPULSE_TELEPORT:
 206                         IS_CHEAT(i, 0, 0);
 207                         if(MoveToRandomMapLocation(self, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((sv_cheats >= 2) ? 100000 : 100), 1024, 256))
 208                         {
 209                                 self.angles_x = -self.angles_x;
 210                                 self.fixangle = TRUE;
 211                                 self.velocity = '0 0 0';
 212                                 DID_CHEAT();
 213                                 break;
 214                         }
 215                         sprint(self, "Emergency teleport could not find a good location, forget it!\n");
 216                         break;
 217                 case CHIMPULSE_R00T:
 218                         IS_CHEAT(i, 0, 0);
 219                         FOR_EACH_PLAYER(e)
 220                         {
 221                                 if( e.playermodel == "models/player/jeandarc.zym"
 222                                                 ||  e.playermodel == "models/player/pyria.zym"
 223                                                 ||  e.playermodel == "models/player/skadi.zym"
 224                                                 || (e.playermodel == "models/player/specop.zym" && random() < 0.5) // you never know
 225                                                 ||  e.playermodel == "models/player/visitant.zym")
 226                                 {
 227                                         makevectors(e.angles);
 228                                         traceline(e.origin, e.origin + v_right * 256, MOVE_NORMAL, e);
 229                                 }
 230                                 else
 231                                 {
 232                                         org_x = random();
 233                                         org_y = random();
 234                                         org_z = 0;
 235                                         org = normalize(org);
 236                                         traceline(e.origin, e.origin + org * 256, MOVE_NORMAL, e); // random direction
 237                                 }
 238
 239                                 org = findbetterlocation(trace_endpos, 12);
 240
 241                                 e2 = spawn();
 242                                 setorigin(e2, org);
 243                                 pointparticles(particleeffectnum("rocket_explode"), org, '0 0 0', 1);
 244                                 sound(e2, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 245                                 RadiusDamage(e2, e, 1000, 0, 128, e, 500, DEATH_CHEAT, world);
 246                                 remove(e2);
 247                         }
 248                         print("404 Sportsmanship not found.\n");
 249                         DID_CHEAT();
 250                         break;
 251         }
 252
 253         END_CHEAT_FUNCTION();
 254 }
 255
 256 void DragBox_Think();
 257 float drag_lastcnt;
 258 float CheatCommand(float argc)
 259 {
 260         BEGIN_CHEAT_FUNCTION();
 261         string cmd;
 262         cmd = argv(0);
 263         switch(cmd)
 264         {
 265                 entity e;
 266                 float effectnum, f;
 267                 vector start, end;
 268                 entity oldself;
 269
 270                 case "pointparticles":
 271                         IS_CHEAT(0, argc, 0);
 272                         if(argc == 5)
 273                         {
 274                                 // arguments:
 275                                 //   effectname
 276                                 //   origin (0..1, on crosshair line)
 277                                 //   velocity
 278                                 //   howmany
 279                                 effectnum = particleeffectnum(argv(1));
 280                                 f = stof(argv(2));
 281                                 crosshair_trace(self);
 282                                 start = (1-f) * self.origin + f * trace_endpos;
 283                                 end = stov(argv(3));
 284                                 f = stof(argv(4));
 285                                 pointparticles(effectnum, start, end, f);
 286                                 DID_CHEAT();
 287                                 break;
 288                         }
 289                         sprint(self, "Usage: sv_cheats 1; restart; cmd pointparticles effectname position(0..1) velocityvector multiplier\n");
 290                         break;
 291                 case "trailparticles":
 292                         IS_CHEAT(0, argc, 0);
 293                         if(argc == 2)
 294                         {
 295                                 // arguments:
 296                                 //   effectname
 297                                 effectnum = particleeffectnum(argv(1));
 298                                 W_SetupShot(self, FALSE, FALSE, "",0);
 299                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 300                                 trailparticles(self, effectnum, w_shotorg, trace_endpos);
 301                                 DID_CHEAT();
 302                                 break;
 303                         }
 304                         sprint(self, "Usage: sv_cheats 1; restart; cmd trailparticles effectname\n");
 305                         break;
 306                 case "make":
 307                         IS_CHEAT(0, argc, 0);
 308                         if(argc == 3)
 309                         {
 310                                 // arguments:
 311                                 //   modelname mode
 312                                 f = stof(argv(2));
 313                                 W_SetupShot(self, FALSE, FALSE, "", 0);
 314                                 traceline(w_shotorg, w_shotorg + w_shotdir * 2048, MOVE_NORMAL, self);
 315                                 if((trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT) || trace_fraction == 1)
 316                                 {
 317                                         sprint(self, "cannot make stuff there (bad surface)\n");
 318                                 }
 319                                 else
 320                                 {
 321                                         e = spawn();
 322                                         e.model = strzone(argv(1));
 323                                         e.mdl = "rocket_explode";
 324                                         e.health = 1000;
 325                                         setorigin(e, trace_endpos);
 326                                         e.effects = EF_NOMODELFLAGS;
 327                                         if(f == 1)
 328                                         {
 329                                                 e.angles = fixedvectoangles2(trace_plane_normal, v_forward);
 330                                                 e.angles = AnglesTransform_ApplyToAngles(e.angles, '-90 0 0'); // so unrotated models work
 331                                         }
 332                                         oldself = self;
 333                                         self = e;
 334                                         spawnfunc_func_breakable();
 335                                         self = oldself;
 336                                         // now, is it valid?
 337                                         if(f == 0)
 338                                         {
 339                                                 tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_NORMAL, e);
 340                                                 if(trace_startsolid)
 341                                                 {
 342                                                         remove(e);
 343                                                         sprint(self, "cannot make stuff there (no space)\n");
 344                                                 }
 345                                                 else
 346                                                         DID_CHEAT();
 347                                         }
 348                                         else
 349                                                 DID_CHEAT();
 350                                 }
 351                         }
 352                         else
 353                                 sprint(self, "Usage: sv_cheats 1; restart; cmd make models/... 0/1/2\n");
 354                         break;
 355                 case "penalty":
 356                         IS_CHEAT(0, argc, 0);
 357                         if(argc == 3)
 358                         {
 359                                 race_ImposePenaltyTime(self, stof(argv(1)), argv(2));
 360                                 DID_CHEAT();
 361                                 break;
 362                         }
 363                         sprint(self, "Usage: sv_cheats 1; restart; cmd penalty 5.0 AHAHAHAHAHAHAH))\n");
 364                         break;
 365                 case "dragbox_spawn":
 366                         IS_CHEAT(0, argc, 0);
 367                         e = spawn();
 368                         e.classname = "dragbox_box";
 369                         e.think = DragBox_Think;
 370                         e.nextthink = time;
 371                         e.solid = -1; // black
 372                         setmodel(e, "null"); // network it
 373                         if(argc == 4)
 374                                 e.cnt = stof(argv(1));
 375                         else
 376                                 e.cnt = max(0, drag_lastcnt);
 377
 378                         e.aiment = spawn();
 379                         e.aiment.classname = "dragbox_corner_1";
 380                         e.aiment.owner = e;
 381                         setmodel(e.aiment, "models/marker.md3");
 382                         e.aiment.skin = 0;
 383                         setsize(e.aiment, '0 0 0', '0 0 0');
 384                         if(argc == 4)
 385                                 setorigin(e.aiment, stov(argv(2)));
 386                         else
 387                         {
 388                                 crosshair_trace(self);
 389                                 setorigin(e.aiment, trace_endpos);
 390                         }
 391
 392                         e.enemy = spawn();
 393                         e.enemy.classname = "dragbox_corner_2";
 394                         e.enemy.owner = e;
 395                         setmodel(e.enemy, "models/marker.md3");
 396                         e.enemy.skin = 1;
 397                         setsize(e.enemy, '0 0 0', '0 0 0');
 398                         end = normalize(self.origin + self.view_ofs - e.aiment.origin);
 399                         end_x = (end_x > 0) * 2 - 1;
 400                         end_y = (end_y > 0) * 2 - 1;
 401                         end_z = (end_z > 0) * 2 - 1;
 402                         if(argc == 4)
 403                                 setorigin(e.enemy, stov(argv(3)));
 404                         else
 405                                 setorigin(e.enemy, e.aiment.origin + 32 * end);
 406
 407                         e.killindicator = spawn();
 408                         e.killindicator.classname = "drag_digit";
 409                         e.killindicator.owner = e;
 410                         setattachment(e.killindicator, e, "");
 411                         setorigin(e.killindicator, '0 0 -8');
 412                         e.killindicator.killindicator = spawn();
 413                         e.killindicator.killindicator.classname = "drag_digit";
 414                         e.killindicator.killindicator.owner = e;
 415                         setattachment(e.killindicator.killindicator, e, "");
 416                         setorigin(e.killindicator.killindicator, '0 0 8');
 417                         DID_CHEAT();
 418                         break;
 419                 case "dragpoint_spawn":
 420                         IS_CHEAT(0, argc, 0);
 421                         e = spawn();
 422                         e.classname = "dragpoint";
 423                         e.think = DragBox_Think;
 424                         e.nextthink = time;
 425                         e.solid = 0; // nothing special
 426                         setmodel(e, "models/marker.md3");
 427                         setsize(e, PL_MIN, PL_MAX);
 428                         e.skin = 2;
 429                         if(argc == 3)
 430                                 e.cnt = stof(argv(1));
 431                         else
 432                                 e.cnt = drag_lastcnt;
 433                         if(argc == 3)
 434                                 setorigin(e, stov(argv(2)));
 435                         else
 436                         {
 437                                 crosshair_trace(self);
 438                                 setorigin(e, trace_endpos + normalize(self.origin + self.view_ofs - trace_endpos));
 439                                 move_out_of_solid(e);
 440                         }
 441
 442                         e.killindicator = spawn();
 443                         e.killindicator.classname = "drag_digit";
 444                         e.killindicator.owner = e;
 445                         setattachment(e.killindicator, e, "");
 446                         setorigin(e.killindicator, '0 0 40');
 447                         e.killindicator.killindicator = spawn();
 448                         e.killindicator.killindicator.classname = "drag_digit";
 449                         e.killindicator.killindicator.owner = e;
 450                         setattachment(e.killindicator.killindicator, e, "");
 451                         setorigin(e.killindicator.killindicator, '0 0 56');
 452                         DID_CHEAT();
 453                         break;
 454                 case "drag_remove":
 455                         IS_CHEAT(0, argc, 0);
 456                         RandomSelection_Init();
 457                         crosshair_trace(self);
 458                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 459                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 460                         for(e = world; (e = find(e, classname, "dragpoint")); )
 461                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 462                         if(RandomSelection_chosen_ent)
 463                         {
 464                                 remove(RandomSelection_chosen_ent.killindicator.killindicator);
 465                                 remove(RandomSelection_chosen_ent.killindicator);
 466                                 if(RandomSelection_chosen_ent.aiment)
 467                                         remove(RandomSelection_chosen_ent.aiment);
 468                                 if(RandomSelection_chosen_ent.enemy)
 469                                         remove(RandomSelection_chosen_ent.enemy);
 470                                 remove(RandomSelection_chosen_ent);
 471                         }
 472                         DID_CHEAT();
 473                         break;
 474                 case "drag_setcnt":
 475                         IS_CHEAT(0, argc, 0);
 476                         if(argc == 2)
 477                         {
 478                                 RandomSelection_Init();
 479                                 crosshair_trace(self);
 480                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 481                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 482                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 483                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 484                                 if(RandomSelection_chosen_ent)
 485                                 {
 486                                         if(substring(argv(1), 0, 1) == "*")
 487                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = RandomSelection_chosen_ent.cnt + stof(substring(argv(1), 1, -1));
 488                                         else
 489                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = stof(argv(1));
 490                                 }
 491                                 DID_CHEAT();
 492                                 break;
 493                         }
 494                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_setcnt cnt\n");
 495                         break;
 496                 case "drag_save":
 497                         IS_CHEAT(0, argc, 0);
 498                         if(argc == 2)
 499                         {
 500                                 f = fopen(argv(1), FILE_WRITE);
 501                                 fputs(f, "cmd drag_clear\n");
 502                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 503                                 {
 504                                         fputs(f, strcat("cmd dragbox_spawn ", ftos(e.cnt), " \"", vtos(e.aiment.origin), "\" \"", vtos(e.enemy.origin), "\"\n"));
 505                                 }
 506                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 507                                 {
 508                                         fputs(f, strcat("cmd dragpoint_spawn ", ftos(e.cnt), " \"", vtos(e.origin), "\"\n"));
 509                                 }
 510                                 fclose(f);
 511                                 DID_CHEAT();
 512                                 break;
 513                         }
 514                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 515                         break;
 516                 case "drag_saveraceent":
 517                         IS_CHEAT(0, argc, 0);
 518                         if(argc == 2)
 519                         {
 520                                 f = fopen(argv(1), FILE_WRITE);
 521                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 522                                 {
 523                                         fputs(f, "{\n");
 524                                         fputs(f, "\"classname\" \"trigger_race_checkpoint\"\n");
 525                                         fputs(f, strcat("\"origin\" \"", ftos(e.absmin_x), " ", ftos(e.absmin_y), " ", ftos(e.absmin_z), "\"\n"));
 526                                         fputs(f, strcat("\"maxs\" \"", ftos(e.absmax_x - e.absmin_x), " ", ftos(e.absmax_y - e.absmin_y), " ", ftos(e.absmax_z - e.absmin_z), "\"\n"));
 527                                         fputs(f, strcat("\"cnt\" \"", ftos(e.cnt), "\"\n"));
 528                                         fputs(f, strcat("\"targetname\" \"checkpoint", ftos(e.cnt), "\"\n"));
 529                                         fputs(f, "}\n");
 530                                 }
 531                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 532                                 {
 533                                         start = '0 0 0';
 534                                         effectnum = 0;
 535                                         for(oldself = world; (oldself = find(oldself, classname, "dragbox_box")); )
 536                                         {
 537                                                 if(e.cnt <= 0 && oldself.cnt == 0 || e.cnt == oldself.cnt)
 538                                                 {
 539                                                         start = start + oldself.origin;
 540                                                         ++effectnum;
 541                                                 }
 542                                         }
 543                                         start *= 1 / effectnum;
 544                                         fputs(f, "{\n");
 545                                         fputs(f, "\"classname\" \"info_player_race\"\n");
 546                                         fputs(f, strcat("\"angle\" \"", ftos(vectoyaw(start - e.origin)), "\"\n"));
 547                                         fputs(f, strcat("\"origin\" \"", ftos(e.origin_x), " ", ftos(e.origin_y), " ", ftos(e.origin_z), "\"\n"));
 548                                         if(e.cnt == -2)
 549                                         {
 550                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 551                                                 fputs(f, "\"race_place\" \"0\"\n");
 552                                         }
 553                                         else if(e.cnt == -1)
 554                                         {
 555                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 556                                                 fputs(f, "\"race_place\" \"-1\"\n");
 557                                         }
 558                                         else
 559                                         {
 560                                                 fputs(f, strcat("\"target\" \"checkpoint", ftos(e.cnt), "\"\n"));
 561                                                 if(e.cnt == 0)
 562                                                 {
 563                                                         // these need race_place
 564                                                         // counting...
 565                                                         effectnum = 1;
 566                                                         for(oldself = world; (oldself = find(oldself, classname, "dragpoint")); )
 567                                                         if(oldself.cnt == 0)
 568                                                         {
 569                                                                 if(vlen(oldself.origin - start) < vlen(e.origin - start))
 570                                                                         ++effectnum;
 571                                                                 else if(vlen(oldself.origin - start) == vlen(e.origin - start) && num_for_edict(oldself) < num_for_edict(e))
 572                                                                         ++effectnum;
 573                                                         }
 574                                                         fputs(f, strcat("\"race_place\" \"", ftos(effectnum), "\"\n"));
 575                                                 }
 576                                         }
 577                                         fputs(f, "}\n");
 578                                 }
 579                                 fclose(f);
 580                                 DID_CHEAT();
 581                                 break;
 582                         }
 583                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 584                         break;
 585                 case "drag_clear":
 586                         IS_CHEAT(0, argc, 0);
 587                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 588                                 remove(e);
 589                         for(e = world; (e = find(e, classname, "dragbox_corner_1")); )
 590                                 remove(e);
 591                         for(e = world; (e = find(e, classname, "dragbox_corner_2")); )
 592                                 remove(e);
 593                         for(e = world; (e = find(e, classname, "dragpoint")); )
 594                                 remove(e);
 595                         for(e = world; (e = find(e, classname, "drag_digit")); )
 596                                 remove(e);
 597                         DID_CHEAT();
 598                         break;
 599                 case "warp":
 600                         IS_CHEAT(0, argc, 0);
 601                         if(argc == 2) if(cvar("g_campaign"))
 602                         {
 603                                 CampaignLevelWarp(stof(argv(1)));
 604                                 DID_CHEAT();
 605                         }
 606                         break;
 607                 case "god":
 608                         IS_CHEAT(0, argc, 0);
 609                         BITXOR_ASSIGN(self.flags, FL_GODMODE);
 610                         if(self.flags & FL_GODMODE)
 611                         {
 612                                 sprint(self, "godmode ON\n");
 613                                 DID_CHEAT();
 614                         }
 615                         else
 616                                 sprint(self, "godmode OFF\n");
 617                         break;
 618                 case "notarget":
 619                         IS_CHEAT(0, argc, 0);
 620                         BITXOR_ASSIGN(self.flags, FL_NOTARGET);
 621                         if(self.flags & FL_NOTARGET)
 622                         {
 623                                 sprint(self, "notarget ON\n");
 624                                 DID_CHEAT();
 625                         }
 626                         else
 627                                 sprint(self, "notarget OFF\n");
 628                         break;
 629                 case "noclip":
 630                         IS_CHEAT(0, argc, 0);
 631                         if(self.movetype != MOVETYPE_NOCLIP)
 632                         {
 633                                 self.movetype = MOVETYPE_NOCLIP;
 634                                 sprint(self, "noclip ON\n");
 635                                 DID_CHEAT();
 636                         }
 637                         else
 638                         {
 639                                 self.movetype = MOVETYPE_WALK;
 640                                 sprint(self, "noclip OFF\n");
 641                         }
 642                         break;
 643                 case "fly":
 644                         IS_CHEAT(0, argc, 0);
 645                         if(self.movetype != MOVETYPE_FLY)
 646                         {
 647                                 self.movetype = MOVETYPE_FLY;
 648                                 sprint(self, "flmodey ON\n");
 649                                 DID_CHEAT();
 650                         }
 651                         else
 652                         {
 653                                 self.movetype = MOVETYPE_WALK;
 654                                 sprint(self, "flymode OFF\n");
 655                         }
 656                         break;
 657                 case "give":
 658                         IS_CHEAT(0, argc, 0);
 659                         if(GiveItems(self, 1, argc))
 660                                 DID_CHEAT();
 661                         break;
 662         }
 663
 664         END_CHEAT_FUNCTION();
 665 }
 666
 667 void Drag_Begin(entity dragger, entity draggee, vector touchpoint);
 668 void Drag_Finish(entity dragger);
 669 float Drag_IsDraggable(entity draggee);
 670 float Drag_MayChangeAngles(entity draggee);
 671 void Drag_MoveForward(entity dragger);
 672 void Drag_SetSpeed(entity dragger, float s);
 673 void Drag_MoveBackward(entity dragger);
 674 void Drag_Update(entity dragger);
 675 float Drag_CanDrag(entity dragger);
 676 float Drag_IsDragging(entity dragger);
 677 void Drag_MoveDrag(entity from, entity to);
 678 .entity dragentity;
 679
 680 float CheatFrame()
 681 {
 682         BEGIN_CHEAT_FUNCTION();
 683
 684         if(Drag_IsDragging(self))
 685         {
 686                 if(self.BUTTON_DRAG)
 687                 {
 688                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 689                         {
 690                                 Drag_MoveForward(self);
 691                                 self.impulse = 0;
 692                         }
 693                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
 694                         {
 695                                 Drag_MoveBackward(self);
 696                                 self.impulse = 0;
 697                         }
 698                         else if(self.impulse >= 1 && self.impulse <= 9)
 699                         {
 700                                 Drag_SetSpeed(self, self.impulse - 1);
 701                         }
 702                         else if(self.impulse == 14)
 703                         {
 704                                 Drag_SetSpeed(self, 9);
 705                         }
 706
 707                         if(frametime)
 708                                 Drag_Update(self);
 709                 }
 710                 else
 711                 {
 712                         Drag_Finish(self);
 713                 }
 714         }
 715         else
 716         {
 717                 if(Drag_CanDrag(self))
 718                         if(self.BUTTON_DRAG)
 719                         {
 720                                 crosshair_trace(self);
 721                                 if(trace_ent)
 722                                         if(Drag_IsDraggable(trace_ent))
 723                                                 switch(0)
 724                                                 {
 725                                                         default:
 726                                                                 IS_CHEAT(0, 0, CHRAME_DRAG);
 727                                                                 if(trace_ent.draggedby)
 728                                                                         Drag_Finish(trace_ent.draggedby);
 729                                                                 if(trace_ent.tag_entity)
 730                                                                         detach_sameorigin(trace_ent);
 731                                                                 Drag_Begin(self, trace_ent, trace_endpos);
 732                                                                 DID_CHEAT();
 733                                                                 break;
 734                                                 }
 735                         }
 736         }
 737
 738         END_CHEAT_FUNCTION();
 739 }
 740
 741
 742
 743
 744
 745 // ENTITY DRAGGING
 746
 747 // on dragger:
 748 .float draggravity;
 749 .float dragspeed; // speed of mouse wheel action
 750 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
 751 .vector draglocalvector; // local attachment vector of the dragentity
 752 .float draglocalangle;
 753 // on draggee:
 754 .entity draggedby;
 755 .float dragmovetype;
 756 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
 757 {
 758         float tagscale;
 759
 760         draggee.dragmovetype = draggee.movetype;
 761         draggee.draggravity = draggee.gravity;
 762         draggee.movetype = MOVETYPE_WALK;
 763         draggee.gravity = 0.00001;
 764         draggee.flags &~= FL_ONGROUND;
 765         draggee.draggedby = dragger;
 766
 767         dragger.dragentity = draggee;
 768
 769         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
 770         dragger.draglocalangle = draggee.angles_y - dragger.v_angle_y;
 771         touchpoint = touchpoint - gettaginfo(draggee, 0);
 772         tagscale = pow(vlen(v_forward), -2);
 773         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
 774         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
 775         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
 776
 777         dragger.dragspeed = 64;
 778 }
 779
 780 void Drag_Finish(entity dragger)
 781 {
 782         entity draggee;
 783         draggee = dragger.dragentity;
 784         if(dragger)
 785                 dragger.dragentity = world;
 786         draggee.draggedby = world;
 787         draggee.movetype = draggee.dragmovetype;
 788         draggee.gravity = draggee.draggravity;
 789
 790         switch(draggee.movetype)
 791         {
 792                 case MOVETYPE_TOSS:
 793                 case MOVETYPE_WALK:
 794                 case MOVETYPE_STEP:
 795                 case MOVETYPE_FLYMISSILE:
 796                 case MOVETYPE_BOUNCE:
 797                 case MOVETYPE_BOUNCEMISSILE:
 798                 case MOVETYPE_PHYSICS:
 799                         break;
 800                 default:
 801                         draggee.velocity = '0 0 0';
 802                         break;
 803         }
 804
 805         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
 806         {
 807                 draggee.velocity = '0 0 0';
 808                 draggee.flags |= FL_ONGROUND; // floating items are FUN
 809         }
 810 }
 811
 812 float Drag_IsDraggable(entity draggee)
 813 {
 814         // TODO add more checks for bad stuff here
 815         if(draggee.classname == "func_bobbing")
 816                 return FALSE;
 817         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
 818                 return FALSE;
 819         if(draggee.classname == "plat")
 820                 return FALSE;
 821         if(draggee.classname == "func_button")
 822                 return FALSE;
 823         if(draggee.model == "")
 824                 return FALSE;
 825         if(draggee.classname == "spectator")
 826                 return FALSE;
 827         if(draggee.classname == "observer")
 828                 return FALSE;
 829         if(draggee.classname == "exteriorweaponentity")
 830                 return FALSE;
 831
 832         return TRUE;
 833 }
 834
 835 float Drag_MayChangeAngles(entity draggee)
 836 {
 837         // TODO add more checks for bad stuff here
 838         if(substring(draggee.model, 0, 1) == "*")
 839                 return FALSE;
 840         return TRUE;
 841 }
 842
 843 void Drag_MoveForward(entity dragger)
 844 {
 845         dragger.dragdistance += dragger.dragspeed;
 846 }
 847
 848 void Drag_SetSpeed(entity dragger, float s)
 849 {
 850         dragger.dragspeed = pow(2, s);
 851 }
 852
 853 void Drag_MoveBackward(entity dragger)
 854 {
 855         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
 856 }
 857
 858 void Drag_Update(entity dragger)
 859 {
 860         vector curorigin, neworigin, goodvelocity;
 861         float f;
 862         entity draggee;
 863
 864         draggee = dragger.dragentity;
 865         draggee.flags &~= FL_ONGROUND;
 866
 867         curorigin = gettaginfo(draggee, 0);
 868         curorigin = curorigin + v_forward * dragger.draglocalvector_x + v_right * dragger.draglocalvector_y + v_up * dragger.draglocalvector_z;
 869         makevectors(dragger.v_angle);
 870         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
 871         goodvelocity = (neworigin - curorigin) * (1 / frametime);
 872
 873         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle > 180)
 874                 dragger.draglocalangle += 360;
 875         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle <= -180)
 876                 dragger.draglocalangle -= 360;
 877
 878         f = min(frametime * 10, 1);
 879         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
 880
 881         if(Drag_MayChangeAngles(draggee))
 882                 draggee.angles_y = draggee.angles_y * (1 - f) + (dragger.v_angle_y + dragger.draglocalangle) * f;
 883
 884         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
 885
 886         te_lightning1(dragger, dragger.origin + dragger.view_ofs, curorigin);
 887 }
 888
 889 float Drag_CanDrag(entity dragger)
 890 {
 891         return (dragger.deadflag == DEAD_NO) || (dragger.classname == "player");
 892 }
 893
 894 float Drag_IsDragging(entity dragger)
 895 {
 896         if(!dragger.dragentity)
 897                 return FALSE;
 898         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
 899         {
 900                 dragger.dragentity = world;
 901                 return FALSE;
 902         }
 903         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
 904         {
 905                 Drag_Finish(dragger);
 906                 return FALSE;
 907         }
 908         return TRUE;
 909 }
 910
 911 void Drag_MoveDrag(entity from, entity to)
 912 {
 913         if(from.draggedby)
 914         {
 915                 to.draggedby = from.draggedby;
 916                 to.draggedby.dragentity = to;
 917                 from.draggedby = world;
 918         }
 919 }
 920
 921
 922
 923
 924
 925
 926 void DragBox_Think()
 927 {
 928         if(self.aiment && self.enemy)
 929         {
 930                 self.origin_x = (self.aiment.origin_x + self.enemy.origin_x) * 0.5;
 931                 self.origin_y = (self.aiment.origin_y + self.enemy.origin_y) * 0.5;
 932                 self.origin_z = (self.aiment.origin_z + self.enemy.origin_z) * 0.5;
 933                 self.maxs_x = fabs(self.aiment.origin_x - self.enemy.origin_x) * 0.5;
 934                 self.maxs_y = fabs(self.aiment.origin_y - self.enemy.origin_y) * 0.5;
 935                 self.maxs_z = fabs(self.aiment.origin_z - self.enemy.origin_z) * 0.5;
 936                 self.mins = -1 * self.maxs;
 937                 setorigin(self, self.origin); setsize(self, self.mins, self.maxs); // link edict
 938         }
 939
 940         if(self.cnt == -1) // actually race_place -1
 941         {
 942                 // show "10 10" for qualifying spawns
 943                 setmodel(self.killindicator, "models/sprites/10.spr32");
 944                 setmodel(self.killindicator.killindicator, "models/sprites/10.spr32");
 945         }
 946         else if(self.cnt == -2) // actually race_place 0
 947         {
 948                 // show "10 0" for loser spawns
 949                 setmodel(self.killindicator, "models/sprites/10.spr32");
 950                 setmodel(self.killindicator.killindicator, "models/sprites/0.spr32");
 951         }
 952         else
 953         {
 954                 setmodel(self.killindicator, strcat("models/sprites/", ftos(mod(self.cnt, 10)), ".spr32"));
 955                 setmodel(self.killindicator.killindicator, strcat("models/sprites/", ftos(floor(self.cnt / 10)), ".spr32"));
 956         }
 957
 958         self.nextthink = time;
 959 }
 960
 961 #endif