data/qcsrc/server/g_grabber.qc

   1 /*============================================\r
   2 \r
   3       Wazat's Voretournament Grabber\r
   4 \r
   5         Contact: Wazat1@gmail.com\r
   6 \r
   7 \r
   8 Installation instructions:\r
   9 --------------------------\r
  10 \r
  11 1. Place grabber.c in your gamec source directory with the other source files.\r
  12 \r
  13 2. Add this line to the bottom of progs.src:\r
  14 \r
  15 gamec/grabber.c\r
  16 \r
  17 3. Open defs.h and add these lines to the very bottom:\r
  18 \r
  19 // Wazat's grabber\r
  20 .entity         grabber;\r
  21 voidGrabberFrame();\r
  22 void RemoveGrabber(entity pl);\r
  23 void SetGrabberBindings();\r
  24 // grabber impulses\r
  25 float GRABBER_FIRE              = 20;\r
  26 float GRABBER_RELEASE           = 21;\r
  27 // (note: you can change the grabber impulse #'s to whatever you please)\r
  28 \r
  29 4. Open client.c and add this to the top of PutClientInServer():\r
  30 \r
  31         RemoveGrabber(self); // Wazat's Grabber\r
  32 \r
  33 5. Find ClientConnect() (in client.c) and add these lines to the bottom:\r
  34 \r
  35         // Wazat's grabber\r
  36         SetGrabberBindings();\r
  37 \r
  38 6. Still in client.c, find PlayerPreThink and add this line just above the call to W_WeaponFrame:\r
  39 \r
  40         GrabberFrame();\r
  41 \r
  42 7. Build and test the mod.  You'll want to bind a key to "+grabber" like this:\r
  43 bind ctrl "+grabber"\r
  44 \r
  45 And you should be done!\r
  46 \r
  47 \r
  48 ============================================*/\r
  49 \r
  50 .string aiment_classname;\r
  51 .float aiment_deadflag;\r
  52 void SetMovetypeFollow(entity ent, entity e)\r
  53 {\r
  54         // FIXME this may not be warpzone aware\r
  55         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow\r
  56         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.\r
  57         ent.aiment = e; // make the hole follow bmodel\r
  58         ent.punchangle = e.angles; // the original angles of bmodel\r
  59         ent.view_ofs = ent.origin - e.origin; // relative origin\r
  60         ent.v_angle = ent.angles - e.angles; // relative angles\r
  61         ent.aiment_classname = strzone(e.classname);\r
  62         ent.aiment_deadflag = e.deadflag;\r
  63 }\r
  64 void UnsetMovetypeFollow(entity ent)\r
  65 {\r
  66         ent.movetype = MOVETYPE_FLY;\r
  67         PROJECTILE_MAKETRIGGER(ent);\r
  68         ent.aiment = world;\r
  69 }\r
  70 float LostMovetypeFollow(entity ent)\r
  71 {\r
  72 /*\r
  73         if(ent.movetype != MOVETYPE_FOLLOW)\r
  74                 if(ent.aiment)\r
  75                         error("???");\r
  76 */\r
  77         if(ent.aiment)\r
  78         {\r
  79                 if(ent.aiment.classname != ent.aiment_classname)\r
  80                         return 1;\r
  81                 if(ent.aiment.deadflag != ent.aiment_deadflag)\r
  82                         return 1;\r
  83         }\r
  84         return 0;\r
  85 }\r
  86 \r
  87 .float grabber_length;\r
  88 .float grabber_switchweapon;\r
  89 \r
  90 void RemoveGrabber(entity pl)\r
  91 {\r
  92         if(pl.grabber == world)\r
  93                 return;\r
  94         remove(pl.grabber);\r
  95         pl.grabber = world;\r
  96         if(pl.movetype == MOVETYPE_FLY)\r
  97                 pl.movetype = MOVETYPE_WALK;\r
  98 \r
  99         //pl.disableclientprediction = FALSE;\r
 100 }\r
 101 \r
 102 void GrabberThink();\r
 103 void Grabber_Stop()\r
 104 {\r
 105         pointparticles(particleeffectnum("grabber_impact"), self.origin, '0 0 0', 1);\r
 106         sound (self, CHAN_PROJECTILE, "weapons/grabber_impact.wav", VOL_BASE, ATTN_NORM);\r
 107 \r
 108         self.state = 1;\r
 109         self.think =GrabberThink;\r
 110         self.nextthink = time;\r
 111         self.touch = SUB_Null;\r
 112         self.velocity = '0 0 0';\r
 113         self.movetype = MOVETYPE_NONE;\r
 114         self.grabber_length = -1;\r
 115 }\r
 116 \r
 117 void GrabberThink()\r
 118 {\r
 119         float spd, dist, minlength, pullspeed, ropestretch, ropeairfriction, rubberforce, newlength, rubberforce_overstretch;\r
 120         vector dir, org, end, v0, dv, v, myorg;\r
 121         if(self.owner.health <= 0 || self.owner.grabber != self)        // how did that happen?\r
 122         {                                                                                                               // well, better fix it anyway\r
 123                 remove(self);\r
 124                 return;\r
 125         }\r
 126         if(LostMovetypeFollow(self))\r
 127         {\r
 128                 RemoveGrabber(self.owner);\r
 129                 return;\r
 130         }\r
 131         if(self.aiment)\r
 132                 WarpZone_RefSys_AddIncrementally(self, self.aiment);\r
 133 \r
 134         self.nextthink = time;\r
 135 \r
 136         makevectors(self.owner.v_angle);\r
 137         org = self.owner.origin + self.owner.view_ofs + v_forward * grabber_shotorigin_x + v_right * grabber_shotorigin_y + v_up * grabber_shotorigin_z;\r
 138         myorg = WarpZone_RefSys_TransformOrigin(self.owner, self, org);\r
 139 \r
 140         if(self.grabber_length < 0)\r
 141                 self.grabber_length = vlen(myorg - self.origin);\r
 142 \r
 143         if(self.state == 1)\r
 144         {\r
 145                 pullspeed = cvar("g_balance_grabber_speed_pull");//2000;\r
 146                 // speed the rope is pulled with\r
 147 \r
 148                 rubberforce = cvar("g_balance_grabber_force_rubber");//2000;\r
 149                 // force the rope will use if it is stretched\r
 150 \r
 151                 rubberforce_overstretch = cvar("g_balance_grabber_force_rubber_overstretch");//1000;\r
 152                 // force the rope will use if it is stretched\r
 153 \r
 154                 minlength = cvar("g_balance_grabber_length_min");//100;\r
 155                 // minimal rope length\r
 156                 // if the rope goes below this length, it isn't pulled any more\r
 157 \r
 158                 ropestretch = cvar("g_balance_grabber_stretch");//400;\r
 159                 // if the rope is stretched by more than this amount, more rope is\r
 160                 // given to you again\r
 161 \r
 162                 ropeairfriction = cvar("g_balance_grabber_airfriction");//0.2\r
 163                 // while hanging on the rope, this friction component will help you a\r
 164                 // bit to control the rope\r
 165 \r
 166                 dir = self.origin - myorg;\r
 167                 dist = vlen(dir);\r
 168                 dir = normalize(dir);\r
 169 \r
 170                 if(cvar("g_grabber_tarzan"))\r
 171                 {\r
 172                         v = v0 = WarpZone_RefSys_TransformVelocity(self.owner, self, self.owner.velocity);\r
 173 \r
 174                         // first pull the rope...\r
 175                         if(self.owner.grabber_state & GRABBER_PULLING)\r
 176                         {\r
 177                                 newlength = self.grabber_length;\r
 178                                 newlength = max(newlength - pullspeed * frametime, minlength);\r
 179 \r
 180                                 if(newlength < dist - ropestretch) // overstretched?\r
 181                                 {\r
 182                                         newlength = dist - ropestretch;\r
 183                                         if(v * dir < 0) // only if not already moving in grabber direction\r
 184                                                 v = v + frametime * dir * rubberforce_overstretch;\r
 185                                 }\r
 186 \r
 187                                 self.grabber_length = newlength;\r
 188                         }\r
 189 \r
 190                         if(self.owner.grabber_state & GRABBER_RELEASING)\r
 191                         {\r
 192                                 newlength = dist;\r
 193                                 self.grabber_length = newlength;\r
 194                         }\r
 195                         else\r
 196                         {\r
 197                                 // then pull the player\r
 198                                 spd = bound(0, (dist - self.grabber_length) / ropestretch, 1);\r
 199                                 v = v * (1 - frametime * ropeairfriction);\r
 200                                 v = v + frametime * dir * spd * rubberforce;\r
 201 \r
 202                                 dv = ((v - v0) * dir) * dir;\r
 203                                 if(cvar("g_grabber_tarzan") >= 2)\r
 204                                 {\r
 205                                         if(self.aiment.movetype == MOVETYPE_WALK)\r
 206                                         {\r
 207                                                 v = v - dv * 0.5;\r
 208                                                 self.aiment.velocity = self.aiment.velocity - dv * 0.5;\r
 209                                                 self.aiment.flags &~= FL_ONGROUND;\r
 210                                                 self.aiment.pusher = self.owner;\r
 211                                                 self.aiment.pushltime = time + cvar("g_maxpushtime");\r
 212                                         }\r
 213                                 }\r
 214 \r
 215                                 self.owner.flags &~= FL_ONGROUND;\r
 216                         }\r
 217 \r
 218                         self.owner.velocity = WarpZone_RefSys_TransformVelocity(self, self.owner, v);\r
 219                 }\r
 220                 else\r
 221                 {\r
 222                         end = self.origin - dir*50;\r
 223                         dist = vlen(end - myorg);\r
 224                         if(dist < 200)\r
 225                                 spd = dist * (pullspeed / 200);\r
 226                         else\r
 227                                 spd = pullspeed;\r
 228                         if(spd < 50)\r
 229                                 spd = 0;\r
 230                         self.owner.velocity = dir*spd;\r
 231                         self.owner.movetype = MOVETYPE_FLY;\r
 232 \r
 233                         self.owner.flags &~= FL_ONGROUND;\r
 234                 }\r
 235         }\r
 236 \r
 237         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');\r
 238         te_beam(self.owner, WarpZone_RefSys_TransformOrigin(self, self.owner, self.origin) + v_forward * (-9), org);\r
 239 }\r
 240 \r
 241 void GrabberTouch (void)\r
 242 {\r
 243         if(SUB_OwnerCheck())\r
 244                 return;\r
 245         if(SUB_NoImpactCheck())\r
 246         {\r
 247                 RemoveGrabber(self.owner);\r
 248                 return;\r
 249         }\r
 250         PROJECTILE_TOUCH;\r
 251 \r
 252         Grabber_Stop();\r
 253 \r
 254         if(other)\r
 255                 if(other.movetype != MOVETYPE_NONE)\r
 256                 {\r
 257                         SetMovetypeFollow(self, other);\r
 258                         WarpZone_RefSys_BeginAddingIncrementally(self, self.aiment);\r
 259                 }\r
 260 \r
 261         //self.owner.disableclientprediction = TRUE;\r
 262 }\r
 263 \r
 264 void Grabber_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)\r
 265 {\r
 266         if(self.health > 0)\r
 267         {\r
 268                 self.health = self.health - damage;\r
 269                 if (self.health <= 0)\r
 270                 {\r
 271                         if(attacker != self.owner)\r
 272                         {\r
 273                                 self.owner.pusher = attacker;\r
 274                                 self.owner.pushltime = time + cvar("g_maxpushtime");\r
 275                         }\r
 276                         RemoveGrabber(self.owner);\r
 277                 }\r
 278         }\r
 279 }\r
 280 \r
 281 void FireGrabber (void)\r
 282 {\r
 283         local entity missile;\r
 284         local vector org;\r
 285 \r
 286         if((arena_roundbased && time < warmup) || (time < game_starttime))\r
 287                 return;\r
 288 \r
 289         makevectors(self.v_angle);\r
 290 \r
 291         // UGLY WORKAROUND: play this on CHAN_WEAPON2 so it can't cut off fire sounds\r
 292         sound (self, CHAN_WEAPON2, "weapons/grabber_fire.wav", VOL_BASE, ATTN_NORM);\r
 293         org = self.origin + self.view_ofs + v_forward * grabber_shotorigin_x + v_right * grabber_shotorigin_y + v_up * grabber_shotorigin_z;\r
 294         pointparticles(particleeffectnum("grapple_muzzleflash"), org, '0 0 0', 1);\r
 295 \r
 296         missile = WarpZone_RefSys_SpawnSameRefSys(self);\r
 297         missile.owner = self;\r
 298         self.grabber = missile;\r
 299         missile.classname = "grabber";\r
 300 \r
 301         missile.movetype = MOVETYPE_FLY;\r
 302         PROJECTILE_MAKETRIGGER(missile);\r
 303 \r
 304         setmodel (missile, "models/grabber.md3"); // precision set below\r
 305         setsize (missile, '-3 -3 -3', '3 3 3');\r
 306         setorigin (missile, org);\r
 307 \r
 308         missile.state = 0; // not latched onto anything\r
 309 \r
 310         W_SetupProjectileVelocityEx(missile, v_forward, v_up, cvar("g_balance_grabber_speed_fly"), 0, 0, 0);\r
 311 \r
 312         missile.angles = vectoangles (missile.velocity);\r
 313         //missile.glow_color = 250; // 244, 250\r
 314         //missile.glow_size = 120;\r
 315         missile.touch =GrabberTouch;\r
 316         missile.think =GrabberThink;\r
 317         missile.nextthink = time + 0.1;\r
 318 \r
 319         missile.effects = /*EF_FULLBRIGHT | EF_ADDITIVE |*/ EF_LOWPRECISION;\r
 320 \r
 321         missile.health = cvar("g_balance_grabber_health");//120\r
 322         missile.event_damage =Grabber_Damage;\r
 323         missile.takedamage = DAMAGE_AIM;\r
 324         missile.damageforcescale = 0;\r
 325 }\r
 326 \r
 327 //  voidGrabberFrame()\r
 328 //  {\r
 329 //         // this function has been modified for Voretournament\r
 330 // -       if (self.BUTTON_GRABBER && g_grabber)\r
 331 //         {\r
 332 // -               if (!self.grabber && self.grabber_time <= time && !self.button6_pressed_before)\r
 333 // -                       if (timeoutStatus != 2) //only allow the player to fire the grabber if the game is not paused (timeout)\r
 334 // -                               FireGrabber();\r
 335 //         }\r
 336 // -       else\r
 337 //         {\r
 338 //                 if (self.grabber)\r
 339 //                         RemoveGrabber(self);\r
 340 //         }\r
 341 // -       self.button6_pressed_before = self.BUTTON_GRABBER;\r
 342 //         /*\r
 343 //         // if I have no grabber or it's not pulling yet, make sure I'm not flying!\r
 344 //         if((self.grabber == world || !self.grabber.state) && self.movetype == MOVETYPE_FLY)\r
 345 \r
 346 void GrabberFrame()\r
 347 {\r
 348         if(timeoutStatus != 2 && self.weapon != WEP_GRABBER)\r
 349         {\r
 350                 // offhand grabber controls\r
 351                 if(self.BUTTON_GRABBER)\r
 352                 {\r
 353                         if not(self.grabber || (self.grabber_state & GRABBER_WAITING_FOR_RELEASE))\r
 354                         {\r
 355                                 self.grabber_state |= GRABBER_FIRING;\r
 356                                 self.grabber_state |= GRABBER_WAITING_FOR_RELEASE;\r
 357                         }\r
 358                 }\r
 359                 else\r
 360                 {\r
 361                         self.grabber_state |= GRABBER_REMOVING;\r
 362                         self.grabber_state &~= GRABBER_WAITING_FOR_RELEASE;\r
 363                 }\r
 364 \r
 365                 self.grabber_state &~= GRABBER_RELEASING;\r
 366                 if(self.BUTTON_CROUCH)\r
 367                 {\r
 368                         self.grabber_state &~= GRABBER_PULLING;\r
 369                         //self.grabber_state |= GRABBER_RELEASING;\r
 370                 }\r
 371                 else\r
 372                 {\r
 373                         self.grabber_state |= GRABBER_PULLING;\r
 374                         //self.grabber_state &~= GRABBER_RELEASING;\r
 375                 }\r
 376         }\r
 377         else if(!(self.items & IT_JETPACK) && self.switchweapon != WEP_GRABBER)\r
 378         {\r
 379                 if(self.BUTTON_GRABBER && !self.grabber_switchweapon)\r
 380                         W_SwitchWeapon(WEP_GRABBER);\r
 381         }\r
 382         self.grabber_switchweapon = self.BUTTON_GRABBER;\r
 383 \r
 384         if(self.weapon != WEP_GRABBER)\r
 385         {\r
 386                 self.grabber_state &~= GRABBER_FIRING;\r
 387                 self.grabber_state |= GRABBER_REMOVING;\r
 388         }\r
 389 \r
 390         if (self.grabber_state & GRABBER_FIRING)\r
 391         {\r
 392                 if (self.grabber)\r
 393                         RemoveGrabber(self);\r
 394                 FireGrabber();\r
 395                 self.grabber_state &~= GRABBER_FIRING;\r
 396         }\r
 397         else if(self.grabber_state & GRABBER_REMOVING)\r
 398         {\r
 399                 if (self.grabber)\r
 400                         RemoveGrabber(self);\r
 401                 self.grabber_state &~= GRABBER_REMOVING;\r
 402         }\r
 403 \r
 404         /*\r
 405         // if I have no grabber or it's not pulling yet, make sure I'm not flying!\r
 406         if((self.grabber == world || !self.grabber.state) && self.movetype == MOVETYPE_FLY)\r
 407         {\r
 408                 self.movetype = MOVETYPE_WALK;\r
 409         }\r
 410         if(self.impulse == GRABBER_FIRE && self.grabber_time <= time)\r
 411         {\r
 412                 // fire grabber\r
 413                 FireGrabber();\r
 414                 return;\r
 415         }\r
 416         else if(self.grabberimpulse == GRABBER_RELEASE)\r
 417         {\r
 418                 // remove grabber, reset movement type\r
 419                 RemoveGrabber(self);\r
 420                 return;\r
 421         }\r
 422         */\r
 423         /*else // make sure the player's movetype is correct\r
 424         {\r
 425                 //if(self.grabber == world && self.movetype == MOVETYPE_FLY)\r
 426                 if((self.grabber == world || !self.grabber.state) && self.movetype == MOVETYPE_FLY)\r
 427                 {\r
 428                         self.movetype = MOVETYPE_WALK;\r
 429                 }\r
 430         }*/\r
 431         // note: The grabber entity does the actual pulling\r
 432 }\r
 433 \r
 434 void GrabberInit()\r
 435 {\r
 436         grabber_shotorigin = shotorg_adjust('26.2148 9.2059 -15.9772', TRUE, FALSE);\r
 437 }\r
 438 \r
 439 void SetGrabberBindings()\r
 440 {\r
 441         // this function has been modified for Voretournament\r
 442         // don't remove these lines! old server or demos coud overwrite the new aliases\r
 443         stuffcmd(self, "alias +grabber +button6\n");\r
 444         stuffcmd(self, "alias -grabber -button6\n");\r
 445 }\r