data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(self.scale) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         vore_w_shotorg = self.origin;\r
  22         vore_w_shotdir = v_forward;\r
  23 \r
  24         WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  25         if(trace_fraction < 1)\r
  26         if(trace_ent.classname == "player")\r
  27                 return trace_ent;\r
  28         return world;\r
  29 }\r
  30 \r
  31 float Swallow_condition_check(entity prey)\r
  32 {\r
  33         // checks the necessary conditions for swallowing a player\r
  34 \r
  35         if(prey != self)\r
  36         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  37         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  38         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  39         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  40         {\r
  41                 string swallow_complain;\r
  42                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  43                         swallow_complain = "You cannot swallow your team mates\n";\r
  44                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  45                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  46                 else if(self.stomach_load >= g_balance_vore_swallow_limit)\r
  47                         swallow_complain = strcat("You cannot swallow more than ^2", ftos(g_balance_vore_swallow_limit), "^7 players at a time\n");\r
  48                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  49                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  50                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  51                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  52 \r
  53                 if(swallow_complain != "")\r
  54                 {\r
  55                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  56                         {\r
  57                                 play2(self, "misc/forbidden.wav");\r
  58                                 sprint(self, swallow_complain);\r
  59                                 self.complain_vore = time + complain_delay_time;\r
  60                         }\r
  61                         return FALSE;\r
  62                 }\r
  63                 return TRUE;\r
  64         }\r
  65         return FALSE;\r
  66 }\r
  67 \r
  68 float Stomach_TeamMates_check(entity pred)\r
  69 {\r
  70         // checks if a player's stomach contains any team mates\r
  71 \r
  72         entity head;\r
  73         if(teams_matter)\r
  74         {\r
  75                 FOR_EACH_PLAYER(head)\r
  76                 {\r
  77                         if(head.predator == pred && head.team == pred.team)\r
  78                                 return TRUE;\r
  79                 }\r
  80         }\r
  81         return FALSE;\r
  82 }\r
  83 \r
  84 float Vore_CanLeave()\r
  85 {\r
  86         if(self.stat_eaten)\r
  87         {\r
  88                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
  89                         return TRUE;\r
  90                 if(teams_matter && self.team == self.predator.team)\r
  91                         return TRUE;\r
  92                 if(g_rpg && cvar("g_rpg_canleave"))\r
  93                         return TRUE;\r
  94         }\r
  95         return FALSE;\r
  96 }\r
  97 \r
  98 // position the camera properly for prey\r
  99 void Vore_SetPreyPositions()\r
 100 {\r
 101         // self is the predator and head is the prey\r
 102 \r
 103         local entity head;\r
 104         local vector origin_apply;\r
 105         local float position_counter;\r
 106 \r
 107         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 108         // else all players overlap in the center. To do this, we run a loop on all players in the same stomach.\r
 109         // For each player, the origin is updated, then a new origin is used for the next player.\r
 110         // This requires that no more than 9 players may be in the stomach at a time!\r
 111         FOR_EACH_PLAYER(head)\r
 112         {\r
 113                 if(head.predator == self)\r
 114                 {\r
 115                         switch(position_counter)\r
 116                         {\r
 117                                 case 0:\r
 118                                         origin_apply = '0 0 0'; // first occupant sits in the middle\r
 119                                         break;\r
 120                                 case 1:\r
 121                                         origin_apply = '1 0 0'; // second occupant sits in the front\r
 122                                         break;\r
 123                                 case 2:\r
 124                                         origin_apply = '-1 0 0'; // third occupant sits in the back\r
 125                                         break;\r
 126                                 case 3:\r
 127                                         origin_apply = '0 1 0'; // fourth occupant sits in the right\r
 128                                         break;\r
 129                                 case 4:\r
 130                                         origin_apply = '0 -1 0'; // fifth occupant sits in the left\r
 131                                         break;\r
 132                                 case 5:\r
 133                                         origin_apply = '1 1 0'; // sixth occupant sits in the front-right\r
 134                                         break;\r
 135                                 case 6:\r
 136                                         origin_apply = '-1 1 0'; // seventh occupant sits in the back-right\r
 137                                         break;\r
 138                                 case 7:\r
 139                                         origin_apply = '1 -1 0'; // eigth occupant sits in the front-left\r
 140                                         break;\r
 141                                 case 8:\r
 142                                         origin_apply = '-1 -1 0'; // ninth occupant sits in the back-left\r
 143                                         break;\r
 144                                 default:\r
 145                                         break;\r
 146                         }\r
 147 \r
 148                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 149                         head.view_ofs = PL_PREY_VIEW_OFS + origin_apply * cvar("g_vore_neighborprey_distance");\r
 150                         head.view_ofs_z *= self.scale; // stomach center depends on predator scale\r
 151 \r
 152                         // change prey height based on scale\r
 153                         float prey_height;\r
 154                                 prey_height = (head.scale - self.scale) * cvar("g_healthsize_vore_pos");\r
 155                         head.view_ofs_z += prey_height;\r
 156 \r
 157                         position_counter += 1;\r
 158                 }\r
 159         }\r
 160 }\r
 161 \r
 162 .float gurgle_oldstomachload;\r
 163 void Vore_GurgleSound()\r
 164 {\r
 165         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 166         {\r
 167                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 168 \r
 169                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 170                 self.gurgle_oldstomachload = self.stomach_load;\r
 171         }\r
 172 }\r
 173 \r
 174 void Vore_WeightApply(entity e)\r
 175 {\r
 176         // apply stomach weight that makes you heavier the more you eat\r
 177         // slowing the player is done in cl_physics.qc\r
 178 \r
 179         if(e.stomach_load != e.vore_oldstomachload)\r
 180                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 181         if(e.gravity == 0)\r
 182                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 183         e.vore_oldstomachload = e.stomach_load;\r
 184 }\r
 185 \r
 186 void Vore_AutoDigest(entity e)\r
 187 {\r
 188         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 189 \r
 190         if(!cvar("g_vore_digestion") || e.digesting)\r
 191                 return;\r
 192         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 193                 return; // this feature is only for players, not bots\r
 194         if(e.stomach_load > 1)\r
 195                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 196         if(Stomach_TeamMates_check(e))\r
 197                 return; // never begin automatic digestion if we've swallowed a team mate\r
 198 \r
 199         e.digesting = TRUE;\r
 200 }\r
 201 \r
 202 void Vore_SwallowModel_Think()\r
 203 {\r
 204         //update the necessary angles to match our view\r
 205         //self.angles_x = self.owner.angles_x;\r
 206         //self.view_ofs = self.owner.view_ofs;\r
 207 \r
 208         self.view_ofs = '1 0 0' * 500;\r
 209 \r
 210         // if our swallow progress is gone, the swallow model must also go\r
 211         if(!self.owner.swallow_progress_prey)\r
 212         {\r
 213                 self.nextthink = 0;\r
 214                 remove(self);\r
 215                 self = world;\r
 216                 return;\r
 217         }\r
 218 \r
 219         self.nextthink = time;\r
 220 }\r
 221 \r
 222 .entity swallow_model;\r
 223 void Vore_SwallowModel_Update(entity prey)\r
 224 {\r
 225         // if we don't have a swallow model already, spawn one\r
 226         if(!prey.swallow_model)\r
 227         {\r
 228                 prey.swallow_model = spawn();\r
 229                 \r
 230                 prey.swallow_model.movetype = MOVETYPE_FOLLOW;\r
 231                 prey.swallow_model.solid = SOLID_NOT;\r
 232 \r
 233                 prey.swallow_model.skin = self.skin;\r
 234                 prey.swallow_model.scale = self.scale;\r
 235 \r
 236                 // apply the properties of the prey\r
 237                 prey.swallow_model.viewmodelforclient = prey;\r
 238                 prey.swallow_model.effects |= EF_NOGUNBOB;\r
 239                 prey.swallow_model.alpha = prey.cvar_cl_vore_stomachmodel;\r
 240                 prey.swallow_model.colormap = prey.colormap;\r
 241                 prey.swallow_model.glowmod = prey.glowmod;\r
 242 \r
 243                 prey.swallow_model.owner = prey; // owned by the prey\r
 244                 prey.swallow_model.think = Vore_SwallowModel_Think;\r
 245                 prey.swallow_model.nextthink = time;\r
 246         }\r
 247 \r
 248         // if predator has changed, update the swallow model\r
 249         if(prey.swallow_model.enemy != self)\r
 250         {\r
 251                 setmodel(prey.swallow_model, strcat(substring(self.playermodel, 0, strlen(self.playermodel) - 4), "_swallow.md3")); // 4 is the extension length\r
 252                 prey.swallow_model.skin = self.skin;\r
 253                 prey.swallow_model.enemy = self; // enemy is the predator\r
 254         }\r
 255 }\r
 256 \r
 257 .entity pusher;\r
 258 .float pushltime;\r
 259 void Vore_Swallow(entity e)\r
 260 {\r
 261         // this player is being swallowed by another player, apply the proper changes\r
 262 \r
 263         e.vore_oldmovetype = e.movetype;\r
 264         e.vore_oldsolid = e.solid;\r
 265 \r
 266         e.predator = self;\r
 267         setorigin(e, e.predator.origin);\r
 268         e.velocity = '0 0 0';\r
 269         e.movetype = MOVETYPE_FOLLOW;\r
 270         e.solid = SOLID_NOT;\r
 271         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 272 \r
 273         // drop keys (KH) and flags (CTF) when we get swallowed\r
 274         kh_Key_DropAll(e, FALSE);\r
 275         if(e.flagcarried)\r
 276                 DropFlag(e.flagcarried, world, e.predator);\r
 277 \r
 278         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 279                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 280 \r
 281         if(teams_matter && e.team == e.predator.team)\r
 282         {\r
 283                 if(cvar("g_vore_kick"))\r
 284                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 285                 if(cvar("g_vore_digestion"))\r
 286                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 287         }\r
 288 \r
 289         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 290         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 291         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 292         e.predator.stomach_load += 1;\r
 293         e.predator.regurgitate_prepare = 0;\r
 294         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 295         Vore_WeightApply(e.predator);\r
 296         Vore_AutoDigest(e.predator);\r
 297 \r
 298         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 299         e.predator.weapon_delay = time + button_delay_time;\r
 300         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 301         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 302         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 303 }\r
 304 \r
 305 void Vore_SwallowStep(entity e)\r
 306 {\r
 307         if(!cvar("g_balance_vore_swallow_speed_fill"))\r
 308         {\r
 309                 Vore_Swallow(e);\r
 310                 return;\r
 311         }\r
 312 \r
 313         Vore_SwallowModel_Update(e);\r
 314 \r
 315         // increase the progress value until it reaches 1, then swallow the player\r
 316         if(e.swallow_progress_prey < 1)\r
 317         {\r
 318                 float fill;\r
 319                 fill = cvar("g_balance_vore_swallow_speed_fill") * frametime;\r
 320                 if(cvar("g_balance_vore_swallow_speed_fill_scalediff")) // fill rate depends on predator size compared to prey size\r
 321                         fill *= (self.scale / e.scale);\r
 322                 if(cvar("g_balance_vore_swallow_speed_fill_stomachload") && e.stomach_load) // fill rate is influenced by the prey's stomach load\r
 323                         fill /= e.stomach_load;\r
 324 \r
 325                 e.swallow_progress_prey += fill;\r
 326         }\r
 327         else\r
 328         {\r
 329                 Vore_Swallow(e);\r
 330                 e.swallow_progress_prey = 0;\r
 331         }\r
 332 \r
 333         // the predator's progress is how much the prey got swallowed\r
 334         self.swallow_progress_pred = e.swallow_progress_prey;\r
 335 }\r
 336 \r
 337 void Vore_Regurgitate(entity e)\r
 338 {\r
 339         // this player is being regurgitated by their predator, apply the proper changes\r
 340 \r
 341         e.movetype = e.vore_oldmovetype;\r
 342         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 343                 e.solid = e.vore_oldsolid;\r
 344         e.view_ofs_z = PL_VIEW_OFS_z;\r
 345 \r
 346         // apply velocities\r
 347         local vector oldforward, oldright, oldup;\r
 348         oldforward = v_forward;\r
 349         oldright = v_right;\r
 350         oldup = v_up;\r
 351         makevectors(e.predator.v_angle);\r
 352         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 353         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 354         v_forward = oldforward;\r
 355         v_right = oldright;\r
 356         v_up = oldup;\r
 357 \r
 358         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 359         e.pushltime = time + cvar("g_maxpushtime");\r
 360 \r
 361         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
 362         if(cvar("g_balance_vore_swallow_speed_fill"))\r
 363                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
 364 \r
 365         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 366         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 367         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 368         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 369         e.predator.stomach_load -= 1;\r
 370         e.predator.regurgitate_prepare = 0;\r
 371         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 372         Vore_WeightApply(e.predator);\r
 373 \r
 374         // block firing for a small amount of time, or we'll be firing the next frame\r
 375         e.weapon_delay = time + button_delay_time;\r
 376         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 377         e.predator = world;\r
 378 }\r
 379 \r
 380 void Vore_DeadPrey_Configure(entity e)\r
 381 {\r
 382         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 383 \r
 384         if(e.fakeprey || !e.stat_eaten) // we already configured everything\r
 385                 return;\r
 386 \r
 387         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 388         e.fakepredator = e.predator;\r
 389         e.fakeprey = TRUE;\r
 390 \r
 391         // first release the prey from the predator, as dead prey needs to be attached differently\r
 392         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 393         e.predator.stomach_load -= 1;\r
 394         Vore_WeightApply(e.predator);\r
 395         e.predator = world;\r
 396 \r
 397         // now put our dead prey inside the predator's stomach, but only as an effect\r
 398         e.movetype = MOVETYPE_FOLLOW;\r
 399         e.takedamage = DAMAGE_NO;\r
 400         e.solid = SOLID_NOT;\r
 401         e.aiment = e.fakepredator;\r
 402 }\r
 403 \r
 404 void Vore_DeadPrey_Detach(entity e)\r
 405 {\r
 406         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 407         // should only execute after Vore_DeadPrey_Configure has ran first\r
 408 \r
 409         if not(cvar("g_vore_keepdeadprey"))\r
 410                 return;\r
 411 \r
 412         e.fakepredator = world;\r
 413         e.fakeprey = TRUE; // keep fakeprey status\r
 414         e.stat_eaten = 0;\r
 415         e.aiment = world;\r
 416         e.movetype = MOVETYPE_TOSS;\r
 417 }\r
 418 \r
 419 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 420 {\r
 421         if(pred_disconnect)\r
 422         {\r
 423                 if(e.fakeprey)\r
 424                         Vore_DeadPrey_Detach(e);\r
 425                 else\r
 426                         Vore_Regurgitate(e);\r
 427         }\r
 428         else if(self.stat_eaten && !self.fakeprey)\r
 429         {\r
 430                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 431                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
 432                         Vore_DeadPrey_Configure(e);\r
 433                 else\r
 434                         Vore_Regurgitate(e);\r
 435         }\r
 436 }\r
 437 \r
 438 void Vore_Disconnect()\r
 439 {\r
 440         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 441 \r
 442         // prey disconnects or goes spectating while inside someone's belly\r
 443         if(self.stat_eaten)\r
 444                 Vore_PreyRelease(self, TRUE);\r
 445 \r
 446         // pred disconnects or goes spectating with players in their belly\r
 447         entity head;\r
 448         FOR_EACH_PLAYER(head)\r
 449         {\r
 450                 if(head.predator == self || head.fakepredator == self)\r
 451                         Vore_PreyRelease(head, TRUE);\r
 452         }\r
 453         Vore_GurgleSound(); // stop the gurgling sound\r
 454 \r
 455         self.stomach_load = self.gravity = 0; // prevents a bug\r
 456 }\r
 457 \r
 458 .float digestion_step;\r
 459 void Vore_Digest()\r
 460 {\r
 461         // apply digestion to prey\r
 462 \r
 463         if(time > self.digestion_step)\r
 464         {\r
 465                 // if distributed digestion is enabled, reduce digestion strength by the number of prey in our stomach\r
 466                 float reduce;\r
 467                 if(cvar("g_balance_vore_digestion_distribute"))\r
 468                         reduce = self.predator.stomach_load;\r
 469                 else\r
 470                         reduce = 1;\r
 471 \r
 472                 float damage;\r
 473                 damage = cvar("g_balance_vore_digestion_damage") / reduce;\r
 474 \r
 475                 // apply player scale to digestion damage\r
 476                 if(cvar("g_balance_vore_digestion_scalediff"))\r
 477                         damage *= (self.predator.scale / self.scale);\r
 478 \r
 479                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
 480                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 481                         self.predator.health += cvar("g_balance_vore_digestion_vampire") / reduce;\r
 482 \r
 483                 if (self.predator.digestsound_finished < time)\r
 484                 {\r
 485                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 486                         self.predator.digestsound_finished = time + 0.5;\r
 487                 }\r
 488                 self.digestion_step = time + steptime;\r
 489         }\r
 490 \r
 491         if(self.deadflag != DEAD_NO)\r
 492         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 493                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 494 }\r
 495 \r
 496 .float teamheal_step;\r
 497 void Vore_Teamheal()\r
 498 {\r
 499         // apply teamheal\r
 500 \r
 501         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 502         if(time > self.teamheal_step)\r
 503         {\r
 504                 self.health += cvar("g_balance_vore_teamheal");\r
 505                 self.teamheal_step = time + steptime;\r
 506 \r
 507                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 508                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 509                 {\r
 510                         play2(self, "misc/beep.wav");\r
 511                         play2(self.predator, "misc/beep.wav");\r
 512                 }\r
 513         }\r
 514 }\r
 515 \r
 516 void Vore_StomachKick()\r
 517 {\r
 518         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 519 \r
 520         if(time > self.stomachkick_delay)\r
 521         {\r
 522                 float damage;\r
 523                 vector force;\r
 524                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 525                 force = v_forward * cvar("g_balance_vore_kick_force");\r
 526 \r
 527                 // apply player scale to the damage / force of the kick\r
 528                 if(cvar("g_balance_vore_kick_scalediff"))\r
 529                 {\r
 530                         damage *= (self.scale / self.predator.scale);\r
 531                         force *= (self.scale / self.predator.scale);\r
 532                 }\r
 533 \r
 534                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
 535                 sound(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), VOL_BASE, ATTN_NORM);\r
 536                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 537                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 538 \r
 539                 // abort the predator's scheduled regurgitation\r
 540                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
 541                         self.predator.regurgitate_prepare = 0;\r
 542 \r
 543                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 544         }\r
 545 }\r
 546 \r
 547 void Vore_StomachLeave()\r
 548 {\r
 549         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 550 \r
 551         if(Vore_CanLeave())\r
 552                 Vore_Regurgitate(self);\r
 553         else if(time > self.complain_vore)\r
 554         {\r
 555                 play2(self, "misc/forbidden.wav");\r
 556                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 557                 self.complain_vore = time + complain_delay_time;\r
 558         }\r
 559 }\r
 560 \r
 561 void Vore_AutoTaunt()\r
 562 {\r
 563         // triggers ambient vore taunts, for both pred and prey\r
 564 \r
 565         float taunt_time;\r
 566 \r
 567         // predator taunts\r
 568         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 569         {\r
 570                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 571                 {\r
 572                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 573                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 574                 }\r
 575         }\r
 576         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 577         {\r
 578                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 579                 SetAutoTaunt(self, 0, 0);\r
 580         }\r
 581 \r
 582         // prey taunts\r
 583         if(self.stat_eaten && !(teams_matter && self.team == self.predator.team))\r
 584         {\r
 585                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 586                 {\r
 587                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 588                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 589                 }\r
 590         }\r
 591         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 592         {\r
 593                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 594                 SetAutoTaunt(self, 0, 0);\r
 595         }\r
 596 }\r
 597 \r
 598 void Vore_SetSbarRings()\r
 599 {\r
 600         // first clear the ring stats, then configure them if needed\r
 601         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 602         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 603 \r
 604         if(self.stat_eaten)\r
 605         {\r
 606                 if(time <= self.stomachkick_delay)\r
 607                 {\r
 608                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
 609                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 610                 }\r
 611         }\r
 612         else\r
 613         {\r
 614                 if(self.swallow_progress_pred)\r
 615                 {\r
 616                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
 617                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
 618                 }\r
 619                 else if(time <= self.action_delay)\r
 620                 {\r
 621                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
 622                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 623                 }\r
 624 \r
 625                 if(self.swallow_progress_prey)\r
 626                 {\r
 627                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
 628                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
 629                 }\r
 630                 else if(time <= self.regurgitate_prepare)\r
 631                 {\r
 632                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
 633                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 634                 }\r
 635         }\r
 636 }\r
 637 \r
 638 void Vore()\r
 639 {\r
 640         // main vore code, this is where it all happens\r
 641 \r
 642         if(!cvar("g_vore")) // the vore system is disabled\r
 643         {\r
 644                 Vore_Disconnect();\r
 645                 return;\r
 646         }\r
 647 \r
 648         Vore_AutoTaunt();\r
 649 \r
 650         // wash the goo away from players once they leave the stomach\r
 651         if(!self.stat_eaten)\r
 652         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 653         if(self.colormod)\r
 654         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 655         {\r
 656                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 657                 if(self.colormod_x > 1)\r
 658                         self.colormod_x = 1;\r
 659                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 660                 if(self.colormod_y > 1)\r
 661                         self.colormod_y = 1;\r
 662                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 663                 if(self.colormod_z > 1)\r
 664                         self.colormod_z = 1;\r
 665         }\r
 666 \r
 667         // set all vore stats\r
 668         Vore_SetSbarRings();\r
 669         if(self.fakepredator.classname == "player")\r
 670                 self.stat_eaten = num_for_edict(self.fakepredator);\r
 671         else if(self.predator.classname == "player")\r
 672         {\r
 673                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 674                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 675                 self.stat_eaten = num_for_edict(self.predator);\r
 676         }\r
 677         else\r
 678         {\r
 679                 self.stat_stomachload = self.stomach_load;\r
 680                 self.stat_digesting = self.digesting;\r
 681                 self.stat_eaten = 0;\r
 682         }\r
 683         self.stat_canleave = Vore_CanLeave();\r
 684 \r
 685         // don't allow a player inside a player inside another player :)\r
 686         // prevent this by checking if such has happened, and taking the proper measures\r
 687         // this code has a high priority and must not be stopped by any delay, so run it here\r
 688         if(self.predator.stat_eaten)\r
 689         {\r
 690                 entity target_predator, target_predator_predator, oldself;\r
 691                 target_predator = self.predator;\r
 692                 target_predator_predator = self.predator.predator;\r
 693 \r
 694                 Vore_Regurgitate(self);\r
 695 \r
 696                 // now steal our prey's prey if this probability applies\r
 697                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 698                 {\r
 699                         oldself = self;\r
 700                         self = target_predator_predator;\r
 701                         if(Swallow_condition_check(oldself))\r
 702                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 703                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 704                                 Vore_Swallow(oldself);\r
 705                         self = oldself;\r
 706                 }\r
 707         }\r
 708 \r
 709         // the swallow progress of prey and preds idly decrease by this amount\r
 710         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
 711         {\r
 712                 if(self.swallow_progress_pred)\r
 713                 {\r
 714                         self.swallow_progress_pred -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 715                         if(self.swallow_progress_pred < 0)\r
 716                                 self.swallow_progress_pred = 0;\r
 717                 }\r
 718                 if(self.swallow_progress_prey)\r
 719                 {\r
 720                         self.swallow_progress_prey -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 721                         if(self.swallow_progress_prey < 0)\r
 722                                 self.swallow_progress_prey = 0;\r
 723                 }\r
 724         }\r
 725 \r
 726         // apply delays and skip the vore system under some circumstances\r
 727         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 728         {\r
 729                 Vore_Disconnect();\r
 730                 return;\r
 731         }\r
 732         if(self.spectatee_status)\r
 733                 return;\r
 734         if(time < self.system_delay)\r
 735                 return;\r
 736 \r
 737 // --------------------------------\r
 738 // Code that addresses predators:\r
 739 // --------------------------------\r
 740 \r
 741         entity prey;\r
 742         prey = Swallow_player_check();\r
 743 \r
 744         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 745         self.stat_canswallow = 0;\r
 746         if(Swallow_condition_check(prey))\r
 747         {\r
 748                 // canswallow stat, used by the HUD\r
 749                 if(teams_matter && prey.team == self.team)\r
 750                         self.stat_canswallow = 2;\r
 751                 else\r
 752                         self.stat_canswallow = 1;\r
 753 \r
 754                 if(self.BUTTON_ATCK)\r
 755                         Vore_SwallowStep(prey);\r
 756         }\r
 757         else if(prey != world)\r
 758                 self.stat_canswallow = -1;\r
 759 \r
 760         // toggle digestion, if the player has someone in their stomach\r
 761         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 762         {\r
 763                 if(self.stomach_load)\r
 764                 {\r
 765                         if(time > self.digest_button_delay_time)\r
 766                         {\r
 767                                 self.digesting = !self.digesting;\r
 768                                 self.digest_button_delay_time = time + button_delay_time;\r
 769                         }\r
 770                 }\r
 771                 else if(time > self.complain_vore)\r
 772                 {\r
 773                         play2(self, "misc/forbidden.wav");\r
 774                         sprint(self, "There is nothing to digest\n");\r
 775                         self.complain_vore = time + complain_delay_time;\r
 776                 }\r
 777         }\r
 778         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 779                 self.digesting = FALSE;\r
 780 \r
 781         // predator wishes to regurgitate his prey\r
 782         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 783         {\r
 784                 if(self.stomach_load)\r
 785                 {\r
 786                         if(time > self.regurgitate_button_delay_time)\r
 787                         {\r
 788                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 789                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 790                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 791                         }\r
 792                 }\r
 793                 else if(time > self.complain_vore)\r
 794                 {\r
 795                         play2(self, "misc/forbidden.wav");\r
 796                         sprint(self, "There is nothing to regurgitate\n");\r
 797                         self.complain_vore = time + complain_delay_time;\r
 798                 }\r
 799         }\r
 800 \r
 801         if(cvar("g_vore_gurglesound"))\r
 802                 Vore_GurgleSound();\r
 803 \r
 804 // --------------------------------\r
 805 // Code that addresses the prey:\r
 806 // --------------------------------\r
 807 \r
 808         Vore_SetPreyPositions();\r
 809 \r
 810         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 811         if(self.fakeprey)\r
 812         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.stat_eaten)\r
 813                 Vore_DeadPrey_Detach(self);\r
 814 \r
 815         if(!self.stat_eaten)\r
 816                 return;\r
 817 \r
 818         if(self.deadflag != DEAD_NO)\r
 819         {\r
 820                 Vore_PreyRelease(self, FALSE);\r
 821                 return;\r
 822         }\r
 823 \r
 824         if(self.predator.deadflag != DEAD_NO)\r
 825                 Vore_Regurgitate(self);\r
 826         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 827                 Vore_Regurgitate(self);\r
 828 \r
 829         // apply delayed regurgitating if it was scheduled\r
 830         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 831         {\r
 832                 self.predator.regurgitate_prepare = 0;\r
 833                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 834                 Vore_Regurgitate(self);\r
 835         }\r
 836 \r
 837         // execute digesting and team healing\r
 838         if(self.predator.digesting == TRUE)\r
 839                 Vore_Digest();\r
 840         if(teams_matter && self.team == self.predator.team)\r
 841         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 842                 Vore_Teamheal();\r
 843 \r
 844         // execute prey commands\r
 845         if(self.BUTTON_ATCK && cvar("g_vore_kick"))\r
 846                 Vore_StomachKick();\r
 847         if(self.BUTTON_JUMP)\r
 848                 Vore_StomachLeave();\r
 849 \r
 850         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 851         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 852         kh_Key_DropAll(self, FALSE);\r
 853 }