data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float system_delay, swallow_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         vector vore_w_shotorg, vore_w_shotdir;\r
  16         vore_w_shotorg = self.origin + self.view_ofs;\r
  17         vore_w_shotdir = v_forward;\r
  18 \r
  19         WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * cvar("g_balance_vore_swallow_range"), FALSE, self, ANTILAG_LATENCY(self));\r
  20         if(trace_fraction < 1)\r
  21         if(trace_ent.classname == "player")\r
  22                 return trace_ent;\r
  23         return world;\r
  24 }\r
  25 \r
  26 float Swallow_condition_check(entity prey)\r
  27 {\r
  28         // checks the necessary conditions for swallowing a player\r
  29 \r
  30         if(prey != self)\r
  31         if(prey.classname == "player" && prey.predator.classname != "player" && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  32         if(self.classname == "player" && self.predator.classname != "player" && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  33         if(!self.BUTTON_REGURGITATE && self.swallow_delay < time)\r
  34         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  35         {\r
  36                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  37                 {\r
  38                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  39                         {\r
  40                                 play2(self, "misc/forbidden.wav");\r
  41                                 sprint(self, "You cannot swallow your team mates\n");\r
  42                                 self.complain_vore = time + complain_delay_time;\r
  43                         }\r
  44                         return FALSE;\r
  45                 }\r
  46 \r
  47                 if(self.stomach_load >= cvar("g_balance_vore_swallow_limit"))\r
  48                 {\r
  49                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  50                         {\r
  51                                 play2(self, "misc/forbidden.wav");\r
  52                                 sprint(self, strcat("You cannot swallow more than ^2", cvar_string("g_balance_vore_swallow_limit"), "^7 players at a time\n"));\r
  53                                 self.complain_vore = time + complain_delay_time;\r
  54                         }\r
  55                         return FALSE;\r
  56                 }\r
  57 \r
  58                 if(cvar("g_vore_biggergut"))\r
  59                 if(prey.stomach_load > self.stomach_load)\r
  60                 {\r
  61                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  62                         {\r
  63                                 play2(self, "misc/forbidden.wav");\r
  64                                 sprint(self, "You cannot swallow someone with a bigger stomach than yours\n");\r
  65                                 self.complain_vore = time + complain_delay_time;\r
  66                         }\r
  67                         return FALSE;\r
  68                 }\r
  69 \r
  70                 if(!cvar("g_vore_spawnshield"))\r
  71                 if(prey.spawnshieldtime > time)\r
  72                 {\r
  73                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  74                         {\r
  75                                 play2(self, "misc/forbidden.wav");\r
  76                                 sprint(self, "You cannot swallow someone protected by the spawn shield\n");\r
  77                                 self.complain_vore = time + complain_delay_time;\r
  78                         }\r
  79                         return FALSE;\r
  80                 }\r
  81 \r
  82                 return TRUE;\r
  83         }\r
  84         return FALSE;\r
  85 }\r
  86 \r
  87 float Stomach_TeamMates_check(entity pred)\r
  88 {\r
  89         // checks if a player's stomach contains any team mates\r
  90 \r
  91         entity head;\r
  92         if(teams_matter)\r
  93         {\r
  94                 FOR_EACH_PLAYER(head)\r
  95                 {\r
  96                         if(head.predator == pred && head.team == pred.team)\r
  97                                 return TRUE;\r
  98                 }\r
  99         }\r
 100         return FALSE;\r
 101 }\r
 102 \r
 103 float Vore_CanLeave()\r
 104 {\r
 105         if(self.predator.classname == "player")\r
 106         {\r
 107                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
 108                         return TRUE;\r
 109                 if(teams_matter && self.team == self.predator.team)\r
 110                         return TRUE;\r
 111                 if(g_rpg && cvar("g_rpg_canleave"))\r
 112                         return TRUE;\r
 113         }\r
 114         return FALSE;\r
 115 }\r
 116 \r
 117 // make the camera smoothly lower itself when we get swallowed\r
 118 // our aim is going from the normal view offset to half of the view offset (because half is the best positioning for the stomach model)\r
 119 .float cameraeffect_current, cameraeffect_target;\r
 120 void Vore_CameraEffect_Set(entity e)\r
 121 {\r
 122         e.cameraeffect_current = 1;\r
 123         e.cameraeffect_target = 2;\r
 124 }\r
 125 void Vore_CameraEffect_Apply()\r
 126 {\r
 127         if not(self.predator.classname == "player" || self.fakeprey)\r
 128                 return;\r
 129 \r
 130         if(self.cvar_cl_vore_cameraspeed)\r
 131         {\r
 132                 local float step;\r
 133                 step = self.cvar_cl_vore_cameraspeed * frametime;\r
 134 \r
 135                 // not sure if these maths are good, as the effect should be smoother\r
 136                 if(self.cameraeffect_current >= self.cameraeffect_target + step)\r
 137                         self.cameraeffect_current -= step;\r
 138                 else if(self.cameraeffect_current <= self.cameraeffect_target - step)\r
 139                         self.cameraeffect_current += step;\r
 140         }\r
 141         else\r
 142                 self.cameraeffect_current = self.cameraeffect_target;\r
 143 \r
 144         self.view_ofs_z = PL_PREY_VIEW_OFS_z / self.cameraeffect_current;\r
 145 }\r
 146 \r
 147 .float gurgle_oldstomachload;\r
 148 void Vore_GurgleSound()\r
 149 {\r
 150         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 151         {\r
 152                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 153 \r
 154                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 155                 self.gurgle_oldstomachload = self.stomach_load;\r
 156         }\r
 157 }\r
 158 \r
 159 void Vore_WeightApply(entity e)\r
 160 {\r
 161         // apply stomach weight that makes you heavier the more you eat\r
 162         // slowing the player is done in cl_physics.qc\r
 163 \r
 164         if(e.stomach_load != e.vore_oldstomachload)\r
 165                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 166         if(e.gravity == 0)\r
 167                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 168         e.vore_oldstomachload = e.stomach_load;\r
 169 }\r
 170 \r
 171 void Vore_AutoDigest(entity e)\r
 172 {\r
 173         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 174 \r
 175         if(!cvar("g_vore_digestion") || e.digesting)\r
 176                 return;\r
 177         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 178                 return; // this feature is only for players, not bots\r
 179         if(e.stomach_load > 1)\r
 180                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 181         if(Stomach_TeamMates_check(e))\r
 182                 return; // never begin automatic digestion if we've swallowed a team mate\r
 183 \r
 184         e.digesting = TRUE;\r
 185 }\r
 186 \r
 187 .entity pusher;\r
 188 .float pushltime;\r
 189 void Vore_Swallow(entity e)\r
 190 {\r
 191         // this player is being swallowed by another player, apply the proper changes\r
 192 \r
 193         e.vore_oldmovetype = e.movetype;\r
 194         e.vore_oldsolid = e.solid;\r
 195 \r
 196         e.predator = self;\r
 197         setorigin(e, e.predator.origin);\r
 198         e.velocity = '0 0 0';\r
 199         e.movetype = MOVETYPE_FOLLOW;\r
 200         e.solid = SOLID_NOT;\r
 201         e.alpha = -1; // best way of hiding the eaten player\r
 202         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 203 \r
 204         // drop keys (KH) and flags (CTF) when we get swallowed\r
 205         kh_Key_DropAll(e, FALSE);\r
 206         if(e.flagcarried)\r
 207                 DropFlag(e.flagcarried, world, e.predator);\r
 208 \r
 209         Vore_CameraEffect_Set(e);\r
 210 \r
 211         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 212                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 213 \r
 214         if(teams_matter && e.team == e.predator.team)\r
 215         {\r
 216                 if(cvar("g_vore_kick"))\r
 217                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 218                 if(cvar("g_vore_digestion"))\r
 219                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 220         }\r
 221 \r
 222         PlayerSound(e.predator, playersound_swallow, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 223         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 224         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 225         e.predator.stomach_load += 1;\r
 226         e.predator.regurgitate_prepare = 0;\r
 227         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 228         Vore_WeightApply(e.predator);\r
 229         Vore_AutoDigest(e.predator);\r
 230 \r
 231         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 232         e.predator.weapon_delay = time + button_delay_time;\r
 233         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 234         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 235 }\r
 236 \r
 237 void Vore_Regurgitate(entity e)\r
 238 {\r
 239         // this player is being regurgitated by their predator, apply the proper changes\r
 240 \r
 241         e.movetype = e.vore_oldmovetype;\r
 242         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 243                 e.solid = e.vore_oldsolid;\r
 244         e.view_ofs_z = PL_VIEW_OFS_z;\r
 245         e.alpha = default_player_alpha;\r
 246 \r
 247         // apply velocities\r
 248         local vector oldforward, oldright, oldup;\r
 249         oldforward = v_forward;\r
 250         oldright = v_right;\r
 251         oldup = v_up;\r
 252         makevectors(e.predator.v_angle);\r
 253         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 254         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 255         v_forward = oldforward;\r
 256         v_right = oldright;\r
 257         v_up = oldup;\r
 258 \r
 259         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 260         e.pushltime = time + cvar("g_maxpushtime");\r
 261 \r
 262         PlayerSound(e.predator, playersound_regurgitate, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 263         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 264         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 265         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 266         e.predator.stomach_load -= 1;\r
 267         e.predator.regurgitate_prepare = 0;\r
 268         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 269         Vore_WeightApply(e.predator);\r
 270 \r
 271         // block firing for a small amount of time, or we'll be firing the next frame\r
 272         e.weapon_delay = time + button_delay_time;\r
 273         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 274         e.predator = world;\r
 275 }\r
 276 \r
 277 void Vore_DeadPrey_Configure(entity e)\r
 278 {\r
 279         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 280 \r
 281         if(e.fakeprey || e.predator.classname != "player") // already configured\r
 282                 return;\r
 283 \r
 284         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 285         e.fakepredator = e.predator;\r
 286         e.fakeprey = TRUE;\r
 287 \r
 288         // first release the prey from the predator, as dead prey needs to be attached differently\r
 289         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 290         e.predator.stomach_load -= 1;\r
 291         Vore_WeightApply(e.predator);\r
 292         e.predator = world;\r
 293 \r
 294         // now put our dead prey inside the predator's stomach, but only as an effect\r
 295         e.movetype = MOVETYPE_FOLLOW;\r
 296         e.takedamage = DAMAGE_NO;\r
 297         e.solid = SOLID_NOT;\r
 298         e.aiment = e.fakepredator;\r
 299 \r
 300         // completely remove the dead body\r
 301         e.modelindex = 0;\r
 302 }\r
 303 \r
 304 void Vore_DeadPrey_Detach(entity e)\r
 305 {\r
 306         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 307         // should only execute after Vore_DeadPrey_Configure has ran first\r
 308 \r
 309         if not(cvar("g_vore_keepdeadprey"))\r
 310                 return;\r
 311 \r
 312         e.fakepredator = world;\r
 313         e.fakeprey = FALSE;\r
 314         e.aiment = world;\r
 315         e.movetype = MOVETYPE_TOSS;\r
 316 }\r
 317 \r
 318 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 319 {\r
 320         if(pred_disconnect)\r
 321         {\r
 322                 if(e.fakeprey)\r
 323                         Vore_DeadPrey_Detach(e);\r
 324                 else\r
 325                         Vore_Regurgitate(e);\r
 326         }\r
 327         else\r
 328         {\r
 329                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 330                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
 331                         Vore_DeadPrey_Configure(e);\r
 332                 else\r
 333                         Vore_Regurgitate(e);\r
 334         }\r
 335 }\r
 336 \r
 337 void Vore_Disconnect()\r
 338 {\r
 339         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 340 \r
 341         // prey disconnects or goes spectating while inside someone's belly\r
 342         if(self.predator.classname == "player")\r
 343                 Vore_PreyRelease(self, TRUE);\r
 344 \r
 345         // pred disconnects or goes spectating with players in their belly\r
 346         entity head;\r
 347         FOR_EACH_PLAYER(head)\r
 348         {\r
 349                 if(head.predator == self || head.fakepredator == self)\r
 350                         Vore_PreyRelease(head, TRUE);\r
 351         }\r
 352         Vore_GurgleSound(); // stop the gurgling sound\r
 353 \r
 354         self.stomach_load = self.gravity = 0; // prevents a bug\r
 355 }\r
 356 \r
 357 .float digestion_step;\r
 358 void Vore_Digest()\r
 359 {\r
 360         // apply digestion to prey\r
 361 \r
 362         if(time > self.predator.digestion_step)\r
 363         {\r
 364                 Damage(self, self.predator, self.predator, cvar("g_balance_vore_digestion_damage"), DEATH_DIGESTION, self.origin, '0 0 0');\r
 365                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 366                         self.predator.health += cvar("g_balance_vore_digestion_vampire");\r
 367 \r
 368                 if (self.predator.digestsound_finished < time)\r
 369                 {\r
 370                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 371                         self.predator.digestsound_finished = time + 0.5;\r
 372                 }\r
 373                 self.predator.digestion_step = time + steptime;\r
 374         }\r
 375 \r
 376         if(self.deadflag != DEAD_NO)\r
 377         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 378                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 379 }\r
 380 \r
 381 .float teamheal_step;\r
 382 void Vore_Teamheal()\r
 383 {\r
 384         // apply teamheal\r
 385 \r
 386         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 387         if(time > self.teamheal_step)\r
 388         {\r
 389                 self.health += cvar("g_balance_vore_teamheal");\r
 390                 self.teamheal_step = time + steptime;\r
 391 \r
 392                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 393                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 394                 {\r
 395                         play2(self, "misc/beep.wav");\r
 396                         play2(self.predator, "misc/beep.wav");\r
 397                 }\r
 398         }\r
 399 }\r
 400 \r
 401 .float stomachkick_delay;\r
 402 void Vore_StomachKick()\r
 403 {\r
 404         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 405 \r
 406         if(time > self.stomachkick_delay)\r
 407         {\r
 408                 float damage;\r
 409                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 410 \r
 411                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, v_forward * cvar("g_balance_vore_kick_force"));\r
 412                 sound(self.predator, CHAN_PROJECTILE, "weapons/stomachkick.wav", VOL_BASE, ATTN_NORM);\r
 413                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 414                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 415 \r
 416                 if(random() < cvar("g_balance_vore_kick_escapeprobability"))\r
 417                         Vore_Regurgitate(self);\r
 418 \r
 419                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 420         }\r
 421 }\r
 422 \r
 423 void Vore_StomachLeave()\r
 424 {\r
 425         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 426 \r
 427         if(Vore_CanLeave())\r
 428                 Vore_Regurgitate(self);\r
 429         else if(time > self.complain_vore)\r
 430         {\r
 431                 play2(self, "misc/forbidden.wav");\r
 432                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 433                 self.complain_vore = time + complain_delay_time;\r
 434         }\r
 435 }\r
 436 \r
 437 void Vore_AutoTaunt()\r
 438 {\r
 439         // triggers ambient vore taunts, for both pred and prey\r
 440 \r
 441         float taunt_time;\r
 442 \r
 443         // predator taunts\r
 444         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 445         {\r
 446                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 447                 {\r
 448                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 449                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 450                 }\r
 451         }\r
 452         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 453         {\r
 454                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 455                 SetAutoTaunt(self, 0, 0);\r
 456         }\r
 457 \r
 458         // prey taunts\r
 459         if(self.predator.classname == "player" && !(teams_matter && self.team == self.predator.team))\r
 460         {\r
 461                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 462                 {\r
 463                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 464                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 465                 }\r
 466         }\r
 467         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 468         {\r
 469                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 470                 SetAutoTaunt(self, 0, 0);\r
 471         }\r
 472 }\r
 473 \r
 474 void Vore()\r
 475 {\r
 476         // main vore code, this is where it all happens\r
 477 \r
 478         if(!cvar("g_vore")) // the vore system is disabled\r
 479         {\r
 480                 Vore_Disconnect();\r
 481                 return;\r
 482         }\r
 483 \r
 484         Vore_AutoTaunt();\r
 485 \r
 486         // wash the goo away from players once they leave the stomach\r
 487         if(self.predator.classname != "player")\r
 488         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 489         if(self.colormod)\r
 490         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 491         {\r
 492                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 493                 if(self.colormod_x > 1)\r
 494                         self.colormod_x = 1;\r
 495                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 496                 if(self.colormod_y > 1)\r
 497                         self.colormod_y = 1;\r
 498                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 499                 if(self.colormod_z > 1)\r
 500                         self.colormod_z = 1;\r
 501         }\r
 502 \r
 503         // set all vore stats\r
 504         if(self.fakeprey)\r
 505                 self.stat_eaten = num_for_edict(self.fakepredator);\r
 506         else if(self.predator.classname == "player")\r
 507         {\r
 508                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 509                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 510                 self.stat_eaten = num_for_edict(self.predator);\r
 511         }\r
 512         else\r
 513         {\r
 514                 self.stat_stomachload = self.stomach_load;\r
 515                 self.stat_digesting = self.digesting;\r
 516                 self.stat_eaten = 0;\r
 517         }\r
 518         self.stat_canleave = Vore_CanLeave();\r
 519 \r
 520         // don't allow a player inside a player inside another player :)\r
 521         // prevent this by checking if such has happened, and taking the proper measures\r
 522         // this code has a high priority and must not be stopped by any delay, so run it here\r
 523         if(self.predator.predator.classname == "player")\r
 524         {\r
 525                 entity target_predator, target_predator_predator, oldself;\r
 526                 target_predator = self.predator;\r
 527                 target_predator_predator = self.predator.predator;\r
 528 \r
 529                 Vore_Regurgitate(self);\r
 530 \r
 531                 // now steal our prey's prey if this probability applies\r
 532                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 533                 {\r
 534                         oldself = self;\r
 535                         self = target_predator_predator;\r
 536                         if(Swallow_condition_check(oldself))\r
 537                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 538                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 539                                 Vore_Swallow(oldself);\r
 540                         self = oldself;\r
 541                 }\r
 542         }\r
 543 \r
 544         // apply delays and skip the vore system under some circumstances\r
 545         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 546         {\r
 547                 Vore_Disconnect();\r
 548                 return;\r
 549         }\r
 550         if(self.spectatee_status)\r
 551                 return;\r
 552         if(time < self.system_delay)\r
 553                 return;\r
 554 \r
 555 // --------------------------------\r
 556 // Code that addresses predators:\r
 557 // --------------------------------\r
 558 \r
 559         entity prey;\r
 560         prey = Swallow_player_check();\r
 561 \r
 562         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 563         self.stat_canswallow = 0;\r
 564         if(Swallow_condition_check(prey))\r
 565         {\r
 566                 // canswallow stat, used by the HUD\r
 567                 if(teams_matter && prey.team == self.team)\r
 568                         self.stat_canswallow = 2;\r
 569                 else\r
 570                         self.stat_canswallow = 1;\r
 571 \r
 572                 if(self.BUTTON_ATCK)\r
 573                         Vore_Swallow(prey);\r
 574         }\r
 575         else if(prey != world)\r
 576                 self.stat_canswallow = -1;\r
 577 \r
 578         // toggle digestion, if the player has someone in their stomach\r
 579         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 580         {\r
 581                 if(self.stomach_load)\r
 582                 {\r
 583                         if(time > self.digest_button_delay_time)\r
 584                         {\r
 585                                 self.digesting = !self.digesting;\r
 586                                 self.digest_button_delay_time = time + button_delay_time;\r
 587                         }\r
 588                 }\r
 589                 else if(time > self.complain_vore)\r
 590                 {\r
 591                         play2(self, "misc/forbidden.wav");\r
 592                         sprint(self, "There is nothing to digest\n");\r
 593                         self.complain_vore = time + complain_delay_time;\r
 594                 }\r
 595         }\r
 596         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 597                 self.digesting = FALSE;\r
 598 \r
 599         // predator wishes to regurgitate his prey\r
 600         if(self.BUTTON_REGURGITATE)\r
 601         {\r
 602                 if(self.stomach_load)\r
 603                 {\r
 604                         if(time > self.regurgitate_button_delay_time)\r
 605                         {\r
 606                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 607                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 608                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 609                         }\r
 610                 }\r
 611                 else if(time > self.complain_vore)\r
 612                 {\r
 613                         play2(self, "misc/forbidden.wav");\r
 614                         sprint(self, "There is nothing to regurgitate\n");\r
 615                         self.complain_vore = time + complain_delay_time;\r
 616                 }\r
 617         }\r
 618 \r
 619         if(cvar("g_vore_gurglesound"))\r
 620                 Vore_GurgleSound();\r
 621 \r
 622 // --------------------------------\r
 623 // Code that addresses the prey:\r
 624 // --------------------------------\r
 625 \r
 626         Vore_CameraEffect_Apply();\r
 627 \r
 628         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 629         if(self.fakepredator.classname == "player")\r
 630         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.predator.classname == "player")\r
 631                 Vore_DeadPrey_Detach(self);\r
 632 \r
 633         if(self.predator.classname != "player")\r
 634                 return;\r
 635 \r
 636         if(self.deadflag != DEAD_NO)\r
 637         {\r
 638                 Vore_PreyRelease(self, FALSE);\r
 639                 return;\r
 640         }\r
 641 \r
 642         if(self.predator.deadflag != DEAD_NO)\r
 643                 Vore_Regurgitate(self);\r
 644         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 645                 Vore_Regurgitate(self);\r
 646 \r
 647         // apply delayed regurgitating if it was scheduled\r
 648         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 649         {\r
 650                 self.predator.regurgitate_prepare = 0;\r
 651                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 652                 Vore_Regurgitate(self);\r
 653         }\r
 654 \r
 655         // execute digesting and team healing\r
 656         if(self.predator.digesting == TRUE)\r
 657                 Vore_Digest();\r
 658         if(teams_matter && self.team == self.predator.team)\r
 659         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 660                 Vore_Teamheal();\r
 661 \r
 662         // execute prey commands\r
 663         if(self.BUTTON_ATCK && cvar("g_vore_kick"))\r
 664                 Vore_StomachKick();\r
 665         if(self.BUTTON_JUMP)\r
 666                 Vore_StomachLeave();\r
 667 \r
 668         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 669         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 670         kh_Key_DropAll(self, FALSE);\r
 671 }