data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float system_delay, swallow_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload, vore_oldview_ofs_z;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_distance_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         vector w_shotorg, w_shotdir;\r
  16         w_shotorg = self.origin + self.view_ofs;\r
  17         w_shotdir = v_forward;\r
  18 \r
  19         WarpZone_traceline_antilag(self, w_shotorg, w_shotorg + w_shotdir * cvar("g_balance_vore_swallow_range"), FALSE, self, ANTILAG_LATENCY(self));\r
  20         if(trace_fraction < 1)\r
  21         if(trace_ent.classname == "player")\r
  22                 return trace_ent;\r
  23         return world;\r
  24 }\r
  25 \r
  26 float Swallow_condition_check(entity prey)\r
  27 {\r
  28         // checks the necessary conditions for swallowing another player\r
  29 \r
  30         if(prey.classname == "player" && prey.predator.classname != "player" && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  31         if(self.classname == "player" && self.predator.classname != "player" && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  32         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  33         {\r
  34                 if(self.stomach_load >= cvar("g_balance_vore_swallow_limit"))\r
  35                 {\r
  36                         if(time > self.complain_vore)\r
  37                         {\r
  38                                 play2(self, "weapons/unavailable.wav");\r
  39                                 sprint(self, strcat("You cannot swallow more than ^2", cvar_string("g_balance_vore_swallow_limit"), "^7 players at a time\n"));\r
  40                                 self.complain_vore = time + complain_delay_time;\r
  41                         }\r
  42                         return FALSE;\r
  43                 }\r
  44 \r
  45                 if(cvar("g_vore_biggergut"))\r
  46                 if(prey.stomach_load > self.stomach_load)\r
  47                 {\r
  48                         if(time > self.complain_vore)\r
  49                         {\r
  50                                 play2(self, "weapons/unavailable.wav");\r
  51                                 sprint(self, "You cannot swallow someone with a bigger stomach than yours\n");\r
  52                                 self.complain_vore = time + complain_delay_time;\r
  53                         }\r
  54                         return FALSE;\r
  55                 }\r
  56 \r
  57                 return TRUE;\r
  58         }\r
  59         return FALSE;\r
  60 }\r
  61 \r
  62 float Vore_CanLeave()\r
  63 {\r
  64         if(teams_matter && self.team == self.predator.team)\r
  65                 return TRUE;\r
  66         return FALSE;\r
  67 }\r
  68 \r
  69 // make the camera smoothly lower itself when we get swallowed\r
  70 // our aim is going from the normal view offset to half of the view offset (because half is the best positioning for the stomach model)\r
  71 .float cameraeffect_current, cameraeffect_target;\r
  72 void Vore_CameraEffect_Set(entity e)\r
  73 {\r
  74         e.cameraeffect_current = 1;\r
  75         e.cameraeffect_target = 2;\r
  76 }\r
  77 void Vore_CameraEffect_Apply()\r
  78 {\r
  79         if(self.predator.classname != "player")\r
  80                 return;\r
  81 \r
  82         if(self.cvar_cl_vore_cameraspeed)\r
  83         {\r
  84                 local float step;\r
  85                 step = self.cvar_cl_vore_cameraspeed * frametime;\r
  86 \r
  87                 // not sure if these maths are good, as the effect should be smoother\r
  88                 if(self.cameraeffect_current >= self.cameraeffect_target + step)\r
  89                         self.cameraeffect_current -= step;\r
  90                 else if(self.cameraeffect_current <= self.cameraeffect_target - step)\r
  91                         self.cameraeffect_current += step;\r
  92         }\r
  93         else\r
  94                 self.cameraeffect_current = self.cameraeffect_target;\r
  95 \r
  96         self.view_ofs_z = self.vore_oldview_ofs_z / self.cameraeffect_current;\r
  97 }\r
  98 \r
  99 .float gurgle_oldstomachload;\r
 100 void Vore_Gurglesound()\r
 101 {\r
 102         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 103         {\r
 104                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 105 \r
 106                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 107                 self.gurgle_oldstomachload = self.stomach_load;\r
 108         }\r
 109 }\r
 110 \r
 111 void Vore_Weight_apply(entity e)\r
 112 {\r
 113         // apply stomach weight that makes you heavier the more you eat\r
 114         // slowing the player is done in cl_physics.qc\r
 115 \r
 116         if(e.stomach_load != e.vore_oldstomachload)\r
 117                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 118         if(e.gravity == 0)\r
 119                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 120         e.vore_oldstomachload = e.stomach_load;\r
 121 }\r
 122 \r
 123 .entity pusher;\r
 124 .float pushltime;\r
 125 void Vore_Swallow(entity e)\r
 126 {\r
 127         // this player is being swallowed by another player, apply the proper changes\r
 128 \r
 129         e.vore_oldmovetype = e.movetype;\r
 130         e.vore_oldsolid = e.solid;\r
 131         e.vore_oldview_ofs_z = e.view_ofs_z;\r
 132 \r
 133         e.predator = self;\r
 134         setorigin(e, e.predator.origin);\r
 135         e.velocity = '0 0 0';\r
 136         e.movetype = MOVETYPE_FOLLOW;\r
 137         e.solid = SOLID_NOT;\r
 138         e.alpha = -1; // best way of hiding the eaten player\r
 139         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 140 \r
 141         // drop keys (KH) and flags (CTF) when we get swallowed\r
 142         kh_Key_DropAll(e, FALSE);\r
 143         if(e.flagcarried)\r
 144                 DropFlag(e.flagcarried, world, e.predator);\r
 145 \r
 146         Vore_CameraEffect_Set(e);\r
 147 \r
 148         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 149                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 150 \r
 151         if(teams_matter && e.team == e.predator.team)\r
 152         {\r
 153                 centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 154                 centerprint(e.predator, "^3You have swallowed a team mate, use caution!");\r
 155         }\r
 156 \r
 157         PlayerSound(e.predator, playersound_swallow, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 158         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 159         e.predator.stomach_load += 1;\r
 160         e.predator.regurgitate_prepare = 0;\r
 161         Vore_Weight_apply(e.predator);\r
 162 \r
 163         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 164         e.predator.weapon_delay = time + button_delay_time;\r
 165         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 166         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 167 }\r
 168 \r
 169 void Vore_Regurgitate(entity e)\r
 170 {\r
 171         // this player is being regurgitated by their predator, apply the proper changes\r
 172 \r
 173         e.movetype = e.vore_oldmovetype;\r
 174         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 175                 e.solid = e.vore_oldsolid;\r
 176         e.view_ofs_z = e.vore_oldview_ofs_z;\r
 177         e.alpha = default_player_alpha;\r
 178 \r
 179         // apply velocities\r
 180         local vector oldforward, oldright, oldup;\r
 181         oldforward = v_forward;\r
 182         oldright = v_right;\r
 183         oldup = v_up;\r
 184         makevectors(e.predator.v_angle);\r
 185         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 186         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 187         v_forward = oldforward;\r
 188         v_right = oldright;\r
 189         v_up = oldup;\r
 190 \r
 191         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 192         e.pushltime = time + cvar("g_maxpushtime");\r
 193 \r
 194         PlayerSound(e.predator, playersound_regurgitate, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 195         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 196         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 197         e.predator.stomach_load -= 1;\r
 198         e.predator.regurgitate_prepare = 0;\r
 199         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 200         Vore_Weight_apply(e.predator);\r
 201 \r
 202         // block firing for a small amount of time, or we'll be firing the next frame\r
 203         e.weapon_delay = time + button_delay_time;\r
 204         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 205         e.predator = world;\r
 206 }\r
 207 \r
 208 void Vore_Disconnect()\r
 209 {\r
 210         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 211 \r
 212         // prey disconnects or goes spectating while inside someone's belly\r
 213         if(self.predator.classname == "player")\r
 214                 Vore_Regurgitate(self);\r
 215 \r
 216         // pred disconnects or goes spectating with players in their belly\r
 217         else if(self.stomach_load > 0)\r
 218         {\r
 219                 entity head;\r
 220                 FOR_EACH_PLAYER(head)\r
 221                 {\r
 222                         if(head.predator == self)\r
 223                                 Vore_Regurgitate(head);\r
 224                 }\r
 225                 Vore_Gurglesound(); // stop the gurgling sound\r
 226         }\r
 227 }\r
 228 \r
 229 .float digestion_step;\r
 230 void Vore_Digest()\r
 231 {\r
 232         // apply digestion to prey\r
 233 \r
 234         if(time > self.predator.digestion_step)\r
 235         {\r
 236                 Damage(self, self.predator, self.predator, cvar("g_balance_vore_digestion_damage"), DEATH_DIGESTION, self.origin, '0 0 0');\r
 237                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 238                         self.predator.health += cvar("g_balance_vore_digestion_vampire");\r
 239 \r
 240                 if (self.predator.digestsound_finished < time)\r
 241                 {\r
 242                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 243                         self.predator.digestsound_finished = time + 0.5;\r
 244                 }\r
 245                 self.predator.digestion_step = time + steptime;\r
 246         }\r
 247 \r
 248         if(self.health <= 0)\r
 249         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 250                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 251 }\r
 252 \r
 253 .float teamheal_step;\r
 254 void Vore_Teamheal()\r
 255 {\r
 256         // apply teamheal\r
 257 \r
 258         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 259         if(time > self.teamheal_step)\r
 260         {\r
 261                 self.health += cvar("g_balance_vore_teamheal");\r
 262                 self.teamheal_step = time + steptime;\r
 263         }\r
 264 }\r
 265 \r
 266 .float stomachkick_delay;\r
 267 void Vore_StomachKick()\r
 268 {\r
 269         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 270 \r
 271         if(time > self.stomachkick_delay)\r
 272         {\r
 273                 float damage;\r
 274                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 275                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, '0 0 0');\r
 276                 sound(self.predator, CHAN_PROJECTILE, "weapons/stomachkick.ogg", VOL_BASE, ATTN_NORM);\r
 277 \r
 278                 if(random() < cvar("g_balance_vore_kick_escapeprobability"))\r
 279                         Vore_Regurgitate(self);\r
 280 \r
 281                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 282         }\r
 283 }\r
 284 \r
 285 void Vore_StomachLeave()\r
 286 {\r
 287         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 288 \r
 289         if(Vore_CanLeave())\r
 290                 Vore_Regurgitate(self);\r
 291         else if(time > self.complain_vore)\r
 292         {\r
 293                 play2(self, "weapons/unavailable.wav");\r
 294                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 295                 self.complain_vore = time + complain_delay_time;\r
 296         }\r
 297 }\r
 298 \r
 299 void Vore()\r
 300 {\r
 301         // main vore code, this is where it all happens\r
 302 \r
 303         // set all vore related stats\r
 304         if(self.predator.classname == "player")\r
 305         {\r
 306                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 307                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 308                 self.stat_eaten = num_for_edict(self.predator);\r
 309         }\r
 310         else\r
 311         {\r
 312                 self.stat_stomachload = self.stomach_load;\r
 313                 self.stat_digesting = self.digesting;\r
 314                 self.stat_eaten = 0;\r
 315         }\r
 316         self.stat_canleave = Vore_CanLeave();\r
 317 \r
 318         // skip the vore system under some circumstances\r
 319         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 320         {\r
 321                 Vore_Disconnect();\r
 322                 return;\r
 323         }\r
 324         if(self.spectatee_status)\r
 325                 return;\r
 326         if(time < self.system_delay)\r
 327                 return;\r
 328 \r
 329 // --------------------------------\r
 330 // Code that addresses predators:\r
 331 // --------------------------------\r
 332 \r
 333         entity prey;\r
 334         prey = Swallow_distance_check();\r
 335 \r
 336         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 337         if(self.BUTTON_ATCK && !self.BUTTON_REGURGITATE && self.swallow_delay < time)\r
 338         if(Swallow_condition_check(prey))\r
 339                 Vore_Swallow(prey);\r
 340 \r
 341         // toggle digestion, if the player has someone in their stomach\r
 342         if(self.BUTTON_DIGEST)\r
 343         {\r
 344                 if(self.stomach_load)\r
 345                 {\r
 346                         if(time > self.digest_button_delay_time)\r
 347                         {\r
 348                                 self.digesting = !self.digesting;\r
 349                                 self.digest_button_delay_time = time + button_delay_time;\r
 350                         }\r
 351                 }\r
 352                 else if(time > self.complain_vore)\r
 353                 {\r
 354                         play2(self, "weapons/unavailable.wav");\r
 355                         sprint(self, "There is nothing to digest\n");\r
 356                         self.complain_vore = time + complain_delay_time;\r
 357                 }\r
 358         }\r
 359         if(!self.stomach_load)\r
 360                 self.digesting = FALSE;\r
 361 \r
 362         // predator wishes to regurgitate his prey\r
 363         if(self.BUTTON_REGURGITATE)\r
 364         {\r
 365                 if(self.stomach_load)\r
 366                 {\r
 367                         if(time > self.regurgitate_button_delay_time)\r
 368                         {\r
 369                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 370                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 371                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 372                         }\r
 373                 }\r
 374                 else if(time > self.complain_vore)\r
 375                 {\r
 376                         play2(self, "weapons/unavailable.wav");\r
 377                         sprint(self, "There is nothing to regurgitate\n");\r
 378                         self.complain_vore = time + complain_delay_time;\r
 379                 }\r
 380         }\r
 381 \r
 382         if(cvar("g_vore_gurglesound"))\r
 383                 Vore_Gurglesound();\r
 384 \r
 385 // --------------------------------\r
 386 // Code that addresses the prey:\r
 387 // --------------------------------\r
 388 \r
 389         if(self.predator.classname != "player")\r
 390                 return;\r
 391 \r
 392         if(self.predator.deadflag || self.deadflag)\r
 393                 Vore_Regurgitate(self);\r
 394         else if(self.predator.predator.classname == "player") // don't allow a player inside a player inside another player :)\r
 395         {\r
 396                 entity target_predator, oldself;\r
 397                 target_predator = self.predator.predator;\r
 398 \r
 399                 Vore_Regurgitate(self);\r
 400                 if(random() < cvar("g_vore_stealprey")) // steal our prey's prey if this probability returns true\r
 401                 if not(teams_matter && self.predator.team == target_predator.team) // don't steal a team mate's prey\r
 402                 if(Swallow_condition_check(self))\r
 403                 {\r
 404                         oldself = self;\r
 405                         self = target_predator;\r
 406                         Vore_Swallow(oldself);\r
 407                         self = oldself;\r
 408                 }\r
 409         }\r
 410         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 411                 Vore_Regurgitate(self);\r
 412 \r
 413         // apply delayed regurgitating if it was scheduled\r
 414         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 415         {\r
 416                 self.predator.regurgitate_prepare = 0;\r
 417                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 418                 Vore_Regurgitate(self);\r
 419         }\r
 420 \r
 421         // execute digesting and team healing\r
 422         if(self.predator.digesting == TRUE)\r
 423                 Vore_Digest();\r
 424         if(teams_matter && self.team == self.predator.team)\r
 425                 Vore_Teamheal();\r
 426 \r
 427         // execute prey commands\r
 428         if(self.BUTTON_ATCK)\r
 429                 Vore_StomachKick();\r
 430         if(self.BUTTON_JUMP)\r
 431                 Vore_StomachLeave();\r
 432 \r
 433         Vore_CameraEffect_Apply();\r
 434 }