798b5cf6d2c9366f070ee128f1615a25c678dfe9
[voretournament/voretournament.git] / data / qcsrc / server / vore.qc
1 .float vore_frametime;\r
2 .float regurgitate_prepare;\r
3 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
4 .float complain_vore;\r
5 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
6 \r
7 const float system_delay_time = 0.1;\r
8 const float complain_delay_time = 1;\r
9 const float button_delay_time = 0.5;\r
10 const float steptime = 0.1;\r
11 \r
12 entity Swallow_player_check()\r
13 {\r
14         // check if we can swallow a player instead of firing our weapon\r
15 \r
16         float swallow_range;\r
17         vector vore_w_shotorg, vore_w_shotdir;\r
18 \r
19         swallow_range = cvar("g_balance_vore_swallow_range");\r
20         if(cvar("g_healthsize")) // we can swallow from further or closer based on our size\r
21                 swallow_range *= self.scale;\r
22         vore_w_shotorg = self.origin;\r
23         vore_w_shotdir = v_forward;\r
24 \r
25         WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
26         if(trace_fraction < 1)\r
27         if(trace_ent.classname == "player")\r
28                 return trace_ent;\r
29         return world;\r
30 }\r
31 \r
32 float Swallow_condition_check(entity prey)\r
33 {\r
34         // checks the necessary conditions for swallowing a player\r
35 \r
36         if(prey != self)\r
37         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
38         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
39         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
40         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap") / (1 + self.stomach_load))\r
41         {\r
42                 string swallow_complain;\r
43                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
44                         swallow_complain = "You cannot swallow your team mates\n";\r
45                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
46                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
47                 else if(self.stomach_load >= g_balance_vore_swallow_limit)\r
48                         swallow_complain = strcat("You cannot swallow more than ^2", ftos(g_balance_vore_swallow_limit), "^7 players at a time\n");\r
49                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
50                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
51                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
52                         swallow_complain = "You cannot swallow someone larger than you\n";\r
53 \r
54                 if(swallow_complain != "")\r
55                 {\r
56                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
57                         {\r
58                                 play2(self, "misc/forbidden.wav");\r
59                                 sprint(self, swallow_complain);\r
60                                 self.complain_vore = time + complain_delay_time;\r
61                         }\r
62                         return FALSE;\r
63                 }\r
64                 return TRUE;\r
65         }\r
66         return FALSE;\r
67 }\r
68 \r
69 float Stomach_TeamMates_check(entity pred)\r
70 {\r
71         // checks if a player's stomach contains any team mates\r
72 \r
73         entity head;\r
74         if(teams_matter)\r
75         {\r
76                 FOR_EACH_PLAYER(head)\r
77                 {\r
78                         if(head.predator == pred && head.team == pred.team)\r
79                                 return TRUE;\r
80                 }\r
81         }\r
82         return FALSE;\r
83 }\r
84 \r
85 float Vore_CanLeave()\r
86 {\r
87         if(self.stat_eaten)\r
88         {\r
89                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
90                         return TRUE;\r
91                 if(teams_matter && self.team == self.predator.team)\r
92                         return TRUE;\r
93                 if(g_rpg && cvar("g_rpg_canleave"))\r
94                         return TRUE;\r
95         }\r
96         return FALSE;\r
97 }\r
98 \r
99 // position the camera properly for prey\r
100 void Vore_SetPreyPositions()\r
101 {\r
102         // self is the predator and head is the prey\r
103 \r
104         local entity head;\r
105         local vector origin_apply;\r
106         local float position_counter;\r
107 \r
108         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
109         // else all players overlap in the center. To do this, we run a loop on all players in the same stomach.\r
110         // For each player, the origin is updated, then a new origin is used for the next player.\r
111         // This requires that no more than 9 players may be in the stomach at a time!\r
112         FOR_EACH_PLAYER(head)\r
113         {\r
114                 if(head.predator == self)\r
115                 {\r
116                         switch(position_counter)\r
117                         {\r
118                                 case 0:\r
119                                         origin_apply = '0 0 0'; // first occupant sits in the middle\r
120                                         break;\r
121                                 case 1:\r
122                                         origin_apply = '1 0 0'; // second occupant sits in the front\r
123                                         break;\r
124                                 case 2:\r
125                                         origin_apply = '-1 0 0'; // third occupant sits in the back\r
126                                         break;\r
127                                 case 3:\r
128                                         origin_apply = '0 1 0'; // fourth occupant sits in the right\r
129                                         break;\r
130                                 case 4:\r
131                                         origin_apply = '0 -1 0'; // fifth occupant sits in the left\r
132                                         break;\r
133                                 case 5:\r
134                                         origin_apply = '1 1 0'; // sixth occupant sits in the front-right\r
135                                         break;\r
136                                 case 6:\r
137                                         origin_apply = '-1 1 0'; // seventh occupant sits in the back-right\r
138                                         break;\r
139                                 case 7:\r
140                                         origin_apply = '1 -1 0'; // eigth occupant sits in the front-left\r
141                                         break;\r
142                                 case 8:\r
143                                         origin_apply = '-1 -1 0'; // ninth occupant sits in the back-left\r
144                                         break;\r
145                                 default:\r
146                                         break;\r
147                         }\r
148 \r
149                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
150                         head.view_ofs = PL_PREY_VIEW_OFS + origin_apply * cvar("g_vore_neighborprey_distance");\r
151                         head.view_ofs_z *= self.scale; // stomach center depends on predator scale\r
152 \r
153                         // change prey height based on scale\r
154                         float prey_height;\r
155                                 prey_height = (head.scale - self.scale) * cvar("g_healthsize_vore_pos");\r
156                         head.view_ofs_z += prey_height;\r
157 \r
158                         position_counter += 1;\r
159                 }\r
160         }\r
161 }\r
162 \r
163 .float gurgle_oldstomachload;\r
164 void Vore_GurgleSound()\r
165 {\r
166         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
167         {\r
168                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
169 \r
170                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
171                 self.gurgle_oldstomachload = self.stomach_load;\r
172         }\r
173 }\r
174 \r
175 void Vore_WeightApply(entity e)\r
176 {\r
177         // apply stomach weight that makes you heavier the more you eat\r
178         // slowing the player is done in cl_physics.qc\r
179 \r
180         if(e.stomach_load != e.vore_oldstomachload)\r
181                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
182         if(e.gravity == 0)\r
183                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
184         e.vore_oldstomachload = e.stomach_load;\r
185 }\r
186 \r
187 void Vore_AutoDigest(entity e)\r
188 {\r
189         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
190 \r
191         if(!cvar("g_vore_digestion") || e.digesting)\r
192                 return;\r
193         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
194                 return; // this feature is only for players, not bots\r
195         if(e.stomach_load > 1)\r
196                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
197         if(Stomach_TeamMates_check(e))\r
198                 return; // never begin automatic digestion if we've swallowed a team mate\r
199 \r
200         e.digesting = TRUE;\r
201 }\r
202 \r
203 .entity swallow_model;\r
204 void Vore_SwallowModel_Think()\r
205 {\r
206         //update the position of the swallow model to match our swallow progress\r
207         float dist;\r
208         dist = (-0.5 + self.owner.swallow_progress_prey) * cvar("g_vore_swallowmodel_range"); // the model is centered at 0.5 progress\r
209         if(cvar("g_healthsize"))\r
210                 dist *= self.scale;\r
211         self.view_ofs = '1 0 0' * dist;\r
212 \r
213         // if our swallow progress is gone or we are dead, the swallow model also goes away\r
214         if(!self.owner.swallow_progress_prey || self.owner.deadflag != DEAD_NO || self.owner.classname != "player")\r
215         {\r
216                 remove(self.owner.swallow_model);\r
217                 self.owner.swallow_model = world;\r
218                 return;\r
219         }\r
220 \r
221         // properties that should update whenever possible, but when the predator is not available\r
222         self.alpha = self.owner.cvar_cl_vore_swallowmodel;\r
223         self.nextthink = time;\r
224 }\r
225 \r
226 void Vore_SwallowModel_Update(entity prey, entity pred)\r
227 {\r
228         // if we don't have a swallow model already, spawn one\r
229         if(!prey.swallow_model)\r
230         {\r
231                 prey.swallow_model = spawn();\r
232 \r
233                 prey.swallow_model.movetype = MOVETYPE_FOLLOW;\r
234                 prey.swallow_model.solid = SOLID_NOT;\r
235 \r
236                 // apply the properties of the prey\r
237                 prey.swallow_model.viewmodelforclient = prey; // use the same system as the weapon model\r
238                 //prey.swallow_model.effects |= EF_NOGUNBOB; // let it bob\r
239                 prey.swallow_model.effects |= EF_NODEPTHTEST; // don't hide behind walls\r
240                 prey.swallow_model.colormap = prey.colormap; // pants and shirt color\r
241                 prey.swallow_model.glowmod = prey.glowmod; // glow color\r
242 \r
243                 prey.swallow_model.owner = prey; // owned by the prey\r
244                 prey.swallow_model.think = Vore_SwallowModel_Think;\r
245                 prey.swallow_model.nextthink = time;\r
246         }\r
247 \r
248         // properties that should update whenever possible, but when the predator is available\r
249         string player_swallowmodel;\r
250         player_swallowmodel = strcat(substring(pred.playermodel, 0, strlen(pred.playermodel) - 4), "_swallow.md3"); // 4 is the extension length\r
251         if(prey.swallow_model.model != player_swallowmodel) // player model can be changed while the predator is active\r
252                 setmodel(prey.swallow_model, player_swallowmodel);\r
253         if(prey.swallow_model.skin != pred.skin) // player skin can be changed while the predator is active\r
254                 prey.swallow_model.skin = pred.skin;\r
255         if(cvar("g_healthsize"))\r
256                 prey.swallow_model.scale = pred.scale / prey.scale; // player size difference\r
257         if(prey.swallow_model.enemy != pred)\r
258                 prey.swallow_model.enemy = pred; // enemy is the predator\r
259 }\r
260 \r
261 .entity pusher;\r
262 .float pushltime;\r
263 void Vore_Swallow(entity e)\r
264 {\r
265         // this player is being swallowed by another player, apply the proper changes\r
266 \r
267         e.vore_oldmovetype = e.movetype;\r
268         e.vore_oldsolid = e.solid;\r
269 \r
270         e.predator = self;\r
271         setorigin(e, e.predator.origin);\r
272         e.velocity = '0 0 0';\r
273         e.movetype = MOVETYPE_FOLLOW;\r
274         e.solid = SOLID_NOT;\r
275         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
276 \r
277         // drop keys (KH) and flags (CTF) when we get swallowed\r
278         kh_Key_DropAll(e, FALSE);\r
279         if(e.flagcarried)\r
280                 DropFlag(e.flagcarried, world, e.predator);\r
281 \r
282         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
283                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
284 \r
285         if(teams_matter && e.team == e.predator.team)\r
286         {\r
287                 if(cvar("g_vore_kick"))\r
288                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
289                 if(cvar("g_vore_digestion"))\r
290                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
291         }\r
292 \r
293         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
294         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
295         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
296         e.predator.stomach_load += 1;\r
297         e.predator.regurgitate_prepare = 0;\r
298         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
299         e.predator.hitsound += 1; // play this for team mates too, as we could be swallowing them to heal them\r
300         Vore_WeightApply(e.predator);\r
301         Vore_AutoDigest(e.predator);\r
302 \r
303         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
304         e.predator.weapon_delay = time + button_delay_time;\r
305         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
306         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
307         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
308 }\r
309 \r
310 void Vore_SwallowStep(entity e)\r
311 {\r
312         if(!cvar("g_balance_vore_swallow_speed_fill"))\r
313         {\r
314                 Vore_Swallow(e);\r
315                 return;\r
316         }\r
317 \r
318         Vore_SwallowModel_Update(e, self);\r
319 \r
320         // increase the progress value until it reaches 1, then swallow the player\r
321         if(e.swallow_progress_prey < 1)\r
322         {\r
323                 float fill;\r
324                 fill = cvar("g_balance_vore_swallow_speed_fill") * frametime;\r
325                 if(cvar("g_healthsize") && cvar("g_balance_vore_swallow_speed_fill_scalediff")) // fill rate depends on predator size compared to prey size\r
326                         fill *= pow(self.scale / e.scale, cvar("g_balance_vore_swallow_speed_fill_scalediff"));\r
327                 if(cvar("g_balance_vore_swallow_speed_fill_stomachload") && e.stomach_load) // fill rate is influenced by the prey's stomach load\r
328                         fill /= e.stomach_load;\r
329 \r
330                 e.swallow_progress_prey += fill;\r
331         }\r
332         else\r
333         {\r
334                 Vore_Swallow(e);\r
335                 e.swallow_progress_prey = 0;\r
336         }\r
337 \r
338         // the predator's progress is how much the prey got swallowed\r
339         self.swallow_progress_pred = e.swallow_progress_prey;\r
340 }\r
341 \r
342 void Vore_Regurgitate(entity e)\r
343 {\r
344         // this player is being regurgitated by their predator, apply the proper changes\r
345 \r
346         e.movetype = e.vore_oldmovetype;\r
347         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
348                 e.solid = e.vore_oldsolid;\r
349         e.view_ofs_z = PL_VIEW_OFS_z;\r
350 \r
351         // apply velocities\r
352         local vector oldforward, oldright, oldup;\r
353         oldforward = v_forward;\r
354         oldright = v_right;\r
355         oldup = v_up;\r
356         makevectors(e.predator.v_angle);\r
357         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
358         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
359         v_forward = oldforward;\r
360         v_right = oldright;\r
361         v_up = oldup;\r
362 \r
363         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
364         e.pushltime = time + cvar("g_maxpushtime");\r
365 \r
366         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
367         if(cvar("g_balance_vore_swallow_speed_fill") && cvar("g_balance_vore_regurgitate_swallowprogress"))\r
368         {\r
369                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
370                 Vore_SwallowModel_Update(e, e.predator);\r
371         }\r
372 \r
373         // apply regurgitation damage to the predator\r
374         if(cvar("g_balance_vore_regurgitate_damage"))\r
375         {\r
376                 float regurgitate_dmg;\r
377                 regurgitate_dmg = cvar("g_balance_vore_regurgitate_damage");\r
378                 if(cvar("g_healthsize"))\r
379                         regurgitate_dmg *= e.scale / e.predator.scale;\r
380                 Damage(e.predator, e.predator, e.predator, regurgitate_dmg, DEATH_REGURGITATION, e.predator.origin, '0 0 0');\r
381         }\r
382 \r
383         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
384         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
385         pointparticles(particleeffectnum("vore_regurgitate"), e.predator.origin, '0 0 0', 1);\r
386         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
387         e.predator.stomach_load -= 1;\r
388         e.predator.regurgitate_prepare = 0;\r
389         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
390         Vore_WeightApply(e.predator);\r
391 \r
392         // block firing for a small amount of time, or we'll be firing the next frame\r
393         e.weapon_delay = time + button_delay_time;\r
394         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
395         e.predator = world;\r
396 }\r
397 \r
398 void Vore_DeadPrey_Configure(entity e)\r
399 {\r
400         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
401 \r
402         if(e.fakeprey || !e.stat_eaten) // we already configured everything\r
403                 return;\r
404 \r
405         // this entity is like e.predator but for dead prey, to avoid conflicts\r
406         e.fakepredator = e.predator;\r
407         e.fakeprey = TRUE;\r
408 \r
409         // first release the prey from the predator, as dead prey needs to be attached differently\r
410         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
411         e.predator.stomach_load -= 1;\r
412         Vore_WeightApply(e.predator);\r
413         e.predator = world;\r
414 \r
415         // now put our dead prey inside the predator's stomach, but only as an effect\r
416         e.movetype = MOVETYPE_FOLLOW;\r
417         e.takedamage = DAMAGE_NO;\r
418         e.solid = SOLID_NOT;\r
419         e.aiment = e.fakepredator;\r
420 }\r
421 \r
422 void Vore_DeadPrey_Detach(entity e)\r
423 {\r
424         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
425         // should only execute after Vore_DeadPrey_Configure has ran first\r
426 \r
427         if not(cvar("g_vore_keepdeadprey"))\r
428                 return;\r
429 \r
430         e.fakepredator = world;\r
431         e.fakeprey = TRUE; // keep fakeprey status\r
432         e.stat_eaten = 0;\r
433         e.aiment = world;\r
434         e.movetype = MOVETYPE_TOSS;\r
435 }\r
436 \r
437 void Vore_PreyRelease(entity e, float pred_disconnect)\r
438 {\r
439         if(pred_disconnect)\r
440         {\r
441                 if(e.fakeprey)\r
442                         Vore_DeadPrey_Detach(e);\r
443                 else\r
444                         Vore_Regurgitate(e);\r
445         }\r
446         else if(self.stat_eaten && !self.fakeprey)\r
447         {\r
448                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
449                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
450                         Vore_DeadPrey_Configure(e);\r
451                 else\r
452                         Vore_Regurgitate(e);\r
453         }\r
454 }\r
455 \r
456 void Vore_Disconnect()\r
457 {\r
458         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
459 \r
460         // prey disconnects or goes spectating while inside someone's belly\r
461         if(self.stat_eaten)\r
462                 Vore_PreyRelease(self, TRUE);\r
463 \r
464         // pred disconnects or goes spectating with players in their belly\r
465         entity head;\r
466         FOR_EACH_PLAYER(head)\r
467         {\r
468                 if(head.predator == self || head.fakepredator == self)\r
469                         Vore_PreyRelease(head, TRUE);\r
470         }\r
471         Vore_GurgleSound(); // stop the gurgling sound\r
472 \r
473         self.stomach_load = self.gravity = 0; // prevents a bug\r
474 }\r
475 \r
476 .float digestion_step;\r
477 void Vore_Digest()\r
478 {\r
479         // apply digestion to prey\r
480 \r
481         if(time > self.digestion_step)\r
482         {\r
483                 // if distributed digestion is enabled, reduce digestion strength by the number of prey in our stomach\r
484                 float reduce;\r
485                 if(cvar("g_balance_vore_digestion_distribute"))\r
486                         reduce = self.predator.stomach_load;\r
487                 else\r
488                         reduce = 1;\r
489 \r
490                 float damage;\r
491                 damage = cvar("g_balance_vore_digestion_damage") / reduce;\r
492 \r
493                 // apply player scale to digestion damage\r
494                 if(cvar("g_healthsize") && cvar("g_balance_vore_digestion_scalediff"))\r
495                         damage *= pow(self.predator.scale / self.scale, cvar("g_balance_vore_digestion_scalediff"));\r
496 \r
497                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
498                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
499                         self.predator.health += cvar("g_balance_vore_digestion_vampire") / reduce;\r
500 \r
501                 if (self.predator.digestsound_finished < time)\r
502                 {\r
503                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
504                         self.predator.digestsound_finished = time + 0.5;\r
505                 }\r
506                 self.digestion_step = time + steptime;\r
507         }\r
508 \r
509         if(self.deadflag != DEAD_NO)\r
510         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
511                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
512 }\r
513 \r
514 .float teamheal_step;\r
515 void Vore_Teamheal()\r
516 {\r
517         // apply teamheal\r
518 \r
519         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
520         if(time > self.teamheal_step)\r
521         {\r
522                 self.health += cvar("g_balance_vore_teamheal");\r
523                 self.teamheal_step = time + steptime;\r
524 \r
525                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
526                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
527                 {\r
528                         play2(self, "misc/beep.wav");\r
529                         play2(self.predator, "misc/beep.wav");\r
530                 }\r
531         }\r
532 }\r
533 \r
534 .float kick_pressed;\r
535 void Vore_StomachKick()\r
536 {\r
537         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
538 \r
539         if(time > self.stomachkick_delay && !self.kick_pressed)\r
540         {\r
541                 float damage, vol;\r
542                 vector force;\r
543                 damage = cvar("g_balance_vore_kick_damage");\r
544                 force = v_forward * cvar("g_balance_vore_kick_force");\r
545                 vol = VOL_BASE;\r
546 \r
547                 // apply player scale to the damage / force of the kick\r
548                 if(cvar("g_healthsize") && cvar("g_balance_vore_kick_scalediff"))\r
549                 {\r
550                         damage *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
551                         force *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
552                         vol *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff")); // kick sound volume based on the same scale\r
553                 }\r
554                 vol = bound(0, vol, 1);\r
555 \r
556                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
557                 sound(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), vol, ATTN_NORM);\r
558                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
559                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
560 \r
561                 // abort the predator's scheduled regurgitation\r
562                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
563                         self.predator.regurgitate_prepare = 0;\r
564 \r
565                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
566                 if(cvar("g_balance_vore_kick_repress"))\r
567                 if not(clienttype(self) == CLIENTTYPE_BOT) // not for bots, to prevent an issue\r
568                         self.kick_pressed = TRUE;\r
569         }\r
570 }\r
571 \r
572 void Vore_StomachLeave()\r
573 {\r
574         // allows players to get out of their predator at will in some circumstances, such as team mates\r
575 \r
576         if(Vore_CanLeave())\r
577                 Vore_Regurgitate(self);\r
578         else if(time > self.complain_vore)\r
579         {\r
580                 play2(self, "misc/forbidden.wav");\r
581                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
582                 self.complain_vore = time + complain_delay_time;\r
583         }\r
584 }\r
585 \r
586 void Vore_AutoTaunt()\r
587 {\r
588         // triggers ambient vore taunts, for both pred and prey\r
589 \r
590         float taunt_time;\r
591 \r
592         // predator taunts\r
593         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
594         {\r
595                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
596                 {\r
597                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
598                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
599                 }\r
600         }\r
601         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
602         {\r
603                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
604                 SetAutoTaunt(self, 0, 0);\r
605         }\r
606 \r
607         // prey taunts\r
608         if(self.stat_eaten && !(teams_matter && self.team == self.predator.team))\r
609         {\r
610                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
611                 {\r
612                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
613                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
614                 }\r
615         }\r
616         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
617         {\r
618                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
619                 SetAutoTaunt(self, 0, 0);\r
620         }\r
621 }\r
622 \r
623 void Vore_SetSbarRings()\r
624 {\r
625         // first clear the ring stats, then configure them if needed\r
626         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
627         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
628 \r
629         if(self.stat_eaten)\r
630         {\r
631                 if(time <= self.stomachkick_delay)\r
632                 {\r
633                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
634                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
635                 }\r
636         }\r
637         else\r
638         {\r
639                 if(self.swallow_progress_pred)\r
640                 {\r
641                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
642                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
643                 }\r
644                 else if(time <= self.action_delay)\r
645                 {\r
646                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
647                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
648                 }\r
649 \r
650                 if(self.swallow_progress_prey)\r
651                 {\r
652                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
653                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
654                 }\r
655                 else if(time <= self.regurgitate_prepare)\r
656                 {\r
657                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
658                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
659                 }\r
660         }\r
661 }\r
662 \r
663 .entity prey;\r
664 void Vore()\r
665 {\r
666         // main vore code, this is where it all happens\r
667 \r
668         Vore_AutoTaunt();\r
669 \r
670         // wash the goo away from players once they leave the stomach\r
671         if(!self.stat_eaten)\r
672         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
673         if(self.colormod)\r
674         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
675         {\r
676                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
677                 if(self.colormod_x > 1)\r
678                         self.colormod_x = 1;\r
679                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
680                 if(self.colormod_y > 1)\r
681                         self.colormod_y = 1;\r
682                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
683                 if(self.colormod_z > 1)\r
684                         self.colormod_z = 1;\r
685         }\r
686 \r
687         // set all vore stats\r
688         Vore_SetSbarRings();\r
689         if(self.fakepredator.classname == "player")\r
690                 self.stat_eaten = num_for_edict(self.fakepredator);\r
691         else if(self.predator.classname == "player")\r
692         {\r
693                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
694                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
695                 self.stat_eaten = num_for_edict(self.predator);\r
696         }\r
697         else\r
698         {\r
699                 self.stat_stomachload = self.stomach_load;\r
700                 self.stat_digesting = self.digesting;\r
701                 self.stat_eaten = 0;\r
702         }\r
703         self.stat_canleave = Vore_CanLeave();\r
704 \r
705         // don't allow a player inside a player inside another player :)\r
706         // prevent this by checking if such has happened, and taking the proper measures\r
707         // this code has a high priority and must not be stopped by any delay, so run it here\r
708         if(self.predator.stat_eaten)\r
709         {\r
710                 entity target_predator, target_predator_predator, oldself;\r
711                 target_predator = self.predator;\r
712                 target_predator_predator = self.predator.predator;\r
713 \r
714                 Vore_Regurgitate(self);\r
715 \r
716                 // now steal our prey's prey if this probability applies\r
717                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
718                 {\r
719                         oldself = self;\r
720                         self = target_predator_predator;\r
721                         if(Swallow_condition_check(oldself))\r
722                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
723                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
724                                 Vore_Swallow(oldself);\r
725                         self = oldself;\r
726                 }\r
727         }\r
728 \r
729         // the swallow progress of prey and preds idly decrease by this amount\r
730         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
731         {\r
732                 if(self.swallow_progress_pred)\r
733                 {\r
734                         self.swallow_progress_pred -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
735                         if(self.swallow_progress_pred < 0)\r
736                                 self.swallow_progress_pred = 0;\r
737                 }\r
738                 if(self.swallow_progress_prey)\r
739                 {\r
740                         self.swallow_progress_prey -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
741                         if(self.swallow_progress_prey < 0)\r
742                                 self.swallow_progress_prey = 0;\r
743                 }\r
744         }\r
745 \r
746         // apply delays and skip the vore system under some circumstances\r
747         if(!cvar("g_vore")) // the vore system is disabled\r
748         {\r
749                 Vore_Disconnect();\r
750                 return;\r
751         }\r
752         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
753         {\r
754                 Vore_Disconnect();\r
755                 return;\r
756         }\r
757         if(self.spectatee_status)\r
758                 return;\r
759         if(time < self.system_delay)\r
760                 return;\r
761 \r
762 // --------------------------------\r
763 // Code that addresses predators:\r
764 // --------------------------------\r
765 \r
766         // only scan prey each server frame, else we get major breakage in multiplayer\r
767         if(self.vore_frametime <= time)\r
768         {\r
769                 self.prey = Swallow_player_check();\r
770                 self.vore_frametime = time + sys_frametime;\r
771         }\r
772 \r
773         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
774         self.stat_canswallow = 0;\r
775         if(Swallow_condition_check(self.prey))\r
776         {\r
777                 // canswallow stat, used by the HUD\r
778                 if(teams_matter && self.prey.team == self.team)\r
779                         self.stat_canswallow = 2;\r
780                 else\r
781                         self.stat_canswallow = 1;\r
782 \r
783                 if(self.BUTTON_ATCK)\r
784                         Vore_SwallowStep(self.prey);\r
785         }\r
786         else if(self.prey != world)\r
787                 self.stat_canswallow = -1;\r
788 \r
789         // toggle digestion, if the player has someone in their stomach\r
790         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
791         {\r
792                 if(self.stomach_load)\r
793                 {\r
794                         if(time > self.digest_button_delay_time)\r
795                         {\r
796                                 self.digesting = !self.digesting;\r
797                                 self.digest_button_delay_time = time + button_delay_time;\r
798                         }\r
799                 }\r
800                 else if(time > self.complain_vore)\r
801                 {\r
802                         play2(self, "misc/forbidden.wav");\r
803                         sprint(self, "There is nothing to digest\n");\r
804                         self.complain_vore = time + complain_delay_time;\r
805                 }\r
806         }\r
807         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
808                 self.digesting = FALSE;\r
809 \r
810         // predator wishes to regurgitate his prey\r
811         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
812         {\r
813                 if(self.stomach_load)\r
814                 {\r
815                         if(time > self.regurgitate_button_delay_time)\r
816                         {\r
817                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
818                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
819                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE); // looks good for preparing regurgitation\r
820                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
821                         }\r
822                 }\r
823                 else if(time > self.complain_vore)\r
824                 {\r
825                         play2(self, "misc/forbidden.wav");\r
826                         sprint(self, "There is nothing to regurgitate\n");\r
827                         self.complain_vore = time + complain_delay_time;\r
828                 }\r
829         }\r
830 \r
831         if(cvar("g_vore_gurglesound"))\r
832                 Vore_GurgleSound();\r
833 \r
834 // --------------------------------\r
835 // Code that addresses the prey:\r
836 // --------------------------------\r
837 \r
838         Vore_SetPreyPositions();\r
839 \r
840         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
841         if(self.fakeprey)\r
842         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.stat_eaten)\r
843                 Vore_DeadPrey_Detach(self);\r
844 \r
845         if(!self.stat_eaten)\r
846                 return;\r
847 \r
848         if(self.deadflag != DEAD_NO)\r
849         {\r
850                 Vore_PreyRelease(self, FALSE);\r
851                 return;\r
852         }\r
853 \r
854         if(self.predator.deadflag != DEAD_NO)\r
855                 Vore_Regurgitate(self);\r
856         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap") / (1 + self.predator.stomach_load))\r
857                 Vore_Regurgitate(self);\r
858 \r
859         // apply delayed regurgitating if it was scheduled\r
860         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
861         {\r
862                 self.predator.regurgitate_prepare = 0;\r
863                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
864                 Vore_Regurgitate(self);\r
865         }\r
866 \r
867         // execute digesting and team healing\r
868         if(self.predator.digesting == TRUE)\r
869                 Vore_Digest();\r
870         if(teams_matter && self.team == self.predator.team)\r
871         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
872                 Vore_Teamheal();\r
873 \r
874         // execute prey commands\r
875         if(self.BUTTON_ATCK)\r
876         {\r
877                 if(cvar("g_vore_kick"))\r
878                         Vore_StomachKick();\r
879         }\r
880         else\r
881                 self.kick_pressed = FALSE;\r
882         if(self.BUTTON_JUMP)\r
883                 Vore_StomachLeave();\r
884 \r
885         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
886         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
887         kh_Key_DropAll(self, FALSE);\r
888 }