data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(self.scale) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         vore_w_shotorg = self.origin;\r
  22         vore_w_shotdir = v_forward;\r
  23 \r
  24         WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  25         if(trace_fraction < 1)\r
  26         if(trace_ent.classname == "player")\r
  27                 return trace_ent;\r
  28         return world;\r
  29 }\r
  30 \r
  31 float Swallow_condition_check(entity prey)\r
  32 {\r
  33         // checks the necessary conditions for swallowing a player\r
  34 \r
  35         if(prey != self)\r
  36         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  37         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  38         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  39         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  40         {\r
  41                 string swallow_complain;\r
  42                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  43                         swallow_complain = "You cannot swallow your team mates\n";\r
  44                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  45                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  46                 else if(self.stomach_load >= g_balance_vore_swallow_limit)\r
  47                         swallow_complain = strcat("You cannot swallow more than ^2", ftos(g_balance_vore_swallow_limit), "^7 players at a time\n");\r
  48                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  49                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  50                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  51                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  52 \r
  53                 if(swallow_complain != "")\r
  54                 {\r
  55                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  56                         {\r
  57                                 play2(self, "misc/forbidden.wav");\r
  58                                 sprint(self, swallow_complain);\r
  59                                 self.complain_vore = time + complain_delay_time;\r
  60                         }\r
  61                         return FALSE;\r
  62                 }\r
  63                 return TRUE;\r
  64         }\r
  65         return FALSE;\r
  66 }\r
  67 \r
  68 float Stomach_TeamMates_check(entity pred)\r
  69 {\r
  70         // checks if a player's stomach contains any team mates\r
  71 \r
  72         entity head;\r
  73         if(teams_matter)\r
  74         {\r
  75                 FOR_EACH_PLAYER(head)\r
  76                 {\r
  77                         if(head.predator == pred && head.team == pred.team)\r
  78                                 return TRUE;\r
  79                 }\r
  80         }\r
  81         return FALSE;\r
  82 }\r
  83 \r
  84 float Vore_CanLeave()\r
  85 {\r
  86         if(self.stat_eaten)\r
  87         {\r
  88                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
  89                         return TRUE;\r
  90                 if(teams_matter && self.team == self.predator.team)\r
  91                         return TRUE;\r
  92                 if(g_rpg && cvar("g_rpg_canleave"))\r
  93                         return TRUE;\r
  94         }\r
  95         return FALSE;\r
  96 }\r
  97 \r
  98 // position the camera properly for prey\r
  99 void Vore_SetPreyPositions()\r
 100 {\r
 101         // self is the predator and head is the prey\r
 102 \r
 103         local entity head;\r
 104         local vector origin_apply;\r
 105         local float position_counter;\r
 106 \r
 107         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 108         // else all players overlap in the center. To do this, we run a loop on all players in the same stomach.\r
 109         // For each player, the origin is updated, then a new origin is used for the next player.\r
 110         // This requires that no more than 9 players may be in the stomach at a time!\r
 111         FOR_EACH_PLAYER(head)\r
 112         {\r
 113                 if(head.predator == self)\r
 114                 {\r
 115                         switch(position_counter)\r
 116                         {\r
 117                                 case 0:\r
 118                                         origin_apply = '0 0 0'; // first occupant sits in the middle\r
 119                                         break;\r
 120                                 case 1:\r
 121                                         origin_apply = '1 0 0'; // second occupant sits in the front\r
 122                                         break;\r
 123                                 case 2:\r
 124                                         origin_apply = '-1 0 0'; // third occupant sits in the back\r
 125                                         break;\r
 126                                 case 3:\r
 127                                         origin_apply = '0 1 0'; // fourth occupant sits in the right\r
 128                                         break;\r
 129                                 case 4:\r
 130                                         origin_apply = '0 -1 0'; // fifth occupant sits in the left\r
 131                                         break;\r
 132                                 case 5:\r
 133                                         origin_apply = '1 1 0'; // sixth occupant sits in the front-right\r
 134                                         break;\r
 135                                 case 6:\r
 136                                         origin_apply = '-1 1 0'; // seventh occupant sits in the back-right\r
 137                                         break;\r
 138                                 case 7:\r
 139                                         origin_apply = '1 -1 0'; // eigth occupant sits in the front-left\r
 140                                         break;\r
 141                                 case 8:\r
 142                                         origin_apply = '-1 -1 0'; // ninth occupant sits in the back-left\r
 143                                         break;\r
 144                                 default:\r
 145                                         break;\r
 146                         }\r
 147 \r
 148                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 149                         head.view_ofs = PL_PREY_VIEW_OFS + origin_apply * cvar("g_vore_neighborprey_distance");\r
 150                         head.view_ofs_z *= self.scale; // stomach center depends on predator scale\r
 151 \r
 152                         // change prey height based on scale\r
 153                         float prey_height;\r
 154                                 prey_height = (head.scale - self.scale) * cvar("g_healthsize_vore_pos");\r
 155                         head.view_ofs_z += prey_height;\r
 156 \r
 157                         position_counter += 1;\r
 158                 }\r
 159         }\r
 160 }\r
 161 \r
 162 .float gurgle_oldstomachload;\r
 163 void Vore_GurgleSound()\r
 164 {\r
 165         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 166         {\r
 167                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 168 \r
 169                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 170                 self.gurgle_oldstomachload = self.stomach_load;\r
 171         }\r
 172 }\r
 173 \r
 174 void Vore_WeightApply(entity e)\r
 175 {\r
 176         // apply stomach weight that makes you heavier the more you eat\r
 177         // slowing the player is done in cl_physics.qc\r
 178 \r
 179         if(e.stomach_load != e.vore_oldstomachload)\r
 180                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 181         if(e.gravity == 0)\r
 182                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 183         e.vore_oldstomachload = e.stomach_load;\r
 184 }\r
 185 \r
 186 void Vore_AutoDigest(entity e)\r
 187 {\r
 188         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 189 \r
 190         if(!cvar("g_vore_digestion") || e.digesting)\r
 191                 return;\r
 192         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 193                 return; // this feature is only for players, not bots\r
 194         if(e.stomach_load > 1)\r
 195                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 196         if(Stomach_TeamMates_check(e))\r
 197                 return; // never begin automatic digestion if we've swallowed a team mate\r
 198 \r
 199         e.digesting = TRUE;\r
 200 }\r
 201 \r
 202 .entity pusher;\r
 203 .float pushltime;\r
 204 void Vore_Swallow(entity e)\r
 205 {\r
 206         // this player is being swallowed by another player, apply the proper changes\r
 207 \r
 208         e.vore_oldmovetype = e.movetype;\r
 209         e.vore_oldsolid = e.solid;\r
 210 \r
 211         e.predator = self;\r
 212         setorigin(e, e.predator.origin);\r
 213         e.velocity = '0 0 0';\r
 214         e.movetype = MOVETYPE_FOLLOW;\r
 215         e.solid = SOLID_NOT;\r
 216         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 217 \r
 218         // drop keys (KH) and flags (CTF) when we get swallowed\r
 219         kh_Key_DropAll(e, FALSE);\r
 220         if(e.flagcarried)\r
 221                 DropFlag(e.flagcarried, world, e.predator);\r
 222 \r
 223         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 224                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 225 \r
 226         if(teams_matter && e.team == e.predator.team)\r
 227         {\r
 228                 if(cvar("g_vore_kick"))\r
 229                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 230                 if(cvar("g_vore_digestion"))\r
 231                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 232         }\r
 233 \r
 234         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 235         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 236         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 237         e.predator.stomach_load += 1;\r
 238         e.predator.regurgitate_prepare = 0;\r
 239         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 240         Vore_WeightApply(e.predator);\r
 241         Vore_AutoDigest(e.predator);\r
 242 \r
 243         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 244         e.predator.weapon_delay = time + button_delay_time;\r
 245         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 246         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 247         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 248 }\r
 249 \r
 250 void Vore_SwallowStep(entity e)\r
 251 {\r
 252         if(!cvar("g_balance_vore_swallow_speed_fill"))\r
 253         {\r
 254                 Vore_Swallow(e);\r
 255                 return;\r
 256         }\r
 257 \r
 258         // increase the progress value until it reaches 1, then swallow the player\r
 259         if(e.swallow_progress_prey < 1)\r
 260         {\r
 261                 float fill;\r
 262                 fill = cvar("g_balance_vore_swallow_speed_fill") * frametime;\r
 263                 if(cvar("g_balance_vore_swallow_speed_fill_scalediff")) // fill rate depends on predator size compared to prey size\r
 264                         fill *= (self.scale / e.scale);\r
 265 \r
 266                 e.swallow_progress_prey += fill;\r
 267         }\r
 268         else\r
 269         {\r
 270                 Vore_Swallow(e);\r
 271                 e.swallow_progress_prey = 0;\r
 272         }\r
 273 \r
 274         // the predator's progress is how much the prey got swallowed\r
 275         self.swallow_progress_pred = e.swallow_progress_prey;\r
 276 }\r
 277 \r
 278 void Vore_Regurgitate(entity e)\r
 279 {\r
 280         // this player is being regurgitated by their predator, apply the proper changes\r
 281 \r
 282         e.movetype = e.vore_oldmovetype;\r
 283         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 284                 e.solid = e.vore_oldsolid;\r
 285         e.view_ofs_z = PL_VIEW_OFS_z;\r
 286 \r
 287         // apply velocities\r
 288         local vector oldforward, oldright, oldup;\r
 289         oldforward = v_forward;\r
 290         oldright = v_right;\r
 291         oldup = v_up;\r
 292         makevectors(e.predator.v_angle);\r
 293         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 294         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 295         v_forward = oldforward;\r
 296         v_right = oldright;\r
 297         v_up = oldup;\r
 298 \r
 299         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 300         e.pushltime = time + cvar("g_maxpushtime");\r
 301 \r
 302         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
 303         if(cvar("g_balance_vore_swallow_speed_fill"))\r
 304                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
 305 \r
 306         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 307         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 308         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 309         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 310         e.predator.stomach_load -= 1;\r
 311         e.predator.regurgitate_prepare = 0;\r
 312         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 313         Vore_WeightApply(e.predator);\r
 314 \r
 315         // block firing for a small amount of time, or we'll be firing the next frame\r
 316         e.weapon_delay = time + button_delay_time;\r
 317         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 318         e.predator = world;\r
 319 }\r
 320 \r
 321 void Vore_DeadPrey_Configure(entity e)\r
 322 {\r
 323         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 324 \r
 325         if(e.fakeprey || !e.stat_eaten) // we already configured everything\r
 326                 return;\r
 327 \r
 328         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 329         e.fakepredator = e.predator;\r
 330         e.fakeprey = TRUE;\r
 331 \r
 332         // first release the prey from the predator, as dead prey needs to be attached differently\r
 333         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 334         e.predator.stomach_load -= 1;\r
 335         Vore_WeightApply(e.predator);\r
 336         e.predator = world;\r
 337 \r
 338         // now put our dead prey inside the predator's stomach, but only as an effect\r
 339         e.movetype = MOVETYPE_FOLLOW;\r
 340         e.takedamage = DAMAGE_NO;\r
 341         e.solid = SOLID_NOT;\r
 342         e.aiment = e.fakepredator;\r
 343 }\r
 344 \r
 345 void Vore_DeadPrey_Detach(entity e)\r
 346 {\r
 347         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 348         // should only execute after Vore_DeadPrey_Configure has ran first\r
 349 \r
 350         if not(cvar("g_vore_keepdeadprey"))\r
 351                 return;\r
 352 \r
 353         e.fakepredator = world;\r
 354         e.fakeprey = TRUE; // keep fakeprey status\r
 355         e.stat_eaten = 0;\r
 356         e.aiment = world;\r
 357         e.movetype = MOVETYPE_TOSS;\r
 358 }\r
 359 \r
 360 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 361 {\r
 362         if(pred_disconnect)\r
 363         {\r
 364                 if(e.fakeprey)\r
 365                         Vore_DeadPrey_Detach(e);\r
 366                 else\r
 367                         Vore_Regurgitate(e);\r
 368         }\r
 369         else if(self.stat_eaten && !self.fakeprey)\r
 370         {\r
 371                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 372                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
 373                         Vore_DeadPrey_Configure(e);\r
 374                 else\r
 375                         Vore_Regurgitate(e);\r
 376         }\r
 377 }\r
 378 \r
 379 void Vore_Disconnect()\r
 380 {\r
 381         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 382 \r
 383         // prey disconnects or goes spectating while inside someone's belly\r
 384         if(self.stat_eaten)\r
 385                 Vore_PreyRelease(self, TRUE);\r
 386 \r
 387         // pred disconnects or goes spectating with players in their belly\r
 388         entity head;\r
 389         FOR_EACH_PLAYER(head)\r
 390         {\r
 391                 if(head.predator == self || head.fakepredator == self)\r
 392                         Vore_PreyRelease(head, TRUE);\r
 393         }\r
 394         Vore_GurgleSound(); // stop the gurgling sound\r
 395 \r
 396         self.stomach_load = self.gravity = 0; // prevents a bug\r
 397 }\r
 398 \r
 399 .float digestion_step;\r
 400 void Vore_Digest()\r
 401 {\r
 402         // apply digestion to prey\r
 403 \r
 404         if(time > self.digestion_step)\r
 405         {\r
 406                 // if distributed digestion is enabled, reduce digestion strength by the number of prey in our stomach\r
 407                 float reduce;\r
 408                 if(cvar("g_balance_vore_digestion_distribute"))\r
 409                         reduce = self.predator.stomach_load;\r
 410                 else\r
 411                         reduce = 1;\r
 412 \r
 413                 float damage;\r
 414                 damage = cvar("g_balance_vore_digestion_damage") / reduce;\r
 415 \r
 416                 // apply player scale to digestion damage\r
 417                 if(cvar("g_balance_vore_digestion_scalediff"))\r
 418                         damage *= (self.predator.scale / self.scale);\r
 419 \r
 420                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
 421                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 422                         self.predator.health += cvar("g_balance_vore_digestion_vampire") / reduce;\r
 423 \r
 424                 if (self.predator.digestsound_finished < time)\r
 425                 {\r
 426                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 427                         self.predator.digestsound_finished = time + 0.5;\r
 428                 }\r
 429                 self.digestion_step = time + steptime;\r
 430         }\r
 431 \r
 432         if(self.deadflag != DEAD_NO)\r
 433         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 434                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 435 }\r
 436 \r
 437 .float teamheal_step;\r
 438 void Vore_Teamheal()\r
 439 {\r
 440         // apply teamheal\r
 441 \r
 442         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 443         if(time > self.teamheal_step)\r
 444         {\r
 445                 self.health += cvar("g_balance_vore_teamheal");\r
 446                 self.teamheal_step = time + steptime;\r
 447 \r
 448                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 449                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 450                 {\r
 451                         play2(self, "misc/beep.wav");\r
 452                         play2(self.predator, "misc/beep.wav");\r
 453                 }\r
 454         }\r
 455 }\r
 456 \r
 457 void Vore_StomachKick()\r
 458 {\r
 459         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 460 \r
 461         if(time > self.stomachkick_delay)\r
 462         {\r
 463                 float damage;\r
 464                 vector force;\r
 465                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 466                 force = v_forward * cvar("g_balance_vore_kick_force");\r
 467 \r
 468                 // apply player scale to the damage / force of the kick\r
 469                 if(cvar("g_balance_vore_kick_scalediff"))\r
 470                 {\r
 471                         damage *= (self.scale / self.predator.scale);\r
 472                         force *= (self.scale / self.predator.scale);\r
 473                 }\r
 474 \r
 475                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
 476                 sound(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), VOL_BASE, ATTN_NORM);\r
 477                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 478                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 479 \r
 480                 // abort the predator's scheduled regurgitation\r
 481                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
 482                         self.predator.regurgitate_prepare = 0;\r
 483 \r
 484                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 485         }\r
 486 }\r
 487 \r
 488 void Vore_StomachLeave()\r
 489 {\r
 490         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 491 \r
 492         if(Vore_CanLeave())\r
 493                 Vore_Regurgitate(self);\r
 494         else if(time > self.complain_vore)\r
 495         {\r
 496                 play2(self, "misc/forbidden.wav");\r
 497                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 498                 self.complain_vore = time + complain_delay_time;\r
 499         }\r
 500 }\r
 501 \r
 502 void Vore_AutoTaunt()\r
 503 {\r
 504         // triggers ambient vore taunts, for both pred and prey\r
 505 \r
 506         float taunt_time;\r
 507 \r
 508         // predator taunts\r
 509         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 510         {\r
 511                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 512                 {\r
 513                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 514                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 515                 }\r
 516         }\r
 517         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 518         {\r
 519                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 520                 SetAutoTaunt(self, 0, 0);\r
 521         }\r
 522 \r
 523         // prey taunts\r
 524         if(self.stat_eaten && !(teams_matter && self.team == self.predator.team))\r
 525         {\r
 526                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 527                 {\r
 528                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 529                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 530                 }\r
 531         }\r
 532         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 533         {\r
 534                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 535                 SetAutoTaunt(self, 0, 0);\r
 536         }\r
 537 }\r
 538 \r
 539 void Vore_SetSbarRings()\r
 540 {\r
 541         // first clear the ring stats, then configure them if needed\r
 542         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 543         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 544 \r
 545         if(self.stat_eaten)\r
 546         {\r
 547                 if(time <= self.stomachkick_delay)\r
 548                 {\r
 549                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
 550                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 551                 }\r
 552         }\r
 553         else\r
 554         {\r
 555                 if(self.swallow_progress_pred)\r
 556                 {\r
 557                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
 558                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
 559                 }\r
 560                 else if(time <= self.action_delay)\r
 561                 {\r
 562                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
 563                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 564                 }\r
 565 \r
 566                 if(self.swallow_progress_prey)\r
 567                 {\r
 568                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
 569                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
 570                 }\r
 571                 else if(time <= self.regurgitate_prepare)\r
 572                 {\r
 573                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
 574                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 575                 }\r
 576         }\r
 577 }\r
 578 \r
 579 void Vore()\r
 580 {\r
 581         // main vore code, this is where it all happens\r
 582 \r
 583         if(!cvar("g_vore")) // the vore system is disabled\r
 584         {\r
 585                 Vore_Disconnect();\r
 586                 return;\r
 587         }\r
 588 \r
 589         Vore_AutoTaunt();\r
 590 \r
 591         // wash the goo away from players once they leave the stomach\r
 592         if(!self.stat_eaten)\r
 593         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 594         if(self.colormod)\r
 595         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 596         {\r
 597                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 598                 if(self.colormod_x > 1)\r
 599                         self.colormod_x = 1;\r
 600                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 601                 if(self.colormod_y > 1)\r
 602                         self.colormod_y = 1;\r
 603                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 604                 if(self.colormod_z > 1)\r
 605                         self.colormod_z = 1;\r
 606         }\r
 607 \r
 608         // set all vore stats\r
 609         Vore_SetSbarRings();\r
 610         if(self.fakepredator.classname == "player")\r
 611                 self.stat_eaten = num_for_edict(self.fakepredator);\r
 612         else if(self.predator.classname == "player")\r
 613         {\r
 614                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 615                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 616                 self.stat_eaten = num_for_edict(self.predator);\r
 617         }\r
 618         else\r
 619         {\r
 620                 self.stat_stomachload = self.stomach_load;\r
 621                 self.stat_digesting = self.digesting;\r
 622                 self.stat_eaten = 0;\r
 623         }\r
 624         self.stat_canleave = Vore_CanLeave();\r
 625 \r
 626         // don't allow a player inside a player inside another player :)\r
 627         // prevent this by checking if such has happened, and taking the proper measures\r
 628         // this code has a high priority and must not be stopped by any delay, so run it here\r
 629         if(self.predator.stat_eaten)\r
 630         {\r
 631                 entity target_predator, target_predator_predator, oldself;\r
 632                 target_predator = self.predator;\r
 633                 target_predator_predator = self.predator.predator;\r
 634 \r
 635                 Vore_Regurgitate(self);\r
 636 \r
 637                 // now steal our prey's prey if this probability applies\r
 638                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 639                 {\r
 640                         oldself = self;\r
 641                         self = target_predator_predator;\r
 642                         if(Swallow_condition_check(oldself))\r
 643                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 644                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 645                                 Vore_Swallow(oldself);\r
 646                         self = oldself;\r
 647                 }\r
 648         }\r
 649 \r
 650         // the swallow progress of prey and preds idly decrease by this amount\r
 651         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
 652         {\r
 653                 if(self.swallow_progress_pred)\r
 654                 {\r
 655                         self.swallow_progress_pred -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 656                         if(self.swallow_progress_pred < 0)\r
 657                                 self.swallow_progress_pred = 0;\r
 658                 }\r
 659                 if(self.swallow_progress_prey)\r
 660                 {\r
 661                         self.swallow_progress_prey -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 662                         if(self.swallow_progress_prey < 0)\r
 663                                 self.swallow_progress_prey = 0;\r
 664                 }\r
 665         }\r
 666 \r
 667         // apply delays and skip the vore system under some circumstances\r
 668         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 669         {\r
 670                 Vore_Disconnect();\r
 671                 return;\r
 672         }\r
 673         if(self.spectatee_status)\r
 674                 return;\r
 675         if(time < self.system_delay)\r
 676                 return;\r
 677 \r
 678 // --------------------------------\r
 679 // Code that addresses predators:\r
 680 // --------------------------------\r
 681 \r
 682         entity prey;\r
 683         prey = Swallow_player_check();\r
 684 \r
 685         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 686         self.stat_canswallow = 0;\r
 687         if(Swallow_condition_check(prey))\r
 688         {\r
 689                 // canswallow stat, used by the HUD\r
 690                 if(teams_matter && prey.team == self.team)\r
 691                         self.stat_canswallow = 2;\r
 692                 else\r
 693                         self.stat_canswallow = 1;\r
 694 \r
 695                 if(self.BUTTON_ATCK)\r
 696                         Vore_SwallowStep(prey);\r
 697         }\r
 698         else if(prey != world)\r
 699                 self.stat_canswallow = -1;\r
 700 \r
 701         // toggle digestion, if the player has someone in their stomach\r
 702         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 703         {\r
 704                 if(self.stomach_load)\r
 705                 {\r
 706                         if(time > self.digest_button_delay_time)\r
 707                         {\r
 708                                 self.digesting = !self.digesting;\r
 709                                 self.digest_button_delay_time = time + button_delay_time;\r
 710                         }\r
 711                 }\r
 712                 else if(time > self.complain_vore)\r
 713                 {\r
 714                         play2(self, "misc/forbidden.wav");\r
 715                         sprint(self, "There is nothing to digest\n");\r
 716                         self.complain_vore = time + complain_delay_time;\r
 717                 }\r
 718         }\r
 719         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 720                 self.digesting = FALSE;\r
 721 \r
 722         // predator wishes to regurgitate his prey\r
 723         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 724         {\r
 725                 if(self.stomach_load)\r
 726                 {\r
 727                         if(time > self.regurgitate_button_delay_time)\r
 728                         {\r
 729                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 730                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 731                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 732                         }\r
 733                 }\r
 734                 else if(time > self.complain_vore)\r
 735                 {\r
 736                         play2(self, "misc/forbidden.wav");\r
 737                         sprint(self, "There is nothing to regurgitate\n");\r
 738                         self.complain_vore = time + complain_delay_time;\r
 739                 }\r
 740         }\r
 741 \r
 742         if(cvar("g_vore_gurglesound"))\r
 743                 Vore_GurgleSound();\r
 744 \r
 745 // --------------------------------\r
 746 // Code that addresses the prey:\r
 747 // --------------------------------\r
 748 \r
 749         Vore_SetPreyPositions();\r
 750 \r
 751         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 752         if(self.fakeprey)\r
 753         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.stat_eaten)\r
 754                 Vore_DeadPrey_Detach(self);\r
 755 \r
 756         if(!self.stat_eaten)\r
 757                 return;\r
 758 \r
 759         if(self.deadflag != DEAD_NO)\r
 760         {\r
 761                 Vore_PreyRelease(self, FALSE);\r
 762                 return;\r
 763         }\r
 764 \r
 765         if(self.predator.deadflag != DEAD_NO)\r
 766                 Vore_Regurgitate(self);\r
 767         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 768                 Vore_Regurgitate(self);\r
 769 \r
 770         // apply delayed regurgitating if it was scheduled\r
 771         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 772         {\r
 773                 self.predator.regurgitate_prepare = 0;\r
 774                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 775                 Vore_Regurgitate(self);\r
 776         }\r
 777 \r
 778         // execute digesting and team healing\r
 779         if(self.predator.digesting == TRUE)\r
 780                 Vore_Digest();\r
 781         if(teams_matter && self.team == self.predator.team)\r
 782         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 783                 Vore_Teamheal();\r
 784 \r
 785         // execute prey commands\r
 786         if(self.BUTTON_ATCK && cvar("g_vore_kick"))\r
 787                 Vore_StomachKick();\r
 788         if(self.BUTTON_JUMP)\r
 789                 Vore_StomachLeave();\r
 790 \r
 791         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 792         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 793         kh_Key_DropAll(self, FALSE);\r
 794 }