data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(self.scale) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         vore_w_shotorg = self.origin;\r
  22         vore_w_shotdir = v_forward;\r
  23 \r
  24         WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  25         if(trace_fraction < 1)\r
  26         if(trace_ent.classname == "player")\r
  27                 return trace_ent;\r
  28         return world;\r
  29 }\r
  30 \r
  31 float Swallow_condition_check(entity prey)\r
  32 {\r
  33         // checks the necessary conditions for swallowing a player\r
  34 \r
  35         if(prey != self)\r
  36         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  37         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  38         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  39         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  40         {\r
  41                 string swallow_complain;\r
  42                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  43                         swallow_complain = "You cannot swallow your team mates\n";\r
  44                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  45                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  46                 else if(self.stomach_load >= g_balance_vore_swallow_limit)\r
  47                         swallow_complain = strcat("You cannot swallow more than ^2", ftos(g_balance_vore_swallow_limit), "^7 players at a time\n");\r
  48                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  49                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  50                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  51                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  52 \r
  53                 if(swallow_complain != "")\r
  54                 {\r
  55                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  56                         {\r
  57                                 play2(self, "misc/forbidden.wav");\r
  58                                 sprint(self, swallow_complain);\r
  59                                 self.complain_vore = time + complain_delay_time;\r
  60                         }\r
  61                         return FALSE;\r
  62                 }\r
  63                 return TRUE;\r
  64         }\r
  65         return FALSE;\r
  66 }\r
  67 \r
  68 float Stomach_TeamMates_check(entity pred)\r
  69 {\r
  70         // checks if a player's stomach contains any team mates\r
  71 \r
  72         entity head;\r
  73         if(teams_matter)\r
  74         {\r
  75                 FOR_EACH_PLAYER(head)\r
  76                 {\r
  77                         if(head.predator == pred && head.team == pred.team)\r
  78                                 return TRUE;\r
  79                 }\r
  80         }\r
  81         return FALSE;\r
  82 }\r
  83 \r
  84 float Vore_CanLeave()\r
  85 {\r
  86         if(self.stat_eaten)\r
  87         {\r
  88                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
  89                         return TRUE;\r
  90                 if(teams_matter && self.team == self.predator.team)\r
  91                         return TRUE;\r
  92                 if(g_rpg && cvar("g_rpg_canleave"))\r
  93                         return TRUE;\r
  94         }\r
  95         return FALSE;\r
  96 }\r
  97 \r
  98 // position the camera properly for prey\r
  99 void Vore_SetPreyPositions()\r
 100 {\r
 101         // self is the predator and head is the prey\r
 102 \r
 103         local entity head;\r
 104         local vector origin_apply;\r
 105         local float position_counter;\r
 106 \r
 107         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 108         // else all players overlap in the center. To do this, we run a loop on all players in the same stomach.\r
 109         // For each player, the origin is updated, then a new origin is used for the next player.\r
 110         // This requires that no more than 9 players may be in the stomach at a time!\r
 111         FOR_EACH_PLAYER(head)\r
 112         {\r
 113                 if(head.predator == self)\r
 114                 {\r
 115                         switch(position_counter)\r
 116                         {\r
 117                                 case 0:\r
 118                                         origin_apply = '0 0 0'; // first occupant sits in the middle\r
 119                                         break;\r
 120                                 case 1:\r
 121                                         origin_apply = '1 0 0'; // second occupant sits in the front\r
 122                                         break;\r
 123                                 case 2:\r
 124                                         origin_apply = '-1 0 0'; // third occupant sits in the back\r
 125                                         break;\r
 126                                 case 3:\r
 127                                         origin_apply = '0 1 0'; // fourth occupant sits in the right\r
 128                                         break;\r
 129                                 case 4:\r
 130                                         origin_apply = '0 -1 0'; // fifth occupant sits in the left\r
 131                                         break;\r
 132                                 case 5:\r
 133                                         origin_apply = '1 1 0'; // sixth occupant sits in the front-right\r
 134                                         break;\r
 135                                 case 6:\r
 136                                         origin_apply = '-1 1 0'; // seventh occupant sits in the back-right\r
 137                                         break;\r
 138                                 case 7:\r
 139                                         origin_apply = '1 -1 0'; // eigth occupant sits in the front-left\r
 140                                         break;\r
 141                                 case 8:\r
 142                                         origin_apply = '-1 -1 0'; // ninth occupant sits in the back-left\r
 143                                         break;\r
 144                                 default:\r
 145                                         break;\r
 146                         }\r
 147 \r
 148                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 149                         head.view_ofs = PL_PREY_VIEW_OFS + origin_apply * cvar("g_vore_neighborprey_distance");\r
 150                         head.view_ofs_z *= self.scale; // stomach center depends on predator scale\r
 151 \r
 152                         // change prey height based on scale\r
 153                         float prey_height;\r
 154                                 prey_height = (head.scale - self.scale) * cvar("g_healthsize_vore_pos");\r
 155                         head.view_ofs_z += prey_height;\r
 156 \r
 157                         position_counter += 1;\r
 158                 }\r
 159         }\r
 160 }\r
 161 \r
 162 .float gurgle_oldstomachload;\r
 163 void Vore_GurgleSound()\r
 164 {\r
 165         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 166         {\r
 167                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 168 \r
 169                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 170                 self.gurgle_oldstomachload = self.stomach_load;\r
 171         }\r
 172 }\r
 173 \r
 174 void Vore_WeightApply(entity e)\r
 175 {\r
 176         // apply stomach weight that makes you heavier the more you eat\r
 177         // slowing the player is done in cl_physics.qc\r
 178 \r
 179         if(e.stomach_load != e.vore_oldstomachload)\r
 180                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 181         if(e.gravity == 0)\r
 182                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 183         e.vore_oldstomachload = e.stomach_load;\r
 184 }\r
 185 \r
 186 void Vore_AutoDigest(entity e)\r
 187 {\r
 188         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 189 \r
 190         if(!cvar("g_vore_digestion") || e.digesting)\r
 191                 return;\r
 192         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 193                 return; // this feature is only for players, not bots\r
 194         if(e.stomach_load > 1)\r
 195                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 196         if(Stomach_TeamMates_check(e))\r
 197                 return; // never begin automatic digestion if we've swallowed a team mate\r
 198 \r
 199         e.digesting = TRUE;\r
 200 }\r
 201 \r
 202 void Vore_SwallowModel_Think()\r
 203 {\r
 204         //update the necessary angles to match our view\r
 205         self.angles_x = self.owner.angles_x;\r
 206         self.view_ofs = self.owner.view_ofs;\r
 207         self.alpha = self.owner.cvar_cl_vore_stomachmodel;\r
 208 \r
 209         // if our swallow progress is gone, the swallow model must also go\r
 210         /*if(!self.owner.swallow_progress_prey)\r
 211         {\r
 212                 self.nextthink = 0;\r
 213                 remove(self);\r
 214                 self = world;\r
 215                 return;\r
 216         }*/\r
 217 \r
 218         self.nextthink = time;\r
 219 }\r
 220 \r
 221 .entity swallow_model;\r
 222 void Vore_SwallowModel_Update(entity prey)\r
 223 {\r
 224         // if we don't have a swallow model already, spawn one\r
 225         if(!prey.swallow_model)\r
 226         {\r
 227                 prey.swallow_model = spawn();\r
 228                 \r
 229                 prey.swallow_model.movetype = MOVETYPE_FOLLOW;\r
 230                 prey.swallow_model.solid = SOLID_NOT;\r
 231 \r
 232                 prey.swallow_model.skin = self.skin;\r
 233                 prey.swallow_model.scale = self.scale;\r
 234 \r
 235                 // apply the properties of the prey\r
 236                 prey.swallow_model.aiment = prey;\r
 237 \r
 238                 prey.swallow_model.owner = prey; // owned by the prey\r
 239                 prey.swallow_model.enemy = self; // enemy is the predator\r
 240                 prey.swallow_model.think = Vore_SwallowModel_Think;\r
 241                 prey.swallow_model.nextthink = time;\r
 242         }\r
 243 \r
 244         // if the model or skin of the prey's swallow model don't match those of our current predator, change them\r
 245         string swallow_mdl;\r
 246         swallow_mdl = strcat(substring(self.playermodel, 0, strlen(self.playermodel) - 4), "_swallow.md3"); // 4 is the extension length\r
 247         if(prey.swallow_model.model != swallow_mdl)\r
 248                 setmodel(prey.swallow_model, swallow_mdl);\r
 249         if(prey.swallow_model.skin != self.skin)\r
 250                 prey.swallow_model.skin = self.skin;\r
 251 }\r
 252 \r
 253 .entity pusher;\r
 254 .float pushltime;\r
 255 void Vore_Swallow(entity e)\r
 256 {\r
 257         // this player is being swallowed by another player, apply the proper changes\r
 258 \r
 259         e.vore_oldmovetype = e.movetype;\r
 260         e.vore_oldsolid = e.solid;\r
 261 \r
 262         e.predator = self;\r
 263         setorigin(e, e.predator.origin);\r
 264         e.velocity = '0 0 0';\r
 265         e.movetype = MOVETYPE_FOLLOW;\r
 266         e.solid = SOLID_NOT;\r
 267         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 268 \r
 269         // drop keys (KH) and flags (CTF) when we get swallowed\r
 270         kh_Key_DropAll(e, FALSE);\r
 271         if(e.flagcarried)\r
 272                 DropFlag(e.flagcarried, world, e.predator);\r
 273 \r
 274         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 275                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 276 \r
 277         if(teams_matter && e.team == e.predator.team)\r
 278         {\r
 279                 if(cvar("g_vore_kick"))\r
 280                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 281                 if(cvar("g_vore_digestion"))\r
 282                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 283         }\r
 284 \r
 285         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 286         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 287         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 288         e.predator.stomach_load += 1;\r
 289         e.predator.regurgitate_prepare = 0;\r
 290         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 291         Vore_WeightApply(e.predator);\r
 292         Vore_AutoDigest(e.predator);\r
 293 \r
 294         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 295         e.predator.weapon_delay = time + button_delay_time;\r
 296         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 297         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 298         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 299 }\r
 300 \r
 301 void Vore_SwallowStep(entity e)\r
 302 {\r
 303         if(!cvar("g_balance_vore_swallow_speed_fill"))\r
 304         {\r
 305                 Vore_Swallow(e);\r
 306                 return;\r
 307         }\r
 308 \r
 309         Vore_SwallowModel_Update(e);\r
 310 \r
 311         // increase the progress value until it reaches 1, then swallow the player\r
 312         if(e.swallow_progress_prey < 1)\r
 313         {\r
 314                 float fill;\r
 315                 fill = cvar("g_balance_vore_swallow_speed_fill") * frametime;\r
 316                 if(cvar("g_balance_vore_swallow_speed_fill_scalediff")) // fill rate depends on predator size compared to prey size\r
 317                         fill *= (self.scale / e.scale);\r
 318                 if(cvar("g_balance_vore_swallow_speed_fill_stomachload") && e.stomach_load) // fill rate is influenced by the prey's stomach load\r
 319                         fill /= e.stomach_load;\r
 320 \r
 321                 e.swallow_progress_prey += fill;\r
 322         }\r
 323         else\r
 324         {\r
 325                 Vore_Swallow(e);\r
 326                 e.swallow_progress_prey = 0;\r
 327         }\r
 328 \r
 329         // the predator's progress is how much the prey got swallowed\r
 330         self.swallow_progress_pred = e.swallow_progress_prey;\r
 331 }\r
 332 \r
 333 void Vore_Regurgitate(entity e)\r
 334 {\r
 335         // this player is being regurgitated by their predator, apply the proper changes\r
 336 \r
 337         e.movetype = e.vore_oldmovetype;\r
 338         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 339                 e.solid = e.vore_oldsolid;\r
 340         e.view_ofs_z = PL_VIEW_OFS_z;\r
 341 \r
 342         // apply velocities\r
 343         local vector oldforward, oldright, oldup;\r
 344         oldforward = v_forward;\r
 345         oldright = v_right;\r
 346         oldup = v_up;\r
 347         makevectors(e.predator.v_angle);\r
 348         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 349         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 350         v_forward = oldforward;\r
 351         v_right = oldright;\r
 352         v_up = oldup;\r
 353 \r
 354         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 355         e.pushltime = time + cvar("g_maxpushtime");\r
 356 \r
 357         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
 358         if(cvar("g_balance_vore_swallow_speed_fill"))\r
 359                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
 360 \r
 361         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 362         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 363         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 364         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 365         e.predator.stomach_load -= 1;\r
 366         e.predator.regurgitate_prepare = 0;\r
 367         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 368         Vore_WeightApply(e.predator);\r
 369 \r
 370         // block firing for a small amount of time, or we'll be firing the next frame\r
 371         e.weapon_delay = time + button_delay_time;\r
 372         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 373         e.predator = world;\r
 374 }\r
 375 \r
 376 void Vore_DeadPrey_Configure(entity e)\r
 377 {\r
 378         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 379 \r
 380         if(e.fakeprey || !e.stat_eaten) // we already configured everything\r
 381                 return;\r
 382 \r
 383         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 384         e.fakepredator = e.predator;\r
 385         e.fakeprey = TRUE;\r
 386 \r
 387         // first release the prey from the predator, as dead prey needs to be attached differently\r
 388         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 389         e.predator.stomach_load -= 1;\r
 390         Vore_WeightApply(e.predator);\r
 391         e.predator = world;\r
 392 \r
 393         // now put our dead prey inside the predator's stomach, but only as an effect\r
 394         e.movetype = MOVETYPE_FOLLOW;\r
 395         e.takedamage = DAMAGE_NO;\r
 396         e.solid = SOLID_NOT;\r
 397         e.aiment = e.fakepredator;\r
 398 }\r
 399 \r
 400 void Vore_DeadPrey_Detach(entity e)\r
 401 {\r
 402         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 403         // should only execute after Vore_DeadPrey_Configure has ran first\r
 404 \r
 405         if not(cvar("g_vore_keepdeadprey"))\r
 406                 return;\r
 407 \r
 408         e.fakepredator = world;\r
 409         e.fakeprey = TRUE; // keep fakeprey status\r
 410         e.stat_eaten = 0;\r
 411         e.aiment = world;\r
 412         e.movetype = MOVETYPE_TOSS;\r
 413 }\r
 414 \r
 415 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 416 {\r
 417         if(pred_disconnect)\r
 418         {\r
 419                 if(e.fakeprey)\r
 420                         Vore_DeadPrey_Detach(e);\r
 421                 else\r
 422                         Vore_Regurgitate(e);\r
 423         }\r
 424         else if(self.stat_eaten && !self.fakeprey)\r
 425         {\r
 426                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 427                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
 428                         Vore_DeadPrey_Configure(e);\r
 429                 else\r
 430                         Vore_Regurgitate(e);\r
 431         }\r
 432 }\r
 433 \r
 434 void Vore_Disconnect()\r
 435 {\r
 436         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 437 \r
 438         // prey disconnects or goes spectating while inside someone's belly\r
 439         if(self.stat_eaten)\r
 440                 Vore_PreyRelease(self, TRUE);\r
 441 \r
 442         // pred disconnects or goes spectating with players in their belly\r
 443         entity head;\r
 444         FOR_EACH_PLAYER(head)\r
 445         {\r
 446                 if(head.predator == self || head.fakepredator == self)\r
 447                         Vore_PreyRelease(head, TRUE);\r
 448         }\r
 449         Vore_GurgleSound(); // stop the gurgling sound\r
 450 \r
 451         self.stomach_load = self.gravity = 0; // prevents a bug\r
 452 }\r
 453 \r
 454 .float digestion_step;\r
 455 void Vore_Digest()\r
 456 {\r
 457         // apply digestion to prey\r
 458 \r
 459         if(time > self.digestion_step)\r
 460         {\r
 461                 // if distributed digestion is enabled, reduce digestion strength by the number of prey in our stomach\r
 462                 float reduce;\r
 463                 if(cvar("g_balance_vore_digestion_distribute"))\r
 464                         reduce = self.predator.stomach_load;\r
 465                 else\r
 466                         reduce = 1;\r
 467 \r
 468                 float damage;\r
 469                 damage = cvar("g_balance_vore_digestion_damage") / reduce;\r
 470 \r
 471                 // apply player scale to digestion damage\r
 472                 if(cvar("g_balance_vore_digestion_scalediff"))\r
 473                         damage *= (self.predator.scale / self.scale);\r
 474 \r
 475                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
 476                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 477                         self.predator.health += cvar("g_balance_vore_digestion_vampire") / reduce;\r
 478 \r
 479                 if (self.predator.digestsound_finished < time)\r
 480                 {\r
 481                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 482                         self.predator.digestsound_finished = time + 0.5;\r
 483                 }\r
 484                 self.digestion_step = time + steptime;\r
 485         }\r
 486 \r
 487         if(self.deadflag != DEAD_NO)\r
 488         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 489                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 490 }\r
 491 \r
 492 .float teamheal_step;\r
 493 void Vore_Teamheal()\r
 494 {\r
 495         // apply teamheal\r
 496 \r
 497         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 498         if(time > self.teamheal_step)\r
 499         {\r
 500                 self.health += cvar("g_balance_vore_teamheal");\r
 501                 self.teamheal_step = time + steptime;\r
 502 \r
 503                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 504                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 505                 {\r
 506                         play2(self, "misc/beep.wav");\r
 507                         play2(self.predator, "misc/beep.wav");\r
 508                 }\r
 509         }\r
 510 }\r
 511 \r
 512 void Vore_StomachKick()\r
 513 {\r
 514         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 515 \r
 516         if(time > self.stomachkick_delay)\r
 517         {\r
 518                 float damage;\r
 519                 vector force;\r
 520                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 521                 force = v_forward * cvar("g_balance_vore_kick_force");\r
 522 \r
 523                 // apply player scale to the damage / force of the kick\r
 524                 if(cvar("g_balance_vore_kick_scalediff"))\r
 525                 {\r
 526                         damage *= (self.scale / self.predator.scale);\r
 527                         force *= (self.scale / self.predator.scale);\r
 528                 }\r
 529 \r
 530                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
 531                 sound(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), VOL_BASE, ATTN_NORM);\r
 532                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 533                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 534 \r
 535                 // abort the predator's scheduled regurgitation\r
 536                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
 537                         self.predator.regurgitate_prepare = 0;\r
 538 \r
 539                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 540         }\r
 541 }\r
 542 \r
 543 void Vore_StomachLeave()\r
 544 {\r
 545         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 546 \r
 547         if(Vore_CanLeave())\r
 548                 Vore_Regurgitate(self);\r
 549         else if(time > self.complain_vore)\r
 550         {\r
 551                 play2(self, "misc/forbidden.wav");\r
 552                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 553                 self.complain_vore = time + complain_delay_time;\r
 554         }\r
 555 }\r
 556 \r
 557 void Vore_AutoTaunt()\r
 558 {\r
 559         // triggers ambient vore taunts, for both pred and prey\r
 560 \r
 561         float taunt_time;\r
 562 \r
 563         // predator taunts\r
 564         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 565         {\r
 566                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 567                 {\r
 568                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 569                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 570                 }\r
 571         }\r
 572         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 573         {\r
 574                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 575                 SetAutoTaunt(self, 0, 0);\r
 576         }\r
 577 \r
 578         // prey taunts\r
 579         if(self.stat_eaten && !(teams_matter && self.team == self.predator.team))\r
 580         {\r
 581                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 582                 {\r
 583                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 584                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 585                 }\r
 586         }\r
 587         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 588         {\r
 589                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 590                 SetAutoTaunt(self, 0, 0);\r
 591         }\r
 592 }\r
 593 \r
 594 void Vore_SetSbarRings()\r
 595 {\r
 596         // first clear the ring stats, then configure them if needed\r
 597         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 598         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 599 \r
 600         if(self.stat_eaten)\r
 601         {\r
 602                 if(time <= self.stomachkick_delay)\r
 603                 {\r
 604                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
 605                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 606                 }\r
 607         }\r
 608         else\r
 609         {\r
 610                 if(self.swallow_progress_pred)\r
 611                 {\r
 612                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
 613                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
 614                 }\r
 615                 else if(time <= self.action_delay)\r
 616                 {\r
 617                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
 618                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 619                 }\r
 620 \r
 621                 if(self.swallow_progress_prey)\r
 622                 {\r
 623                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
 624                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
 625                 }\r
 626                 else if(time <= self.regurgitate_prepare)\r
 627                 {\r
 628                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
 629                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 630                 }\r
 631         }\r
 632 }\r
 633 \r
 634 void Vore()\r
 635 {\r
 636         // main vore code, this is where it all happens\r
 637 \r
 638         if(!cvar("g_vore")) // the vore system is disabled\r
 639         {\r
 640                 Vore_Disconnect();\r
 641                 return;\r
 642         }\r
 643 \r
 644         Vore_AutoTaunt();\r
 645 \r
 646         // wash the goo away from players once they leave the stomach\r
 647         if(!self.stat_eaten)\r
 648         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 649         if(self.colormod)\r
 650         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 651         {\r
 652                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 653                 if(self.colormod_x > 1)\r
 654                         self.colormod_x = 1;\r
 655                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 656                 if(self.colormod_y > 1)\r
 657                         self.colormod_y = 1;\r
 658                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 659                 if(self.colormod_z > 1)\r
 660                         self.colormod_z = 1;\r
 661         }\r
 662 \r
 663         // set all vore stats\r
 664         Vore_SetSbarRings();\r
 665         if(self.fakepredator.classname == "player")\r
 666                 self.stat_eaten = num_for_edict(self.fakepredator);\r
 667         else if(self.predator.classname == "player")\r
 668         {\r
 669                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 670                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 671                 self.stat_eaten = num_for_edict(self.predator);\r
 672         }\r
 673         else\r
 674         {\r
 675                 self.stat_stomachload = self.stomach_load;\r
 676                 self.stat_digesting = self.digesting;\r
 677                 self.stat_eaten = 0;\r
 678         }\r
 679         self.stat_canleave = Vore_CanLeave();\r
 680 \r
 681         // don't allow a player inside a player inside another player :)\r
 682         // prevent this by checking if such has happened, and taking the proper measures\r
 683         // this code has a high priority and must not be stopped by any delay, so run it here\r
 684         if(self.predator.stat_eaten)\r
 685         {\r
 686                 entity target_predator, target_predator_predator, oldself;\r
 687                 target_predator = self.predator;\r
 688                 target_predator_predator = self.predator.predator;\r
 689 \r
 690                 Vore_Regurgitate(self);\r
 691 \r
 692                 // now steal our prey's prey if this probability applies\r
 693                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 694                 {\r
 695                         oldself = self;\r
 696                         self = target_predator_predator;\r
 697                         if(Swallow_condition_check(oldself))\r
 698                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 699                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 700                                 Vore_Swallow(oldself);\r
 701                         self = oldself;\r
 702                 }\r
 703         }\r
 704 \r
 705         // the swallow progress of prey and preds idly decrease by this amount\r
 706         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
 707         {\r
 708                 if(self.swallow_progress_pred)\r
 709                 {\r
 710                         self.swallow_progress_pred -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 711                         if(self.swallow_progress_pred < 0)\r
 712                                 self.swallow_progress_pred = 0;\r
 713                 }\r
 714                 if(self.swallow_progress_prey)\r
 715                 {\r
 716                         self.swallow_progress_prey -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 717                         if(self.swallow_progress_prey < 0)\r
 718                                 self.swallow_progress_prey = 0;\r
 719                 }\r
 720         }\r
 721 \r
 722         // apply delays and skip the vore system under some circumstances\r
 723         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 724         {\r
 725                 Vore_Disconnect();\r
 726                 return;\r
 727         }\r
 728         if(self.spectatee_status)\r
 729                 return;\r
 730         if(time < self.system_delay)\r
 731                 return;\r
 732 \r
 733 // --------------------------------\r
 734 // Code that addresses predators:\r
 735 // --------------------------------\r
 736 \r
 737         entity prey;\r
 738         prey = Swallow_player_check();\r
 739 \r
 740         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 741         self.stat_canswallow = 0;\r
 742         if(Swallow_condition_check(prey))\r
 743         {\r
 744                 // canswallow stat, used by the HUD\r
 745                 if(teams_matter && prey.team == self.team)\r
 746                         self.stat_canswallow = 2;\r
 747                 else\r
 748                         self.stat_canswallow = 1;\r
 749 \r
 750                 if(self.BUTTON_ATCK)\r
 751                         Vore_SwallowStep(prey);\r
 752         }\r
 753         else if(prey != world)\r
 754                 self.stat_canswallow = -1;\r
 755 \r
 756         // toggle digestion, if the player has someone in their stomach\r
 757         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 758         {\r
 759                 if(self.stomach_load)\r
 760                 {\r
 761                         if(time > self.digest_button_delay_time)\r
 762                         {\r
 763                                 self.digesting = !self.digesting;\r
 764                                 self.digest_button_delay_time = time + button_delay_time;\r
 765                         }\r
 766                 }\r
 767                 else if(time > self.complain_vore)\r
 768                 {\r
 769                         play2(self, "misc/forbidden.wav");\r
 770                         sprint(self, "There is nothing to digest\n");\r
 771                         self.complain_vore = time + complain_delay_time;\r
 772                 }\r
 773         }\r
 774         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 775                 self.digesting = FALSE;\r
 776 \r
 777         // predator wishes to regurgitate his prey\r
 778         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 779         {\r
 780                 if(self.stomach_load)\r
 781                 {\r
 782                         if(time > self.regurgitate_button_delay_time)\r
 783                         {\r
 784                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 785                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 786                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 787                         }\r
 788                 }\r
 789                 else if(time > self.complain_vore)\r
 790                 {\r
 791                         play2(self, "misc/forbidden.wav");\r
 792                         sprint(self, "There is nothing to regurgitate\n");\r
 793                         self.complain_vore = time + complain_delay_time;\r
 794                 }\r
 795         }\r
 796 \r
 797         if(cvar("g_vore_gurglesound"))\r
 798                 Vore_GurgleSound();\r
 799 \r
 800 // --------------------------------\r
 801 // Code that addresses the prey:\r
 802 // --------------------------------\r
 803 \r
 804         Vore_SetPreyPositions();\r
 805 \r
 806         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 807         if(self.fakeprey)\r
 808         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.stat_eaten)\r
 809                 Vore_DeadPrey_Detach(self);\r
 810 \r
 811         if(!self.stat_eaten)\r
 812                 return;\r
 813 \r
 814         if(self.deadflag != DEAD_NO)\r
 815         {\r
 816                 Vore_PreyRelease(self, FALSE);\r
 817                 return;\r
 818         }\r
 819 \r
 820         if(self.predator.deadflag != DEAD_NO)\r
 821                 Vore_Regurgitate(self);\r
 822         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 823                 Vore_Regurgitate(self);\r
 824 \r
 825         // apply delayed regurgitating if it was scheduled\r
 826         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 827         {\r
 828                 self.predator.regurgitate_prepare = 0;\r
 829                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 830                 Vore_Regurgitate(self);\r
 831         }\r
 832 \r
 833         // execute digesting and team healing\r
 834         if(self.predator.digesting == TRUE)\r
 835                 Vore_Digest();\r
 836         if(teams_matter && self.team == self.predator.team)\r
 837         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 838                 Vore_Teamheal();\r
 839 \r
 840         // execute prey commands\r
 841         if(self.BUTTON_ATCK && cvar("g_vore_kick"))\r
 842                 Vore_StomachKick();\r
 843         if(self.BUTTON_JUMP)\r
 844                 Vore_StomachLeave();\r
 845 \r
 846         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 847         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 848         kh_Key_DropAll(self, FALSE);\r
 849 }