Use a different, and very weird solution for the prey scan issue in multiplayer....
[voretournament/voretournament.git] / data / qcsrc / server / vore.qc
1 .float regurgitate_prepare;\r
2 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
3 .float complain_vore;\r
4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
5 \r
6 const float system_delay_time = 0.1;\r
7 const float complain_delay_time = 1;\r
8 const float button_delay_time = 0.5;\r
9 const float steptime = 0.1;\r
10 \r
11 entity Swallow_player_check()\r
12 {\r
13         // check if we can swallow a player instead of firing our weapon\r
14 \r
15         float swallow_range;\r
16         vector vore_w_shotorg, vore_w_shotdir;\r
17 \r
18         swallow_range = cvar("g_balance_vore_swallow_range");\r
19         if(cvar("g_healthsize")) // we can swallow from further or closer based on our size\r
20                 swallow_range *= self.scale;\r
21         vore_w_shotorg = self.origin;\r
22         vore_w_shotdir = v_forward;\r
23 \r
24         if(self.antilag_debug)\r
25                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, self.antilag_debug);\r
26         else\r
27                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
28         if(trace_fraction < 1)\r
29         if(trace_ent.classname == "player")\r
30                 return trace_ent;\r
31         return world;\r
32 }\r
33 \r
34 float Swallow_condition_check(entity prey)\r
35 {\r
36         // checks the necessary conditions for swallowing a player\r
37 \r
38         if(prey != self)\r
39         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
40         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
41         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
42         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap") / (1 + self.stomach_load))\r
43         {\r
44                 string swallow_complain;\r
45                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
46                         swallow_complain = "You cannot swallow your team mates\n";\r
47                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
48                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
49                 else if(self.stomach_load >= g_balance_vore_swallow_limit)\r
50                         swallow_complain = strcat("You cannot swallow more than ^2", ftos(g_balance_vore_swallow_limit), "^7 players at a time\n");\r
51                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
52                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
53                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
54                         swallow_complain = "You cannot swallow someone larger than you\n";\r
55 \r
56                 if(swallow_complain != "")\r
57                 {\r
58                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
59                         {\r
60                                 play2(self, "misc/forbidden.wav");\r
61                                 sprint(self, swallow_complain);\r
62                                 self.complain_vore = time + complain_delay_time;\r
63                         }\r
64                         return FALSE;\r
65                 }\r
66                 return TRUE;\r
67         }\r
68         return FALSE;\r
69 }\r
70 \r
71 float Stomach_TeamMates_check(entity pred)\r
72 {\r
73         // checks if a player's stomach contains any team mates\r
74 \r
75         entity head;\r
76         if(teams_matter)\r
77         {\r
78                 FOR_EACH_PLAYER(head)\r
79                 {\r
80                         if(head.predator == pred && head.team == pred.team)\r
81                                 return TRUE;\r
82                 }\r
83         }\r
84         return FALSE;\r
85 }\r
86 \r
87 float Vore_CanLeave()\r
88 {\r
89         if(self.stat_eaten)\r
90         {\r
91                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
92                         return TRUE;\r
93                 if(teams_matter && self.team == self.predator.team)\r
94                         return TRUE;\r
95                 if(g_rpg && cvar("g_rpg_canleave"))\r
96                         return TRUE;\r
97         }\r
98         return FALSE;\r
99 }\r
100 \r
101 // position the camera properly for prey\r
102 void Vore_SetPreyPositions()\r
103 {\r
104         // self is the predator and head is the prey\r
105 \r
106         local entity head;\r
107         local vector origin_apply;\r
108         local float position_counter;\r
109 \r
110         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
111         // else all players overlap in the center. To do this, we run a loop on all players in the same stomach.\r
112         // For each player, the origin is updated, then a new origin is used for the next player.\r
113         // This requires that no more than 9 players may be in the stomach at a time!\r
114         FOR_EACH_PLAYER(head)\r
115         {\r
116                 if(head.predator == self)\r
117                 {\r
118                         switch(position_counter)\r
119                         {\r
120                                 case 0:\r
121                                         origin_apply = '0 0 0'; // first occupant sits in the middle\r
122                                         break;\r
123                                 case 1:\r
124                                         origin_apply = '1 0 0'; // second occupant sits in the front\r
125                                         break;\r
126                                 case 2:\r
127                                         origin_apply = '-1 0 0'; // third occupant sits in the back\r
128                                         break;\r
129                                 case 3:\r
130                                         origin_apply = '0 1 0'; // fourth occupant sits in the right\r
131                                         break;\r
132                                 case 4:\r
133                                         origin_apply = '0 -1 0'; // fifth occupant sits in the left\r
134                                         break;\r
135                                 case 5:\r
136                                         origin_apply = '1 1 0'; // sixth occupant sits in the front-right\r
137                                         break;\r
138                                 case 6:\r
139                                         origin_apply = '-1 1 0'; // seventh occupant sits in the back-right\r
140                                         break;\r
141                                 case 7:\r
142                                         origin_apply = '1 -1 0'; // eigth occupant sits in the front-left\r
143                                         break;\r
144                                 case 8:\r
145                                         origin_apply = '-1 -1 0'; // ninth occupant sits in the back-left\r
146                                         break;\r
147                                 default:\r
148                                         break;\r
149                         }\r
150 \r
151                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
152                         head.view_ofs = PL_PREY_VIEW_OFS + origin_apply * cvar("g_vore_neighborprey_distance");\r
153                         head.view_ofs_z *= self.scale; // stomach center depends on predator scale\r
154 \r
155                         // change prey height based on scale\r
156                         float prey_height;\r
157                                 prey_height = (head.scale - self.scale) * cvar("g_healthsize_vore_pos");\r
158                         head.view_ofs_z += prey_height;\r
159 \r
160                         position_counter += 1;\r
161                 }\r
162         }\r
163 }\r
164 \r
165 .float gurgle_oldstomachload;\r
166 void Vore_GurgleSound()\r
167 {\r
168         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
169         {\r
170                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
171 \r
172                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
173                 self.gurgle_oldstomachload = self.stomach_load;\r
174         }\r
175 }\r
176 \r
177 void Vore_WeightApply(entity e)\r
178 {\r
179         // apply stomach weight that makes you heavier the more you eat\r
180         // slowing the player is done in cl_physics.qc\r
181 \r
182         if(e.stomach_load != e.vore_oldstomachload)\r
183                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
184         if(e.gravity == 0)\r
185                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
186         e.vore_oldstomachload = e.stomach_load;\r
187 }\r
188 \r
189 void Vore_AutoDigest(entity e)\r
190 {\r
191         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
192 \r
193         if(!cvar("g_vore_digestion") || e.digesting)\r
194                 return;\r
195         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
196                 return; // this feature is only for players, not bots\r
197         if(e.stomach_load > 1)\r
198                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
199         if(Stomach_TeamMates_check(e))\r
200                 return; // never begin automatic digestion if we've swallowed a team mate\r
201 \r
202         e.digesting = TRUE;\r
203 }\r
204 \r
205 .entity swallow_model;\r
206 void Vore_SwallowModel_Think()\r
207 {\r
208         //update the position of the swallow model to match our swallow progress\r
209         float dist;\r
210         dist = (-0.5 + self.owner.swallow_progress_prey) * cvar("g_vore_swallowmodel_range"); // the model is centered at 0.5 progress\r
211         if(cvar("g_healthsize"))\r
212                 dist *= self.scale;\r
213         self.view_ofs = '1 0 0' * dist;\r
214 \r
215         // if our swallow progress is gone or we are dead, the swallow model also goes away\r
216         if(!self.owner.swallow_progress_prey || self.owner.deadflag != DEAD_NO || self.owner.classname != "player")\r
217         {\r
218                 remove(self.owner.swallow_model);\r
219                 self.owner.swallow_model = world;\r
220                 return;\r
221         }\r
222 \r
223         // properties that should update whenever possible, but when the predator is not available\r
224         self.alpha = self.owner.cvar_cl_vore_swallowmodel;\r
225         self.nextthink = time;\r
226 }\r
227 \r
228 void Vore_SwallowModel_Update(entity prey, entity pred)\r
229 {\r
230         // if we don't have a swallow model already, spawn one\r
231         if(!prey.swallow_model)\r
232         {\r
233                 prey.swallow_model = spawn();\r
234 \r
235                 prey.swallow_model.movetype = MOVETYPE_FOLLOW;\r
236                 prey.swallow_model.solid = SOLID_NOT;\r
237 \r
238                 // apply the properties of the prey\r
239                 prey.swallow_model.viewmodelforclient = prey; // use the same system as the weapon model\r
240                 //prey.swallow_model.effects |= EF_NOGUNBOB; // let it bob\r
241                 prey.swallow_model.effects |= EF_NODEPTHTEST; // don't hide behind walls\r
242                 prey.swallow_model.colormap = prey.colormap; // pants and shirt color\r
243                 prey.swallow_model.glowmod = prey.glowmod; // glow color\r
244 \r
245                 prey.swallow_model.owner = prey; // owned by the prey\r
246                 prey.swallow_model.think = Vore_SwallowModel_Think;\r
247                 prey.swallow_model.nextthink = time;\r
248         }\r
249 \r
250         // properties that should update whenever possible, but when the predator is available\r
251         string player_swallowmodel;\r
252         player_swallowmodel = strcat(substring(pred.playermodel, 0, strlen(pred.playermodel) - 4), "_swallow.md3"); // 4 is the extension length\r
253         if(prey.swallow_model.model != player_swallowmodel) // player model can be changed while the predator is active\r
254                 setmodel(prey.swallow_model, player_swallowmodel);\r
255         if(prey.swallow_model.skin != pred.skin) // player skin can be changed while the predator is active\r
256                 prey.swallow_model.skin = pred.skin;\r
257         if(cvar("g_healthsize"))\r
258                 prey.swallow_model.scale = pred.scale / prey.scale; // player size difference\r
259         if(prey.swallow_model.enemy != pred)\r
260                 prey.swallow_model.enemy = pred; // enemy is the predator\r
261 }\r
262 \r
263 .entity pusher;\r
264 .float pushltime;\r
265 void Vore_Swallow(entity e)\r
266 {\r
267         // this player is being swallowed by another player, apply the proper changes\r
268 \r
269         e.vore_oldmovetype = e.movetype;\r
270         e.vore_oldsolid = e.solid;\r
271 \r
272         e.predator = self;\r
273         setorigin(e, e.predator.origin);\r
274         e.velocity = '0 0 0';\r
275         e.movetype = MOVETYPE_FOLLOW;\r
276         e.solid = SOLID_NOT;\r
277         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
278 \r
279         // drop keys (KH) and flags (CTF) when we get swallowed\r
280         kh_Key_DropAll(e, FALSE);\r
281         if(e.flagcarried)\r
282                 DropFlag(e.flagcarried, world, e.predator);\r
283 \r
284         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
285                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
286 \r
287         if(teams_matter && e.team == e.predator.team)\r
288         {\r
289                 if(cvar("g_vore_kick"))\r
290                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
291                 if(cvar("g_vore_digestion"))\r
292                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
293         }\r
294 \r
295         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
296         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
297         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
298         e.predator.stomach_load += 1;\r
299         e.predator.regurgitate_prepare = 0;\r
300         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
301         e.predator.hitsound += 1; // play this for team mates too, as we could be swallowing them to heal them\r
302         Vore_WeightApply(e.predator);\r
303         Vore_AutoDigest(e.predator);\r
304 \r
305         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
306         e.predator.weapon_delay = time + button_delay_time;\r
307         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
308         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
309         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
310 }\r
311 \r
312 void Vore_SwallowStep(entity e)\r
313 {\r
314         if(!cvar("g_balance_vore_swallow_speed_fill"))\r
315         {\r
316                 Vore_Swallow(e);\r
317                 return;\r
318         }\r
319 \r
320         Vore_SwallowModel_Update(e, self);\r
321 \r
322         // increase the progress value until it reaches 1, then swallow the player\r
323         if(e.swallow_progress_prey < 1)\r
324         {\r
325                 float fill;\r
326                 fill = cvar("g_balance_vore_swallow_speed_fill") * frametime;\r
327                 if(cvar("g_healthsize") && cvar("g_balance_vore_swallow_speed_fill_scalediff")) // fill rate depends on predator size compared to prey size\r
328                         fill *= pow(self.scale / e.scale, cvar("g_balance_vore_swallow_speed_fill_scalediff"));\r
329                 if(cvar("g_balance_vore_swallow_speed_fill_stomachload") && e.stomach_load) // fill rate is influenced by the prey's stomach load\r
330                         fill /= e.stomach_load;\r
331 \r
332                 e.swallow_progress_prey += fill;\r
333         }\r
334         else\r
335         {\r
336                 Vore_Swallow(e);\r
337                 e.swallow_progress_prey = 0;\r
338         }\r
339 \r
340         // the predator's progress is how much the prey got swallowed\r
341         self.swallow_progress_pred = e.swallow_progress_prey;\r
342 }\r
343 \r
344 void Vore_Regurgitate(entity e)\r
345 {\r
346         // this player is being regurgitated by their predator, apply the proper changes\r
347 \r
348         e.movetype = e.vore_oldmovetype;\r
349         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
350                 e.solid = e.vore_oldsolid;\r
351         e.view_ofs_z = PL_VIEW_OFS_z;\r
352 \r
353         // apply velocities\r
354         local vector oldforward, oldright, oldup;\r
355         oldforward = v_forward;\r
356         oldright = v_right;\r
357         oldup = v_up;\r
358         makevectors(e.predator.v_angle);\r
359         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
360         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
361         v_forward = oldforward;\r
362         v_right = oldright;\r
363         v_up = oldup;\r
364 \r
365         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
366         e.pushltime = time + cvar("g_maxpushtime");\r
367 \r
368         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
369         if(cvar("g_balance_vore_swallow_speed_fill") && cvar("g_balance_vore_regurgitate_swallowprogress"))\r
370         {\r
371                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
372                 Vore_SwallowModel_Update(e, e.predator);\r
373         }\r
374 \r
375         // apply regurgitation damage to the predator\r
376         if(cvar("g_balance_vore_regurgitate_damage"))\r
377         {\r
378                 float regurgitate_dmg;\r
379                 regurgitate_dmg = cvar("g_balance_vore_regurgitate_damage");\r
380                 if(cvar("g_healthsize"))\r
381                         regurgitate_dmg *= e.scale / e.predator.scale;\r
382                 Damage(e.predator, e.predator, e.predator, regurgitate_dmg, DEATH_REGURGITATION, e.predator.origin, '0 0 0');\r
383         }\r
384 \r
385         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
386         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
387         pointparticles(particleeffectnum("vore_regurgitate"), e.predator.origin, '0 0 0', 1);\r
388         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
389         e.predator.stomach_load -= 1;\r
390         e.predator.regurgitate_prepare = 0;\r
391         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
392         Vore_WeightApply(e.predator);\r
393 \r
394         // block firing for a small amount of time, or we'll be firing the next frame\r
395         e.weapon_delay = time + button_delay_time;\r
396         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
397         e.predator = world;\r
398 }\r
399 \r
400 void Vore_DeadPrey_Configure(entity e)\r
401 {\r
402         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
403 \r
404         if(e.fakeprey || !e.stat_eaten) // we already configured everything\r
405                 return;\r
406 \r
407         // this entity is like e.predator but for dead prey, to avoid conflicts\r
408         e.fakepredator = e.predator;\r
409         e.fakeprey = TRUE;\r
410 \r
411         // first release the prey from the predator, as dead prey needs to be attached differently\r
412         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
413         e.predator.stomach_load -= 1;\r
414         Vore_WeightApply(e.predator);\r
415         e.predator = world;\r
416 \r
417         // now put our dead prey inside the predator's stomach, but only as an effect\r
418         e.movetype = MOVETYPE_FOLLOW;\r
419         e.takedamage = DAMAGE_NO;\r
420         e.solid = SOLID_NOT;\r
421         e.aiment = e.fakepredator;\r
422 }\r
423 \r
424 void Vore_DeadPrey_Detach(entity e)\r
425 {\r
426         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
427         // should only execute after Vore_DeadPrey_Configure has ran first\r
428 \r
429         if not(cvar("g_vore_keepdeadprey"))\r
430                 return;\r
431 \r
432         e.fakepredator = world;\r
433         e.fakeprey = TRUE; // keep fakeprey status\r
434         e.stat_eaten = 0;\r
435         e.aiment = world;\r
436         e.movetype = MOVETYPE_TOSS;\r
437 }\r
438 \r
439 void Vore_PreyRelease(entity e, float pred_disconnect)\r
440 {\r
441         if(pred_disconnect)\r
442         {\r
443                 if(e.fakeprey)\r
444                         Vore_DeadPrey_Detach(e);\r
445                 else\r
446                         Vore_Regurgitate(e);\r
447         }\r
448         else if(self.stat_eaten && !self.fakeprey)\r
449         {\r
450                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
451                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
452                         Vore_DeadPrey_Configure(e);\r
453                 else\r
454                         Vore_Regurgitate(e);\r
455         }\r
456 }\r
457 \r
458 void Vore_Disconnect()\r
459 {\r
460         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
461 \r
462         // prey disconnects or goes spectating while inside someone's belly\r
463         if(self.stat_eaten)\r
464                 Vore_PreyRelease(self, TRUE);\r
465 \r
466         // pred disconnects or goes spectating with players in their belly\r
467         entity head;\r
468         FOR_EACH_PLAYER(head)\r
469         {\r
470                 if(head.predator == self || head.fakepredator == self)\r
471                         Vore_PreyRelease(head, TRUE);\r
472         }\r
473         Vore_GurgleSound(); // stop the gurgling sound\r
474 \r
475         self.stomach_load = self.gravity = 0; // prevents a bug\r
476 }\r
477 \r
478 .float digestion_step;\r
479 void Vore_Digest()\r
480 {\r
481         // apply digestion to prey\r
482 \r
483         if(time > self.digestion_step)\r
484         {\r
485                 // if distributed digestion is enabled, reduce digestion strength by the number of prey in our stomach\r
486                 float reduce;\r
487                 if(cvar("g_balance_vore_digestion_distribute"))\r
488                         reduce = self.predator.stomach_load;\r
489                 else\r
490                         reduce = 1;\r
491 \r
492                 float damage;\r
493                 damage = cvar("g_balance_vore_digestion_damage") / reduce;\r
494 \r
495                 // apply player scale to digestion damage\r
496                 if(cvar("g_healthsize") && cvar("g_balance_vore_digestion_scalediff"))\r
497                         damage *= pow(self.predator.scale / self.scale, cvar("g_balance_vore_digestion_scalediff"));\r
498 \r
499                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
500                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
501                         self.predator.health += cvar("g_balance_vore_digestion_vampire") / reduce;\r
502 \r
503                 if (self.predator.digestsound_finished < time)\r
504                 {\r
505                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
506                         self.predator.digestsound_finished = time + 0.5;\r
507                 }\r
508                 self.digestion_step = time + steptime;\r
509         }\r
510 \r
511         if(self.deadflag != DEAD_NO)\r
512         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
513                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
514 }\r
515 \r
516 .float teamheal_step;\r
517 void Vore_Teamheal()\r
518 {\r
519         // apply teamheal\r
520 \r
521         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
522         if(time > self.teamheal_step)\r
523         {\r
524                 self.health += cvar("g_balance_vore_teamheal");\r
525                 self.teamheal_step = time + steptime;\r
526 \r
527                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
528                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
529                 {\r
530                         play2(self, "misc/beep.wav");\r
531                         play2(self.predator, "misc/beep.wav");\r
532                 }\r
533         }\r
534 }\r
535 \r
536 .float kick_pressed;\r
537 void Vore_StomachKick()\r
538 {\r
539         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
540 \r
541         if(time > self.stomachkick_delay && !self.kick_pressed)\r
542         {\r
543                 float damage, vol;\r
544                 vector force;\r
545                 damage = cvar("g_balance_vore_kick_damage");\r
546                 force = v_forward * cvar("g_balance_vore_kick_force");\r
547                 vol = VOL_BASE;\r
548 \r
549                 // apply player scale to the damage / force of the kick\r
550                 if(cvar("g_healthsize") && cvar("g_balance_vore_kick_scalediff"))\r
551                 {\r
552                         damage *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
553                         force *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
554                         vol *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff")); // kick sound volume based on the same scale\r
555                 }\r
556                 vol = bound(0, vol, 1);\r
557 \r
558                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
559                 sound(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), vol, ATTN_NORM);\r
560                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
561                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
562 \r
563                 // abort the predator's scheduled regurgitation\r
564                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
565                         self.predator.regurgitate_prepare = 0;\r
566 \r
567                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
568                 if(cvar("g_balance_vore_kick_repress"))\r
569                 if not(clienttype(self) == CLIENTTYPE_BOT) // not for bots, to prevent an issue\r
570                         self.kick_pressed = TRUE;\r
571         }\r
572 }\r
573 \r
574 void Vore_StomachLeave()\r
575 {\r
576         // allows players to get out of their predator at will in some circumstances, such as team mates\r
577 \r
578         if(Vore_CanLeave())\r
579                 Vore_Regurgitate(self);\r
580         else if(time > self.complain_vore)\r
581         {\r
582                 play2(self, "misc/forbidden.wav");\r
583                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
584                 self.complain_vore = time + complain_delay_time;\r
585         }\r
586 }\r
587 \r
588 void Vore_AutoTaunt()\r
589 {\r
590         // triggers ambient vore taunts, for both pred and prey\r
591 \r
592         float taunt_time;\r
593 \r
594         // predator taunts\r
595         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
596         {\r
597                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
598                 {\r
599                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
600                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
601                 }\r
602         }\r
603         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
604         {\r
605                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
606                 SetAutoTaunt(self, 0, 0);\r
607         }\r
608 \r
609         // prey taunts\r
610         if(self.stat_eaten && !(teams_matter && self.team == self.predator.team))\r
611         {\r
612                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
613                 {\r
614                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
615                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
616                 }\r
617         }\r
618         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
619         {\r
620                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
621                 SetAutoTaunt(self, 0, 0);\r
622         }\r
623 }\r
624 \r
625 void Vore_SetSbarRings()\r
626 {\r
627         // first clear the ring stats, then configure them if needed\r
628         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
629         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
630 \r
631         if(self.stat_eaten)\r
632         {\r
633                 if(time <= self.stomachkick_delay)\r
634                 {\r
635                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
636                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
637                 }\r
638         }\r
639         else\r
640         {\r
641                 if(self.swallow_progress_pred)\r
642                 {\r
643                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
644                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
645                 }\r
646                 else if(time <= self.action_delay)\r
647                 {\r
648                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
649                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
650                 }\r
651 \r
652                 if(self.swallow_progress_prey)\r
653                 {\r
654                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
655                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
656                 }\r
657                 else if(time <= self.regurgitate_prepare)\r
658                 {\r
659                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
660                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
661                 }\r
662         }\r
663 }\r
664 \r
665 .entity prey;\r
666 void Vore()\r
667 {\r
668         // main vore code, this is where it all happens\r
669 \r
670         Vore_AutoTaunt();\r
671 \r
672         // wash the goo away from players once they leave the stomach\r
673         if(!self.stat_eaten)\r
674         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
675         if(self.colormod)\r
676         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
677         {\r
678                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
679                 if(self.colormod_x > 1)\r
680                         self.colormod_x = 1;\r
681                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
682                 if(self.colormod_y > 1)\r
683                         self.colormod_y = 1;\r
684                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
685                 if(self.colormod_z > 1)\r
686                         self.colormod_z = 1;\r
687         }\r
688 \r
689         // set all vore stats\r
690         Vore_SetSbarRings();\r
691         if(self.fakepredator.classname == "player")\r
692                 self.stat_eaten = num_for_edict(self.fakepredator);\r
693         else if(self.predator.classname == "player")\r
694         {\r
695                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
696                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
697                 self.stat_eaten = num_for_edict(self.predator);\r
698         }\r
699         else\r
700         {\r
701                 self.stat_stomachload = self.stomach_load;\r
702                 self.stat_digesting = self.digesting;\r
703                 self.stat_eaten = 0;\r
704         }\r
705         self.stat_canleave = Vore_CanLeave();\r
706 \r
707         // don't allow a player inside a player inside another player :)\r
708         // prevent this by checking if such has happened, and taking the proper measures\r
709         // this code has a high priority and must not be stopped by any delay, so run it here\r
710         if(self.predator.stat_eaten)\r
711         {\r
712                 entity target_predator, target_predator_predator, oldself;\r
713                 target_predator = self.predator;\r
714                 target_predator_predator = self.predator.predator;\r
715 \r
716                 Vore_Regurgitate(self);\r
717 \r
718                 // now steal our prey's prey if this probability applies\r
719                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
720                 {\r
721                         oldself = self;\r
722                         self = target_predator_predator;\r
723                         if(Swallow_condition_check(oldself))\r
724                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
725                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
726                                 Vore_Swallow(oldself);\r
727                         self = oldself;\r
728                 }\r
729         }\r
730 \r
731         // the swallow progress of prey and preds idly decrease by this amount\r
732         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
733         {\r
734                 if(self.swallow_progress_pred)\r
735                 {\r
736                         self.swallow_progress_pred -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
737                         if(self.swallow_progress_pred < 0)\r
738                                 self.swallow_progress_pred = 0;\r
739                 }\r
740                 if(self.swallow_progress_prey)\r
741                 {\r
742                         self.swallow_progress_prey -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
743                         if(self.swallow_progress_prey < 0)\r
744                                 self.swallow_progress_prey = 0;\r
745                 }\r
746         }\r
747 \r
748         // apply delays and skip the vore system under some circumstances\r
749         if(!cvar("g_vore")) // the vore system is disabled\r
750         {\r
751                 Vore_Disconnect();\r
752                 return;\r
753         }\r
754         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
755         {\r
756                 Vore_Disconnect();\r
757                 return;\r
758         }\r
759         if(self.spectatee_status)\r
760                 return;\r
761         if(time < self.system_delay)\r
762                 return;\r
763 \r
764 // --------------------------------\r
765 // Code that addresses predators:\r
766 // --------------------------------\r
767 \r
768         // only scan prey between server frames, else we get major breakage in multiplayer and jitter\r
769         if(!frametime)\r
770                 self.prey = Swallow_player_check();\r
771 \r
772         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
773         self.stat_canswallow = 0;\r
774         if(Swallow_condition_check(self.prey))\r
775         {\r
776                 // canswallow stat, used by the HUD\r
777                 if(teams_matter && self.prey.team == self.team)\r
778                         self.stat_canswallow = 2;\r
779                 else\r
780                         self.stat_canswallow = 1;\r
781 \r
782                 if(self.BUTTON_ATCK)\r
783                         Vore_SwallowStep(self.prey);\r
784         }\r
785         else if(self.prey != world)\r
786                 self.stat_canswallow = -1;\r
787 \r
788         // toggle digestion, if the player has someone in their stomach\r
789         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
790         {\r
791                 if(self.stomach_load)\r
792                 {\r
793                         if(time > self.digest_button_delay_time)\r
794                         {\r
795                                 self.digesting = !self.digesting;\r
796                                 self.digest_button_delay_time = time + button_delay_time;\r
797                         }\r
798                 }\r
799                 else if(time > self.complain_vore)\r
800                 {\r
801                         play2(self, "misc/forbidden.wav");\r
802                         sprint(self, "There is nothing to digest\n");\r
803                         self.complain_vore = time + complain_delay_time;\r
804                 }\r
805         }\r
806         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
807                 self.digesting = FALSE;\r
808 \r
809         // predator wishes to regurgitate his prey\r
810         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
811         {\r
812                 if(self.stomach_load)\r
813                 {\r
814                         if(time > self.regurgitate_button_delay_time)\r
815                         {\r
816                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
817                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
818                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE); // looks good for preparing regurgitation\r
819                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
820                         }\r
821                 }\r
822                 else if(time > self.complain_vore)\r
823                 {\r
824                         play2(self, "misc/forbidden.wav");\r
825                         sprint(self, "There is nothing to regurgitate\n");\r
826                         self.complain_vore = time + complain_delay_time;\r
827                 }\r
828         }\r
829 \r
830         if(cvar("g_vore_gurglesound"))\r
831                 Vore_GurgleSound();\r
832 \r
833 // --------------------------------\r
834 // Code that addresses the prey:\r
835 // --------------------------------\r
836 \r
837         Vore_SetPreyPositions();\r
838 \r
839         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
840         if(self.fakeprey)\r
841         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.stat_eaten)\r
842                 Vore_DeadPrey_Detach(self);\r
843 \r
844         if(!self.stat_eaten)\r
845                 return;\r
846 \r
847         if(self.deadflag != DEAD_NO)\r
848         {\r
849                 Vore_PreyRelease(self, FALSE);\r
850                 return;\r
851         }\r
852 \r
853         if(self.predator.deadflag != DEAD_NO)\r
854                 Vore_Regurgitate(self);\r
855         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap") / (1 + self.predator.stomach_load))\r
856                 Vore_Regurgitate(self);\r
857 \r
858         // apply delayed regurgitating if it was scheduled\r
859         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
860         {\r
861                 self.predator.regurgitate_prepare = 0;\r
862                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
863                 Vore_Regurgitate(self);\r
864         }\r
865 \r
866         // execute digesting and team healing\r
867         if(self.predator.digesting == TRUE)\r
868                 Vore_Digest();\r
869         if(teams_matter && self.team == self.predator.team)\r
870         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
871                 Vore_Teamheal();\r
872 \r
873         // execute prey commands\r
874         if(self.BUTTON_ATCK)\r
875         {\r
876                 if(cvar("g_vore_kick"))\r
877                         Vore_StomachKick();\r
878         }\r
879         else\r
880                 self.kick_pressed = FALSE;\r
881         if(self.BUTTON_JUMP)\r
882                 Vore_StomachLeave();\r
883 \r
884         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
885         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
886         kh_Key_DropAll(self, FALSE);\r
887 }