data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float system_delay, swallow_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(self.scale) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         vore_w_shotorg = self.origin;\r
  22         vore_w_shotdir = v_forward;\r
  23 \r
  24         WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  25         if(trace_fraction < 1)\r
  26         if(trace_ent.classname == "player")\r
  27                 return trace_ent;\r
  28         return world;\r
  29 }\r
  30 \r
  31 float Swallow_condition_check(entity prey)\r
  32 {\r
  33         // checks the necessary conditions for swallowing a player\r
  34 \r
  35         if(prey != self)\r
  36         if(prey.classname == "player" && prey.predator.classname != "player" && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  37         if(self.classname == "player" && self.predator.classname != "player" && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  38         if(!self.BUTTON_REGURGITATE && self.swallow_delay < time)\r
  39         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  40         {\r
  41                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  42                 {\r
  43                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  44                         {\r
  45                                 play2(self, "misc/forbidden.wav");\r
  46                                 sprint(self, "You cannot swallow your team mates\n");\r
  47                                 self.complain_vore = time + complain_delay_time;\r
  48                         }\r
  49                         return FALSE;\r
  50                 }\r
  51 \r
  52                 if(self.stomach_load >= cvar("g_balance_vore_swallow_limit"))\r
  53                 {\r
  54                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  55                         {\r
  56                                 play2(self, "misc/forbidden.wav");\r
  57                                 sprint(self, strcat("You cannot swallow more than ^2", cvar_string("g_balance_vore_swallow_limit"), "^7 players at a time\n"));\r
  58                                 self.complain_vore = time + complain_delay_time;\r
  59                         }\r
  60                         return FALSE;\r
  61                 }\r
  62 \r
  63                 if(cvar("g_vore_biggergut"))\r
  64                 if(prey.stomach_load > self.stomach_load)\r
  65                 {\r
  66                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  67                         {\r
  68                                 play2(self, "misc/forbidden.wav");\r
  69                                 sprint(self, "You cannot swallow someone with a bigger stomach than yours\n");\r
  70                                 self.complain_vore = time + complain_delay_time;\r
  71                         }\r
  72                         return FALSE;\r
  73                 }\r
  74 \r
  75                 if(!cvar("g_vore_spawnshield"))\r
  76                 if(prey.spawnshieldtime > time)\r
  77                 {\r
  78                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  79                         {\r
  80                                 play2(self, "misc/forbidden.wav");\r
  81                                 sprint(self, "You cannot swallow someone protected by the spawn shield\n");\r
  82                                 self.complain_vore = time + complain_delay_time;\r
  83                         }\r
  84                         return FALSE;\r
  85                 }\r
  86 \r
  87                 return TRUE;\r
  88         }\r
  89         return FALSE;\r
  90 }\r
  91 \r
  92 float Stomach_TeamMates_check(entity pred)\r
  93 {\r
  94         // checks if a player's stomach contains any team mates\r
  95 \r
  96         entity head;\r
  97         if(teams_matter)\r
  98         {\r
  99                 FOR_EACH_PLAYER(head)\r
 100                 {\r
 101                         if(head.predator == pred && head.team == pred.team)\r
 102                                 return TRUE;\r
 103                 }\r
 104         }\r
 105         return FALSE;\r
 106 }\r
 107 \r
 108 float Vore_CanLeave()\r
 109 {\r
 110         if(self.predator.classname == "player")\r
 111         {\r
 112                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
 113                         return TRUE;\r
 114                 if(teams_matter && self.team == self.predator.team)\r
 115                         return TRUE;\r
 116                 if(g_rpg && cvar("g_rpg_canleave"))\r
 117                         return TRUE;\r
 118         }\r
 119         return FALSE;\r
 120 }\r
 121 \r
 122 // make the camera smoothly lower itself when we get swallowed\r
 123 // our aim is going from the normal view offset to half of the view offset (because half is the best positioning for the stomach model)\r
 124 .float cameraeffect_current, cameraeffect_target;\r
 125 void Vore_CameraEffect_Set(entity e)\r
 126 {\r
 127         e.cameraeffect_current = 1;\r
 128         e.cameraeffect_target = 2;\r
 129 }\r
 130 void Vore_CameraEffect_Apply()\r
 131 {\r
 132         if(self.predator.classname != "player")\r
 133                 return;\r
 134 \r
 135         if(self.cvar_cl_vore_cameraspeed)\r
 136         {\r
 137                 local float step;\r
 138                 step = self.cvar_cl_vore_cameraspeed * frametime;\r
 139 \r
 140                 // not sure if these maths are good, as the effect should be smoother\r
 141                 if(self.cameraeffect_current >= self.cameraeffect_target + step)\r
 142                         self.cameraeffect_current -= step;\r
 143                 else if(self.cameraeffect_current <= self.cameraeffect_target - step)\r
 144                         self.cameraeffect_current += step;\r
 145         }\r
 146         else\r
 147                 self.cameraeffect_current = self.cameraeffect_target;\r
 148 \r
 149         self.view_ofs_z = PL_VIEW_OFS_z / self.cameraeffect_current;\r
 150 }\r
 151 \r
 152 .float gurgle_oldstomachload;\r
 153 void Vore_GurgleSound()\r
 154 {\r
 155         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 156         {\r
 157                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 158 \r
 159                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 160                 self.gurgle_oldstomachload = self.stomach_load;\r
 161         }\r
 162 }\r
 163 \r
 164 void Vore_WeightApply(entity e)\r
 165 {\r
 166         // apply stomach weight that makes you heavier the more you eat\r
 167         // slowing the player is done in cl_physics.qc\r
 168 \r
 169         if(e.stomach_load != e.vore_oldstomachload)\r
 170                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 171         if(e.gravity == 0)\r
 172                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 173         e.vore_oldstomachload = e.stomach_load;\r
 174 }\r
 175 \r
 176 void Vore_AutoDigest(entity e)\r
 177 {\r
 178         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 179 \r
 180         if(!cvar("g_vore_digestion") || e.digesting)\r
 181                 return;\r
 182         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 183                 return; // this feature is only for players, not bots\r
 184         if(e.stomach_load > 1)\r
 185                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 186         if(Stomach_TeamMates_check(e))\r
 187                 return; // never begin automatic digestion if we've swallowed a team mate\r
 188 \r
 189         e.digesting = TRUE;\r
 190 }\r
 191 \r
 192 .entity pusher;\r
 193 .float pushltime;\r
 194 void Vore_Swallow(entity e)\r
 195 {\r
 196         // this player is being swallowed by another player, apply the proper changes\r
 197 \r
 198         e.vore_oldmovetype = e.movetype;\r
 199         e.vore_oldsolid = e.solid;\r
 200 \r
 201         e.predator = self;\r
 202         setorigin(e, e.predator.origin);\r
 203         e.velocity = '0 0 0';\r
 204         e.movetype = MOVETYPE_FOLLOW;\r
 205         e.solid = SOLID_NOT;\r
 206         e.alpha = -1; // best way of hiding the eaten player\r
 207         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 208 \r
 209         // drop keys (KH) and flags (CTF) when we get swallowed\r
 210         kh_Key_DropAll(e, FALSE);\r
 211         if(e.flagcarried)\r
 212                 DropFlag(e.flagcarried, world, e.predator);\r
 213 \r
 214         Vore_CameraEffect_Set(e);\r
 215 \r
 216         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 217                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 218 \r
 219         if(teams_matter && e.team == e.predator.team)\r
 220         {\r
 221                 if(cvar("g_vore_kick"))\r
 222                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 223                 if(cvar("g_vore_digestion"))\r
 224                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 225         }\r
 226 \r
 227         PlayerSound(e.predator, playersound_swallow, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 228         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 229         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 230         e.predator.stomach_load += 1;\r
 231         e.predator.regurgitate_prepare = 0;\r
 232         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 233         Vore_WeightApply(e.predator);\r
 234         Vore_AutoDigest(e.predator);\r
 235 \r
 236         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 237         e.predator.weapon_delay = time + button_delay_time;\r
 238         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 239         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 240 }\r
 241 \r
 242 void Vore_Regurgitate(entity e)\r
 243 {\r
 244         // this player is being regurgitated by their predator, apply the proper changes\r
 245 \r
 246         e.movetype = e.vore_oldmovetype;\r
 247         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 248                 e.solid = e.vore_oldsolid;\r
 249         e.view_ofs_z = PL_VIEW_OFS_z;\r
 250         e.alpha = default_player_alpha;\r
 251 \r
 252         // apply velocities\r
 253         local vector oldforward, oldright, oldup;\r
 254         oldforward = v_forward;\r
 255         oldright = v_right;\r
 256         oldup = v_up;\r
 257         makevectors(e.predator.v_angle);\r
 258         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 259         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 260         v_forward = oldforward;\r
 261         v_right = oldright;\r
 262         v_up = oldup;\r
 263 \r
 264         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 265         e.pushltime = time + cvar("g_maxpushtime");\r
 266 \r
 267         PlayerSound(e.predator, playersound_regurgitate, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 268         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 269         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 270         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 271         e.predator.stomach_load -= 1;\r
 272         e.predator.regurgitate_prepare = 0;\r
 273         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 274         Vore_WeightApply(e.predator);\r
 275 \r
 276         // block firing for a small amount of time, or we'll be firing the next frame\r
 277         e.weapon_delay = time + button_delay_time;\r
 278         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 279         e.predator = world;\r
 280 }\r
 281 \r
 282 void Vore_DeadPrey_Configure(entity e)\r
 283 {\r
 284         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 285 \r
 286         if(e.fakeprey || e.predator.classname != "player") // already configured\r
 287                 return;\r
 288 \r
 289         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 290         e.fakepredator = e.predator;\r
 291         e.fakeprey = TRUE;\r
 292 \r
 293         // first release the prey from the predator, as dead prey needs to be attached differently\r
 294         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 295         e.predator.stomach_load -= 1;\r
 296         Vore_WeightApply(e.predator);\r
 297         e.predator = world;\r
 298 \r
 299         // now put our dead prey inside the predator's stomach, but only as an effect\r
 300         e.movetype = MOVETYPE_FOLLOW;\r
 301         e.takedamage = DAMAGE_NO;\r
 302         e.solid = SOLID_NOT;\r
 303         e.aiment = e.fakepredator;\r
 304 \r
 305         // completely remove the dead body\r
 306         e.modelindex = 0;\r
 307 }\r
 308 \r
 309 void Vore_DeadPrey_Detach(entity e)\r
 310 {\r
 311         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 312         // should only execute after Vore_DeadPrey_Configure has ran first\r
 313 \r
 314         if not(cvar("g_vore_keepdeadprey"))\r
 315                 return;\r
 316 \r
 317         e.fakepredator = world;\r
 318         e.fakeprey = FALSE;\r
 319         e.aiment = world;\r
 320         e.movetype = MOVETYPE_TOSS;\r
 321 }\r
 322 \r
 323 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 324 {\r
 325         if(pred_disconnect)\r
 326         {\r
 327                 if(e.fakeprey)\r
 328                         Vore_DeadPrey_Detach(e);\r
 329                 else\r
 330                         Vore_Regurgitate(e);\r
 331         }\r
 332         else\r
 333         {\r
 334                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 335                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
 336                         Vore_DeadPrey_Configure(e);\r
 337                 else\r
 338                         Vore_Regurgitate(e);\r
 339         }\r
 340 }\r
 341 \r
 342 void Vore_Disconnect()\r
 343 {\r
 344         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 345 \r
 346         // prey disconnects or goes spectating while inside someone's belly\r
 347         if(self.predator.classname == "player")\r
 348                 Vore_PreyRelease(self, TRUE);\r
 349 \r
 350         // pred disconnects or goes spectating with players in their belly\r
 351         entity head;\r
 352         FOR_EACH_PLAYER(head)\r
 353         {\r
 354                 if(head.predator == self || head.fakepredator == self)\r
 355                         Vore_PreyRelease(head, TRUE);\r
 356         }\r
 357         Vore_GurgleSound(); // stop the gurgling sound\r
 358 \r
 359         self.stomach_load = self.gravity = 0; // prevents a bug\r
 360 }\r
 361 \r
 362 .float digestion_step;\r
 363 void Vore_Digest()\r
 364 {\r
 365         // apply digestion to prey\r
 366 \r
 367         if(time > self.predator.digestion_step)\r
 368         {\r
 369                 Damage(self, self.predator, self.predator, cvar("g_balance_vore_digestion_damage"), DEATH_DIGESTION, self.origin, '0 0 0');\r
 370                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 371                         self.predator.health += cvar("g_balance_vore_digestion_vampire");\r
 372 \r
 373                 if (self.predator.digestsound_finished < time)\r
 374                 {\r
 375                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 376                         self.predator.digestsound_finished = time + 0.5;\r
 377                 }\r
 378                 self.predator.digestion_step = time + steptime;\r
 379         }\r
 380 \r
 381         if(self.deadflag != DEAD_NO)\r
 382         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 383                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 384 }\r
 385 \r
 386 .float teamheal_step;\r
 387 void Vore_Teamheal()\r
 388 {\r
 389         // apply teamheal\r
 390 \r
 391         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 392         if(time > self.teamheal_step)\r
 393         {\r
 394                 self.health += cvar("g_balance_vore_teamheal");\r
 395                 self.teamheal_step = time + steptime;\r
 396 \r
 397                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 398                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 399                 {\r
 400                         play2(self, "misc/beep.wav");\r
 401                         play2(self.predator, "misc/beep.wav");\r
 402                 }\r
 403         }\r
 404 }\r
 405 \r
 406 .float stomachkick_delay;\r
 407 void Vore_StomachKick()\r
 408 {\r
 409         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 410 \r
 411         if(time > self.stomachkick_delay)\r
 412         {\r
 413                 float damage;\r
 414                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 415 \r
 416                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, v_forward * cvar("g_balance_vore_kick_force"));\r
 417                 sound(self.predator, CHAN_PROJECTILE, "weapons/stomachkick.wav", VOL_BASE, ATTN_NORM);\r
 418                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 419                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 420 \r
 421                 if(random() < cvar("g_balance_vore_kick_escapeprobability"))\r
 422                         Vore_Regurgitate(self);\r
 423 \r
 424                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 425         }\r
 426 }\r
 427 \r
 428 void Vore_StomachLeave()\r
 429 {\r
 430         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 431 \r
 432         if(Vore_CanLeave())\r
 433                 Vore_Regurgitate(self);\r
 434         else if(time > self.complain_vore)\r
 435         {\r
 436                 play2(self, "misc/forbidden.wav");\r
 437                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 438                 self.complain_vore = time + complain_delay_time;\r
 439         }\r
 440 }\r
 441 \r
 442 void Vore_AutoTaunt()\r
 443 {\r
 444         // triggers ambient vore taunts, for both pred and prey\r
 445 \r
 446         float taunt_time;\r
 447 \r
 448         // predator taunts\r
 449         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 450         {\r
 451                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 452                 {\r
 453                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 454                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 455                 }\r
 456         }\r
 457         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 458         {\r
 459                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 460                 SetAutoTaunt(self, 0, 0);\r
 461         }\r
 462 \r
 463         // prey taunts\r
 464         if(self.predator.classname == "player" && !(teams_matter && self.team == self.predator.team))\r
 465         {\r
 466                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 467                 {\r
 468                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 469                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 470                 }\r
 471         }\r
 472         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 473         {\r
 474                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 475                 SetAutoTaunt(self, 0, 0);\r
 476         }\r
 477 }\r
 478 \r
 479 void Vore()\r
 480 {\r
 481         // main vore code, this is where it all happens\r
 482 \r
 483         if(!cvar("g_vore")) // the vore system is disabled\r
 484         {\r
 485                 Vore_Disconnect();\r
 486                 return;\r
 487         }\r
 488 \r
 489         Vore_AutoTaunt();\r
 490 \r
 491         // wash the goo away from players once they leave the stomach\r
 492         if(self.predator.classname != "player")\r
 493         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 494         if(self.colormod)\r
 495         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 496         {\r
 497                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 498                 if(self.colormod_x > 1)\r
 499                         self.colormod_x = 1;\r
 500                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 501                 if(self.colormod_y > 1)\r
 502                         self.colormod_y = 1;\r
 503                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 504                 if(self.colormod_z > 1)\r
 505                         self.colormod_z = 1;\r
 506         }\r
 507 \r
 508         // set all vore stats\r
 509         if(self.fakeprey)\r
 510                 self.stat_eaten = num_for_edict(self.fakepredator);\r
 511         else if(self.predator.classname == "player")\r
 512         {\r
 513                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 514                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 515                 self.stat_eaten = num_for_edict(self.predator);\r
 516         }\r
 517         else\r
 518         {\r
 519                 self.stat_stomachload = self.stomach_load;\r
 520                 self.stat_digesting = self.digesting;\r
 521                 self.stat_eaten = 0;\r
 522         }\r
 523         self.stat_canleave = Vore_CanLeave();\r
 524 \r
 525         // don't allow a player inside a player inside another player :)\r
 526         // prevent this by checking if such has happened, and taking the proper measures\r
 527         // this code has a high priority and must not be stopped by any delay, so run it here\r
 528         if(self.predator.predator.classname == "player")\r
 529         {\r
 530                 entity target_predator, target_predator_predator, oldself;\r
 531                 target_predator = self.predator;\r
 532                 target_predator_predator = self.predator.predator;\r
 533 \r
 534                 Vore_Regurgitate(self);\r
 535 \r
 536                 // now steal our prey's prey if this probability applies\r
 537                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 538                 {\r
 539                         oldself = self;\r
 540                         self = target_predator_predator;\r
 541                         if(Swallow_condition_check(oldself))\r
 542                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 543                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 544                                 Vore_Swallow(oldself);\r
 545                         self = oldself;\r
 546                 }\r
 547         }\r
 548 \r
 549         // apply delays and skip the vore system under some circumstances\r
 550         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 551         {\r
 552                 Vore_Disconnect();\r
 553                 return;\r
 554         }\r
 555         if(self.spectatee_status)\r
 556                 return;\r
 557         if(time < self.system_delay)\r
 558                 return;\r
 559 \r
 560 // --------------------------------\r
 561 // Code that addresses predators:\r
 562 // --------------------------------\r
 563 \r
 564         entity prey;\r
 565         prey = Swallow_player_check();\r
 566 \r
 567         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 568         self.stat_canswallow = 0;\r
 569         if(Swallow_condition_check(prey))\r
 570         {\r
 571                 // canswallow stat, used by the HUD\r
 572                 if(teams_matter && prey.team == self.team)\r
 573                         self.stat_canswallow = 2;\r
 574                 else\r
 575                         self.stat_canswallow = 1;\r
 576 \r
 577                 if(self.BUTTON_ATCK)\r
 578                         Vore_Swallow(prey);\r
 579         }\r
 580         else if(prey != world)\r
 581                 self.stat_canswallow = -1;\r
 582 \r
 583         // toggle digestion, if the player has someone in their stomach\r
 584         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 585         {\r
 586                 if(self.stomach_load)\r
 587                 {\r
 588                         if(time > self.digest_button_delay_time)\r
 589                         {\r
 590                                 self.digesting = !self.digesting;\r
 591                                 self.digest_button_delay_time = time + button_delay_time;\r
 592                         }\r
 593                 }\r
 594                 else if(time > self.complain_vore)\r
 595                 {\r
 596                         play2(self, "misc/forbidden.wav");\r
 597                         sprint(self, "There is nothing to digest\n");\r
 598                         self.complain_vore = time + complain_delay_time;\r
 599                 }\r
 600         }\r
 601         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 602                 self.digesting = FALSE;\r
 603 \r
 604         // predator wishes to regurgitate his prey\r
 605         if(self.BUTTON_REGURGITATE)\r
 606         {\r
 607                 if(self.stomach_load)\r
 608                 {\r
 609                         if(time > self.regurgitate_button_delay_time)\r
 610                         {\r
 611                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 612                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 613                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 614                         }\r
 615                 }\r
 616                 else if(time > self.complain_vore)\r
 617                 {\r
 618                         play2(self, "misc/forbidden.wav");\r
 619                         sprint(self, "There is nothing to regurgitate\n");\r
 620                         self.complain_vore = time + complain_delay_time;\r
 621                 }\r
 622         }\r
 623 \r
 624         if(cvar("g_vore_gurglesound"))\r
 625                 Vore_GurgleSound();\r
 626 \r
 627 // --------------------------------\r
 628 // Code that addresses the prey:\r
 629 // --------------------------------\r
 630 \r
 631         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 632         if(self.fakepredator.classname == "player")\r
 633         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.predator.classname == "player")\r
 634                 Vore_DeadPrey_Detach(self);\r
 635 \r
 636         if(self.predator.classname != "player")\r
 637                 return;\r
 638 \r
 639         if(self.deadflag != DEAD_NO)\r
 640         {\r
 641                 Vore_PreyRelease(self, FALSE);\r
 642                 return;\r
 643         }\r
 644 \r
 645         if(self.predator.deadflag != DEAD_NO)\r
 646                 Vore_Regurgitate(self);\r
 647         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 648                 Vore_Regurgitate(self);\r
 649 \r
 650         // apply delayed regurgitating if it was scheduled\r
 651         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 652         {\r
 653                 self.predator.regurgitate_prepare = 0;\r
 654                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 655                 Vore_Regurgitate(self);\r
 656         }\r
 657 \r
 658         // execute digesting and team healing\r
 659         if(self.predator.digesting == TRUE)\r
 660                 Vore_Digest();\r
 661         if(teams_matter && self.team == self.predator.team)\r
 662         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 663                 Vore_Teamheal();\r
 664 \r
 665         // execute prey commands\r
 666         if(self.BUTTON_ATCK && cvar("g_vore_kick"))\r
 667                 Vore_StomachKick();\r
 668         if(self.BUTTON_JUMP)\r
 669                 Vore_StomachLeave();\r
 670 \r
 671         Vore_CameraEffect_Apply();\r
 672 \r
 673         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 674         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 675         kh_Key_DropAll(self, FALSE);\r
 676 }