data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float system_delay, swallow_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         vector w_shotorg, w_shotdir;\r
  16         w_shotorg = self.origin + self.view_ofs;\r
  17         w_shotdir = v_forward;\r
  18 \r
  19         WarpZone_traceline_antilag(self, w_shotorg, w_shotorg + w_shotdir * cvar("g_balance_vore_swallow_range"), FALSE, self, ANTILAG_LATENCY(self));\r
  20         if(trace_fraction < 1)\r
  21         if(trace_ent.classname == "player")\r
  22                 return trace_ent;\r
  23         return world;\r
  24 }\r
  25 \r
  26 float Swallow_condition_check(entity prey)\r
  27 {\r
  28         // checks the necessary conditions for swallowing a player\r
  29 \r
  30         if(prey != self)\r
  31         if(prey.classname == "player" && prey.predator.classname != "player" && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  32         if(self.classname == "player" && self.predator.classname != "player" && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  33         if(!self.BUTTON_REGURGITATE && self.swallow_delay < time)\r
  34         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  35         {\r
  36                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  37                 {\r
  38                         if(time > self.complain_vore)\r
  39                         {\r
  40                                 play2(self, "misc/unavailable.wav");\r
  41                                 sprint(self, "You cannot swallow your team mates\n");\r
  42                                 self.complain_vore = time + complain_delay_time;\r
  43                         }\r
  44                         return FALSE;\r
  45                 }\r
  46 \r
  47                 if(self.stomach_load >= cvar("g_balance_vore_swallow_limit"))\r
  48                 {\r
  49                         if(time > self.complain_vore)\r
  50                         {\r
  51                                 play2(self, "misc/unavailable.wav");\r
  52                                 sprint(self, strcat("You cannot swallow more than ^2", cvar_string("g_balance_vore_swallow_limit"), "^7 players at a time\n"));\r
  53                                 self.complain_vore = time + complain_delay_time;\r
  54                         }\r
  55                         return FALSE;\r
  56                 }\r
  57 \r
  58                 if(cvar("g_vore_biggergut"))\r
  59                 if(prey.stomach_load > self.stomach_load)\r
  60                 {\r
  61                         if(time > self.complain_vore)\r
  62                         {\r
  63                                 play2(self, "misc/unavailable.wav");\r
  64                                 sprint(self, "You cannot swallow someone with a bigger stomach than yours\n");\r
  65                                 self.complain_vore = time + complain_delay_time;\r
  66                         }\r
  67                         return FALSE;\r
  68                 }\r
  69 \r
  70                 return TRUE;\r
  71         }\r
  72         return FALSE;\r
  73 }\r
  74 \r
  75 float Vore_CanLeave()\r
  76 {\r
  77         if(self.predator.classname == "player")\r
  78         {\r
  79                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
  80                         return TRUE;\r
  81                 if(teams_matter && self.team == self.predator.team)\r
  82                         return TRUE;\r
  83                 if(g_rpg && cvar("g_rpg_canleave"))\r
  84                         return TRUE;\r
  85         }\r
  86         return FALSE;\r
  87 }\r
  88 \r
  89 // make the camera smoothly lower itself when we get swallowed\r
  90 // our aim is going from the normal view offset to half of the view offset (because half is the best positioning for the stomach model)\r
  91 .float cameraeffect_current, cameraeffect_target;\r
  92 void Vore_CameraEffect_Set(entity e)\r
  93 {\r
  94         e.cameraeffect_current = 1;\r
  95         e.cameraeffect_target = 2;\r
  96 }\r
  97 void Vore_CameraEffect_Apply()\r
  98 {\r
  99         if(self.predator.classname != "player")\r
 100                 return;\r
 101 \r
 102         if(self.cvar_cl_vore_cameraspeed)\r
 103         {\r
 104                 local float step;\r
 105                 step = self.cvar_cl_vore_cameraspeed * frametime;\r
 106 \r
 107                 // not sure if these maths are good, as the effect should be smoother\r
 108                 if(self.cameraeffect_current >= self.cameraeffect_target + step)\r
 109                         self.cameraeffect_current -= step;\r
 110                 else if(self.cameraeffect_current <= self.cameraeffect_target - step)\r
 111                         self.cameraeffect_current += step;\r
 112         }\r
 113         else\r
 114                 self.cameraeffect_current = self.cameraeffect_target;\r
 115 \r
 116         self.view_ofs_z = PL_VIEW_OFS_z / self.cameraeffect_current;\r
 117 }\r
 118 \r
 119 .float gurgle_oldstomachload;\r
 120 void Vore_GurgleSound()\r
 121 {\r
 122         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 123         {\r
 124                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 125 \r
 126                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 127                 self.gurgle_oldstomachload = self.stomach_load;\r
 128         }\r
 129 }\r
 130 \r
 131 void Vore_WeightApply(entity e)\r
 132 {\r
 133         // apply stomach weight that makes you heavier the more you eat\r
 134         // slowing the player is done in cl_physics.qc\r
 135 \r
 136         if(e.stomach_load != e.vore_oldstomachload)\r
 137                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 138         if(e.gravity == 0)\r
 139                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 140         e.vore_oldstomachload = e.stomach_load;\r
 141 }\r
 142 \r
 143 void Vore_AutoDigest(entity e)\r
 144 {\r
 145         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 146 \r
 147         if not(cvar("g_vore_digestion"))\r
 148                 return;\r
 149         if not(e.cvar_cl_vore_autodigest)\r
 150                 return;\r
 151         if(clienttype(e) != CLIENTTYPE_REAL)\r
 152                 return; // this feature is only for players\r
 153 \r
 154         entity head;\r
 155         if(teams_matter)\r
 156         {\r
 157                 FOR_EACH_PLAYER(head)\r
 158                 {\r
 159                         // never begin automatic digestion if we've swallowed a team mate\r
 160                         if(head.predator == e && head.team == e.team)\r
 161                                 return;\r
 162                 }\r
 163         }\r
 164 \r
 165         e.digesting = TRUE;\r
 166 }\r
 167 \r
 168 .entity pusher;\r
 169 .float pushltime;\r
 170 void Vore_Swallow(entity e)\r
 171 {\r
 172         // this player is being swallowed by another player, apply the proper changes\r
 173 \r
 174         e.vore_oldmovetype = e.movetype;\r
 175         e.vore_oldsolid = e.solid;\r
 176 \r
 177         e.predator = self;\r
 178         setorigin(e, e.predator.origin);\r
 179         e.velocity = '0 0 0';\r
 180         e.movetype = MOVETYPE_FOLLOW;\r
 181         e.solid = SOLID_NOT;\r
 182         e.alpha = -1; // best way of hiding the eaten player\r
 183         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 184 \r
 185         // drop keys (KH) and flags (CTF) when we get swallowed\r
 186         kh_Key_DropAll(e, FALSE);\r
 187         if(e.flagcarried)\r
 188                 DropFlag(e.flagcarried, world, e.predator);\r
 189 \r
 190         Vore_CameraEffect_Set(e);\r
 191 \r
 192         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 193                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 194 \r
 195         if(teams_matter && e.team == e.predator.team)\r
 196         {\r
 197                 centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 198                 centerprint(e.predator, "^3You have swallowed a team mate, use caution!");\r
 199         }\r
 200 \r
 201         PlayerSound(e.predator, playersound_swallow, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 202         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 203         e.predator.punchangle_x -= e.predator.cvar_cl_vore_punchangle;\r
 204         e.predator.stomach_load += 1;\r
 205         e.predator.regurgitate_prepare = 0;\r
 206         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 207         Vore_WeightApply(e.predator);\r
 208         Vore_AutoDigest(e.predator);\r
 209 \r
 210         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 211         e.predator.weapon_delay = time + button_delay_time;\r
 212         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 213         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 214 }\r
 215 \r
 216 void Vore_Regurgitate(entity e)\r
 217 {\r
 218         // this player is being regurgitated by their predator, apply the proper changes\r
 219 \r
 220         e.movetype = e.vore_oldmovetype;\r
 221         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 222                 e.solid = e.vore_oldsolid;\r
 223         e.view_ofs_z = PL_VIEW_OFS_z;\r
 224         e.alpha = default_player_alpha;\r
 225 \r
 226         // apply velocities\r
 227         local vector oldforward, oldright, oldup;\r
 228         oldforward = v_forward;\r
 229         oldright = v_right;\r
 230         oldup = v_up;\r
 231         makevectors(e.predator.v_angle);\r
 232         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 233         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 234         v_forward = oldforward;\r
 235         v_right = oldright;\r
 236         v_up = oldup;\r
 237 \r
 238         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 239         e.pushltime = time + cvar("g_maxpushtime");\r
 240 \r
 241         PlayerSound(e.predator, playersound_regurgitate, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 242         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 243         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 244         e.predator.punchangle_x += e.predator.cvar_cl_vore_punchangle;\r
 245         e.predator.stomach_load -= 1;\r
 246         e.predator.regurgitate_prepare = 0;\r
 247         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 248         Vore_WeightApply(e.predator);\r
 249 \r
 250         // block firing for a small amount of time, or we'll be firing the next frame\r
 251         e.weapon_delay = time + button_delay_time;\r
 252         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 253         e.predator = world;\r
 254 }\r
 255 \r
 256 void Vore_DeadPrey_Configure(entity e)\r
 257 {\r
 258         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 259 \r
 260         if(e.fakeprey || e.predator.classname != "player") // already configured\r
 261                 return;\r
 262 \r
 263         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 264         e.fakepredator = e.predator;\r
 265         e.fakeprey = TRUE;\r
 266 \r
 267         // first release the prey from the predator, as dead prey needs to be attached differently\r
 268         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 269         e.predator.stomach_load -= 1;\r
 270         Vore_WeightApply(e.predator);\r
 271         e.predator = world;\r
 272 \r
 273         // now put our dead prey inside the predator's stomach, but only as an effect\r
 274         e.movetype = MOVETYPE_FOLLOW;\r
 275         e.takedamage = DAMAGE_NO;\r
 276         e.solid = SOLID_NOT;\r
 277         e.aiment = e.fakepredator;\r
 278 \r
 279         // completely remove the dead body\r
 280         e.alpha = -1;\r
 281 }\r
 282 \r
 283 void Vore_DeadPrey_Detach(entity e)\r
 284 {\r
 285         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 286         // should only execute after Vore_DeadPrey_Configure has ran first\r
 287 \r
 288         if not(cvar("g_vore_keepdeadprey"))\r
 289                 return;\r
 290 \r
 291         e.fakepredator = world;\r
 292         e.aiment = world;\r
 293 \r
 294         if(!e.deadflag)\r
 295                 e.fakeprey = FALSE;\r
 296 }\r
 297 \r
 298 void Vore_PreyRelease(entity e)\r
 299 {\r
 300         // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 301         if(e.health <= 0 && cvar("g_vore_keepdeadprey"))\r
 302         {\r
 303                 Vore_DeadPrey_Configure(e);\r
 304 \r
 305                 // if keepdeadprey is enabled and the predator disconnected, detach the dead prey\r
 306                 if(e.fakepredator.classname != "player")\r
 307                         Vore_DeadPrey_Detach(e);\r
 308         }\r
 309         else\r
 310                 Vore_Regurgitate(e);\r
 311 }\r
 312 \r
 313 void Vore_Disconnect()\r
 314 {\r
 315         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 316 \r
 317         // prey disconnects or goes spectating while inside someone's belly\r
 318         if(self.predator.classname == "player")\r
 319                 Vore_PreyRelease(self);\r
 320 \r
 321         // pred disconnects or goes spectating with players in their belly\r
 322         else if(self.stomach_load > 0)\r
 323         {\r
 324                 entity head;\r
 325                 FOR_EACH_PLAYER(head)\r
 326                 {\r
 327                         if(head.predator == self)\r
 328                                 Vore_PreyRelease(head);\r
 329                 }\r
 330                 Vore_GurgleSound(); // stop the gurgling sound\r
 331         }\r
 332 \r
 333         self.stomach_load = self.gravity = 0; // prevents a bug\r
 334 }\r
 335 \r
 336 .float digestion_step;\r
 337 void Vore_Digest()\r
 338 {\r
 339         // apply digestion to prey\r
 340 \r
 341         if(time > self.predator.digestion_step)\r
 342         {\r
 343                 Damage(self, self.predator, self.predator, cvar("g_balance_vore_digestion_damage"), DEATH_DIGESTION, self.origin, '0 0 0');\r
 344                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 345                         self.predator.health += cvar("g_balance_vore_digestion_vampire");\r
 346 \r
 347                 if (self.predator.digestsound_finished < time)\r
 348                 {\r
 349                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 350                         self.predator.digestsound_finished = time + 0.5;\r
 351                 }\r
 352                 self.predator.digestion_step = time + steptime;\r
 353         }\r
 354 \r
 355         if(self.health <= 0)\r
 356         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 357                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 358 }\r
 359 \r
 360 .float teamheal_step;\r
 361 void Vore_Teamheal()\r
 362 {\r
 363         // apply teamheal\r
 364 \r
 365         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 366         if(time > self.teamheal_step)\r
 367         {\r
 368                 self.health += cvar("g_balance_vore_teamheal");\r
 369                 self.teamheal_step = time + steptime;\r
 370         }\r
 371 }\r
 372 \r
 373 .float stomachkick_delay;\r
 374 void Vore_StomachKick()\r
 375 {\r
 376         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 377 \r
 378         if(time > self.stomachkick_delay)\r
 379         {\r
 380                 float damage;\r
 381                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 382                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, v_forward * cvar("g_balance_vore_kick_force"));\r
 383                 sound(self.predator, CHAN_PROJECTILE, "weapons/stomachkick.ogg", VOL_BASE, ATTN_NORM);\r
 384 \r
 385                 if(random() < cvar("g_balance_vore_kick_escapeprobability"))\r
 386                         Vore_Regurgitate(self);\r
 387 \r
 388                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 389         }\r
 390 }\r
 391 \r
 392 void Vore_StomachLeave()\r
 393 {\r
 394         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 395 \r
 396         if(Vore_CanLeave())\r
 397                 Vore_Regurgitate(self);\r
 398         else if(time > self.complain_vore)\r
 399         {\r
 400                 play2(self, "misc/unavailable.wav");\r
 401                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 402                 self.complain_vore = time + complain_delay_time;\r
 403         }\r
 404 }\r
 405 \r
 406 void Vore()\r
 407 {\r
 408         // main vore code, this is where it all happens\r
 409 \r
 410         if(!cvar("g_vore")) // the vore system is disabled\r
 411         {\r
 412                 Vore_Disconnect();\r
 413                 return;\r
 414         }\r
 415 \r
 416         // wash the goo away from players once they leave the stomach\r
 417         if(self.predator.classname != "player")\r
 418         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 419         if(self.colormod)\r
 420         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 421         {\r
 422                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 423                 if(self.colormod_x > 1)\r
 424                         self.colormod_x = 1;\r
 425                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 426                 if(self.colormod_y > 1)\r
 427                         self.colormod_y = 1;\r
 428                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 429                 if(self.colormod_z > 1)\r
 430                         self.colormod_z = 1;\r
 431         }\r
 432 \r
 433         // set all vore related stats\r
 434         if(self.predator.classname == "player")\r
 435         {\r
 436                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 437                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 438                 self.stat_eaten = num_for_edict(self.predator);\r
 439         }\r
 440         else\r
 441         {\r
 442                 self.stat_stomachload = self.stomach_load;\r
 443                 self.stat_digesting = self.digesting;\r
 444                 self.stat_eaten = 0;\r
 445         }\r
 446         self.stat_canleave = Vore_CanLeave();\r
 447 \r
 448         // don't allow a player inside a player inside another player :)\r
 449         // prevent this by checking if such has happened, and taking the proper measures\r
 450         // this code has a high priority and must not be stopped by any delay, so run it here\r
 451         if(self.predator.predator.classname == "player")\r
 452         {\r
 453                 entity target_predator, target_predator_predator, oldself;\r
 454                 target_predator = self.predator;\r
 455                 target_predator_predator = self.predator.predator;\r
 456 \r
 457                 Vore_Regurgitate(self);\r
 458 \r
 459                 // now steal our prey's prey if this probability applies\r
 460                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 461                 {\r
 462                         oldself = self;\r
 463                         self = target_predator_predator;\r
 464                         if(Swallow_condition_check(oldself))\r
 465                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 466                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 467                                 Vore_Swallow(oldself);\r
 468                         self = oldself;\r
 469                 }\r
 470         }\r
 471 \r
 472         // apply delays and skip the vore system under some circumstances\r
 473         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 474         {\r
 475                 Vore_Disconnect();\r
 476                 return;\r
 477         }\r
 478         if(self.spectatee_status)\r
 479                 return;\r
 480         if(time < self.system_delay)\r
 481                 return;\r
 482 \r
 483 // --------------------------------\r
 484 // Code that addresses predators:\r
 485 // --------------------------------\r
 486 \r
 487         entity prey;\r
 488         prey = Swallow_player_check();\r
 489 \r
 490         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 491         if(self.BUTTON_ATCK)\r
 492         if(Swallow_condition_check(prey))\r
 493                 Vore_Swallow(prey);\r
 494 \r
 495         // toggle digestion, if the player has someone in their stomach\r
 496         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 497         {\r
 498                 if(self.stomach_load)\r
 499                 {\r
 500                         if(time > self.digest_button_delay_time)\r
 501                         {\r
 502                                 self.digesting = !self.digesting;\r
 503                                 self.digest_button_delay_time = time + button_delay_time;\r
 504                         }\r
 505                 }\r
 506                 else if(time > self.complain_vore)\r
 507                 {\r
 508                         play2(self, "misc/unavailable.wav");\r
 509                         sprint(self, "There is nothing to digest\n");\r
 510                         self.complain_vore = time + complain_delay_time;\r
 511                 }\r
 512         }\r
 513         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 514                 self.digesting = FALSE;\r
 515 \r
 516         // predator wishes to regurgitate his prey\r
 517         if(self.BUTTON_REGURGITATE)\r
 518         {\r
 519                 if(self.stomach_load)\r
 520                 {\r
 521                         if(time > self.regurgitate_button_delay_time)\r
 522                         {\r
 523                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 524                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 525                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 526                         }\r
 527                 }\r
 528                 else if(time > self.complain_vore)\r
 529                 {\r
 530                         play2(self, "misc/unavailable.wav");\r
 531                         sprint(self, "There is nothing to regurgitate\n");\r
 532                         self.complain_vore = time + complain_delay_time;\r
 533                 }\r
 534         }\r
 535 \r
 536         if(cvar("g_vore_gurglesound"))\r
 537                 Vore_GurgleSound();\r
 538 \r
 539 // --------------------------------\r
 540 // Code that addresses the prey:\r
 541 // --------------------------------\r
 542 \r
 543         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 544         if(self.fakepredator.classname == "player")\r
 545         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.predator.classname == "player")\r
 546                 Vore_DeadPrey_Detach(self);\r
 547 \r
 548         if(self.predator.classname != "player")\r
 549                 return;\r
 550 \r
 551         if(self.deadflag)\r
 552         {\r
 553                 Vore_PreyRelease(self);\r
 554                 return;\r
 555         }\r
 556 \r
 557         if(self.predator.deadflag)\r
 558                 Vore_Regurgitate(self);\r
 559         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 560                 Vore_Regurgitate(self);\r
 561 \r
 562         // apply delayed regurgitating if it was scheduled\r
 563         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 564         {\r
 565                 self.predator.regurgitate_prepare = 0;\r
 566                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 567                 Vore_Regurgitate(self);\r
 568         }\r
 569 \r
 570         // execute digesting and team healing\r
 571         if(self.predator.digesting == TRUE)\r
 572                 Vore_Digest();\r
 573         if(teams_matter && self.team == self.predator.team)\r
 574         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 575                 Vore_Teamheal();\r
 576 \r
 577         // execute prey commands\r
 578         if(self.BUTTON_ATCK && cvar("g_vore_kick"))\r
 579                 Vore_StomachKick();\r
 580         if(self.BUTTON_JUMP)\r
 581                 Vore_StomachLeave();\r
 582 \r
 583         Vore_CameraEffect_Apply();\r
 584 }