data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(self.scale) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         vore_w_shotorg = self.origin;\r
  22         vore_w_shotdir = v_forward;\r
  23 \r
  24         WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  25         if(trace_fraction < 1)\r
  26         if(trace_ent.classname == "player")\r
  27                 return trace_ent;\r
  28         return world;\r
  29 }\r
  30 \r
  31 float Swallow_condition_check(entity prey)\r
  32 {\r
  33         // checks the necessary conditions for swallowing a player\r
  34 \r
  35         if(prey != self)\r
  36         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  37         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  38         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  39         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  40         {\r
  41                 string swallow_complain;\r
  42                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  43                         swallow_complain = "You cannot swallow your team mates\n";\r
  44                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  45                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  46                 else if(self.stomach_load >= g_balance_vore_swallow_limit)\r
  47                         swallow_complain = strcat("You cannot swallow more than ^2", ftos(g_balance_vore_swallow_limit), "^7 players at a time\n");\r
  48                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  49                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  50                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  51                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  52 \r
  53                 if(swallow_complain != "")\r
  54                 {\r
  55                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  56                         {\r
  57                                 play2(self, "misc/forbidden.wav");\r
  58                                 sprint(self, swallow_complain);\r
  59                                 self.complain_vore = time + complain_delay_time;\r
  60                         }\r
  61                         return FALSE;\r
  62                 }\r
  63                 return TRUE;\r
  64         }\r
  65         return FALSE;\r
  66 }\r
  67 \r
  68 float Stomach_TeamMates_check(entity pred)\r
  69 {\r
  70         // checks if a player's stomach contains any team mates\r
  71 \r
  72         entity head;\r
  73         if(teams_matter)\r
  74         {\r
  75                 FOR_EACH_PLAYER(head)\r
  76                 {\r
  77                         if(head.predator == pred && head.team == pred.team)\r
  78                                 return TRUE;\r
  79                 }\r
  80         }\r
  81         return FALSE;\r
  82 }\r
  83 \r
  84 float Vore_CanLeave()\r
  85 {\r
  86         if(self.stat_eaten)\r
  87         {\r
  88                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
  89                         return TRUE;\r
  90                 if(teams_matter && self.team == self.predator.team)\r
  91                         return TRUE;\r
  92                 if(g_rpg && cvar("g_rpg_canleave"))\r
  93                         return TRUE;\r
  94         }\r
  95         return FALSE;\r
  96 }\r
  97 \r
  98 // position the camera properly for prey\r
  99 void Vore_SetPreyPositions()\r
 100 {\r
 101         // self is the predator and head is the prey\r
 102 \r
 103         local entity head;\r
 104         local vector origin_apply;\r
 105         local float position_counter;\r
 106 \r
 107         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 108         // else all players overlap in the center. To do this, we run a loop on all players in the same stomach.\r
 109         // For each player, the origin is updated, then a new origin is used for the next player.\r
 110         // This requires that no more than 9 players may be in the stomach at a time!\r
 111         FOR_EACH_PLAYER(head)\r
 112         {\r
 113                 if(head.predator == self)\r
 114                 {\r
 115                         switch(position_counter)\r
 116                         {\r
 117                                 case 0:\r
 118                                         origin_apply = '0 0 0'; // first occupant sits in the middle\r
 119                                         break;\r
 120                                 case 1:\r
 121                                         origin_apply = '1 0 0'; // second occupant sits in the front\r
 122                                         break;\r
 123                                 case 2:\r
 124                                         origin_apply = '-1 0 0'; // third occupant sits in the back\r
 125                                         break;\r
 126                                 case 3:\r
 127                                         origin_apply = '0 1 0'; // fourth occupant sits in the right\r
 128                                         break;\r
 129                                 case 4:\r
 130                                         origin_apply = '0 -1 0'; // fifth occupant sits in the left\r
 131                                         break;\r
 132                                 case 5:\r
 133                                         origin_apply = '1 1 0'; // sixth occupant sits in the front-right\r
 134                                         break;\r
 135                                 case 6:\r
 136                                         origin_apply = '-1 1 0'; // seventh occupant sits in the back-right\r
 137                                         break;\r
 138                                 case 7:\r
 139                                         origin_apply = '1 -1 0'; // eigth occupant sits in the front-left\r
 140                                         break;\r
 141                                 case 8:\r
 142                                         origin_apply = '-1 -1 0'; // ninth occupant sits in the back-left\r
 143                                         break;\r
 144                                 default:\r
 145                                         break;\r
 146                         }\r
 147 \r
 148                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 149                         head.view_ofs = PL_PREY_VIEW_OFS + origin_apply * cvar("g_vore_neighborprey_distance");\r
 150                         head.view_ofs_z *= self.scale; // stomach center depends on predator scale\r
 151 \r
 152                         // change prey height based on scale\r
 153                         float prey_height;\r
 154                                 prey_height = (head.scale - self.scale) * cvar("g_healthsize_vore_pos");\r
 155                         head.view_ofs_z += prey_height;\r
 156 \r
 157                         position_counter += 1;\r
 158                 }\r
 159         }\r
 160 }\r
 161 \r
 162 .float gurgle_oldstomachload;\r
 163 void Vore_GurgleSound()\r
 164 {\r
 165         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 166         {\r
 167                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 168 \r
 169                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 170                 self.gurgle_oldstomachload = self.stomach_load;\r
 171         }\r
 172 }\r
 173 \r
 174 void Vore_WeightApply(entity e)\r
 175 {\r
 176         // apply stomach weight that makes you heavier the more you eat\r
 177         // slowing the player is done in cl_physics.qc\r
 178 \r
 179         if(e.stomach_load != e.vore_oldstomachload)\r
 180                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 181         if(e.gravity == 0)\r
 182                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 183         e.vore_oldstomachload = e.stomach_load;\r
 184 }\r
 185 \r
 186 void Vore_AutoDigest(entity e)\r
 187 {\r
 188         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 189 \r
 190         if(!cvar("g_vore_digestion") || e.digesting)\r
 191                 return;\r
 192         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 193                 return; // this feature is only for players, not bots\r
 194         if(e.stomach_load > 1)\r
 195                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 196         if(Stomach_TeamMates_check(e))\r
 197                 return; // never begin automatic digestion if we've swallowed a team mate\r
 198 \r
 199         e.digesting = TRUE;\r
 200 }\r
 201 \r
 202 .entity swallow_model;\r
 203 void Vore_SwallowModel_Think()\r
 204 {\r
 205         //update the position of the swallow model to match our swallow progress\r
 206         float dist;\r
 207         dist = (-0.5 + self.owner.swallow_progress_prey) * cvar("g_vore_swallowmodel_range"); // the model is centered at 0.5 progress\r
 208         if(cvar("g_healthsize"))\r
 209                 dist *= self.scale;\r
 210         self.view_ofs = '1 0 0' * dist;\r
 211 \r
 212         // if our swallow progress is gone or we are dead, the swallow model also goes away\r
 213         if(!self.owner.swallow_progress_prey || self.owner.deadflag != DEAD_NO || self.owner.classname != "player")\r
 214         {\r
 215                 remove(self.owner.swallow_model);\r
 216                 self.owner.swallow_model = world;\r
 217                 return;\r
 218         }\r
 219 \r
 220         // properties that should update whenever possible, but when the predator is not available\r
 221         self.alpha = self.owner.cvar_cl_vore_swallowmodel;\r
 222         self.nextthink = time;\r
 223 }\r
 224 \r
 225 void Vore_SwallowModel_Update(entity prey, entity pred)\r
 226 {\r
 227         // if we don't have a swallow model already, spawn one\r
 228         if(!prey.swallow_model)\r
 229         {\r
 230                 prey.swallow_model = spawn();\r
 231 \r
 232                 prey.swallow_model.movetype = MOVETYPE_FOLLOW;\r
 233                 prey.swallow_model.solid = SOLID_NOT;\r
 234 \r
 235                 // apply the properties of the prey\r
 236                 prey.swallow_model.viewmodelforclient = prey; // use the same system as the weapon model\r
 237                 //prey.swallow_model.effects |= EF_NOGUNBOB; // let it bob\r
 238                 prey.swallow_model.effects |= EF_NODEPTHTEST; // don't hide behind walls\r
 239                 prey.swallow_model.colormap = prey.colormap; // pants and shirt color\r
 240                 prey.swallow_model.glowmod = prey.glowmod; // glow color\r
 241 \r
 242                 prey.swallow_model.owner = prey; // owned by the prey\r
 243                 prey.swallow_model.think = Vore_SwallowModel_Think;\r
 244                 prey.swallow_model.nextthink = time;\r
 245         }\r
 246 \r
 247         // properties that should update whenever possible, but when the predator is available\r
 248         string player_swallowmodel;\r
 249         player_swallowmodel = strcat(substring(pred.playermodel, 0, strlen(pred.playermodel) - 4), "_swallow.md3"); // 4 is the extension length\r
 250         if(prey.swallow_model.model != player_swallowmodel) // player model can be changed while the predator is active\r
 251                 setmodel(prey.swallow_model, player_swallowmodel);\r
 252         if(prey.swallow_model.skin != pred.skin) // player skin can be changed while the predator is active\r
 253                 prey.swallow_model.skin = pred.skin;\r
 254         if(cvar("g_healthsize"))\r
 255                 prey.swallow_model.scale = pred.scale / prey.scale; // player size difference\r
 256         if(prey.swallow_model.enemy != pred)\r
 257                 prey.swallow_model.enemy = pred; // enemy is the predator\r
 258 }\r
 259 \r
 260 .entity pusher;\r
 261 .float pushltime;\r
 262 void Vore_Swallow(entity e)\r
 263 {\r
 264         // this player is being swallowed by another player, apply the proper changes\r
 265 \r
 266         e.vore_oldmovetype = e.movetype;\r
 267         e.vore_oldsolid = e.solid;\r
 268 \r
 269         e.predator = self;\r
 270         setorigin(e, e.predator.origin);\r
 271         e.velocity = '0 0 0';\r
 272         e.movetype = MOVETYPE_FOLLOW;\r
 273         e.solid = SOLID_NOT;\r
 274         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 275 \r
 276         // drop keys (KH) and flags (CTF) when we get swallowed\r
 277         kh_Key_DropAll(e, FALSE);\r
 278         if(e.flagcarried)\r
 279                 DropFlag(e.flagcarried, world, e.predator);\r
 280 \r
 281         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 282                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 283 \r
 284         if(teams_matter && e.team == e.predator.team)\r
 285         {\r
 286                 if(cvar("g_vore_kick"))\r
 287                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 288                 if(cvar("g_vore_digestion"))\r
 289                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 290         }\r
 291 \r
 292         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 293         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 294         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 295         e.predator.stomach_load += 1;\r
 296         e.predator.regurgitate_prepare = 0;\r
 297         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 298         Vore_WeightApply(e.predator);\r
 299         Vore_AutoDigest(e.predator);\r
 300 \r
 301         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 302         e.predator.weapon_delay = time + button_delay_time;\r
 303         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 304         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 305         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 306 }\r
 307 \r
 308 void Vore_SwallowStep(entity e)\r
 309 {\r
 310         if(!cvar("g_balance_vore_swallow_speed_fill"))\r
 311         {\r
 312                 Vore_Swallow(e);\r
 313                 return;\r
 314         }\r
 315 \r
 316         Vore_SwallowModel_Update(e, self);\r
 317 \r
 318         // increase the progress value until it reaches 1, then swallow the player\r
 319         if(e.swallow_progress_prey < 1)\r
 320         {\r
 321                 float fill;\r
 322                 fill = cvar("g_balance_vore_swallow_speed_fill") * frametime;\r
 323                 if(cvar("g_balance_vore_swallow_speed_fill_scalediff")) // fill rate depends on predator size compared to prey size\r
 324                         fill *= (self.scale / e.scale);\r
 325                 if(cvar("g_balance_vore_swallow_speed_fill_stomachload") && e.stomach_load) // fill rate is influenced by the prey's stomach load\r
 326                         fill /= e.stomach_load;\r
 327 \r
 328                 e.swallow_progress_prey += fill;\r
 329         }\r
 330         else\r
 331         {\r
 332                 Vore_Swallow(e);\r
 333                 e.swallow_progress_prey = 0;\r
 334         }\r
 335 \r
 336         // the predator's progress is how much the prey got swallowed\r
 337         self.swallow_progress_pred = e.swallow_progress_prey;\r
 338 }\r
 339 \r
 340 void Vore_Regurgitate(entity e)\r
 341 {\r
 342         // this player is being regurgitated by their predator, apply the proper changes\r
 343 \r
 344         e.movetype = e.vore_oldmovetype;\r
 345         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 346                 e.solid = e.vore_oldsolid;\r
 347         e.view_ofs_z = PL_VIEW_OFS_z;\r
 348 \r
 349         // apply velocities\r
 350         local vector oldforward, oldright, oldup;\r
 351         oldforward = v_forward;\r
 352         oldright = v_right;\r
 353         oldup = v_up;\r
 354         makevectors(e.predator.v_angle);\r
 355         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 356         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 357         v_forward = oldforward;\r
 358         v_right = oldright;\r
 359         v_up = oldup;\r
 360 \r
 361         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 362         e.pushltime = time + cvar("g_maxpushtime");\r
 363 \r
 364         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
 365         if(cvar("g_balance_vore_swallow_speed_fill") && cvar("g_balance_vore_regurgitate_swallowprogress"))\r
 366         {\r
 367                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
 368                 Vore_SwallowModel_Update(e, e.predator);\r
 369         }\r
 370 \r
 371         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 372         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 373         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 374         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 375         e.predator.stomach_load -= 1;\r
 376         e.predator.regurgitate_prepare = 0;\r
 377         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 378         Vore_WeightApply(e.predator);\r
 379 \r
 380         // block firing for a small amount of time, or we'll be firing the next frame\r
 381         e.weapon_delay = time + button_delay_time;\r
 382         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 383         e.predator = world;\r
 384 }\r
 385 \r
 386 void Vore_DeadPrey_Configure(entity e)\r
 387 {\r
 388         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 389 \r
 390         if(e.fakeprey || !e.stat_eaten) // we already configured everything\r
 391                 return;\r
 392 \r
 393         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 394         e.fakepredator = e.predator;\r
 395         e.fakeprey = TRUE;\r
 396 \r
 397         // first release the prey from the predator, as dead prey needs to be attached differently\r
 398         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 399         e.predator.stomach_load -= 1;\r
 400         Vore_WeightApply(e.predator);\r
 401         e.predator = world;\r
 402 \r
 403         // now put our dead prey inside the predator's stomach, but only as an effect\r
 404         e.movetype = MOVETYPE_FOLLOW;\r
 405         e.takedamage = DAMAGE_NO;\r
 406         e.solid = SOLID_NOT;\r
 407         e.aiment = e.fakepredator;\r
 408 }\r
 409 \r
 410 void Vore_DeadPrey_Detach(entity e)\r
 411 {\r
 412         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 413         // should only execute after Vore_DeadPrey_Configure has ran first\r
 414 \r
 415         if not(cvar("g_vore_keepdeadprey"))\r
 416                 return;\r
 417 \r
 418         e.fakepredator = world;\r
 419         e.fakeprey = TRUE; // keep fakeprey status\r
 420         e.stat_eaten = 0;\r
 421         e.aiment = world;\r
 422         e.movetype = MOVETYPE_TOSS;\r
 423 }\r
 424 \r
 425 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 426 {\r
 427         if(pred_disconnect)\r
 428         {\r
 429                 if(e.fakeprey)\r
 430                         Vore_DeadPrey_Detach(e);\r
 431                 else\r
 432                         Vore_Regurgitate(e);\r
 433         }\r
 434         else if(self.stat_eaten && !self.fakeprey)\r
 435         {\r
 436                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 437                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
 438                         Vore_DeadPrey_Configure(e);\r
 439                 else\r
 440                         Vore_Regurgitate(e);\r
 441         }\r
 442 }\r
 443 \r
 444 void Vore_Disconnect()\r
 445 {\r
 446         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 447 \r
 448         // prey disconnects or goes spectating while inside someone's belly\r
 449         if(self.stat_eaten)\r
 450                 Vore_PreyRelease(self, TRUE);\r
 451 \r
 452         // pred disconnects or goes spectating with players in their belly\r
 453         entity head;\r
 454         FOR_EACH_PLAYER(head)\r
 455         {\r
 456                 if(head.predator == self || head.fakepredator == self)\r
 457                         Vore_PreyRelease(head, TRUE);\r
 458         }\r
 459         Vore_GurgleSound(); // stop the gurgling sound\r
 460 \r
 461         self.stomach_load = self.gravity = 0; // prevents a bug\r
 462 }\r
 463 \r
 464 .float digestion_step;\r
 465 void Vore_Digest()\r
 466 {\r
 467         // apply digestion to prey\r
 468 \r
 469         if(time > self.digestion_step)\r
 470         {\r
 471                 // if distributed digestion is enabled, reduce digestion strength by the number of prey in our stomach\r
 472                 float reduce;\r
 473                 if(cvar("g_balance_vore_digestion_distribute"))\r
 474                         reduce = self.predator.stomach_load;\r
 475                 else\r
 476                         reduce = 1;\r
 477 \r
 478                 float damage;\r
 479                 damage = cvar("g_balance_vore_digestion_damage") / reduce;\r
 480 \r
 481                 // apply player scale to digestion damage\r
 482                 if(cvar("g_balance_vore_digestion_scalediff"))\r
 483                         damage *= (self.predator.scale / self.scale);\r
 484 \r
 485                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
 486                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 487                         self.predator.health += cvar("g_balance_vore_digestion_vampire") / reduce;\r
 488 \r
 489                 if (self.predator.digestsound_finished < time)\r
 490                 {\r
 491                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 492                         self.predator.digestsound_finished = time + 0.5;\r
 493                 }\r
 494                 self.digestion_step = time + steptime;\r
 495         }\r
 496 \r
 497         if(self.deadflag != DEAD_NO)\r
 498         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 499                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 500 }\r
 501 \r
 502 .float teamheal_step;\r
 503 void Vore_Teamheal()\r
 504 {\r
 505         // apply teamheal\r
 506 \r
 507         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 508         if(time > self.teamheal_step)\r
 509         {\r
 510                 self.health += cvar("g_balance_vore_teamheal");\r
 511                 self.teamheal_step = time + steptime;\r
 512 \r
 513                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 514                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 515                 {\r
 516                         play2(self, "misc/beep.wav");\r
 517                         play2(self.predator, "misc/beep.wav");\r
 518                 }\r
 519         }\r
 520 }\r
 521 \r
 522 .float kick_pressed;\r
 523 void Vore_StomachKick()\r
 524 {\r
 525         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 526 \r
 527         if(time > self.stomachkick_delay && !self.kick_pressed)\r
 528         {\r
 529                 float damage;\r
 530                 vector force;\r
 531                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 532                 force = v_forward * cvar("g_balance_vore_kick_force");\r
 533 \r
 534                 // apply player scale to the damage / force of the kick\r
 535                 if(cvar("g_balance_vore_kick_scalediff"))\r
 536                 {\r
 537                         damage *= (self.scale / self.predator.scale);\r
 538                         force *= (self.scale / self.predator.scale);\r
 539                 }\r
 540 \r
 541                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
 542                 sound(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), VOL_BASE, ATTN_NORM);\r
 543                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 544                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 545 \r
 546                 // abort the predator's scheduled regurgitation\r
 547                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
 548                         self.predator.regurgitate_prepare = 0;\r
 549 \r
 550                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 551                 if(cvar("g_balance_vore_kick_repress"))\r
 552                         self.kick_pressed = TRUE;\r
 553         }\r
 554 }\r
 555 \r
 556 void Vore_StomachLeave()\r
 557 {\r
 558         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 559 \r
 560         if(Vore_CanLeave())\r
 561                 Vore_Regurgitate(self);\r
 562         else if(time > self.complain_vore)\r
 563         {\r
 564                 play2(self, "misc/forbidden.wav");\r
 565                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 566                 self.complain_vore = time + complain_delay_time;\r
 567         }\r
 568 }\r
 569 \r
 570 void Vore_AutoTaunt()\r
 571 {\r
 572         // triggers ambient vore taunts, for both pred and prey\r
 573 \r
 574         float taunt_time;\r
 575 \r
 576         // predator taunts\r
 577         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 578         {\r
 579                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 580                 {\r
 581                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 582                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 583                 }\r
 584         }\r
 585         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 586         {\r
 587                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 588                 SetAutoTaunt(self, 0, 0);\r
 589         }\r
 590 \r
 591         // prey taunts\r
 592         if(self.stat_eaten && !(teams_matter && self.team == self.predator.team))\r
 593         {\r
 594                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 595                 {\r
 596                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 597                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 598                 }\r
 599         }\r
 600         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 601         {\r
 602                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 603                 SetAutoTaunt(self, 0, 0);\r
 604         }\r
 605 }\r
 606 \r
 607 void Vore_SetSbarRings()\r
 608 {\r
 609         // first clear the ring stats, then configure them if needed\r
 610         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 611         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 612 \r
 613         if(self.stat_eaten)\r
 614         {\r
 615                 if(time <= self.stomachkick_delay)\r
 616                 {\r
 617                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
 618                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 619                 }\r
 620         }\r
 621         else\r
 622         {\r
 623                 if(self.swallow_progress_pred)\r
 624                 {\r
 625                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
 626                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
 627                 }\r
 628                 else if(time <= self.action_delay)\r
 629                 {\r
 630                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
 631                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 632                 }\r
 633 \r
 634                 if(self.swallow_progress_prey)\r
 635                 {\r
 636                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
 637                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
 638                 }\r
 639                 else if(time <= self.regurgitate_prepare)\r
 640                 {\r
 641                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
 642                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 643                 }\r
 644         }\r
 645 }\r
 646 \r
 647 void Vore()\r
 648 {\r
 649         // main vore code, this is where it all happens\r
 650 \r
 651         if(!cvar("g_vore")) // the vore system is disabled\r
 652         {\r
 653                 Vore_Disconnect();\r
 654                 return;\r
 655         }\r
 656 \r
 657         Vore_AutoTaunt();\r
 658 \r
 659         // wash the goo away from players once they leave the stomach\r
 660         if(!self.stat_eaten)\r
 661         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 662         if(self.colormod)\r
 663         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 664         {\r
 665                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 666                 if(self.colormod_x > 1)\r
 667                         self.colormod_x = 1;\r
 668                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 669                 if(self.colormod_y > 1)\r
 670                         self.colormod_y = 1;\r
 671                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 672                 if(self.colormod_z > 1)\r
 673                         self.colormod_z = 1;\r
 674         }\r
 675 \r
 676         // set all vore stats\r
 677         Vore_SetSbarRings();\r
 678         if(self.fakepredator.classname == "player")\r
 679                 self.stat_eaten = num_for_edict(self.fakepredator);\r
 680         else if(self.predator.classname == "player")\r
 681         {\r
 682                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 683                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 684                 self.stat_eaten = num_for_edict(self.predator);\r
 685         }\r
 686         else\r
 687         {\r
 688                 self.stat_stomachload = self.stomach_load;\r
 689                 self.stat_digesting = self.digesting;\r
 690                 self.stat_eaten = 0;\r
 691         }\r
 692         self.stat_canleave = Vore_CanLeave();\r
 693 \r
 694         // don't allow a player inside a player inside another player :)\r
 695         // prevent this by checking if such has happened, and taking the proper measures\r
 696         // this code has a high priority and must not be stopped by any delay, so run it here\r
 697         if(self.predator.stat_eaten)\r
 698         {\r
 699                 entity target_predator, target_predator_predator, oldself;\r
 700                 target_predator = self.predator;\r
 701                 target_predator_predator = self.predator.predator;\r
 702 \r
 703                 Vore_Regurgitate(self);\r
 704 \r
 705                 // now steal our prey's prey if this probability applies\r
 706                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 707                 {\r
 708                         oldself = self;\r
 709                         self = target_predator_predator;\r
 710                         if(Swallow_condition_check(oldself))\r
 711                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 712                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 713                                 Vore_Swallow(oldself);\r
 714                         self = oldself;\r
 715                 }\r
 716         }\r
 717 \r
 718         // the swallow progress of prey and preds idly decrease by this amount\r
 719         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
 720         {\r
 721                 if(self.swallow_progress_pred)\r
 722                 {\r
 723                         self.swallow_progress_pred -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 724                         if(self.swallow_progress_pred < 0)\r
 725                                 self.swallow_progress_pred = 0;\r
 726                 }\r
 727                 if(self.swallow_progress_prey)\r
 728                 {\r
 729                         self.swallow_progress_prey -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 730                         if(self.swallow_progress_prey < 0)\r
 731                                 self.swallow_progress_prey = 0;\r
 732                 }\r
 733         }\r
 734 \r
 735         // apply delays and skip the vore system under some circumstances\r
 736         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 737         {\r
 738                 Vore_Disconnect();\r
 739                 return;\r
 740         }\r
 741         if(self.spectatee_status)\r
 742                 return;\r
 743         if(time < self.system_delay)\r
 744                 return;\r
 745 \r
 746 // --------------------------------\r
 747 // Code that addresses predators:\r
 748 // --------------------------------\r
 749 \r
 750         entity prey;\r
 751         prey = Swallow_player_check();\r
 752 \r
 753         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 754         self.stat_canswallow = 0;\r
 755         if(Swallow_condition_check(prey))\r
 756         {\r
 757                 // canswallow stat, used by the HUD\r
 758                 if(teams_matter && prey.team == self.team)\r
 759                         self.stat_canswallow = 2;\r
 760                 else\r
 761                         self.stat_canswallow = 1;\r
 762 \r
 763                 if(self.BUTTON_ATCK)\r
 764                         Vore_SwallowStep(prey);\r
 765         }\r
 766         else if(prey != world)\r
 767                 self.stat_canswallow = -1;\r
 768 \r
 769         // toggle digestion, if the player has someone in their stomach\r
 770         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 771         {\r
 772                 if(self.stomach_load)\r
 773                 {\r
 774                         if(time > self.digest_button_delay_time)\r
 775                         {\r
 776                                 self.digesting = !self.digesting;\r
 777                                 self.digest_button_delay_time = time + button_delay_time;\r
 778                         }\r
 779                 }\r
 780                 else if(time > self.complain_vore)\r
 781                 {\r
 782                         play2(self, "misc/forbidden.wav");\r
 783                         sprint(self, "There is nothing to digest\n");\r
 784                         self.complain_vore = time + complain_delay_time;\r
 785                 }\r
 786         }\r
 787         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 788                 self.digesting = FALSE;\r
 789 \r
 790         // predator wishes to regurgitate his prey\r
 791         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 792         {\r
 793                 if(self.stomach_load)\r
 794                 {\r
 795                         if(time > self.regurgitate_button_delay_time)\r
 796                         {\r
 797                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 798                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 799                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 800                         }\r
 801                 }\r
 802                 else if(time > self.complain_vore)\r
 803                 {\r
 804                         play2(self, "misc/forbidden.wav");\r
 805                         sprint(self, "There is nothing to regurgitate\n");\r
 806                         self.complain_vore = time + complain_delay_time;\r
 807                 }\r
 808         }\r
 809 \r
 810         if(cvar("g_vore_gurglesound"))\r
 811                 Vore_GurgleSound();\r
 812 \r
 813 // --------------------------------\r
 814 // Code that addresses the prey:\r
 815 // --------------------------------\r
 816 \r
 817         Vore_SetPreyPositions();\r
 818 \r
 819         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 820         if(self.fakeprey)\r
 821         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.stat_eaten)\r
 822                 Vore_DeadPrey_Detach(self);\r
 823 \r
 824         if(!self.stat_eaten)\r
 825                 return;\r
 826 \r
 827         if(self.deadflag != DEAD_NO)\r
 828         {\r
 829                 Vore_PreyRelease(self, FALSE);\r
 830                 return;\r
 831         }\r
 832 \r
 833         if(self.predator.deadflag != DEAD_NO)\r
 834                 Vore_Regurgitate(self);\r
 835         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 836                 Vore_Regurgitate(self);\r
 837 \r
 838         // apply delayed regurgitating if it was scheduled\r
 839         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 840         {\r
 841                 self.predator.regurgitate_prepare = 0;\r
 842                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 843                 Vore_Regurgitate(self);\r
 844         }\r
 845 \r
 846         // execute digesting and team healing\r
 847         if(self.predator.digesting == TRUE)\r
 848                 Vore_Digest();\r
 849         if(teams_matter && self.team == self.predator.team)\r
 850         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 851                 Vore_Teamheal();\r
 852 \r
 853         // execute prey commands\r
 854         if(self.BUTTON_ATCK)\r
 855         {\r
 856                 if(cvar("g_vore_kick"))\r
 857                         Vore_StomachKick();\r
 858         }\r
 859         else\r
 860                 self.kick_pressed = FALSE;\r
 861         if(self.BUTTON_JUMP)\r
 862                 Vore_StomachLeave();\r
 863 \r
 864         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 865         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 866         kh_Key_DropAll(self, FALSE);\r
 867 }