data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(self.scale) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         vore_w_shotorg = self.origin;\r
  22         vore_w_shotdir = v_forward;\r
  23 \r
  24         WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  25         if(trace_fraction < 1)\r
  26         if(trace_ent.classname == "player")\r
  27                 return trace_ent;\r
  28         return world;\r
  29 }\r
  30 \r
  31 float Swallow_condition_check(entity prey)\r
  32 {\r
  33         // checks the necessary conditions for swallowing a player\r
  34 \r
  35         if(prey != self)\r
  36         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  37         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  38         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  39         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  40         {\r
  41                 string swallow_complain;\r
  42                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  43                         swallow_complain = "You cannot swallow your team mates\n";\r
  44                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  45                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  46                 else if(self.stomach_load >= cvar("g_balance_vore_swallow_limit"))\r
  47                         swallow_complain = strcat("You cannot swallow more than ^2", cvar_string("g_balance_vore_swallow_limit"), "^7 players at a time\n");\r
  48                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  49                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  50                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  51                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  52 \r
  53                 if(swallow_complain != "")\r
  54                 {\r
  55                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  56                         {\r
  57                                 play2(self, "misc/forbidden.wav");\r
  58                                 sprint(self, swallow_complain);\r
  59                                 self.complain_vore = time + complain_delay_time;\r
  60                         }\r
  61                         return FALSE;\r
  62                 }\r
  63                 return TRUE;\r
  64         }\r
  65         return FALSE;\r
  66 }\r
  67 \r
  68 float Stomach_TeamMates_check(entity pred)\r
  69 {\r
  70         // checks if a player's stomach contains any team mates\r
  71 \r
  72         entity head;\r
  73         if(teams_matter)\r
  74         {\r
  75                 FOR_EACH_PLAYER(head)\r
  76                 {\r
  77                         if(head.predator == pred && head.team == pred.team)\r
  78                                 return TRUE;\r
  79                 }\r
  80         }\r
  81         return FALSE;\r
  82 }\r
  83 \r
  84 float Vore_CanLeave()\r
  85 {\r
  86         if(self.stat_eaten)\r
  87         {\r
  88                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
  89                         return TRUE;\r
  90                 if(teams_matter && self.team == self.predator.team)\r
  91                         return TRUE;\r
  92                 if(g_rpg && cvar("g_rpg_canleave"))\r
  93                         return TRUE;\r
  94         }\r
  95         return FALSE;\r
  96 }\r
  97 \r
  98 // position the camera properly for prey\r
  99 void Vore_SetPreyPositions()\r
 100 {\r
 101         // self is the predator and head is the prey\r
 102 \r
 103         local entity head;\r
 104         local vector oldforward, oldright, oldup;\r
 105         local vector origin_apply;\r
 106         local float position_counter;\r
 107 \r
 108         oldforward = v_forward;\r
 109         oldright = v_right;\r
 110         oldup = v_up;\r
 111         makevectors(self.v_angle);\r
 112 \r
 113         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 114         // else all players overlap in the center. To do this, we run a loop on all players in the same stomach.\r
 115         // For each player, the origin is updated, then a new origin is used for the next player.\r
 116         // This requires that no more than 9 players may be in the stomach at a time!\r
 117         FOR_EACH_PLAYER(head)\r
 118         {\r
 119                 if(head.predator == self)\r
 120                 {\r
 121                         switch(position_counter)\r
 122                         {\r
 123                                 case 0:\r
 124                                         origin_apply = '0 0 0'; // first occupant sits in the middle\r
 125                                         break;\r
 126                                 case 1:\r
 127                                         origin_apply = '1 0 0'; // second occupant sits in the front\r
 128                                         break;\r
 129                                 case 2:\r
 130                                         origin_apply = '-1 0 0'; // third occupant sits in the back\r
 131                                         break;\r
 132                                 case 3:\r
 133                                         origin_apply = '0 1 0'; // fourth occupant sits in the right\r
 134                                         break;\r
 135                                 case 4:\r
 136                                         origin_apply = '0 -1 0'; // fifth occupant sits in the left\r
 137                                         break;\r
 138                                 case 5:\r
 139                                         origin_apply = '1 1 0'; // sixth occupant sits in the front-right\r
 140                                         break;\r
 141                                 case 6:\r
 142                                         origin_apply = '-1 1 0'; // seventh occupant sits in the back-right\r
 143                                         break;\r
 144                                 case 7:\r
 145                                         origin_apply = '1 -1 0'; // eigth occupant sits in the front-left\r
 146                                         break;\r
 147                                 case 8:\r
 148                                         origin_apply = '-1 -1 0'; // ninth occupant sits in the back-left\r
 149                                         break;\r
 150                                 default:\r
 151                                         break;\r
 152                         }\r
 153 \r
 154                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 155                         origin_apply_x *= v_forward_x; // position depends on the predator's rotation\r
 156                         origin_apply_y *= v_forward_y; // position depends on the predator's rotation\r
 157                         head.view_ofs = PL_PREY_VIEW_OFS + origin_apply * cvar("g_vore_neighborprey_distance");\r
 158                         head.view_ofs_z *= self.scale; // stomach center depends on predator scale\r
 159 \r
 160                         // change prey height based on scale\r
 161                         float prey_height;\r
 162                                 prey_height = (head.scale - self.scale) * cvar("g_healthsize_vore_pos");\r
 163                         head.view_ofs_z += prey_height;\r
 164 \r
 165                         position_counter += 1;\r
 166                 }\r
 167         }\r
 168 \r
 169         v_forward = oldforward;\r
 170         v_right = oldright;\r
 171         v_up = oldup;\r
 172 }\r
 173 \r
 174 .float gurgle_oldstomachload;\r
 175 void Vore_GurgleSound()\r
 176 {\r
 177         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 178         {\r
 179                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 180 \r
 181                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 182                 self.gurgle_oldstomachload = self.stomach_load;\r
 183         }\r
 184 }\r
 185 \r
 186 void Vore_WeightApply(entity e)\r
 187 {\r
 188         // apply stomach weight that makes you heavier the more you eat\r
 189         // slowing the player is done in cl_physics.qc\r
 190 \r
 191         if(e.stomach_load != e.vore_oldstomachload)\r
 192                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 193         if(e.gravity == 0)\r
 194                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 195         e.vore_oldstomachload = e.stomach_load;\r
 196 }\r
 197 \r
 198 void Vore_AutoDigest(entity e)\r
 199 {\r
 200         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 201 \r
 202         if(!cvar("g_vore_digestion") || e.digesting)\r
 203                 return;\r
 204         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 205                 return; // this feature is only for players, not bots\r
 206         if(e.stomach_load > 1)\r
 207                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 208         if(Stomach_TeamMates_check(e))\r
 209                 return; // never begin automatic digestion if we've swallowed a team mate\r
 210 \r
 211         e.digesting = TRUE;\r
 212 }\r
 213 \r
 214 .entity pusher;\r
 215 .float pushltime;\r
 216 void Vore_Swallow(entity e)\r
 217 {\r
 218         // this player is being swallowed by another player, apply the proper changes\r
 219 \r
 220         e.vore_oldmovetype = e.movetype;\r
 221         e.vore_oldsolid = e.solid;\r
 222 \r
 223         e.predator = self;\r
 224         setorigin(e, e.predator.origin);\r
 225         e.velocity = '0 0 0';\r
 226         e.movetype = MOVETYPE_FOLLOW;\r
 227         e.solid = SOLID_NOT;\r
 228         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 229 \r
 230         // drop keys (KH) and flags (CTF) when we get swallowed\r
 231         kh_Key_DropAll(e, FALSE);\r
 232         if(e.flagcarried)\r
 233                 DropFlag(e.flagcarried, world, e.predator);\r
 234 \r
 235         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 236                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 237 \r
 238         if(teams_matter && e.team == e.predator.team)\r
 239         {\r
 240                 if(cvar("g_vore_kick"))\r
 241                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 242                 if(cvar("g_vore_digestion"))\r
 243                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 244         }\r
 245 \r
 246         PlayerSound(e.predator, playersound_swallow, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 247         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 248         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 249         e.predator.stomach_load += 1;\r
 250         e.predator.regurgitate_prepare = 0;\r
 251         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 252         Vore_WeightApply(e.predator);\r
 253         Vore_AutoDigest(e.predator);\r
 254 \r
 255         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 256         e.predator.weapon_delay = time + button_delay_time;\r
 257         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 258         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 259         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 260 }\r
 261 \r
 262 void Vore_Regurgitate(entity e)\r
 263 {\r
 264         // this player is being regurgitated by their predator, apply the proper changes\r
 265 \r
 266         e.movetype = e.vore_oldmovetype;\r
 267         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 268                 e.solid = e.vore_oldsolid;\r
 269         e.view_ofs_z = PL_VIEW_OFS_z;\r
 270 \r
 271         // apply velocities\r
 272         local vector oldforward, oldright, oldup;\r
 273         oldforward = v_forward;\r
 274         oldright = v_right;\r
 275         oldup = v_up;\r
 276         makevectors(e.predator.v_angle);\r
 277         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 278         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 279         v_forward = oldforward;\r
 280         v_right = oldright;\r
 281         v_up = oldup;\r
 282 \r
 283         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 284         e.pushltime = time + cvar("g_maxpushtime");\r
 285 \r
 286         PlayerSound(e.predator, playersound_regurgitate, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 287         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 288         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 289         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 290         e.predator.stomach_load -= 1;\r
 291         e.predator.regurgitate_prepare = 0;\r
 292         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 293         Vore_WeightApply(e.predator);\r
 294 \r
 295         // block firing for a small amount of time, or we'll be firing the next frame\r
 296         e.weapon_delay = time + button_delay_time;\r
 297         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 298         e.predator = world;\r
 299 }\r
 300 \r
 301 void Vore_DeadPrey_Configure(entity e)\r
 302 {\r
 303         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 304 \r
 305         if(e.fakeprey || !e.stat_eaten) // we already configured everything\r
 306                 return;\r
 307 \r
 308         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 309         e.fakepredator = e.predator;\r
 310         e.fakeprey = TRUE;\r
 311 \r
 312         // first release the prey from the predator, as dead prey needs to be attached differently\r
 313         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 314         e.predator.stomach_load -= 1;\r
 315         Vore_WeightApply(e.predator);\r
 316         e.predator = world;\r
 317 \r
 318         // now put our dead prey inside the predator's stomach, but only as an effect\r
 319         e.movetype = MOVETYPE_FOLLOW;\r
 320         e.takedamage = DAMAGE_NO;\r
 321         e.solid = SOLID_NOT;\r
 322         e.aiment = e.fakepredator;\r
 323 }\r
 324 \r
 325 void Vore_DeadPrey_Detach(entity e)\r
 326 {\r
 327         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 328         // should only execute after Vore_DeadPrey_Configure has ran first\r
 329 \r
 330         if not(cvar("g_vore_keepdeadprey"))\r
 331                 return;\r
 332 \r
 333         e.fakepredator = world;\r
 334         e.fakeprey = TRUE; // keep fakeprey status\r
 335         e.stat_eaten = 0;\r
 336         e.aiment = world;\r
 337         e.movetype = MOVETYPE_TOSS;\r
 338 }\r
 339 \r
 340 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 341 {\r
 342         if(pred_disconnect)\r
 343         {\r
 344                 if(e.fakeprey)\r
 345                         Vore_DeadPrey_Detach(e);\r
 346                 else\r
 347                         Vore_Regurgitate(e);\r
 348         }\r
 349         else if(self.stat_eaten && !self.fakeprey)\r
 350         {\r
 351                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 352                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
 353                         Vore_DeadPrey_Configure(e);\r
 354                 else\r
 355                         Vore_Regurgitate(e);\r
 356         }\r
 357 }\r
 358 \r
 359 void Vore_Disconnect()\r
 360 {\r
 361         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 362 \r
 363         // prey disconnects or goes spectating while inside someone's belly\r
 364         if(self.stat_eaten)\r
 365                 Vore_PreyRelease(self, TRUE);\r
 366 \r
 367         // pred disconnects or goes spectating with players in their belly\r
 368         entity head;\r
 369         FOR_EACH_PLAYER(head)\r
 370         {\r
 371                 if(head.predator == self || head.fakepredator == self)\r
 372                         Vore_PreyRelease(head, TRUE);\r
 373         }\r
 374         Vore_GurgleSound(); // stop the gurgling sound\r
 375 \r
 376         self.stomach_load = self.gravity = 0; // prevents a bug\r
 377 }\r
 378 \r
 379 .float digestion_step;\r
 380 void Vore_Digest()\r
 381 {\r
 382         // apply digestion to prey\r
 383 \r
 384         if(time > self.predator.digestion_step)\r
 385         {\r
 386                 Damage(self, self.predator, self.predator, cvar("g_balance_vore_digestion_damage"), DEATH_DIGESTION, self.origin, '0 0 0');\r
 387                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 388                         self.predator.health += cvar("g_balance_vore_digestion_vampire");\r
 389 \r
 390                 if (self.predator.digestsound_finished < time)\r
 391                 {\r
 392                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 393                         self.predator.digestsound_finished = time + 0.5;\r
 394                 }\r
 395                 self.predator.digestion_step = time + steptime;\r
 396         }\r
 397 \r
 398         if(self.deadflag != DEAD_NO)\r
 399         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 400                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 401 }\r
 402 \r
 403 .float teamheal_step;\r
 404 void Vore_Teamheal()\r
 405 {\r
 406         // apply teamheal\r
 407 \r
 408         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 409         if(time > self.teamheal_step)\r
 410         {\r
 411                 self.health += cvar("g_balance_vore_teamheal");\r
 412                 self.teamheal_step = time + steptime;\r
 413 \r
 414                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 415                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 416                 {\r
 417                         play2(self, "misc/beep.wav");\r
 418                         play2(self.predator, "misc/beep.wav");\r
 419                 }\r
 420         }\r
 421 }\r
 422 \r
 423 void Vore_StomachKick()\r
 424 {\r
 425         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 426 \r
 427         if(time > self.stomachkick_delay)\r
 428         {\r
 429                 float damage;\r
 430                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 431 \r
 432                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, v_forward * cvar("g_balance_vore_kick_force"));\r
 433                 sound(self.predator, CHAN_PROJECTILE, "weapons/stomachkick.wav", VOL_BASE, ATTN_NORM);\r
 434                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 435                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 436 \r
 437                 if(random() < cvar("g_balance_vore_kick_escapeprobability"))\r
 438                         Vore_Regurgitate(self);\r
 439 \r
 440                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 441         }\r
 442 }\r
 443 \r
 444 void Vore_StomachLeave()\r
 445 {\r
 446         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 447 \r
 448         if(Vore_CanLeave())\r
 449                 Vore_Regurgitate(self);\r
 450         else if(time > self.complain_vore)\r
 451         {\r
 452                 play2(self, "misc/forbidden.wav");\r
 453                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 454                 self.complain_vore = time + complain_delay_time;\r
 455         }\r
 456 }\r
 457 \r
 458 void Vore_AutoTaunt()\r
 459 {\r
 460         // triggers ambient vore taunts, for both pred and prey\r
 461 \r
 462         float taunt_time;\r
 463 \r
 464         // predator taunts\r
 465         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 466         {\r
 467                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 468                 {\r
 469                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 470                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 471                 }\r
 472         }\r
 473         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 474         {\r
 475                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 476                 SetAutoTaunt(self, 0, 0);\r
 477         }\r
 478 \r
 479         // prey taunts\r
 480         if(self.stat_eaten && !(teams_matter && self.team == self.predator.team))\r
 481         {\r
 482                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 483                 {\r
 484                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 485                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 486                 }\r
 487         }\r
 488         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 489         {\r
 490                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 491                 SetAutoTaunt(self, 0, 0);\r
 492         }\r
 493 }\r
 494 \r
 495 void Vore_SetSbarRings()\r
 496 {\r
 497         // first clear the ring stats, then configure them if needed\r
 498         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 499         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 500 \r
 501         if(self.stat_eaten)\r
 502         {\r
 503                 if(time <= self.stomachkick_delay)\r
 504                 {\r
 505                         self.stat_sbring1_type = 2; // ring shows stomach kick delay, empties with progress\r
 506                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 507                 }\r
 508         }\r
 509         else\r
 510         {\r
 511                 if(time <= self.action_delay)\r
 512                 {\r
 513                         self.stat_sbring1_type = 1; // ring shows vore action delay, empties with progress\r
 514                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 515                 }\r
 516                 if(time <= self.regurgitate_prepare)\r
 517                 {\r
 518                         self.stat_sbring2_type = 1; // ring shows regurgitation preparing, fills with progress\r
 519                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 520                 }\r
 521         }\r
 522 }\r
 523 \r
 524 void Vore()\r
 525 {\r
 526         // main vore code, this is where it all happens\r
 527 \r
 528         if(!cvar("g_vore")) // the vore system is disabled\r
 529         {\r
 530                 Vore_Disconnect();\r
 531                 return;\r
 532         }\r
 533 \r
 534         Vore_AutoTaunt();\r
 535 \r
 536         // wash the goo away from players once they leave the stomach\r
 537         if(!self.stat_eaten)\r
 538         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 539         if(self.colormod)\r
 540         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 541         {\r
 542                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 543                 if(self.colormod_x > 1)\r
 544                         self.colormod_x = 1;\r
 545                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 546                 if(self.colormod_y > 1)\r
 547                         self.colormod_y = 1;\r
 548                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 549                 if(self.colormod_z > 1)\r
 550                         self.colormod_z = 1;\r
 551         }\r
 552 \r
 553         // set all vore stats\r
 554         Vore_SetSbarRings();\r
 555         if(self.fakepredator.classname == "player")\r
 556                 self.stat_eaten = num_for_edict(self.fakepredator);\r
 557         else if(self.predator.classname == "player")\r
 558         {\r
 559                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 560                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 561                 self.stat_eaten = num_for_edict(self.predator);\r
 562         }\r
 563         else\r
 564         {\r
 565                 self.stat_stomachload = self.stomach_load;\r
 566                 self.stat_digesting = self.digesting;\r
 567                 self.stat_eaten = 0;\r
 568         }\r
 569         self.stat_canleave = Vore_CanLeave();\r
 570 \r
 571         // don't allow a player inside a player inside another player :)\r
 572         // prevent this by checking if such has happened, and taking the proper measures\r
 573         // this code has a high priority and must not be stopped by any delay, so run it here\r
 574         if(self.predator.stat_eaten)\r
 575         {\r
 576                 entity target_predator, target_predator_predator, oldself;\r
 577                 target_predator = self.predator;\r
 578                 target_predator_predator = self.predator.predator;\r
 579 \r
 580                 Vore_Regurgitate(self);\r
 581 \r
 582                 // now steal our prey's prey if this probability applies\r
 583                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 584                 {\r
 585                         oldself = self;\r
 586                         self = target_predator_predator;\r
 587                         if(Swallow_condition_check(oldself))\r
 588                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 589                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 590                                 Vore_Swallow(oldself);\r
 591                         self = oldself;\r
 592                 }\r
 593         }\r
 594 \r
 595         // apply delays and skip the vore system under some circumstances\r
 596         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 597         {\r
 598                 Vore_Disconnect();\r
 599                 return;\r
 600         }\r
 601         if(self.spectatee_status)\r
 602                 return;\r
 603         if(time < self.system_delay)\r
 604                 return;\r
 605 \r
 606 // --------------------------------\r
 607 // Code that addresses predators:\r
 608 // --------------------------------\r
 609 \r
 610         entity prey;\r
 611         prey = Swallow_player_check();\r
 612 \r
 613         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 614         self.stat_canswallow = 0;\r
 615         if(Swallow_condition_check(prey))\r
 616         {\r
 617                 // canswallow stat, used by the HUD\r
 618                 if(teams_matter && prey.team == self.team)\r
 619                         self.stat_canswallow = 2;\r
 620                 else\r
 621                         self.stat_canswallow = 1;\r
 622 \r
 623                 if(self.BUTTON_ATCK)\r
 624                         Vore_Swallow(prey);\r
 625         }\r
 626         else if(prey != world)\r
 627                 self.stat_canswallow = -1;\r
 628 \r
 629         // toggle digestion, if the player has someone in their stomach\r
 630         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 631         {\r
 632                 if(self.stomach_load)\r
 633                 {\r
 634                         if(time > self.digest_button_delay_time)\r
 635                         {\r
 636                                 self.digesting = !self.digesting;\r
 637                                 self.digest_button_delay_time = time + button_delay_time;\r
 638                         }\r
 639                 }\r
 640                 else if(time > self.complain_vore)\r
 641                 {\r
 642                         play2(self, "misc/forbidden.wav");\r
 643                         sprint(self, "There is nothing to digest\n");\r
 644                         self.complain_vore = time + complain_delay_time;\r
 645                 }\r
 646         }\r
 647         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 648                 self.digesting = FALSE;\r
 649 \r
 650         // predator wishes to regurgitate his prey\r
 651         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 652         {\r
 653                 if(self.stomach_load)\r
 654                 {\r
 655                         if(time > self.regurgitate_button_delay_time)\r
 656                         {\r
 657                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 658                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 659                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 660                         }\r
 661                 }\r
 662                 else if(time > self.complain_vore)\r
 663                 {\r
 664                         play2(self, "misc/forbidden.wav");\r
 665                         sprint(self, "There is nothing to regurgitate\n");\r
 666                         self.complain_vore = time + complain_delay_time;\r
 667                 }\r
 668         }\r
 669 \r
 670         if(cvar("g_vore_gurglesound"))\r
 671                 Vore_GurgleSound();\r
 672 \r
 673 // --------------------------------\r
 674 // Code that addresses the prey:\r
 675 // --------------------------------\r
 676 \r
 677         Vore_SetPreyPositions();\r
 678 \r
 679         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 680         if(self.fakeprey)\r
 681         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.stat_eaten)\r
 682                 Vore_DeadPrey_Detach(self);\r
 683 \r
 684         if(!self.stat_eaten)\r
 685                 return;\r
 686 \r
 687         if(self.deadflag != DEAD_NO)\r
 688         {\r
 689                 Vore_PreyRelease(self, FALSE);\r
 690                 return;\r
 691         }\r
 692 \r
 693         if(self.predator.deadflag != DEAD_NO)\r
 694                 Vore_Regurgitate(self);\r
 695         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 696                 Vore_Regurgitate(self);\r
 697 \r
 698         // apply delayed regurgitating if it was scheduled\r
 699         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 700         {\r
 701                 self.predator.regurgitate_prepare = 0;\r
 702                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 703                 Vore_Regurgitate(self);\r
 704         }\r
 705 \r
 706         // execute digesting and team healing\r
 707         if(self.predator.digesting == TRUE)\r
 708                 Vore_Digest();\r
 709         if(teams_matter && self.team == self.predator.team)\r
 710         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 711                 Vore_Teamheal();\r
 712 \r
 713         // execute prey commands\r
 714         if(self.BUTTON_ATCK && cvar("g_vore_kick"))\r
 715                 Vore_StomachKick();\r
 716         if(self.BUTTON_JUMP)\r
 717                 Vore_StomachLeave();\r
 718 \r
 719         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 720         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 721         kh_Key_DropAll(self, FALSE);\r
 722 }