data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(self.scale) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         vore_w_shotorg = self.origin;\r
  22         vore_w_shotdir = v_forward;\r
  23 \r
  24         WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  25         if(trace_fraction < 1)\r
  26         if(trace_ent.classname == "player")\r
  27                 return trace_ent;\r
  28         return world;\r
  29 }\r
  30 \r
  31 float Swallow_condition_check(entity prey)\r
  32 {\r
  33         // checks the necessary conditions for swallowing a player\r
  34 \r
  35         if(prey != self)\r
  36         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  37         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  38         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  39         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  40         {\r
  41                 string swallow_complain;\r
  42                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  43                         swallow_complain = "You cannot swallow your team mates\n";\r
  44                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  45                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  46                 else if(self.stomach_load >= cvar("g_balance_vore_swallow_limit"))\r
  47                         swallow_complain = strcat("You cannot swallow more than ^2", cvar_string("g_balance_vore_swallow_limit"), "^7 players at a time\n");\r
  48                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  49                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  50                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  51                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  52 \r
  53                 if(swallow_complain != "")\r
  54                 {\r
  55                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  56                         {\r
  57                                 play2(self, "misc/forbidden.wav");\r
  58                                 sprint(self, swallow_complain);\r
  59                                 self.complain_vore = time + complain_delay_time;\r
  60                         }\r
  61                         return FALSE;\r
  62                 }\r
  63                 return TRUE;\r
  64         }\r
  65         return FALSE;\r
  66 }\r
  67 \r
  68 float Stomach_TeamMates_check(entity pred)\r
  69 {\r
  70         // checks if a player's stomach contains any team mates\r
  71 \r
  72         entity head;\r
  73         if(teams_matter)\r
  74         {\r
  75                 FOR_EACH_PLAYER(head)\r
  76                 {\r
  77                         if(head.predator == pred && head.team == pred.team)\r
  78                                 return TRUE;\r
  79                 }\r
  80         }\r
  81         return FALSE;\r
  82 }\r
  83 \r
  84 float Vore_CanLeave()\r
  85 {\r
  86         if(self.stat_eaten)\r
  87         {\r
  88                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
  89                         return TRUE;\r
  90                 if(teams_matter && self.team == self.predator.team)\r
  91                         return TRUE;\r
  92                 if(g_rpg && cvar("g_rpg_canleave"))\r
  93                         return TRUE;\r
  94         }\r
  95         return FALSE;\r
  96 }\r
  97 \r
  98 // position the camera properly for prey\r
  99 void Vore_SetPreyPositions()\r
 100 {\r
 101         // self is the predator and head is the prey\r
 102 \r
 103         local entity head;\r
 104         local vector oldforward, oldright, oldup;\r
 105         local vector origin_apply;\r
 106         local float position_counter;\r
 107 \r
 108         oldforward = v_forward;\r
 109         oldright = v_right;\r
 110         oldup = v_up;\r
 111         makevectors(self.v_angle);\r
 112 \r
 113         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 114         // else all players overlap in the center. To do this, we run a loop on all players in the same stomach.\r
 115         // For each player, the origin is updated, then a new origin is used for the next player.\r
 116         // This requires that no more than 9 players may be in the stomach at a time!\r
 117         FOR_EACH_PLAYER(head)\r
 118         {\r
 119                 if(head.predator == self)\r
 120                 {\r
 121                         switch(position_counter)\r
 122                         {\r
 123                                 case 0:\r
 124                                         origin_apply = '0 0 0'; // first occupant sits in the middle\r
 125                                         break;\r
 126                                 case 1:\r
 127                                         origin_apply = '1 0 0'; // second occupant sits in the front\r
 128                                         break;\r
 129                                 case 2:\r
 130                                         origin_apply = '-1 0 0'; // third occupant sits in the back\r
 131                                         break;\r
 132                                 case 3:\r
 133                                         origin_apply = '0 1 0'; // fourth occupant sits in the right\r
 134                                         break;\r
 135                                 case 4:\r
 136                                         origin_apply = '0 -1 0'; // fifth occupant sits in the left\r
 137                                         break;\r
 138                                 case 5:\r
 139                                         origin_apply = '1 1 0'; // sixth occupant sits in the front-right\r
 140                                         break;\r
 141                                 case 6:\r
 142                                         origin_apply = '-1 1 0'; // seventh occupant sits in the back-right\r
 143                                         break;\r
 144                                 case 7:\r
 145                                         origin_apply = '1 -1 0'; // eigth occupant sits in the front-left\r
 146                                         break;\r
 147                                 case 8:\r
 148                                         origin_apply = '-1 -1 0'; // ninth occupant sits in the back-left\r
 149                                         break;\r
 150                                 default:\r
 151                                         break;\r
 152                         }\r
 153 \r
 154                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 155                         origin_apply_x *= v_forward_x; // position depends on the predator's rotation\r
 156                         origin_apply_y *= v_forward_y; // position depends on the predator's rotation\r
 157                         head.view_ofs = PL_PREY_VIEW_OFS + origin_apply * cvar("g_vore_neighborprey_distance");\r
 158 \r
 159                         // change prey height based on scale\r
 160                         float prey_height;\r
 161                                 prey_height = (head.scale - self.scale) * cvar("g_healthsize_vore_pos");\r
 162                         head.view_ofs_z += prey_height;\r
 163 \r
 164                         position_counter += 1;\r
 165                 }\r
 166         }\r
 167 \r
 168         v_forward = oldforward;\r
 169         v_right = oldright;\r
 170         v_up = oldup;\r
 171 }\r
 172 \r
 173 .float gurgle_oldstomachload;\r
 174 void Vore_GurgleSound()\r
 175 {\r
 176         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 177         {\r
 178                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 179 \r
 180                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 181                 self.gurgle_oldstomachload = self.stomach_load;\r
 182         }\r
 183 }\r
 184 \r
 185 void Vore_WeightApply(entity e)\r
 186 {\r
 187         // apply stomach weight that makes you heavier the more you eat\r
 188         // slowing the player is done in cl_physics.qc\r
 189 \r
 190         if(e.stomach_load != e.vore_oldstomachload)\r
 191                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 192         if(e.gravity == 0)\r
 193                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 194         e.vore_oldstomachload = e.stomach_load;\r
 195 }\r
 196 \r
 197 void Vore_AutoDigest(entity e)\r
 198 {\r
 199         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 200 \r
 201         if(!cvar("g_vore_digestion") || e.digesting)\r
 202                 return;\r
 203         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 204                 return; // this feature is only for players, not bots\r
 205         if(e.stomach_load > 1)\r
 206                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 207         if(Stomach_TeamMates_check(e))\r
 208                 return; // never begin automatic digestion if we've swallowed a team mate\r
 209 \r
 210         e.digesting = TRUE;\r
 211 }\r
 212 \r
 213 .entity pusher;\r
 214 .float pushltime;\r
 215 void Vore_Swallow(entity e)\r
 216 {\r
 217         // this player is being swallowed by another player, apply the proper changes\r
 218 \r
 219         e.vore_oldmovetype = e.movetype;\r
 220         e.vore_oldsolid = e.solid;\r
 221 \r
 222         e.predator = self;\r
 223         setorigin(e, e.predator.origin);\r
 224         e.velocity = '0 0 0';\r
 225         e.movetype = MOVETYPE_FOLLOW;\r
 226         e.solid = SOLID_NOT;\r
 227         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 228 \r
 229         // drop keys (KH) and flags (CTF) when we get swallowed\r
 230         kh_Key_DropAll(e, FALSE);\r
 231         if(e.flagcarried)\r
 232                 DropFlag(e.flagcarried, world, e.predator);\r
 233 \r
 234         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 235                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 236 \r
 237         if(teams_matter && e.team == e.predator.team)\r
 238         {\r
 239                 if(cvar("g_vore_kick"))\r
 240                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 241                 if(cvar("g_vore_digestion"))\r
 242                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 243         }\r
 244 \r
 245         PlayerSound(e.predator, playersound_swallow, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 246         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 247         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 248         e.predator.stomach_load += 1;\r
 249         e.predator.regurgitate_prepare = 0;\r
 250         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 251         Vore_WeightApply(e.predator);\r
 252         Vore_AutoDigest(e.predator);\r
 253 \r
 254         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 255         e.predator.weapon_delay = time + button_delay_time;\r
 256         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 257         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 258         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 259 }\r
 260 \r
 261 void Vore_Regurgitate(entity e)\r
 262 {\r
 263         // this player is being regurgitated by their predator, apply the proper changes\r
 264 \r
 265         e.movetype = e.vore_oldmovetype;\r
 266         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 267                 e.solid = e.vore_oldsolid;\r
 268         e.view_ofs_z = PL_VIEW_OFS_z;\r
 269 \r
 270         // apply velocities\r
 271         local vector oldforward, oldright, oldup;\r
 272         oldforward = v_forward;\r
 273         oldright = v_right;\r
 274         oldup = v_up;\r
 275         makevectors(e.predator.v_angle);\r
 276         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 277         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 278         v_forward = oldforward;\r
 279         v_right = oldright;\r
 280         v_up = oldup;\r
 281 \r
 282         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 283         e.pushltime = time + cvar("g_maxpushtime");\r
 284 \r
 285         PlayerSound(e.predator, playersound_regurgitate, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 286         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 287         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 288         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 289         e.predator.stomach_load -= 1;\r
 290         e.predator.regurgitate_prepare = 0;\r
 291         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 292         Vore_WeightApply(e.predator);\r
 293 \r
 294         // block firing for a small amount of time, or we'll be firing the next frame\r
 295         e.weapon_delay = time + button_delay_time;\r
 296         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 297         e.predator = world;\r
 298 }\r
 299 \r
 300 void Vore_DeadPrey_Configure(entity e)\r
 301 {\r
 302         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 303 \r
 304         if(e.fakeprey || !e.stat_eaten) // we already configured everything\r
 305                 return;\r
 306 \r
 307         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 308         e.fakepredator = e.predator;\r
 309         e.fakeprey = TRUE;\r
 310 \r
 311         // first release the prey from the predator, as dead prey needs to be attached differently\r
 312         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 313         e.predator.stomach_load -= 1;\r
 314         Vore_WeightApply(e.predator);\r
 315         e.predator = world;\r
 316 \r
 317         // now put our dead prey inside the predator's stomach, but only as an effect\r
 318         e.movetype = MOVETYPE_FOLLOW;\r
 319         e.takedamage = DAMAGE_NO;\r
 320         e.solid = SOLID_NOT;\r
 321         e.aiment = e.fakepredator;\r
 322 }\r
 323 \r
 324 void Vore_DeadPrey_Detach(entity e)\r
 325 {\r
 326         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 327         // should only execute after Vore_DeadPrey_Configure has ran first\r
 328 \r
 329         if not(cvar("g_vore_keepdeadprey"))\r
 330                 return;\r
 331 \r
 332         e.fakepredator = world;\r
 333         e.fakeprey = TRUE; // keep fakeprey status\r
 334         e.stat_eaten = 0;\r
 335         e.aiment = world;\r
 336         e.movetype = MOVETYPE_TOSS;\r
 337 }\r
 338 \r
 339 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 340 {\r
 341         if(pred_disconnect)\r
 342         {\r
 343                 if(e.fakeprey)\r
 344                         Vore_DeadPrey_Detach(e);\r
 345                 else\r
 346                         Vore_Regurgitate(e);\r
 347         }\r
 348         else if(self.stat_eaten && !self.fakeprey)\r
 349         {\r
 350                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 351                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
 352                         Vore_DeadPrey_Configure(e);\r
 353                 else\r
 354                         Vore_Regurgitate(e);\r
 355         }\r
 356 }\r
 357 \r
 358 void Vore_Disconnect()\r
 359 {\r
 360         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 361 \r
 362         // prey disconnects or goes spectating while inside someone's belly\r
 363         if(self.stat_eaten)\r
 364                 Vore_PreyRelease(self, TRUE);\r
 365 \r
 366         // pred disconnects or goes spectating with players in their belly\r
 367         entity head;\r
 368         FOR_EACH_PLAYER(head)\r
 369         {\r
 370                 if(head.predator == self || head.fakepredator == self)\r
 371                         Vore_PreyRelease(head, TRUE);\r
 372         }\r
 373         Vore_GurgleSound(); // stop the gurgling sound\r
 374 \r
 375         self.stomach_load = self.gravity = 0; // prevents a bug\r
 376 }\r
 377 \r
 378 .float digestion_step;\r
 379 void Vore_Digest()\r
 380 {\r
 381         // apply digestion to prey\r
 382 \r
 383         if(time > self.predator.digestion_step)\r
 384         {\r
 385                 Damage(self, self.predator, self.predator, cvar("g_balance_vore_digestion_damage"), DEATH_DIGESTION, self.origin, '0 0 0');\r
 386                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 387                         self.predator.health += cvar("g_balance_vore_digestion_vampire");\r
 388 \r
 389                 if (self.predator.digestsound_finished < time)\r
 390                 {\r
 391                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 392                         self.predator.digestsound_finished = time + 0.5;\r
 393                 }\r
 394                 self.predator.digestion_step = time + steptime;\r
 395         }\r
 396 \r
 397         if(self.deadflag != DEAD_NO)\r
 398         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 399                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 400 }\r
 401 \r
 402 .float teamheal_step;\r
 403 void Vore_Teamheal()\r
 404 {\r
 405         // apply teamheal\r
 406 \r
 407         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 408         if(time > self.teamheal_step)\r
 409         {\r
 410                 self.health += cvar("g_balance_vore_teamheal");\r
 411                 self.teamheal_step = time + steptime;\r
 412 \r
 413                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 414                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 415                 {\r
 416                         play2(self, "misc/beep.wav");\r
 417                         play2(self.predator, "misc/beep.wav");\r
 418                 }\r
 419         }\r
 420 }\r
 421 \r
 422 void Vore_StomachKick()\r
 423 {\r
 424         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 425 \r
 426         if(time > self.stomachkick_delay)\r
 427         {\r
 428                 float damage;\r
 429                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 430 \r
 431                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, v_forward * cvar("g_balance_vore_kick_force"));\r
 432                 sound(self.predator, CHAN_PROJECTILE, "weapons/stomachkick.wav", VOL_BASE, ATTN_NORM);\r
 433                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 434                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 435 \r
 436                 if(random() < cvar("g_balance_vore_kick_escapeprobability"))\r
 437                         Vore_Regurgitate(self);\r
 438 \r
 439                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 440         }\r
 441 }\r
 442 \r
 443 void Vore_StomachLeave()\r
 444 {\r
 445         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 446 \r
 447         if(Vore_CanLeave())\r
 448                 Vore_Regurgitate(self);\r
 449         else if(time > self.complain_vore)\r
 450         {\r
 451                 play2(self, "misc/forbidden.wav");\r
 452                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 453                 self.complain_vore = time + complain_delay_time;\r
 454         }\r
 455 }\r
 456 \r
 457 void Vore_AutoTaunt()\r
 458 {\r
 459         // triggers ambient vore taunts, for both pred and prey\r
 460 \r
 461         float taunt_time;\r
 462 \r
 463         // predator taunts\r
 464         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 465         {\r
 466                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 467                 {\r
 468                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 469                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 470                 }\r
 471         }\r
 472         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 473         {\r
 474                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 475                 SetAutoTaunt(self, 0, 0);\r
 476         }\r
 477 \r
 478         // prey taunts\r
 479         if(self.stat_eaten && !(teams_matter && self.team == self.predator.team))\r
 480         {\r
 481                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 482                 {\r
 483                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 484                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 485                 }\r
 486         }\r
 487         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 488         {\r
 489                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 490                 SetAutoTaunt(self, 0, 0);\r
 491         }\r
 492 }\r
 493 \r
 494 void Vore_SetSbarRings()\r
 495 {\r
 496         // first clear the ring stats, then configure them if needed\r
 497         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 498         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 499 \r
 500         if(self.stat_eaten)\r
 501         {\r
 502                 if(time <= self.stomachkick_delay)\r
 503                 {\r
 504                         self.stat_sbring1_type = 2; // ring shows stomach kick delay, empties with progress\r
 505                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 506                 }\r
 507         }\r
 508         else\r
 509         {\r
 510                 if(time <= self.action_delay)\r
 511                 {\r
 512                         self.stat_sbring1_type = 1; // ring shows vore action delay, empties with progress\r
 513                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 514                 }\r
 515                 if(time <= self.regurgitate_prepare)\r
 516                 {\r
 517                         self.stat_sbring2_type = 1; // ring shows regurgitation preparing, fills with progress\r
 518                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 519                 }\r
 520         }\r
 521 }\r
 522 \r
 523 void Vore()\r
 524 {\r
 525         // main vore code, this is where it all happens\r
 526 \r
 527         if(!cvar("g_vore")) // the vore system is disabled\r
 528         {\r
 529                 Vore_Disconnect();\r
 530                 return;\r
 531         }\r
 532 \r
 533         Vore_AutoTaunt();\r
 534 \r
 535         // wash the goo away from players once they leave the stomach\r
 536         if(!self.stat_eaten)\r
 537         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 538         if(self.colormod)\r
 539         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 540         {\r
 541                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 542                 if(self.colormod_x > 1)\r
 543                         self.colormod_x = 1;\r
 544                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 545                 if(self.colormod_y > 1)\r
 546                         self.colormod_y = 1;\r
 547                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 548                 if(self.colormod_z > 1)\r
 549                         self.colormod_z = 1;\r
 550         }\r
 551 \r
 552         // set all vore stats\r
 553         Vore_SetSbarRings();\r
 554         if(self.fakepredator.classname == "player")\r
 555                 self.stat_eaten = num_for_edict(self.fakepredator);\r
 556         else if(self.predator.classname == "player")\r
 557         {\r
 558                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 559                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 560                 self.stat_eaten = num_for_edict(self.predator);\r
 561         }\r
 562         else\r
 563         {\r
 564                 self.stat_stomachload = self.stomach_load;\r
 565                 self.stat_digesting = self.digesting;\r
 566                 self.stat_eaten = 0;\r
 567         }\r
 568         self.stat_canleave = Vore_CanLeave();\r
 569 \r
 570         // don't allow a player inside a player inside another player :)\r
 571         // prevent this by checking if such has happened, and taking the proper measures\r
 572         // this code has a high priority and must not be stopped by any delay, so run it here\r
 573         if(self.predator.stat_eaten)\r
 574         {\r
 575                 entity target_predator, target_predator_predator, oldself;\r
 576                 target_predator = self.predator;\r
 577                 target_predator_predator = self.predator.predator;\r
 578 \r
 579                 Vore_Regurgitate(self);\r
 580 \r
 581                 // now steal our prey's prey if this probability applies\r
 582                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 583                 {\r
 584                         oldself = self;\r
 585                         self = target_predator_predator;\r
 586                         if(Swallow_condition_check(oldself))\r
 587                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 588                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 589                                 Vore_Swallow(oldself);\r
 590                         self = oldself;\r
 591                 }\r
 592         }\r
 593 \r
 594         // apply delays and skip the vore system under some circumstances\r
 595         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 596         {\r
 597                 Vore_Disconnect();\r
 598                 return;\r
 599         }\r
 600         if(self.spectatee_status)\r
 601                 return;\r
 602         if(time < self.system_delay)\r
 603                 return;\r
 604 \r
 605 // --------------------------------\r
 606 // Code that addresses predators:\r
 607 // --------------------------------\r
 608 \r
 609         entity prey;\r
 610         prey = Swallow_player_check();\r
 611 \r
 612         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 613         self.stat_canswallow = 0;\r
 614         if(Swallow_condition_check(prey))\r
 615         {\r
 616                 // canswallow stat, used by the HUD\r
 617                 if(teams_matter && prey.team == self.team)\r
 618                         self.stat_canswallow = 2;\r
 619                 else\r
 620                         self.stat_canswallow = 1;\r
 621 \r
 622                 if(self.BUTTON_ATCK)\r
 623                         Vore_Swallow(prey);\r
 624         }\r
 625         else if(prey != world)\r
 626                 self.stat_canswallow = -1;\r
 627 \r
 628         // toggle digestion, if the player has someone in their stomach\r
 629         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 630         {\r
 631                 if(self.stomach_load)\r
 632                 {\r
 633                         if(time > self.digest_button_delay_time)\r
 634                         {\r
 635                                 self.digesting = !self.digesting;\r
 636                                 self.digest_button_delay_time = time + button_delay_time;\r
 637                         }\r
 638                 }\r
 639                 else if(time > self.complain_vore)\r
 640                 {\r
 641                         play2(self, "misc/forbidden.wav");\r
 642                         sprint(self, "There is nothing to digest\n");\r
 643                         self.complain_vore = time + complain_delay_time;\r
 644                 }\r
 645         }\r
 646         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 647                 self.digesting = FALSE;\r
 648 \r
 649         // predator wishes to regurgitate his prey\r
 650         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 651         {\r
 652                 if(self.stomach_load)\r
 653                 {\r
 654                         if(time > self.regurgitate_button_delay_time)\r
 655                         {\r
 656                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 657                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 658                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 659                         }\r
 660                 }\r
 661                 else if(time > self.complain_vore)\r
 662                 {\r
 663                         play2(self, "misc/forbidden.wav");\r
 664                         sprint(self, "There is nothing to regurgitate\n");\r
 665                         self.complain_vore = time + complain_delay_time;\r
 666                 }\r
 667         }\r
 668 \r
 669         if(cvar("g_vore_gurglesound"))\r
 670                 Vore_GurgleSound();\r
 671 \r
 672 // --------------------------------\r
 673 // Code that addresses the prey:\r
 674 // --------------------------------\r
 675 \r
 676         Vore_SetPreyPositions();\r
 677 \r
 678         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 679         if(self.fakeprey)\r
 680         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.stat_eaten)\r
 681                 Vore_DeadPrey_Detach(self);\r
 682 \r
 683         if(!self.stat_eaten)\r
 684                 return;\r
 685 \r
 686         if(self.deadflag != DEAD_NO)\r
 687         {\r
 688                 Vore_PreyRelease(self, FALSE);\r
 689                 return;\r
 690         }\r
 691 \r
 692         if(self.predator.deadflag != DEAD_NO)\r
 693                 Vore_Regurgitate(self);\r
 694         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 695                 Vore_Regurgitate(self);\r
 696 \r
 697         // apply delayed regurgitating if it was scheduled\r
 698         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 699         {\r
 700                 self.predator.regurgitate_prepare = 0;\r
 701                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 702                 Vore_Regurgitate(self);\r
 703         }\r
 704 \r
 705         // execute digesting and team healing\r
 706         if(self.predator.digesting == TRUE)\r
 707                 Vore_Digest();\r
 708         if(teams_matter && self.team == self.predator.team)\r
 709         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 710                 Vore_Teamheal();\r
 711 \r
 712         // execute prey commands\r
 713         if(self.BUTTON_ATCK && cvar("g_vore_kick"))\r
 714                 Vore_StomachKick();\r
 715         if(self.BUTTON_JUMP)\r
 716                 Vore_StomachLeave();\r
 717 \r
 718         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 719         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 720         kh_Key_DropAll(self, FALSE);\r
 721 }