data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float system_delay, swallow_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         vector w_shotorg, w_shotdir;\r
  16         w_shotorg = self.origin + self.view_ofs;\r
  17         w_shotdir = v_forward;\r
  18 \r
  19         WarpZone_traceline_antilag(self, w_shotorg, w_shotorg + w_shotdir * cvar("g_balance_vore_swallow_range"), FALSE, self, ANTILAG_LATENCY(self));\r
  20         if(trace_fraction < 1)\r
  21         if(trace_ent.classname == "player")\r
  22                 return trace_ent;\r
  23         return world;\r
  24 }\r
  25 \r
  26 float Swallow_condition_check(entity prey)\r
  27 {\r
  28         // checks the necessary conditions for swallowing a player\r
  29 \r
  30         if(prey != self)\r
  31         if(prey.classname == "player" && prey.predator.classname != "player" && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  32         if(self.classname == "player" && self.predator.classname != "player" && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  33         if(!self.BUTTON_REGURGITATE && self.swallow_delay < time)\r
  34         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  35         {\r
  36                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  37                 {\r
  38                         if(time > self.complain_vore)\r
  39                         {\r
  40                                 play2(self, "misc/unavailable.wav");\r
  41                                 sprint(self, "You cannot swallow your team mates\n");\r
  42                                 self.complain_vore = time + complain_delay_time;\r
  43                         }\r
  44                         return FALSE;\r
  45                 }\r
  46 \r
  47                 if(self.stomach_load >= cvar("g_balance_vore_swallow_limit"))\r
  48                 {\r
  49                         if(time > self.complain_vore)\r
  50                         {\r
  51                                 play2(self, "misc/unavailable.wav");\r
  52                                 sprint(self, strcat("You cannot swallow more than ^2", cvar_string("g_balance_vore_swallow_limit"), "^7 players at a time\n"));\r
  53                                 self.complain_vore = time + complain_delay_time;\r
  54                         }\r
  55                         return FALSE;\r
  56                 }\r
  57 \r
  58                 if(cvar("g_vore_biggergut"))\r
  59                 if(prey.stomach_load > self.stomach_load)\r
  60                 {\r
  61                         if(time > self.complain_vore)\r
  62                         {\r
  63                                 play2(self, "misc/unavailable.wav");\r
  64                                 sprint(self, "You cannot swallow someone with a bigger stomach than yours\n");\r
  65                                 self.complain_vore = time + complain_delay_time;\r
  66                         }\r
  67                         return FALSE;\r
  68                 }\r
  69 \r
  70                 return TRUE;\r
  71         }\r
  72         return FALSE;\r
  73 }\r
  74 \r
  75 float Stomach_TeamMates_check(entity pred)\r
  76 {\r
  77         // checks if a player's stomach contains any team mates\r
  78 \r
  79         entity head;\r
  80         if(teams_matter)\r
  81         {\r
  82                 FOR_EACH_PLAYER(head)\r
  83                 {\r
  84                         if(head.predator == pred && head.team == pred.team)\r
  85                                 return TRUE;\r
  86                 }\r
  87         }\r
  88         return FALSE;\r
  89 }\r
  90 \r
  91 float Vore_CanLeave()\r
  92 {\r
  93         if(self.predator.classname == "player")\r
  94         {\r
  95                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
  96                         return TRUE;\r
  97                 if(teams_matter && self.team == self.predator.team)\r
  98                         return TRUE;\r
  99                 if(g_rpg && cvar("g_rpg_canleave"))\r
 100                         return TRUE;\r
 101         }\r
 102         return FALSE;\r
 103 }\r
 104 \r
 105 // make the camera smoothly lower itself when we get swallowed\r
 106 // our aim is going from the normal view offset to half of the view offset (because half is the best positioning for the stomach model)\r
 107 .float cameraeffect_current, cameraeffect_target;\r
 108 void Vore_CameraEffect_Set(entity e)\r
 109 {\r
 110         e.cameraeffect_current = 1;\r
 111         e.cameraeffect_target = 2;\r
 112 }\r
 113 void Vore_CameraEffect_Apply()\r
 114 {\r
 115         if(self.predator.classname != "player")\r
 116                 return;\r
 117 \r
 118         if(self.cvar_cl_vore_cameraspeed)\r
 119         {\r
 120                 local float step;\r
 121                 step = self.cvar_cl_vore_cameraspeed * frametime;\r
 122 \r
 123                 // not sure if these maths are good, as the effect should be smoother\r
 124                 if(self.cameraeffect_current >= self.cameraeffect_target + step)\r
 125                         self.cameraeffect_current -= step;\r
 126                 else if(self.cameraeffect_current <= self.cameraeffect_target - step)\r
 127                         self.cameraeffect_current += step;\r
 128         }\r
 129         else\r
 130                 self.cameraeffect_current = self.cameraeffect_target;\r
 131 \r
 132         self.view_ofs_z = PL_VIEW_OFS_z / self.cameraeffect_current;\r
 133 }\r
 134 \r
 135 .float gurgle_oldstomachload;\r
 136 void Vore_GurgleSound()\r
 137 {\r
 138         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 139         {\r
 140                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 141 \r
 142                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 143                 self.gurgle_oldstomachload = self.stomach_load;\r
 144         }\r
 145 }\r
 146 \r
 147 void Vore_WeightApply(entity e)\r
 148 {\r
 149         // apply stomach weight that makes you heavier the more you eat\r
 150         // slowing the player is done in cl_physics.qc\r
 151 \r
 152         if(e.stomach_load != e.vore_oldstomachload)\r
 153                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 154         if(e.gravity == 0)\r
 155                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 156         e.vore_oldstomachload = e.stomach_load;\r
 157 }\r
 158 \r
 159 void Vore_AutoDigest(entity e)\r
 160 {\r
 161         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 162 \r
 163         if(!cvar("g_vore_digestion") || e.digesting)\r
 164                 return;\r
 165         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 166                 return; // this feature is only for players, not bots\r
 167         if(e.stomach_load > 1)\r
 168                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 169         if(Stomach_TeamMates_check(e))\r
 170                 return; // never begin automatic digestion if we've swallowed a team mate\r
 171 \r
 172         e.digesting = TRUE;\r
 173 }\r
 174 \r
 175 .entity pusher;\r
 176 .float pushltime;\r
 177 void Vore_Swallow(entity e)\r
 178 {\r
 179         // this player is being swallowed by another player, apply the proper changes\r
 180 \r
 181         e.vore_oldmovetype = e.movetype;\r
 182         e.vore_oldsolid = e.solid;\r
 183 \r
 184         e.predator = self;\r
 185         setorigin(e, e.predator.origin);\r
 186         e.velocity = '0 0 0';\r
 187         e.movetype = MOVETYPE_FOLLOW;\r
 188         e.solid = SOLID_NOT;\r
 189         e.alpha = -1; // best way of hiding the eaten player\r
 190         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 191 \r
 192         // drop keys (KH) and flags (CTF) when we get swallowed\r
 193         kh_Key_DropAll(e, FALSE);\r
 194         if(e.flagcarried)\r
 195                 DropFlag(e.flagcarried, world, e.predator);\r
 196 \r
 197         Vore_CameraEffect_Set(e);\r
 198 \r
 199         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 200                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 201 \r
 202         if(teams_matter && e.team == e.predator.team)\r
 203         {\r
 204                 centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 205                 centerprint(e.predator, "^3You have swallowed a team mate, use caution!");\r
 206         }\r
 207 \r
 208         PlayerSound(e.predator, playersound_swallow, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 209         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 210         e.predator.punchangle_x -= e.predator.cvar_cl_vore_punchangle;\r
 211         e.predator.stomach_load += 1;\r
 212         e.predator.regurgitate_prepare = 0;\r
 213         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 214         Vore_WeightApply(e.predator);\r
 215         Vore_AutoDigest(e.predator);\r
 216 \r
 217         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 218         e.predator.weapon_delay = time + button_delay_time;\r
 219         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 220         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 221 }\r
 222 \r
 223 void Vore_Regurgitate(entity e)\r
 224 {\r
 225         // this player is being regurgitated by their predator, apply the proper changes\r
 226 \r
 227         e.movetype = e.vore_oldmovetype;\r
 228         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 229                 e.solid = e.vore_oldsolid;\r
 230         e.view_ofs_z = PL_VIEW_OFS_z;\r
 231         e.alpha = default_player_alpha;\r
 232 \r
 233         // apply velocities\r
 234         local vector oldforward, oldright, oldup;\r
 235         oldforward = v_forward;\r
 236         oldright = v_right;\r
 237         oldup = v_up;\r
 238         makevectors(e.predator.v_angle);\r
 239         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 240         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 241         v_forward = oldforward;\r
 242         v_right = oldright;\r
 243         v_up = oldup;\r
 244 \r
 245         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 246         e.pushltime = time + cvar("g_maxpushtime");\r
 247 \r
 248         PlayerSound(e.predator, playersound_regurgitate, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 249         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 250         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 251         e.predator.punchangle_x += e.predator.cvar_cl_vore_punchangle;\r
 252         e.predator.stomach_load -= 1;\r
 253         e.predator.regurgitate_prepare = 0;\r
 254         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 255         Vore_WeightApply(e.predator);\r
 256 \r
 257         // block firing for a small amount of time, or we'll be firing the next frame\r
 258         e.weapon_delay = time + button_delay_time;\r
 259         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 260         e.predator = world;\r
 261 }\r
 262 \r
 263 void Vore_DeadPrey_Configure(entity e)\r
 264 {\r
 265         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 266 \r
 267         if(e.fakeprey || e.predator.classname != "player") // already configured\r
 268                 return;\r
 269 \r
 270         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 271         e.fakepredator = e.predator;\r
 272         e.fakeprey = TRUE;\r
 273 \r
 274         // first release the prey from the predator, as dead prey needs to be attached differently\r
 275         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 276         e.predator.stomach_load -= 1;\r
 277         Vore_WeightApply(e.predator);\r
 278         e.predator = world;\r
 279 \r
 280         // now put our dead prey inside the predator's stomach, but only as an effect\r
 281         e.movetype = MOVETYPE_FOLLOW;\r
 282         e.takedamage = DAMAGE_NO;\r
 283         e.solid = SOLID_NOT;\r
 284         e.aiment = e.fakepredator;\r
 285 \r
 286         // completely remove the dead body\r
 287         e.alpha = -1;\r
 288 }\r
 289 \r
 290 void Vore_DeadPrey_Detach(entity e)\r
 291 {\r
 292         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 293         // should only execute after Vore_DeadPrey_Configure has ran first\r
 294 \r
 295         if not(cvar("g_vore_keepdeadprey"))\r
 296                 return;\r
 297 \r
 298         e.fakepredator = world;\r
 299         e.aiment = world;\r
 300 \r
 301         if(!e.deadflag)\r
 302                 e.fakeprey = FALSE;\r
 303 }\r
 304 \r
 305 void Vore_PreyRelease(entity e)\r
 306 {\r
 307         // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 308         if(e.health <= 0 && cvar("g_vore_keepdeadprey"))\r
 309         {\r
 310                 Vore_DeadPrey_Configure(e);\r
 311 \r
 312                 // if keepdeadprey is enabled and the predator disconnected, detach the dead prey\r
 313                 if(e.fakepredator.classname != "player")\r
 314                         Vore_DeadPrey_Detach(e);\r
 315         }\r
 316         else\r
 317                 Vore_Regurgitate(e);\r
 318 }\r
 319 \r
 320 void Vore_Disconnect()\r
 321 {\r
 322         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 323 \r
 324         // prey disconnects or goes spectating while inside someone's belly\r
 325         if(self.predator.classname == "player")\r
 326                 Vore_PreyRelease(self);\r
 327 \r
 328         // pred disconnects or goes spectating with players in their belly\r
 329         else if(self.stomach_load > 0)\r
 330         {\r
 331                 entity head;\r
 332                 FOR_EACH_PLAYER(head)\r
 333                 {\r
 334                         if(head.predator == self)\r
 335                                 Vore_PreyRelease(head);\r
 336                 }\r
 337                 Vore_GurgleSound(); // stop the gurgling sound\r
 338         }\r
 339 \r
 340         self.stomach_load = self.gravity = 0; // prevents a bug\r
 341 }\r
 342 \r
 343 .float digestion_step;\r
 344 void Vore_Digest()\r
 345 {\r
 346         // apply digestion to prey\r
 347 \r
 348         if(time > self.predator.digestion_step)\r
 349         {\r
 350                 Damage(self, self.predator, self.predator, cvar("g_balance_vore_digestion_damage"), DEATH_DIGESTION, self.origin, '0 0 0');\r
 351                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 352                         self.predator.health += cvar("g_balance_vore_digestion_vampire");\r
 353 \r
 354                 if (self.predator.digestsound_finished < time)\r
 355                 {\r
 356                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 357                         self.predator.digestsound_finished = time + 0.5;\r
 358                 }\r
 359                 self.predator.digestion_step = time + steptime;\r
 360         }\r
 361 \r
 362         if(self.health <= 0)\r
 363         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 364                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 365 }\r
 366 \r
 367 .float teamheal_step;\r
 368 void Vore_Teamheal()\r
 369 {\r
 370         // apply teamheal\r
 371 \r
 372         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 373         if(time > self.teamheal_step)\r
 374         {\r
 375                 self.health += cvar("g_balance_vore_teamheal");\r
 376                 self.teamheal_step = time + steptime;\r
 377         }\r
 378 }\r
 379 \r
 380 .float stomachkick_delay;\r
 381 void Vore_StomachKick()\r
 382 {\r
 383         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 384 \r
 385         if(time > self.stomachkick_delay)\r
 386         {\r
 387                 float damage;\r
 388                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 389                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, v_forward * cvar("g_balance_vore_kick_force"));\r
 390                 sound(self.predator, CHAN_PROJECTILE, "weapons/stomachkick.ogg", VOL_BASE, ATTN_NORM);\r
 391 \r
 392                 if(random() < cvar("g_balance_vore_kick_escapeprobability"))\r
 393                         Vore_Regurgitate(self);\r
 394 \r
 395                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 396         }\r
 397 }\r
 398 \r
 399 void Vore_StomachLeave()\r
 400 {\r
 401         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 402 \r
 403         if(Vore_CanLeave())\r
 404                 Vore_Regurgitate(self);\r
 405         else if(time > self.complain_vore)\r
 406         {\r
 407                 play2(self, "misc/unavailable.wav");\r
 408                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 409                 self.complain_vore = time + complain_delay_time;\r
 410         }\r
 411 }\r
 412 \r
 413 void Vore_AutoTaunt()\r
 414 {\r
 415         // triggers ambient vore taunts, for both pred and prey\r
 416 \r
 417         float taunt_time;\r
 418 \r
 419         // predator taunts\r
 420         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 421         {\r
 422                 if(!self.taunt_soundtime)\r
 423                 {\r
 424                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 425                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 426                 }\r
 427         }\r
 428         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 429         {\r
 430                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 431                 SetAutoTaunt(self, 0, 0);\r
 432         }\r
 433 \r
 434         // prey taunts\r
 435         if(self.predator.classname == "player" && !(teams_matter && self.team == self.predator.team))\r
 436         {\r
 437                 if(!self.taunt_soundtime)\r
 438                 {\r
 439                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 440                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 441                 }\r
 442         }\r
 443         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 444         {\r
 445                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 446                 SetAutoTaunt(self, 0, 0);\r
 447         }\r
 448 }\r
 449 \r
 450 void Vore()\r
 451 {\r
 452         // main vore code, this is where it all happens\r
 453 \r
 454         if(!cvar("g_vore")) // the vore system is disabled\r
 455         {\r
 456                 Vore_Disconnect();\r
 457                 return;\r
 458         }\r
 459 \r
 460         Vore_AutoTaunt();\r
 461 \r
 462         // wash the goo away from players once they leave the stomach\r
 463         if(self.predator.classname != "player")\r
 464         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 465         if(self.colormod)\r
 466         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 467         {\r
 468                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 469                 if(self.colormod_x > 1)\r
 470                         self.colormod_x = 1;\r
 471                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 472                 if(self.colormod_y > 1)\r
 473                         self.colormod_y = 1;\r
 474                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 475                 if(self.colormod_z > 1)\r
 476                         self.colormod_z = 1;\r
 477         }\r
 478 \r
 479         // set all vore related stats\r
 480         if(self.predator.classname == "player")\r
 481         {\r
 482                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 483                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 484                 self.stat_eaten = num_for_edict(self.predator);\r
 485         }\r
 486         else\r
 487         {\r
 488                 self.stat_stomachload = self.stomach_load;\r
 489                 self.stat_digesting = self.digesting;\r
 490                 self.stat_eaten = 0;\r
 491         }\r
 492         self.stat_canleave = Vore_CanLeave();\r
 493 \r
 494         // don't allow a player inside a player inside another player :)\r
 495         // prevent this by checking if such has happened, and taking the proper measures\r
 496         // this code has a high priority and must not be stopped by any delay, so run it here\r
 497         if(self.predator.predator.classname == "player")\r
 498         {\r
 499                 entity target_predator, target_predator_predator, oldself;\r
 500                 target_predator = self.predator;\r
 501                 target_predator_predator = self.predator.predator;\r
 502 \r
 503                 Vore_Regurgitate(self);\r
 504 \r
 505                 // now steal our prey's prey if this probability applies\r
 506                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 507                 {\r
 508                         oldself = self;\r
 509                         self = target_predator_predator;\r
 510                         if(Swallow_condition_check(oldself))\r
 511                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 512                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 513                                 Vore_Swallow(oldself);\r
 514                         self = oldself;\r
 515                 }\r
 516         }\r
 517 \r
 518         // apply delays and skip the vore system under some circumstances\r
 519         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 520         {\r
 521                 Vore_Disconnect();\r
 522                 return;\r
 523         }\r
 524         if(self.spectatee_status)\r
 525                 return;\r
 526         if(time < self.system_delay)\r
 527                 return;\r
 528 \r
 529 // --------------------------------\r
 530 // Code that addresses predators:\r
 531 // --------------------------------\r
 532 \r
 533         entity prey;\r
 534         prey = Swallow_player_check();\r
 535 \r
 536         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 537         if(self.BUTTON_ATCK)\r
 538         if(Swallow_condition_check(prey))\r
 539                 Vore_Swallow(prey);\r
 540 \r
 541         // toggle digestion, if the player has someone in their stomach\r
 542         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 543         {\r
 544                 if(self.stomach_load)\r
 545                 {\r
 546                         if(time > self.digest_button_delay_time)\r
 547                         {\r
 548                                 self.digesting = !self.digesting;\r
 549                                 self.digest_button_delay_time = time + button_delay_time;\r
 550                         }\r
 551                 }\r
 552                 else if(time > self.complain_vore)\r
 553                 {\r
 554                         play2(self, "misc/unavailable.wav");\r
 555                         sprint(self, "There is nothing to digest\n");\r
 556                         self.complain_vore = time + complain_delay_time;\r
 557                 }\r
 558         }\r
 559         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 560                 self.digesting = FALSE;\r
 561 \r
 562         // predator wishes to regurgitate his prey\r
 563         if(self.BUTTON_REGURGITATE)\r
 564         {\r
 565                 if(self.stomach_load)\r
 566                 {\r
 567                         if(time > self.regurgitate_button_delay_time)\r
 568                         {\r
 569                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 570                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 571                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 572                         }\r
 573                 }\r
 574                 else if(time > self.complain_vore)\r
 575                 {\r
 576                         play2(self, "misc/unavailable.wav");\r
 577                         sprint(self, "There is nothing to regurgitate\n");\r
 578                         self.complain_vore = time + complain_delay_time;\r
 579                 }\r
 580         }\r
 581 \r
 582         if(cvar("g_vore_gurglesound"))\r
 583                 Vore_GurgleSound();\r
 584 \r
 585 // --------------------------------\r
 586 // Code that addresses the prey:\r
 587 // --------------------------------\r
 588 \r
 589         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 590         if(self.fakepredator.classname == "player")\r
 591         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.predator.classname == "player")\r
 592                 Vore_DeadPrey_Detach(self);\r
 593 \r
 594         if(self.predator.classname != "player")\r
 595                 return;\r
 596 \r
 597         if(self.deadflag)\r
 598         {\r
 599                 Vore_PreyRelease(self);\r
 600                 return;\r
 601         }\r
 602 \r
 603         if(self.predator.deadflag)\r
 604                 Vore_Regurgitate(self);\r
 605         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 606                 Vore_Regurgitate(self);\r
 607 \r
 608         // apply delayed regurgitating if it was scheduled\r
 609         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 610         {\r
 611                 self.predator.regurgitate_prepare = 0;\r
 612                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 613                 Vore_Regurgitate(self);\r
 614         }\r
 615 \r
 616         // execute digesting and team healing\r
 617         if(self.predator.digesting == TRUE)\r
 618                 Vore_Digest();\r
 619         if(teams_matter && self.team == self.predator.team)\r
 620         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 621                 Vore_Teamheal();\r
 622 \r
 623         // execute prey commands\r
 624         if(self.BUTTON_ATCK && cvar("g_vore_kick"))\r
 625                 Vore_StomachKick();\r
 626         if(self.BUTTON_JUMP)\r
 627                 Vore_StomachLeave();\r
 628 \r
 629         Vore_CameraEffect_Apply();\r
 630 }