data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float system_delay, swallow_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(self.scale) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         vore_w_shotorg = self.origin;\r
  22         vore_w_shotdir = v_forward;\r
  23 \r
  24         WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  25         if(trace_fraction < 1)\r
  26         if(trace_ent.classname == "player")\r
  27                 return trace_ent;\r
  28         return world;\r
  29 }\r
  30 \r
  31 float Swallow_condition_check(entity prey)\r
  32 {\r
  33         // checks the necessary conditions for swallowing a player\r
  34 \r
  35         if(prey != self)\r
  36         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  37         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  38         if(!self.BUTTON_REGURGITATE && self.swallow_delay < time)\r
  39         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  40         {\r
  41                 string swallow_complain;\r
  42                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  43                         swallow_complain = "You cannot swallow your team mates\n";\r
  44                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  45                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  46                 else if(self.stomach_load >= cvar("g_balance_vore_swallow_limit"))\r
  47                         swallow_complain = strcat("You cannot swallow more than ^2", cvar_string("g_balance_vore_swallow_limit"), "^7 players at a time\n");\r
  48                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  49                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  50                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  51                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  52 \r
  53                 if(swallow_complain != "")\r
  54                 {\r
  55                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  56                         {\r
  57                                 play2(self, "misc/forbidden.wav");\r
  58                                 sprint(self, swallow_complain);\r
  59                                 self.complain_vore = time + complain_delay_time;\r
  60                         }\r
  61                         return FALSE;\r
  62                 }\r
  63                 return TRUE;\r
  64         }\r
  65         return FALSE;\r
  66 }\r
  67 \r
  68 float Stomach_TeamMates_check(entity pred)\r
  69 {\r
  70         // checks if a player's stomach contains any team mates\r
  71 \r
  72         entity head;\r
  73         if(teams_matter)\r
  74         {\r
  75                 FOR_EACH_PLAYER(head)\r
  76                 {\r
  77                         if(head.predator == pred && head.team == pred.team)\r
  78                                 return TRUE;\r
  79                 }\r
  80         }\r
  81         return FALSE;\r
  82 }\r
  83 \r
  84 float Vore_CanLeave()\r
  85 {\r
  86         if(self.stat_eaten)\r
  87         {\r
  88                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
  89                         return TRUE;\r
  90                 if(teams_matter && self.team == self.predator.team)\r
  91                         return TRUE;\r
  92                 if(g_rpg && cvar("g_rpg_canleave"))\r
  93                         return TRUE;\r
  94         }\r
  95         return FALSE;\r
  96 }\r
  97 \r
  98 // position the camera properly for prey\r
  99 void Vore_SetCamera()\r
 100 {\r
 101         if not(self.stat_eaten)\r
 102                 return;\r
 103 \r
 104         self.view_ofs = PL_PREY_VIEW_OFS;\r
 105 \r
 106         float prey_height;\r
 107         if(self.fakeprey)\r
 108                 prey_height = (self.scale - self.fakepredator.scale) * cvar("g_healthsize_vore_pos");\r
 109         else\r
 110                 prey_height = (self.scale - self.predator.scale) * cvar("g_healthsize_vore_pos");\r
 111         self.view_ofs_z += prey_height;\r
 112 }\r
 113 \r
 114 .float gurgle_oldstomachload;\r
 115 void Vore_GurgleSound()\r
 116 {\r
 117         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 118         {\r
 119                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 120 \r
 121                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 122                 self.gurgle_oldstomachload = self.stomach_load;\r
 123         }\r
 124 }\r
 125 \r
 126 void Vore_WeightApply(entity e)\r
 127 {\r
 128         // apply stomach weight that makes you heavier the more you eat\r
 129         // slowing the player is done in cl_physics.qc\r
 130 \r
 131         if(e.stomach_load != e.vore_oldstomachload)\r
 132                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 133         if(e.gravity == 0)\r
 134                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 135         e.vore_oldstomachload = e.stomach_load;\r
 136 }\r
 137 \r
 138 void Vore_AutoDigest(entity e)\r
 139 {\r
 140         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 141 \r
 142         if(!cvar("g_vore_digestion") || e.digesting)\r
 143                 return;\r
 144         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 145                 return; // this feature is only for players, not bots\r
 146         if(e.stomach_load > 1)\r
 147                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 148         if(Stomach_TeamMates_check(e))\r
 149                 return; // never begin automatic digestion if we've swallowed a team mate\r
 150 \r
 151         e.digesting = TRUE;\r
 152 }\r
 153 \r
 154 .entity pusher;\r
 155 .float pushltime;\r
 156 void Vore_Swallow(entity e)\r
 157 {\r
 158         // this player is being swallowed by another player, apply the proper changes\r
 159 \r
 160         e.vore_oldmovetype = e.movetype;\r
 161         e.vore_oldsolid = e.solid;\r
 162 \r
 163         e.predator = self;\r
 164         setorigin(e, e.predator.origin);\r
 165         e.velocity = '0 0 0';\r
 166         e.movetype = MOVETYPE_FOLLOW;\r
 167         e.solid = SOLID_NOT;\r
 168         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 169 \r
 170         // drop keys (KH) and flags (CTF) when we get swallowed\r
 171         kh_Key_DropAll(e, FALSE);\r
 172         if(e.flagcarried)\r
 173                 DropFlag(e.flagcarried, world, e.predator);\r
 174 \r
 175         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 176                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 177 \r
 178         if(teams_matter && e.team == e.predator.team)\r
 179         {\r
 180                 if(cvar("g_vore_kick"))\r
 181                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 182                 if(cvar("g_vore_digestion"))\r
 183                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 184         }\r
 185 \r
 186         PlayerSound(e.predator, playersound_swallow, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 187         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 188         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 189         e.predator.stomach_load += 1;\r
 190         e.predator.regurgitate_prepare = 0;\r
 191         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 192         Vore_WeightApply(e.predator);\r
 193         Vore_AutoDigest(e.predator);\r
 194 \r
 195         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 196         e.predator.weapon_delay = time + button_delay_time;\r
 197         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 198         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 199 }\r
 200 \r
 201 void Vore_Regurgitate(entity e)\r
 202 {\r
 203         // this player is being regurgitated by their predator, apply the proper changes\r
 204 \r
 205         e.movetype = e.vore_oldmovetype;\r
 206         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 207                 e.solid = e.vore_oldsolid;\r
 208         e.view_ofs_z = PL_VIEW_OFS_z;\r
 209 \r
 210         // apply velocities\r
 211         local vector oldforward, oldright, oldup;\r
 212         oldforward = v_forward;\r
 213         oldright = v_right;\r
 214         oldup = v_up;\r
 215         makevectors(e.predator.v_angle);\r
 216         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 217         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 218         v_forward = oldforward;\r
 219         v_right = oldright;\r
 220         v_up = oldup;\r
 221 \r
 222         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 223         e.pushltime = time + cvar("g_maxpushtime");\r
 224 \r
 225         PlayerSound(e.predator, playersound_regurgitate, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 226         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 227         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 228         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 229         e.predator.stomach_load -= 1;\r
 230         e.predator.regurgitate_prepare = 0;\r
 231         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 232         Vore_WeightApply(e.predator);\r
 233 \r
 234         // block firing for a small amount of time, or we'll be firing the next frame\r
 235         e.weapon_delay = time + button_delay_time;\r
 236         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 237         e.predator = world;\r
 238 }\r
 239 \r
 240 void Vore_DeadPrey_Configure(entity e)\r
 241 {\r
 242         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 243 \r
 244         if(e.fakeprey || !e.stat_eaten) // we already configured everything\r
 245                 return;\r
 246 \r
 247         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 248         e.fakepredator = e.predator;\r
 249         e.fakeprey = TRUE;\r
 250 \r
 251         // first release the prey from the predator, as dead prey needs to be attached differently\r
 252         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 253         e.predator.stomach_load -= 1;\r
 254         Vore_WeightApply(e.predator);\r
 255         e.predator = world;\r
 256 \r
 257         // now put our dead prey inside the predator's stomach, but only as an effect\r
 258         e.movetype = MOVETYPE_FOLLOW;\r
 259         e.takedamage = DAMAGE_NO;\r
 260         e.solid = SOLID_NOT;\r
 261         e.aiment = e.fakepredator;\r
 262 }\r
 263 \r
 264 void Vore_DeadPrey_Detach(entity e)\r
 265 {\r
 266         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 267         // should only execute after Vore_DeadPrey_Configure has ran first\r
 268 \r
 269         if not(cvar("g_vore_keepdeadprey"))\r
 270                 return;\r
 271 \r
 272         e.fakepredator = world;\r
 273         e.fakeprey = TRUE; // keep fakeprey status\r
 274         e.aiment = world;\r
 275         e.movetype = MOVETYPE_TOSS;\r
 276 }\r
 277 \r
 278 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 279 {\r
 280         if(pred_disconnect)\r
 281         {\r
 282                 if(e.fakeprey)\r
 283                         Vore_DeadPrey_Detach(e);\r
 284                 else\r
 285                         Vore_Regurgitate(e);\r
 286         }\r
 287         else\r
 288         {\r
 289                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 290                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
 291                         Vore_DeadPrey_Configure(e);\r
 292                 else\r
 293                         Vore_Regurgitate(e);\r
 294         }\r
 295 }\r
 296 \r
 297 void Vore_Disconnect()\r
 298 {\r
 299         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 300 \r
 301         // prey disconnects or goes spectating while inside someone's belly\r
 302         if(self.stat_eaten)\r
 303                 Vore_PreyRelease(self, TRUE);\r
 304 \r
 305         // pred disconnects or goes spectating with players in their belly\r
 306         entity head;\r
 307         FOR_EACH_PLAYER(head)\r
 308         {\r
 309                 if(head.predator == self || head.fakepredator == self)\r
 310                         Vore_PreyRelease(head, TRUE);\r
 311         }\r
 312         Vore_GurgleSound(); // stop the gurgling sound\r
 313 \r
 314         self.stomach_load = self.gravity = 0; // prevents a bug\r
 315 }\r
 316 \r
 317 .float digestion_step;\r
 318 void Vore_Digest()\r
 319 {\r
 320         // apply digestion to prey\r
 321 \r
 322         if(time > self.predator.digestion_step)\r
 323         {\r
 324                 Damage(self, self.predator, self.predator, cvar("g_balance_vore_digestion_damage"), DEATH_DIGESTION, self.origin, '0 0 0');\r
 325                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 326                         self.predator.health += cvar("g_balance_vore_digestion_vampire");\r
 327 \r
 328                 if (self.predator.digestsound_finished < time)\r
 329                 {\r
 330                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 331                         self.predator.digestsound_finished = time + 0.5;\r
 332                 }\r
 333                 self.predator.digestion_step = time + steptime;\r
 334         }\r
 335 \r
 336         if(self.deadflag != DEAD_NO)\r
 337         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 338                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 339 }\r
 340 \r
 341 .float teamheal_step;\r
 342 void Vore_Teamheal()\r
 343 {\r
 344         // apply teamheal\r
 345 \r
 346         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 347         if(time > self.teamheal_step)\r
 348         {\r
 349                 self.health += cvar("g_balance_vore_teamheal");\r
 350                 self.teamheal_step = time + steptime;\r
 351 \r
 352                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 353                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 354                 {\r
 355                         play2(self, "misc/beep.wav");\r
 356                         play2(self.predator, "misc/beep.wav");\r
 357                 }\r
 358         }\r
 359 }\r
 360 \r
 361 .float stomachkick_delay;\r
 362 void Vore_StomachKick()\r
 363 {\r
 364         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 365 \r
 366         if(time > self.stomachkick_delay)\r
 367         {\r
 368                 float damage;\r
 369                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 370 \r
 371                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, v_forward * cvar("g_balance_vore_kick_force"));\r
 372                 sound(self.predator, CHAN_PROJECTILE, "weapons/stomachkick.wav", VOL_BASE, ATTN_NORM);\r
 373                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 374                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 375 \r
 376                 if(random() < cvar("g_balance_vore_kick_escapeprobability"))\r
 377                         Vore_Regurgitate(self);\r
 378 \r
 379                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 380         }\r
 381 }\r
 382 \r
 383 void Vore_StomachLeave()\r
 384 {\r
 385         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 386 \r
 387         if(Vore_CanLeave())\r
 388                 Vore_Regurgitate(self);\r
 389         else if(time > self.complain_vore)\r
 390         {\r
 391                 play2(self, "misc/forbidden.wav");\r
 392                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 393                 self.complain_vore = time + complain_delay_time;\r
 394         }\r
 395 }\r
 396 \r
 397 void Vore_AutoTaunt()\r
 398 {\r
 399         // triggers ambient vore taunts, for both pred and prey\r
 400 \r
 401         float taunt_time;\r
 402 \r
 403         // predator taunts\r
 404         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 405         {\r
 406                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 407                 {\r
 408                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 409                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 410                 }\r
 411         }\r
 412         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 413         {\r
 414                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 415                 SetAutoTaunt(self, 0, 0);\r
 416         }\r
 417 \r
 418         // prey taunts\r
 419         if(self.stat_eaten && !(teams_matter && self.team == self.predator.team))\r
 420         {\r
 421                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 422                 {\r
 423                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 424                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 425                 }\r
 426         }\r
 427         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 428         {\r
 429                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 430                 SetAutoTaunt(self, 0, 0);\r
 431         }\r
 432 }\r
 433 \r
 434 void Vore()\r
 435 {\r
 436         // main vore code, this is where it all happens\r
 437 \r
 438         if(!cvar("g_vore")) // the vore system is disabled\r
 439         {\r
 440                 Vore_Disconnect();\r
 441                 return;\r
 442         }\r
 443 \r
 444         Vore_AutoTaunt();\r
 445 \r
 446         // wash the goo away from players once they leave the stomach\r
 447         if(!self.stat_eaten)\r
 448         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 449         if(self.colormod)\r
 450         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 451         {\r
 452                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 453                 if(self.colormod_x > 1)\r
 454                         self.colormod_x = 1;\r
 455                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 456                 if(self.colormod_y > 1)\r
 457                         self.colormod_y = 1;\r
 458                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 459                 if(self.colormod_z > 1)\r
 460                         self.colormod_z = 1;\r
 461         }\r
 462 \r
 463         // set all vore stats\r
 464         if(self.fakepredator.classname == "player")\r
 465                 self.stat_eaten = num_for_edict(self.fakepredator);\r
 466         else if(self.predator.classname == "player")\r
 467         {\r
 468                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 469                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 470                 self.stat_eaten = num_for_edict(self.predator);\r
 471         }\r
 472         else\r
 473         {\r
 474                 self.stat_stomachload = self.stomach_load;\r
 475                 self.stat_digesting = self.digesting;\r
 476                 self.stat_eaten = 0;\r
 477         }\r
 478         self.stat_canleave = Vore_CanLeave();\r
 479 \r
 480         // don't allow a player inside a player inside another player :)\r
 481         // prevent this by checking if such has happened, and taking the proper measures\r
 482         // this code has a high priority and must not be stopped by any delay, so run it here\r
 483         if(self.predator.stat_eaten)\r
 484         {\r
 485                 entity target_predator, target_predator_predator, oldself;\r
 486                 target_predator = self.predator;\r
 487                 target_predator_predator = self.predator.predator;\r
 488 \r
 489                 Vore_Regurgitate(self);\r
 490 \r
 491                 // now steal our prey's prey if this probability applies\r
 492                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 493                 {\r
 494                         oldself = self;\r
 495                         self = target_predator_predator;\r
 496                         if(Swallow_condition_check(oldself))\r
 497                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 498                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 499                                 Vore_Swallow(oldself);\r
 500                         self = oldself;\r
 501                 }\r
 502         }\r
 503 \r
 504         // apply delays and skip the vore system under some circumstances\r
 505         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 506         {\r
 507                 Vore_Disconnect();\r
 508                 return;\r
 509         }\r
 510         if(self.spectatee_status)\r
 511                 return;\r
 512         if(time < self.system_delay)\r
 513                 return;\r
 514 \r
 515 // --------------------------------\r
 516 // Code that addresses predators:\r
 517 // --------------------------------\r
 518 \r
 519         entity prey;\r
 520         prey = Swallow_player_check();\r
 521 \r
 522         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 523         self.stat_canswallow = 0;\r
 524         if(Swallow_condition_check(prey))\r
 525         {\r
 526                 // canswallow stat, used by the HUD\r
 527                 if(teams_matter && prey.team == self.team)\r
 528                         self.stat_canswallow = 2;\r
 529                 else\r
 530                         self.stat_canswallow = 1;\r
 531 \r
 532                 if(self.BUTTON_ATCK)\r
 533                         Vore_Swallow(prey);\r
 534         }\r
 535         else if(prey != world)\r
 536                 self.stat_canswallow = -1;\r
 537 \r
 538         // toggle digestion, if the player has someone in their stomach\r
 539         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 540         {\r
 541                 if(self.stomach_load)\r
 542                 {\r
 543                         if(time > self.digest_button_delay_time)\r
 544                         {\r
 545                                 self.digesting = !self.digesting;\r
 546                                 self.digest_button_delay_time = time + button_delay_time;\r
 547                         }\r
 548                 }\r
 549                 else if(time > self.complain_vore)\r
 550                 {\r
 551                         play2(self, "misc/forbidden.wav");\r
 552                         sprint(self, "There is nothing to digest\n");\r
 553                         self.complain_vore = time + complain_delay_time;\r
 554                 }\r
 555         }\r
 556         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 557                 self.digesting = FALSE;\r
 558 \r
 559         // predator wishes to regurgitate his prey\r
 560         if(self.BUTTON_REGURGITATE)\r
 561         {\r
 562                 if(self.stomach_load)\r
 563                 {\r
 564                         if(time > self.regurgitate_button_delay_time)\r
 565                         {\r
 566                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 567                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 568                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 569                         }\r
 570                 }\r
 571                 else if(time > self.complain_vore)\r
 572                 {\r
 573                         play2(self, "misc/forbidden.wav");\r
 574                         sprint(self, "There is nothing to regurgitate\n");\r
 575                         self.complain_vore = time + complain_delay_time;\r
 576                 }\r
 577         }\r
 578 \r
 579         if(cvar("g_vore_gurglesound"))\r
 580                 Vore_GurgleSound();\r
 581 \r
 582 // --------------------------------\r
 583 // Code that addresses the prey:\r
 584 // --------------------------------\r
 585 \r
 586         Vore_SetCamera();\r
 587 \r
 588         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 589         if(self.fakeprey)\r
 590         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.stat_eaten)\r
 591                 Vore_DeadPrey_Detach(self);\r
 592 \r
 593         if(!self.stat_eaten)\r
 594                 return;\r
 595 \r
 596         if(self.deadflag != DEAD_NO)\r
 597         {\r
 598                 Vore_PreyRelease(self, FALSE);\r
 599                 return;\r
 600         }\r
 601 \r
 602         if(self.predator.deadflag != DEAD_NO)\r
 603                 Vore_Regurgitate(self);\r
 604         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 605                 Vore_Regurgitate(self);\r
 606 \r
 607         // apply delayed regurgitating if it was scheduled\r
 608         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 609         {\r
 610                 self.predator.regurgitate_prepare = 0;\r
 611                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 612                 Vore_Regurgitate(self);\r
 613         }\r
 614 \r
 615         // execute digesting and team healing\r
 616         if(self.predator.digesting == TRUE)\r
 617                 Vore_Digest();\r
 618         if(teams_matter && self.team == self.predator.team)\r
 619         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 620                 Vore_Teamheal();\r
 621 \r
 622         // execute prey commands\r
 623         if(self.BUTTON_ATCK && cvar("g_vore_kick"))\r
 624                 Vore_StomachKick();\r
 625         if(self.BUTTON_JUMP)\r
 626                 Vore_StomachLeave();\r
 627 \r
 628         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 629         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 630         kh_Key_DropAll(self, FALSE);\r
 631 }