data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float system_delay, swallow_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         vector w_shotorg, w_shotdir;\r
  16         w_shotorg = self.origin + self.view_ofs;\r
  17         w_shotdir = v_forward;\r
  18 \r
  19         WarpZone_traceline_antilag(self, w_shotorg, w_shotorg + w_shotdir * cvar("g_balance_vore_swallow_range"), FALSE, self, ANTILAG_LATENCY(self));\r
  20         if(trace_fraction < 1)\r
  21         if(trace_ent.classname == "player")\r
  22                 return trace_ent;\r
  23         return world;\r
  24 }\r
  25 \r
  26 float Swallow_condition_check(entity prey)\r
  27 {\r
  28         // checks the necessary conditions for swallowing a player\r
  29 \r
  30         if(prey != self)\r
  31         if(prey.classname == "player" && prey.predator.classname != "player" && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  32         if(self.classname == "player" && self.predator.classname != "player" && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  33         if(!self.BUTTON_REGURGITATE && self.swallow_delay < time)\r
  34         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  35         {\r
  36                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  37                 {\r
  38                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  39                         {\r
  40                                 play2(self, "misc/forbidden.wav");\r
  41                                 sprint(self, "You cannot swallow your team mates\n");\r
  42                                 self.complain_vore = time + complain_delay_time;\r
  43                         }\r
  44                         return FALSE;\r
  45                 }\r
  46 \r
  47                 if(self.stomach_load >= cvar("g_balance_vore_swallow_limit"))\r
  48                 {\r
  49                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  50                         {\r
  51                                 play2(self, "misc/forbidden.wav");\r
  52                                 sprint(self, strcat("You cannot swallow more than ^2", cvar_string("g_balance_vore_swallow_limit"), "^7 players at a time\n"));\r
  53                                 self.complain_vore = time + complain_delay_time;\r
  54                         }\r
  55                         return FALSE;\r
  56                 }\r
  57 \r
  58                 if(cvar("g_vore_biggergut"))\r
  59                 if(prey.stomach_load > self.stomach_load)\r
  60                 {\r
  61                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  62                         {\r
  63                                 play2(self, "misc/forbidden.wav");\r
  64                                 sprint(self, "You cannot swallow someone with a bigger stomach than yours\n");\r
  65                                 self.complain_vore = time + complain_delay_time;\r
  66                         }\r
  67                         return FALSE;\r
  68                 }\r
  69 \r
  70                 return TRUE;\r
  71         }\r
  72         return FALSE;\r
  73 }\r
  74 \r
  75 float Stomach_TeamMates_check(entity pred)\r
  76 {\r
  77         // checks if a player's stomach contains any team mates\r
  78 \r
  79         entity head;\r
  80         if(teams_matter)\r
  81         {\r
  82                 FOR_EACH_PLAYER(head)\r
  83                 {\r
  84                         if(head.predator == pred && head.team == pred.team)\r
  85                                 return TRUE;\r
  86                 }\r
  87         }\r
  88         return FALSE;\r
  89 }\r
  90 \r
  91 float Vore_CanLeave()\r
  92 {\r
  93         if(self.predator.classname == "player")\r
  94         {\r
  95                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
  96                         return TRUE;\r
  97                 if(teams_matter && self.team == self.predator.team)\r
  98                         return TRUE;\r
  99                 if(g_rpg && cvar("g_rpg_canleave"))\r
 100                         return TRUE;\r
 101         }\r
 102         return FALSE;\r
 103 }\r
 104 \r
 105 // make the camera smoothly lower itself when we get swallowed\r
 106 // our aim is going from the normal view offset to half of the view offset (because half is the best positioning for the stomach model)\r
 107 .float cameraeffect_current, cameraeffect_target;\r
 108 void Vore_CameraEffect_Set(entity e)\r
 109 {\r
 110         e.cameraeffect_current = 1;\r
 111         e.cameraeffect_target = 2;\r
 112 }\r
 113 void Vore_CameraEffect_Apply()\r
 114 {\r
 115         if(self.predator.classname != "player")\r
 116                 return;\r
 117 \r
 118         if(self.cvar_cl_vore_cameraspeed)\r
 119         {\r
 120                 local float step;\r
 121                 step = self.cvar_cl_vore_cameraspeed * frametime;\r
 122 \r
 123                 // not sure if these maths are good, as the effect should be smoother\r
 124                 if(self.cameraeffect_current >= self.cameraeffect_target + step)\r
 125                         self.cameraeffect_current -= step;\r
 126                 else if(self.cameraeffect_current <= self.cameraeffect_target - step)\r
 127                         self.cameraeffect_current += step;\r
 128         }\r
 129         else\r
 130                 self.cameraeffect_current = self.cameraeffect_target;\r
 131 \r
 132         self.view_ofs_z = PL_VIEW_OFS_z / self.cameraeffect_current;\r
 133 }\r
 134 \r
 135 .float gurgle_oldstomachload;\r
 136 void Vore_GurgleSound()\r
 137 {\r
 138         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 139         {\r
 140                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 141 \r
 142                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 143                 self.gurgle_oldstomachload = self.stomach_load;\r
 144         }\r
 145 }\r
 146 \r
 147 void Vore_WeightApply(entity e)\r
 148 {\r
 149         // apply stomach weight that makes you heavier the more you eat\r
 150         // slowing the player is done in cl_physics.qc\r
 151 \r
 152         if(e.stomach_load != e.vore_oldstomachload)\r
 153                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 154         if(e.gravity == 0)\r
 155                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 156         e.vore_oldstomachload = e.stomach_load;\r
 157 }\r
 158 \r
 159 void Vore_AutoDigest(entity e)\r
 160 {\r
 161         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 162 \r
 163         if(!cvar("g_vore_digestion") || e.digesting)\r
 164                 return;\r
 165         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 166                 return; // this feature is only for players, not bots\r
 167         if(e.stomach_load > 1)\r
 168                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 169         if(Stomach_TeamMates_check(e))\r
 170                 return; // never begin automatic digestion if we've swallowed a team mate\r
 171 \r
 172         e.digesting = TRUE;\r
 173 }\r
 174 \r
 175 .entity pusher;\r
 176 .float pushltime;\r
 177 void Vore_Swallow(entity e)\r
 178 {\r
 179         // this player is being swallowed by another player, apply the proper changes\r
 180 \r
 181         e.vore_oldmovetype = e.movetype;\r
 182         e.vore_oldsolid = e.solid;\r
 183 \r
 184         e.predator = self;\r
 185         setorigin(e, e.predator.origin);\r
 186         e.velocity = '0 0 0';\r
 187         e.movetype = MOVETYPE_FOLLOW;\r
 188         e.solid = SOLID_NOT;\r
 189         e.alpha = -1; // best way of hiding the eaten player\r
 190         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 191 \r
 192         // drop keys (KH) and flags (CTF) when we get swallowed\r
 193         kh_Key_DropAll(e, FALSE);\r
 194         if(e.flagcarried)\r
 195                 DropFlag(e.flagcarried, world, e.predator);\r
 196 \r
 197         Vore_CameraEffect_Set(e);\r
 198 \r
 199         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 200                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 201 \r
 202         if(teams_matter && e.team == e.predator.team)\r
 203         {\r
 204                 if(cvar("g_vore_kick"))\r
 205                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 206                 if(cvar("g_vore_digestion"))\r
 207                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 208         }\r
 209 \r
 210         PlayerSound(e.predator, playersound_swallow, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 211         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 212         e.predator.punchangle_x -= e.predator.cvar_cl_vore_punchangle;\r
 213         e.predator.stomach_load += 1;\r
 214         e.predator.regurgitate_prepare = 0;\r
 215         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 216         Vore_WeightApply(e.predator);\r
 217         Vore_AutoDigest(e.predator);\r
 218 \r
 219         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 220         e.predator.weapon_delay = time + button_delay_time;\r
 221         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 222         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 223 }\r
 224 \r
 225 void Vore_Regurgitate(entity e)\r
 226 {\r
 227         // this player is being regurgitated by their predator, apply the proper changes\r
 228 \r
 229         e.movetype = e.vore_oldmovetype;\r
 230         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 231                 e.solid = e.vore_oldsolid;\r
 232         e.view_ofs_z = PL_VIEW_OFS_z;\r
 233         e.alpha = default_player_alpha;\r
 234 \r
 235         // apply velocities\r
 236         local vector oldforward, oldright, oldup;\r
 237         oldforward = v_forward;\r
 238         oldright = v_right;\r
 239         oldup = v_up;\r
 240         makevectors(e.predator.v_angle);\r
 241         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 242         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 243         v_forward = oldforward;\r
 244         v_right = oldright;\r
 245         v_up = oldup;\r
 246 \r
 247         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 248         e.pushltime = time + cvar("g_maxpushtime");\r
 249 \r
 250         PlayerSound(e.predator, playersound_regurgitate, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 251         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 252         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 253         e.predator.punchangle_x += e.predator.cvar_cl_vore_punchangle;\r
 254         e.predator.stomach_load -= 1;\r
 255         e.predator.regurgitate_prepare = 0;\r
 256         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 257         Vore_WeightApply(e.predator);\r
 258 \r
 259         // block firing for a small amount of time, or we'll be firing the next frame\r
 260         e.weapon_delay = time + button_delay_time;\r
 261         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 262         e.predator = world;\r
 263 }\r
 264 \r
 265 void Vore_DeadPrey_Configure(entity e)\r
 266 {\r
 267         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 268 \r
 269         if(e.fakeprey || e.predator.classname != "player") // already configured\r
 270                 return;\r
 271 \r
 272         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 273         e.fakepredator = e.predator;\r
 274         e.fakeprey = TRUE;\r
 275 \r
 276         // first release the prey from the predator, as dead prey needs to be attached differently\r
 277         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 278         e.predator.stomach_load -= 1;\r
 279         Vore_WeightApply(e.predator);\r
 280         e.predator = world;\r
 281 \r
 282         // now put our dead prey inside the predator's stomach, but only as an effect\r
 283         e.movetype = MOVETYPE_FOLLOW;\r
 284         e.takedamage = DAMAGE_NO;\r
 285         e.solid = SOLID_NOT;\r
 286         e.aiment = e.fakepredator;\r
 287 \r
 288         // completely remove the dead body\r
 289         e.modelindex = 0;\r
 290 }\r
 291 \r
 292 void Vore_DeadPrey_Detach(entity e)\r
 293 {\r
 294         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 295         // should only execute after Vore_DeadPrey_Configure has ran first\r
 296 \r
 297         if not(cvar("g_vore_keepdeadprey"))\r
 298                 return;\r
 299 \r
 300         e.fakepredator = world;\r
 301         e.fakeprey = FALSE;\r
 302         e.aiment = world;\r
 303         e.movetype = MOVETYPE_TOSS;\r
 304 }\r
 305 \r
 306 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 307 {\r
 308         // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 309         if(e.health <= 0 && cvar("g_vore_keepdeadprey"))\r
 310         {\r
 311                 // if keepdeadprey is enabled and the predator disconnected, detach the dead prey\r
 312                 if(pred_disconnect)\r
 313                 {\r
 314                         if(e.fakeprey)\r
 315                                 Vore_DeadPrey_Detach(e);\r
 316                 }\r
 317                 else\r
 318                         Vore_DeadPrey_Configure(e);\r
 319         }\r
 320         else\r
 321                 Vore_Regurgitate(e);\r
 322 }\r
 323 \r
 324 void Vore_Disconnect()\r
 325 {\r
 326         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 327 \r
 328         // prey disconnects or goes spectating while inside someone's belly\r
 329         if(self.predator.classname == "player")\r
 330                 Vore_PreyRelease(self, TRUE);\r
 331 \r
 332         // pred disconnects or goes spectating with players in their belly\r
 333         entity head;\r
 334         FOR_EACH_PLAYER(head)\r
 335         {\r
 336                 if(head.predator == self || head.fakepredator == self)\r
 337                         Vore_PreyRelease(head, TRUE);\r
 338         }\r
 339         Vore_GurgleSound(); // stop the gurgling sound\r
 340 \r
 341         self.stomach_load = self.gravity = 0; // prevents a bug\r
 342 }\r
 343 \r
 344 .float digestion_step;\r
 345 void Vore_Digest()\r
 346 {\r
 347         // apply digestion to prey\r
 348 \r
 349         if(time > self.predator.digestion_step)\r
 350         {\r
 351                 Damage(self, self.predator, self.predator, cvar("g_balance_vore_digestion_damage"), DEATH_DIGESTION, self.origin, '0 0 0');\r
 352                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 353                         self.predator.health += cvar("g_balance_vore_digestion_vampire");\r
 354 \r
 355                 if (self.predator.digestsound_finished < time)\r
 356                 {\r
 357                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 358                         self.predator.digestsound_finished = time + 0.5;\r
 359                 }\r
 360                 self.predator.digestion_step = time + steptime;\r
 361         }\r
 362 \r
 363         if(self.health <= 0)\r
 364         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 365                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 366 }\r
 367 \r
 368 .float teamheal_step;\r
 369 void Vore_Teamheal()\r
 370 {\r
 371         // apply teamheal\r
 372 \r
 373         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 374         if(time > self.teamheal_step)\r
 375         {\r
 376                 self.health += cvar("g_balance_vore_teamheal");\r
 377                 self.teamheal_step = time + steptime;\r
 378 \r
 379                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 380                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 381                 {\r
 382                         play2(self, "misc/beep.wav");\r
 383                         play2(self.predator, "misc/beep.wav");\r
 384                 }\r
 385         }\r
 386 }\r
 387 \r
 388 .float stomachkick_delay;\r
 389 void Vore_StomachKick()\r
 390 {\r
 391         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 392 \r
 393         if(time > self.stomachkick_delay)\r
 394         {\r
 395                 float damage;\r
 396                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 397                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, v_forward * cvar("g_balance_vore_kick_force"));\r
 398                 sound(self.predator, CHAN_PROJECTILE, "weapons/stomachkick.wav", VOL_BASE, ATTN_NORM);\r
 399                 self.predator.punchangle_x -= self.predator.cvar_cl_vore_kick_punchangle;\r
 400 \r
 401                 if(random() < cvar("g_balance_vore_kick_escapeprobability"))\r
 402                         Vore_Regurgitate(self);\r
 403 \r
 404                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 405         }\r
 406 }\r
 407 \r
 408 void Vore_StomachLeave()\r
 409 {\r
 410         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 411 \r
 412         if(Vore_CanLeave())\r
 413                 Vore_Regurgitate(self);\r
 414         else if(time > self.complain_vore)\r
 415         {\r
 416                 play2(self, "misc/forbidden.wav");\r
 417                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 418                 self.complain_vore = time + complain_delay_time;\r
 419         }\r
 420 }\r
 421 \r
 422 void Vore_AutoTaunt()\r
 423 {\r
 424         // triggers ambient vore taunts, for both pred and prey\r
 425 \r
 426         float taunt_time;\r
 427 \r
 428         // predator taunts\r
 429         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 430         {\r
 431                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 432                 {\r
 433                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 434                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 435                 }\r
 436         }\r
 437         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 438         {\r
 439                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 440                 SetAutoTaunt(self, 0, 0);\r
 441         }\r
 442 \r
 443         // prey taunts\r
 444         if(self.predator.classname == "player" && !(teams_matter && self.team == self.predator.team))\r
 445         {\r
 446                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 447                 {\r
 448                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 449                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 450                 }\r
 451         }\r
 452         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 453         {\r
 454                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 455                 SetAutoTaunt(self, 0, 0);\r
 456         }\r
 457 }\r
 458 \r
 459 void Vore()\r
 460 {\r
 461         // main vore code, this is where it all happens\r
 462 \r
 463         if(!cvar("g_vore")) // the vore system is disabled\r
 464         {\r
 465                 Vore_Disconnect();\r
 466                 return;\r
 467         }\r
 468 \r
 469         Vore_AutoTaunt();\r
 470 \r
 471         // wash the goo away from players once they leave the stomach\r
 472         if(self.predator.classname != "player")\r
 473         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 474         if(self.colormod)\r
 475         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 476         {\r
 477                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 478                 if(self.colormod_x > 1)\r
 479                         self.colormod_x = 1;\r
 480                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 481                 if(self.colormod_y > 1)\r
 482                         self.colormod_y = 1;\r
 483                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 484                 if(self.colormod_z > 1)\r
 485                         self.colormod_z = 1;\r
 486         }\r
 487 \r
 488         // set all vore related stats\r
 489         if(self.predator.classname == "player")\r
 490         {\r
 491                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 492                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 493                 self.stat_eaten = num_for_edict(self.predator);\r
 494         }\r
 495         else\r
 496         {\r
 497                 self.stat_stomachload = self.stomach_load;\r
 498                 self.stat_digesting = self.digesting;\r
 499                 self.stat_eaten = 0;\r
 500         }\r
 501         self.stat_canleave = Vore_CanLeave();\r
 502 \r
 503         // don't allow a player inside a player inside another player :)\r
 504         // prevent this by checking if such has happened, and taking the proper measures\r
 505         // this code has a high priority and must not be stopped by any delay, so run it here\r
 506         if(self.predator.predator.classname == "player")\r
 507         {\r
 508                 entity target_predator, target_predator_predator, oldself;\r
 509                 target_predator = self.predator;\r
 510                 target_predator_predator = self.predator.predator;\r
 511 \r
 512                 Vore_Regurgitate(self);\r
 513 \r
 514                 // now steal our prey's prey if this probability applies\r
 515                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 516                 {\r
 517                         oldself = self;\r
 518                         self = target_predator_predator;\r
 519                         if(Swallow_condition_check(oldself))\r
 520                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 521                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 522                                 Vore_Swallow(oldself);\r
 523                         self = oldself;\r
 524                 }\r
 525         }\r
 526 \r
 527         // apply delays and skip the vore system under some circumstances\r
 528         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 529         {\r
 530                 Vore_Disconnect();\r
 531                 return;\r
 532         }\r
 533         if(self.spectatee_status)\r
 534                 return;\r
 535         if(time < self.system_delay)\r
 536                 return;\r
 537 \r
 538 // --------------------------------\r
 539 // Code that addresses predators:\r
 540 // --------------------------------\r
 541 \r
 542         entity prey;\r
 543         prey = Swallow_player_check();\r
 544 \r
 545         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 546         self.stat_canswallow = 0;\r
 547         if(Swallow_condition_check(prey))\r
 548         {\r
 549                 // canswallow stat, used by the HUD\r
 550                 if(teams_matter && prey.team == self.team)\r
 551                         self.stat_canswallow = 2;\r
 552                 else\r
 553                         self.stat_canswallow = 1;\r
 554 \r
 555                 if(self.BUTTON_ATCK)\r
 556                         Vore_Swallow(prey);\r
 557         }\r
 558         else if(prey != world)\r
 559                 self.stat_canswallow = -1;\r
 560 \r
 561         // toggle digestion, if the player has someone in their stomach\r
 562         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 563         {\r
 564                 if(self.stomach_load)\r
 565                 {\r
 566                         if(time > self.digest_button_delay_time)\r
 567                         {\r
 568                                 self.digesting = !self.digesting;\r
 569                                 self.digest_button_delay_time = time + button_delay_time;\r
 570                         }\r
 571                 }\r
 572                 else if(time > self.complain_vore)\r
 573                 {\r
 574                         play2(self, "misc/forbidden.wav");\r
 575                         sprint(self, "There is nothing to digest\n");\r
 576                         self.complain_vore = time + complain_delay_time;\r
 577                 }\r
 578         }\r
 579         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 580                 self.digesting = FALSE;\r
 581 \r
 582         // predator wishes to regurgitate his prey\r
 583         if(self.BUTTON_REGURGITATE)\r
 584         {\r
 585                 if(self.stomach_load)\r
 586                 {\r
 587                         if(time > self.regurgitate_button_delay_time)\r
 588                         {\r
 589                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 590                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 591                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 592                         }\r
 593                 }\r
 594                 else if(time > self.complain_vore)\r
 595                 {\r
 596                         play2(self, "misc/forbidden.wav");\r
 597                         sprint(self, "There is nothing to regurgitate\n");\r
 598                         self.complain_vore = time + complain_delay_time;\r
 599                 }\r
 600         }\r
 601 \r
 602         if(cvar("g_vore_gurglesound"))\r
 603                 Vore_GurgleSound();\r
 604 \r
 605 // --------------------------------\r
 606 // Code that addresses the prey:\r
 607 // --------------------------------\r
 608 \r
 609         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 610         if(self.fakepredator.classname == "player")\r
 611         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.predator.classname == "player")\r
 612                 Vore_DeadPrey_Detach(self);\r
 613 \r
 614         if(self.predator.classname != "player")\r
 615                 return;\r
 616 \r
 617         if(self.deadflag)\r
 618         {\r
 619                 Vore_PreyRelease(self, FALSE);\r
 620                 return;\r
 621         }\r
 622 \r
 623         if(self.predator.deadflag)\r
 624                 Vore_Regurgitate(self);\r
 625         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 626                 Vore_Regurgitate(self);\r
 627 \r
 628         // apply delayed regurgitating if it was scheduled\r
 629         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 630         {\r
 631                 self.predator.regurgitate_prepare = 0;\r
 632                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 633                 Vore_Regurgitate(self);\r
 634         }\r
 635 \r
 636         // execute digesting and team healing\r
 637         if(self.predator.digesting == TRUE)\r
 638                 Vore_Digest();\r
 639         if(teams_matter && self.team == self.predator.team)\r
 640         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 641                 Vore_Teamheal();\r
 642 \r
 643         // execute prey commands\r
 644         if(self.BUTTON_ATCK && cvar("g_vore_kick"))\r
 645                 Vore_StomachKick();\r
 646         if(self.BUTTON_JUMP)\r
 647                 Vore_StomachLeave();\r
 648 \r
 649         Vore_CameraEffect_Apply();\r
 650 }