data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(cvar("g_healthsize")) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         makevectors(self.angles);\r
  22         vore_w_shotorg = self.origin;\r
  23         vore_w_shotdir = v_forward;\r
  24 \r
  25         if(self.antilag_debug)\r
  26                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, self.antilag_debug);\r
  27         else\r
  28                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  29         if(trace_fraction < 1)\r
  30         if(trace_ent.classname == "player")\r
  31                 return trace_ent;\r
  32         return world;\r
  33 }\r
  34 \r
  35 float Swallow_condition_check(entity prey)\r
  36 {\r
  37         // checks the necessary conditions for swallowing a player\r
  38 \r
  39         if(prey != self)\r
  40         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  41         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  42         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  43         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap") / (1 + self.stomach_load))\r
  44         {\r
  45                 string swallow_complain;\r
  46                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  47                         swallow_complain = "You cannot swallow your team mates\n";\r
  48                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  49                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  50                 else if(self.stomach_load >= g_balance_vore_swallow_limit)\r
  51                         swallow_complain = strcat("You cannot swallow more than ^2", ftos(g_balance_vore_swallow_limit), "^7 players at a time\n");\r
  52                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  53                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  54                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  55                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  56 \r
  57                 if(swallow_complain != "")\r
  58                 {\r
  59                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  60                         {\r
  61                                 play2(self, "misc/forbidden.wav");\r
  62                                 sprint(self, swallow_complain);\r
  63                                 self.complain_vore = time + complain_delay_time;\r
  64                         }\r
  65                         return FALSE;\r
  66                 }\r
  67                 return TRUE;\r
  68         }\r
  69         return FALSE;\r
  70 }\r
  71 \r
  72 float Stomach_TeamMates_check(entity pred)\r
  73 {\r
  74         // checks if a player's stomach contains any team mates\r
  75 \r
  76         entity head;\r
  77         if(teams_matter)\r
  78         {\r
  79                 FOR_EACH_PLAYER(head)\r
  80                 {\r
  81                         if(head.predator == pred && head.team == pred.team)\r
  82                                 return TRUE;\r
  83                 }\r
  84         }\r
  85         return FALSE;\r
  86 }\r
  87 \r
  88 float Vore_CanLeave()\r
  89 {\r
  90         if(self.stat_eaten)\r
  91         {\r
  92                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
  93                         return TRUE;\r
  94                 if(teams_matter && self.team == self.predator.team)\r
  95                         return TRUE;\r
  96                 if(g_rpg && cvar("g_rpg_canleave"))\r
  97                         return TRUE;\r
  98         }\r
  99         return FALSE;\r
 100 }\r
 101 \r
 102 // position the camera properly for prey\r
 103 void Vore_SetPreyPositions()\r
 104 {\r
 105         // self is the predator and head is the prey\r
 106 \r
 107         local entity head;\r
 108         local vector origin_apply;\r
 109         local float position_counter;\r
 110 \r
 111         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 112         // else all players overlap in the center. To do this, we run a loop on all players in the same stomach.\r
 113         // For each player, the origin is updated, then a new origin is used for the next player.\r
 114         // This requires that no more than 9 players may be in the stomach at a time!\r
 115         FOR_EACH_PLAYER(head)\r
 116         {\r
 117                 if(head.predator == self)\r
 118                 {\r
 119                         switch(position_counter)\r
 120                         {\r
 121                                 case 0:\r
 122                                         origin_apply = '0 0 0'; // first occupant sits in the middle\r
 123                                         break;\r
 124                                 case 1:\r
 125                                         origin_apply = '1 0 0'; // second occupant sits in the front\r
 126                                         break;\r
 127                                 case 2:\r
 128                                         origin_apply = '-1 0 0'; // third occupant sits in the back\r
 129                                         break;\r
 130                                 case 3:\r
 131                                         origin_apply = '0 1 0'; // fourth occupant sits in the right\r
 132                                         break;\r
 133                                 case 4:\r
 134                                         origin_apply = '0 -1 0'; // fifth occupant sits in the left\r
 135                                         break;\r
 136                                 case 5:\r
 137                                         origin_apply = '1 1 0'; // sixth occupant sits in the front-right\r
 138                                         break;\r
 139                                 case 6:\r
 140                                         origin_apply = '-1 1 0'; // seventh occupant sits in the back-right\r
 141                                         break;\r
 142                                 case 7:\r
 143                                         origin_apply = '1 -1 0'; // eigth occupant sits in the front-left\r
 144                                         break;\r
 145                                 case 8:\r
 146                                         origin_apply = '-1 -1 0'; // ninth occupant sits in the back-left\r
 147                                         break;\r
 148                                 default:\r
 149                                         break;\r
 150                         }\r
 151 \r
 152                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 153                         head.view_ofs = PL_PREY_VIEW_OFS + origin_apply * cvar("g_vore_neighborprey_distance");\r
 154                         head.view_ofs_z *= self.scale; // stomach center depends on predator scale\r
 155 \r
 156                         // change prey height based on scale\r
 157                         float prey_height;\r
 158                                 prey_height = (head.scale - self.scale) * cvar("g_healthsize_vore_pos");\r
 159                         head.view_ofs_z += prey_height;\r
 160 \r
 161                         position_counter += 1;\r
 162                 }\r
 163         }\r
 164 }\r
 165 \r
 166 .float gurgle_oldstomachload;\r
 167 void Vore_GurgleSound()\r
 168 {\r
 169         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 170         {\r
 171                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 172 \r
 173                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 174                 self.gurgle_oldstomachload = self.stomach_load;\r
 175         }\r
 176 }\r
 177 \r
 178 void Vore_WeightApply(entity e)\r
 179 {\r
 180         // apply stomach weight that makes you heavier the more you eat\r
 181         // slowing the player is done in cl_physics.qc\r
 182 \r
 183         if(e.stomach_load != e.vore_oldstomachload)\r
 184                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 185         if(e.gravity == 0)\r
 186                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 187         e.vore_oldstomachload = e.stomach_load;\r
 188 }\r
 189 \r
 190 void Vore_AutoDigest(entity e)\r
 191 {\r
 192         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 193 \r
 194         if(!cvar("g_vore_digestion") || e.digesting)\r
 195                 return;\r
 196         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 197                 return; // this feature is only for players, not bots\r
 198         if(e.stomach_load > 1)\r
 199                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 200         if(Stomach_TeamMates_check(e))\r
 201                 return; // never begin automatic digestion if we've swallowed a team mate\r
 202 \r
 203         e.digesting = TRUE;\r
 204 }\r
 205 \r
 206 .entity swallow_model;\r
 207 void Vore_SwallowModel_Think()\r
 208 {\r
 209         //update the position of the swallow model to match our swallow progress\r
 210         float dist;\r
 211         dist = (-0.5 + self.owner.swallow_progress_prey) * cvar("g_vore_swallowmodel_range"); // the model is centered at 0.5 progress\r
 212         if(cvar("g_healthsize"))\r
 213                 dist *= self.scale;\r
 214         self.view_ofs = '1 0 0' * dist;\r
 215 \r
 216         // if our swallow progress is gone or we are dead, the swallow model also goes away\r
 217         if(!self.owner.swallow_progress_prey || self.owner.deadflag != DEAD_NO || self.owner.classname != "player")\r
 218         {\r
 219                 remove(self.owner.swallow_model);\r
 220                 self.owner.swallow_model = world;\r
 221                 return;\r
 222         }\r
 223 \r
 224         // properties that should update whenever possible, but when the predator is not available\r
 225         self.alpha = self.owner.cvar_cl_vore_swallowmodel;\r
 226         self.nextthink = time;\r
 227 }\r
 228 \r
 229 void Vore_SwallowModel_Update(entity prey, entity pred)\r
 230 {\r
 231         // if we don't have a swallow model already, spawn one\r
 232         if(!prey.swallow_model)\r
 233         {\r
 234                 prey.swallow_model = spawn();\r
 235 \r
 236                 prey.swallow_model.movetype = MOVETYPE_FOLLOW;\r
 237                 prey.swallow_model.solid = SOLID_NOT;\r
 238 \r
 239                 // apply the properties of the prey\r
 240                 prey.swallow_model.viewmodelforclient = prey; // use the same system as the weapon model\r
 241                 //prey.swallow_model.effects |= EF_NOGUNBOB; // let it bob\r
 242                 prey.swallow_model.effects |= EF_NODEPTHTEST; // don't hide behind walls\r
 243                 prey.swallow_model.colormap = prey.colormap; // pants and shirt color\r
 244                 prey.swallow_model.glowmod = prey.glowmod; // glow color\r
 245 \r
 246                 prey.swallow_model.owner = prey; // owned by the prey\r
 247                 prey.swallow_model.think = Vore_SwallowModel_Think;\r
 248                 prey.swallow_model.nextthink = time;\r
 249         }\r
 250 \r
 251         // properties that should update whenever possible, but when the predator is available\r
 252         string player_swallowmodel;\r
 253         player_swallowmodel = strcat(substring(pred.playermodel, 0, strlen(pred.playermodel) - 4), "_swallow.md3"); // 4 is the extension length\r
 254         if(prey.swallow_model.model != player_swallowmodel) // player model can be changed while the predator is active\r
 255                 setmodel(prey.swallow_model, player_swallowmodel);\r
 256         if(prey.swallow_model.skin != pred.skin) // player skin can be changed while the predator is active\r
 257                 prey.swallow_model.skin = pred.skin;\r
 258         if(cvar("g_healthsize"))\r
 259                 prey.swallow_model.scale = pred.scale / prey.scale; // player size difference\r
 260         if(prey.swallow_model.enemy != pred)\r
 261                 prey.swallow_model.enemy = pred; // enemy is the predator\r
 262 }\r
 263 \r
 264 .entity pusher;\r
 265 .float pushltime;\r
 266 void Vore_Swallow(entity e)\r
 267 {\r
 268         // this player is being swallowed by another player, apply the proper changes\r
 269 \r
 270         e.vore_oldmovetype = e.movetype;\r
 271         e.vore_oldsolid = e.solid;\r
 272 \r
 273         e.predator = self;\r
 274         setorigin(e, e.predator.origin);\r
 275         e.velocity = '0 0 0';\r
 276         e.movetype = MOVETYPE_FOLLOW;\r
 277         e.solid = SOLID_NOT;\r
 278         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 279 \r
 280         // drop keys (KH) and flags (CTF) when we get swallowed\r
 281         kh_Key_DropAll(e, FALSE);\r
 282         if(e.flagcarried)\r
 283                 DropFlag(e.flagcarried, world, e.predator);\r
 284 \r
 285         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 286                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 287 \r
 288         if(teams_matter && e.team == e.predator.team)\r
 289         {\r
 290                 if(cvar("g_vore_kick"))\r
 291                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 292                 if(cvar("g_vore_digestion"))\r
 293                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 294         }\r
 295 \r
 296         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 297         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 298         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 299         e.predator.stomach_load += 1;\r
 300         e.predator.regurgitate_prepare = 0;\r
 301         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 302         e.predator.hitsound += 1; // play this for team mates too, as we could be swallowing them to heal them\r
 303         Vore_WeightApply(e.predator);\r
 304         Vore_AutoDigest(e.predator);\r
 305 \r
 306         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 307         e.predator.weapon_delay = time + button_delay_time;\r
 308         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 309         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 310         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 311 }\r
 312 \r
 313 void Vore_SwallowStep(entity e)\r
 314 {\r
 315         if(!cvar("g_balance_vore_swallow_speed_fill"))\r
 316         {\r
 317                 Vore_Swallow(e);\r
 318                 return;\r
 319         }\r
 320 \r
 321         Vore_SwallowModel_Update(e, self);\r
 322 \r
 323         // increase the progress value until it reaches 1, then swallow the player\r
 324         if(e.swallow_progress_prey < 1)\r
 325         {\r
 326                 float fill;\r
 327                 fill = cvar("g_balance_vore_swallow_speed_fill") * frametime;\r
 328                 if(cvar("g_healthsize") && cvar("g_balance_vore_swallow_speed_fill_scalediff")) // fill rate depends on predator size compared to prey size\r
 329                         fill *= pow(self.scale / e.scale, cvar("g_balance_vore_swallow_speed_fill_scalediff"));\r
 330                 if(cvar("g_balance_vore_swallow_speed_fill_stomachload") && e.stomach_load) // fill rate is influenced by the prey's stomach load\r
 331                         fill /= e.stomach_load;\r
 332 \r
 333                 e.swallow_progress_prey += fill;\r
 334         }\r
 335         else\r
 336         {\r
 337                 Vore_Swallow(e);\r
 338                 e.swallow_progress_prey = 0;\r
 339         }\r
 340 \r
 341         // the predator's progress is how much the prey got swallowed\r
 342         self.swallow_progress_pred = e.swallow_progress_prey;\r
 343 }\r
 344 \r
 345 void Vore_Regurgitate(entity e)\r
 346 {\r
 347         // this player is being regurgitated by their predator, apply the proper changes\r
 348 \r
 349         e.movetype = e.vore_oldmovetype;\r
 350         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 351                 e.solid = e.vore_oldsolid;\r
 352         e.view_ofs_z = PL_VIEW_OFS_z;\r
 353 \r
 354         // apply velocities\r
 355         local vector oldforward, oldright, oldup;\r
 356         oldforward = v_forward;\r
 357         oldright = v_right;\r
 358         oldup = v_up;\r
 359         makevectors(e.predator.v_angle);\r
 360         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 361         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 362         v_forward = oldforward;\r
 363         v_right = oldright;\r
 364         v_up = oldup;\r
 365 \r
 366         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 367         e.pushltime = time + cvar("g_maxpushtime");\r
 368 \r
 369         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
 370         if(cvar("g_balance_vore_swallow_speed_fill") && cvar("g_balance_vore_regurgitate_swallowprogress"))\r
 371         {\r
 372                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
 373                 Vore_SwallowModel_Update(e, e.predator);\r
 374         }\r
 375 \r
 376         // apply regurgitation damage to the predator\r
 377         if(cvar("g_balance_vore_regurgitate_damage"))\r
 378         {\r
 379                 float regurgitate_dmg;\r
 380                 regurgitate_dmg = cvar("g_balance_vore_regurgitate_damage");\r
 381                 if(cvar("g_healthsize"))\r
 382                         regurgitate_dmg *= e.scale / e.predator.scale;\r
 383                 Damage(e.predator, e.predator, e.predator, regurgitate_dmg, DEATH_REGURGITATION, e.predator.origin, '0 0 0');\r
 384         }\r
 385 \r
 386         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 387         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 388         pointparticles(particleeffectnum("vore_regurgitate"), e.predator.origin, '0 0 0', 1);\r
 389         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 390         e.predator.stomach_load -= 1;\r
 391         e.predator.regurgitate_prepare = 0;\r
 392         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 393         Vore_WeightApply(e.predator);\r
 394 \r
 395         // block firing for a small amount of time, or we'll be firing the next frame\r
 396         e.weapon_delay = time + button_delay_time;\r
 397         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 398         e.predator = world;\r
 399 }\r
 400 \r
 401 void Vore_DeadPrey_Configure(entity e)\r
 402 {\r
 403         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 404 \r
 405         if(e.fakeprey || !e.stat_eaten) // we already configured everything\r
 406                 return;\r
 407 \r
 408         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 409         e.fakepredator = e.predator;\r
 410         e.fakeprey = TRUE;\r
 411 \r
 412         // first release the prey from the predator, as dead prey needs to be attached differently\r
 413         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 414         e.predator.stomach_load -= 1;\r
 415         Vore_WeightApply(e.predator);\r
 416         e.predator = world;\r
 417 \r
 418         // now put our dead prey inside the predator's stomach, but only as an effect\r
 419         e.movetype = MOVETYPE_FOLLOW;\r
 420         e.takedamage = DAMAGE_NO;\r
 421         e.solid = SOLID_NOT;\r
 422         e.aiment = e.fakepredator;\r
 423 }\r
 424 \r
 425 void Vore_DeadPrey_Detach(entity e)\r
 426 {\r
 427         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 428         // should only execute after Vore_DeadPrey_Configure has ran first\r
 429 \r
 430         if not(cvar("g_vore_keepdeadprey"))\r
 431                 return;\r
 432 \r
 433         e.fakepredator = world;\r
 434         e.fakeprey = TRUE; // keep fakeprey status\r
 435         e.stat_eaten = 0;\r
 436         e.aiment = world;\r
 437         e.movetype = MOVETYPE_TOSS;\r
 438 }\r
 439 \r
 440 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 441 {\r
 442         if(pred_disconnect)\r
 443         {\r
 444                 if(e.fakeprey)\r
 445                         Vore_DeadPrey_Detach(e);\r
 446                 else\r
 447                         Vore_Regurgitate(e);\r
 448         }\r
 449         else if(self.stat_eaten && !self.fakeprey)\r
 450         {\r
 451                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 452                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
 453                         Vore_DeadPrey_Configure(e);\r
 454                 else\r
 455                         Vore_Regurgitate(e);\r
 456         }\r
 457 }\r
 458 \r
 459 void Vore_Disconnect()\r
 460 {\r
 461         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 462 \r
 463         // prey disconnects or goes spectating while inside someone's belly\r
 464         if(self.stat_eaten)\r
 465                 Vore_PreyRelease(self, TRUE);\r
 466 \r
 467         // pred disconnects or goes spectating with players in their belly\r
 468         entity head;\r
 469         FOR_EACH_PLAYER(head)\r
 470         {\r
 471                 if(head.predator == self || head.fakepredator == self)\r
 472                         Vore_PreyRelease(head, TRUE);\r
 473         }\r
 474         Vore_GurgleSound(); // stop the gurgling sound\r
 475 \r
 476         self.stomach_load = self.gravity = 0; // prevents a bug\r
 477 }\r
 478 \r
 479 .float digestion_step;\r
 480 void Vore_Digest()\r
 481 {\r
 482         // apply digestion to prey\r
 483 \r
 484         if(time > self.digestion_step)\r
 485         {\r
 486                 // if distributed digestion is enabled, reduce digestion strength by the number of prey in our stomach\r
 487                 float reduce;\r
 488                 if(cvar("g_balance_vore_digestion_distribute"))\r
 489                         reduce = self.predator.stomach_load;\r
 490                 else\r
 491                         reduce = 1;\r
 492 \r
 493                 float damage;\r
 494                 damage = cvar("g_balance_vore_digestion_damage") / reduce;\r
 495 \r
 496                 // apply player scale to digestion damage\r
 497                 if(cvar("g_healthsize") && cvar("g_balance_vore_digestion_scalediff"))\r
 498                         damage *= pow(self.predator.scale / self.scale, cvar("g_balance_vore_digestion_scalediff"));\r
 499 \r
 500                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
 501                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 502                         self.predator.health += cvar("g_balance_vore_digestion_vampire") / reduce;\r
 503 \r
 504                 if (self.predator.digestsound_finished < time)\r
 505                 {\r
 506                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 507                         self.predator.digestsound_finished = time + 0.5;\r
 508                 }\r
 509                 self.digestion_step = time + steptime;\r
 510         }\r
 511 \r
 512         if(self.deadflag != DEAD_NO)\r
 513         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 514                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 515 }\r
 516 \r
 517 .float teamheal_step;\r
 518 void Vore_Teamheal()\r
 519 {\r
 520         // apply teamheal\r
 521 \r
 522         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 523         if(time > self.teamheal_step)\r
 524         {\r
 525                 self.health += cvar("g_balance_vore_teamheal");\r
 526                 self.teamheal_step = time + steptime;\r
 527 \r
 528                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 529                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 530                 {\r
 531                         play2(self, "misc/beep.wav");\r
 532                         play2(self.predator, "misc/beep.wav");\r
 533                 }\r
 534         }\r
 535 }\r
 536 \r
 537 .float kick_pressed;\r
 538 void Vore_StomachKick()\r
 539 {\r
 540         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 541 \r
 542         if(time > self.stomachkick_delay && !self.kick_pressed)\r
 543         {\r
 544                 float damage, vol;\r
 545                 vector force;\r
 546                 damage = cvar("g_balance_vore_kick_damage");\r
 547                 force = v_forward * cvar("g_balance_vore_kick_force");\r
 548                 vol = VOL_BASE;\r
 549 \r
 550                 // apply player scale to the damage / force of the kick\r
 551                 if(cvar("g_healthsize") && cvar("g_balance_vore_kick_scalediff"))\r
 552                 {\r
 553                         damage *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 554                         force *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 555                         vol *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff")); // kick sound volume based on the same scale\r
 556                 }\r
 557                 vol = bound(0, vol, 1);\r
 558 \r
 559                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
 560                 sound(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), vol, ATTN_NORM);\r
 561                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 562                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 563 \r
 564                 // abort the predator's scheduled regurgitation\r
 565                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
 566                         self.predator.regurgitate_prepare = 0;\r
 567 \r
 568                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 569                 if(cvar("g_balance_vore_kick_repress"))\r
 570                 if not(clienttype(self) == CLIENTTYPE_BOT) // not for bots, to prevent an issue\r
 571                         self.kick_pressed = TRUE;\r
 572         }\r
 573 }\r
 574 \r
 575 void Vore_StomachLeave()\r
 576 {\r
 577         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 578 \r
 579         if(Vore_CanLeave())\r
 580                 Vore_Regurgitate(self);\r
 581         else if(time > self.complain_vore)\r
 582         {\r
 583                 play2(self, "misc/forbidden.wav");\r
 584                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 585                 self.complain_vore = time + complain_delay_time;\r
 586         }\r
 587 }\r
 588 \r
 589 void Vore_AutoTaunt()\r
 590 {\r
 591         // triggers ambient vore taunts, for both pred and prey\r
 592 \r
 593         float taunt_time;\r
 594 \r
 595         // predator taunts\r
 596         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 597         {\r
 598                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 599                 {\r
 600                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 601                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 602                 }\r
 603         }\r
 604         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 605         {\r
 606                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 607                 SetAutoTaunt(self, 0, 0);\r
 608         }\r
 609 \r
 610         // prey taunts\r
 611         if(self.stat_eaten && !(teams_matter && self.team == self.predator.team))\r
 612         {\r
 613                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 614                 {\r
 615                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 616                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 617                 }\r
 618         }\r
 619         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 620         {\r
 621                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 622                 SetAutoTaunt(self, 0, 0);\r
 623         }\r
 624 }\r
 625 \r
 626 void Vore_SetSbarRings()\r
 627 {\r
 628         // first clear the ring stats, then configure them if needed\r
 629         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 630         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 631 \r
 632         if(self.stat_eaten)\r
 633         {\r
 634                 if(time <= self.stomachkick_delay)\r
 635                 {\r
 636                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
 637                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 638                 }\r
 639         }\r
 640         else\r
 641         {\r
 642                 if(self.swallow_progress_pred)\r
 643                 {\r
 644                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
 645                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
 646                 }\r
 647                 else if(time <= self.action_delay)\r
 648                 {\r
 649                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
 650                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 651                 }\r
 652 \r
 653                 if(self.swallow_progress_prey)\r
 654                 {\r
 655                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
 656                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
 657                 }\r
 658                 else if(time <= self.regurgitate_prepare)\r
 659                 {\r
 660                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
 661                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 662                 }\r
 663         }\r
 664 }\r
 665 \r
 666 void Vore()\r
 667 {\r
 668         // main vore code, this is where it all happens\r
 669 \r
 670         Vore_AutoTaunt();\r
 671 \r
 672         // wash the goo away from players once they leave the stomach\r
 673         if(!self.stat_eaten)\r
 674         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 675         if(self.colormod)\r
 676         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 677         {\r
 678                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 679                 if(self.colormod_x > 1)\r
 680                         self.colormod_x = 1;\r
 681                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 682                 if(self.colormod_y > 1)\r
 683                         self.colormod_y = 1;\r
 684                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 685                 if(self.colormod_z > 1)\r
 686                         self.colormod_z = 1;\r
 687         }\r
 688 \r
 689         // set all vore stats\r
 690         Vore_SetSbarRings();\r
 691         if(self.fakepredator.classname == "player")\r
 692                 self.stat_eaten = num_for_edict(self.fakepredator);\r
 693         else if(self.predator.classname == "player")\r
 694         {\r
 695                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 696                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 697                 self.stat_eaten = num_for_edict(self.predator);\r
 698         }\r
 699         else\r
 700         {\r
 701                 self.stat_stomachload = self.stomach_load;\r
 702                 self.stat_digesting = self.digesting;\r
 703                 self.stat_eaten = 0;\r
 704         }\r
 705         self.stat_canleave = Vore_CanLeave();\r
 706 \r
 707         // don't allow a player inside a player inside another player :)\r
 708         // prevent this by checking if such has happened, and taking the proper measures\r
 709         // this code has a high priority and must not be stopped by any delay, so run it here\r
 710         if(self.predator.stat_eaten)\r
 711         {\r
 712                 entity target_predator, target_predator_predator, oldself;\r
 713                 target_predator = self.predator;\r
 714                 target_predator_predator = self.predator.predator;\r
 715 \r
 716                 Vore_Regurgitate(self);\r
 717 \r
 718                 // now steal our prey's prey if this probability applies\r
 719                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 720                 {\r
 721                         oldself = self;\r
 722                         self = target_predator_predator;\r
 723                         if(Swallow_condition_check(oldself))\r
 724                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 725                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 726                                 Vore_Swallow(oldself);\r
 727                         self = oldself;\r
 728                 }\r
 729         }\r
 730 \r
 731         // the swallow progress of prey and preds idly decrease by this amount\r
 732         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
 733         {\r
 734                 if(self.swallow_progress_pred)\r
 735                 {\r
 736                         self.swallow_progress_pred -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 737                         if(self.swallow_progress_pred < 0)\r
 738                                 self.swallow_progress_pred = 0;\r
 739                 }\r
 740                 if(self.swallow_progress_prey)\r
 741                 {\r
 742                         self.swallow_progress_prey -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 743                         if(self.swallow_progress_prey < 0)\r
 744                                 self.swallow_progress_prey = 0;\r
 745                 }\r
 746         }\r
 747 \r
 748         // apply delays and skip the vore system under some circumstances\r
 749         if(!cvar("g_vore")) // the vore system is disabled\r
 750         {\r
 751                 Vore_Disconnect();\r
 752                 return;\r
 753         }\r
 754         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 755         {\r
 756                 Vore_Disconnect();\r
 757                 return;\r
 758         }\r
 759         if(self.spectatee_status)\r
 760                 return;\r
 761         if(time < self.system_delay)\r
 762                 return;\r
 763 \r
 764 // --------------------------------\r
 765 // Code that addresses predators:\r
 766 // --------------------------------\r
 767 \r
 768         entity prey;\r
 769         prey = Swallow_player_check();\r
 770 \r
 771         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 772         self.stat_canswallow = 0;\r
 773         if(Swallow_condition_check(prey))\r
 774         {\r
 775                 // canswallow stat, used by the HUD\r
 776                 if(teams_matter && prey.team == self.team)\r
 777                         self.stat_canswallow = 2;\r
 778                 else\r
 779                         self.stat_canswallow = 1;\r
 780 \r
 781                 if(self.BUTTON_ATCK)\r
 782                         Vore_SwallowStep(prey);\r
 783         }\r
 784         else if(prey != world)\r
 785                 self.stat_canswallow = -1;\r
 786 \r
 787         // toggle digestion, if the player has someone in their stomach\r
 788         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 789         {\r
 790                 if(self.stomach_load)\r
 791                 {\r
 792                         if(time > self.digest_button_delay_time)\r
 793                         {\r
 794                                 self.digesting = !self.digesting;\r
 795                                 self.digest_button_delay_time = time + button_delay_time;\r
 796                         }\r
 797                 }\r
 798                 else if(time > self.complain_vore)\r
 799                 {\r
 800                         play2(self, "misc/forbidden.wav");\r
 801                         sprint(self, "There is nothing to digest\n");\r
 802                         self.complain_vore = time + complain_delay_time;\r
 803                 }\r
 804         }\r
 805         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 806                 self.digesting = FALSE;\r
 807 \r
 808         // predator wishes to regurgitate his prey\r
 809         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 810         {\r
 811                 if(self.stomach_load)\r
 812                 {\r
 813                         if(time > self.regurgitate_button_delay_time)\r
 814                         {\r
 815                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 816                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 817                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE); // looks good for preparing regurgitation\r
 818                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 819                         }\r
 820                 }\r
 821                 else if(time > self.complain_vore)\r
 822                 {\r
 823                         play2(self, "misc/forbidden.wav");\r
 824                         sprint(self, "There is nothing to regurgitate\n");\r
 825                         self.complain_vore = time + complain_delay_time;\r
 826                 }\r
 827         }\r
 828 \r
 829         if(cvar("g_vore_gurglesound"))\r
 830                 Vore_GurgleSound();\r
 831 \r
 832 // --------------------------------\r
 833 // Code that addresses the prey:\r
 834 // --------------------------------\r
 835 \r
 836         Vore_SetPreyPositions();\r
 837 \r
 838         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 839         if(self.fakeprey)\r
 840         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.stat_eaten)\r
 841                 Vore_DeadPrey_Detach(self);\r
 842 \r
 843         if(!self.stat_eaten)\r
 844                 return;\r
 845 \r
 846         if(self.deadflag != DEAD_NO)\r
 847         {\r
 848                 Vore_PreyRelease(self, FALSE);\r
 849                 return;\r
 850         }\r
 851 \r
 852         if(self.predator.deadflag != DEAD_NO)\r
 853                 Vore_Regurgitate(self);\r
 854         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap") / (1 + self.predator.stomach_load))\r
 855                 Vore_Regurgitate(self);\r
 856 \r
 857         // apply delayed regurgitating if it was scheduled\r
 858         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 859         {\r
 860                 self.predator.regurgitate_prepare = 0;\r
 861                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 862                 Vore_Regurgitate(self);\r
 863         }\r
 864 \r
 865         // execute digesting and team healing\r
 866         if(self.predator.digesting == TRUE)\r
 867                 Vore_Digest();\r
 868         if(teams_matter && self.team == self.predator.team)\r
 869         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 870                 Vore_Teamheal();\r
 871 \r
 872         // execute prey commands\r
 873         if(self.BUTTON_ATCK)\r
 874         {\r
 875                 if(cvar("g_vore_kick"))\r
 876                         Vore_StomachKick();\r
 877         }\r
 878         else\r
 879                 self.kick_pressed = FALSE;\r
 880         if(self.BUTTON_JUMP)\r
 881                 Vore_StomachLeave();\r
 882 \r
 883         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 884         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 885         kh_Key_DropAll(self, FALSE);\r
 886 }