data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float system_delay, swallow_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         vector w_shotorg, w_shotdir;\r
  16         w_shotorg = self.origin + self.view_ofs;\r
  17         w_shotdir = v_forward;\r
  18 \r
  19         WarpZone_traceline_antilag(self, w_shotorg, w_shotorg + w_shotdir * cvar("g_balance_vore_swallow_range"), FALSE, self, ANTILAG_LATENCY(self));\r
  20         if(trace_fraction < 1)\r
  21         if(trace_ent.classname == "player")\r
  22                 return trace_ent;\r
  23         return world;\r
  24 }\r
  25 \r
  26 float Swallow_condition_check(entity prey)\r
  27 {\r
  28         // checks the necessary conditions for swallowing a player\r
  29 \r
  30         if(prey != self)\r
  31         if(prey.classname == "player" && prey.predator.classname != "player" && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  32         if(self.classname == "player" && self.predator.classname != "player" && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  33         if(!self.BUTTON_REGURGITATE && self.swallow_delay < time)\r
  34         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
  35         {\r
  36                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  37                 {\r
  38                         if(time > self.complain_vore)\r
  39                         {\r
  40                                 play2(self, "misc/unavailable.wav");\r
  41                                 sprint(self, "You cannot swallow your team mates\n");\r
  42                                 self.complain_vore = time + complain_delay_time;\r
  43                         }\r
  44                         return FALSE;\r
  45                 }\r
  46 \r
  47                 if(self.stomach_load >= cvar("g_balance_vore_swallow_limit"))\r
  48                 {\r
  49                         if(time > self.complain_vore)\r
  50                         {\r
  51                                 play2(self, "misc/unavailable.wav");\r
  52                                 sprint(self, strcat("You cannot swallow more than ^2", cvar_string("g_balance_vore_swallow_limit"), "^7 players at a time\n"));\r
  53                                 self.complain_vore = time + complain_delay_time;\r
  54                         }\r
  55                         return FALSE;\r
  56                 }\r
  57 \r
  58                 if(cvar("g_vore_biggergut"))\r
  59                 if(prey.stomach_load > self.stomach_load)\r
  60                 {\r
  61                         if(time > self.complain_vore)\r
  62                         {\r
  63                                 play2(self, "misc/unavailable.wav");\r
  64                                 sprint(self, "You cannot swallow someone with a bigger stomach than yours\n");\r
  65                                 self.complain_vore = time + complain_delay_time;\r
  66                         }\r
  67                         return FALSE;\r
  68                 }\r
  69 \r
  70                 return TRUE;\r
  71         }\r
  72         return FALSE;\r
  73 }\r
  74 \r
  75 float Vore_CanLeave()\r
  76 {\r
  77         if(self.predator.classname == "player")\r
  78         {\r
  79                 if(teams_matter && self.team == self.predator.team)\r
  80                         return TRUE;\r
  81                 if(g_rpg && cvar("g_rpg_canleave"))\r
  82                         return TRUE;\r
  83         }\r
  84         return FALSE;\r
  85 }\r
  86 \r
  87 // make the camera smoothly lower itself when we get swallowed\r
  88 // our aim is going from the normal view offset to half of the view offset (because half is the best positioning for the stomach model)\r
  89 .float cameraeffect_current, cameraeffect_target;\r
  90 void Vore_CameraEffect_Set(entity e)\r
  91 {\r
  92         e.cameraeffect_current = 1;\r
  93         e.cameraeffect_target = 2;\r
  94 }\r
  95 void Vore_CameraEffect_Apply()\r
  96 {\r
  97         if(self.predator.classname != "player")\r
  98                 return;\r
  99 \r
 100         if(self.cvar_cl_vore_cameraspeed)\r
 101         {\r
 102                 local float step;\r
 103                 step = self.cvar_cl_vore_cameraspeed * frametime;\r
 104 \r
 105                 // not sure if these maths are good, as the effect should be smoother\r
 106                 if(self.cameraeffect_current >= self.cameraeffect_target + step)\r
 107                         self.cameraeffect_current -= step;\r
 108                 else if(self.cameraeffect_current <= self.cameraeffect_target - step)\r
 109                         self.cameraeffect_current += step;\r
 110         }\r
 111         else\r
 112                 self.cameraeffect_current = self.cameraeffect_target;\r
 113 \r
 114         self.view_ofs_z = PL_VIEW_OFS_z / self.cameraeffect_current;\r
 115 }\r
 116 \r
 117 .float gurgle_oldstomachload;\r
 118 void Vore_Gurglesound()\r
 119 {\r
 120         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 121         {\r
 122                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 123 \r
 124                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 125                 self.gurgle_oldstomachload = self.stomach_load;\r
 126         }\r
 127 }\r
 128 \r
 129 void Vore_Weight_apply(entity e)\r
 130 {\r
 131         // apply stomach weight that makes you heavier the more you eat\r
 132         // slowing the player is done in cl_physics.qc\r
 133 \r
 134         if(e.stomach_load != e.vore_oldstomachload)\r
 135                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 136         if(e.gravity == 0)\r
 137                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 138         e.vore_oldstomachload = e.stomach_load;\r
 139 }\r
 140 \r
 141 .entity pusher;\r
 142 .float pushltime;\r
 143 void Vore_Swallow(entity e)\r
 144 {\r
 145         // this player is being swallowed by another player, apply the proper changes\r
 146 \r
 147         e.vore_oldmovetype = e.movetype;\r
 148         e.vore_oldsolid = e.solid;\r
 149 \r
 150         e.predator = self;\r
 151         setorigin(e, e.predator.origin);\r
 152         e.velocity = '0 0 0';\r
 153         e.movetype = MOVETYPE_FOLLOW;\r
 154         e.solid = SOLID_NOT;\r
 155         e.alpha = -1; // best way of hiding the eaten player\r
 156         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 157 \r
 158         // drop keys (KH) and flags (CTF) when we get swallowed\r
 159         kh_Key_DropAll(e, FALSE);\r
 160         if(e.flagcarried)\r
 161                 DropFlag(e.flagcarried, world, e.predator);\r
 162 \r
 163         Vore_CameraEffect_Set(e);\r
 164 \r
 165         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 166                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 167 \r
 168         if(teams_matter && e.team == e.predator.team)\r
 169         {\r
 170                 centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 171                 centerprint(e.predator, "^3You have swallowed a team mate, use caution!");\r
 172         }\r
 173 \r
 174         PlayerSound(e.predator, playersound_swallow, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 175         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 176         e.predator.punchangle_x -= e.predator.cvar_cl_vore_punchangle;\r
 177         e.predator.stomach_load += 1;\r
 178         e.predator.regurgitate_prepare = 0;\r
 179         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 180         Vore_Weight_apply(e.predator);\r
 181 \r
 182         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 183         e.predator.weapon_delay = time + button_delay_time;\r
 184         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 185         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 186 }\r
 187 \r
 188 void Vore_Regurgitate(entity e)\r
 189 {\r
 190         // this player is being regurgitated by their predator, apply the proper changes\r
 191 \r
 192         e.movetype = e.vore_oldmovetype;\r
 193         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 194                 e.solid = e.vore_oldsolid;\r
 195         e.view_ofs_z = PL_VIEW_OFS_z;\r
 196         e.alpha = default_player_alpha;\r
 197 \r
 198         // apply velocities\r
 199         local vector oldforward, oldright, oldup;\r
 200         oldforward = v_forward;\r
 201         oldright = v_right;\r
 202         oldup = v_up;\r
 203         makevectors(e.predator.v_angle);\r
 204         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 205         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 206         v_forward = oldforward;\r
 207         v_right = oldright;\r
 208         v_up = oldup;\r
 209 \r
 210         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 211         e.pushltime = time + cvar("g_maxpushtime");\r
 212 \r
 213         PlayerSound(e.predator, playersound_regurgitate, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 214         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 215         pointparticles(particleeffectnum("regurgitate"), e.predator.origin, '0 0 0', 1);\r
 216         e.predator.punchangle_x += e.predator.cvar_cl_vore_punchangle;\r
 217         e.predator.stomach_load -= 1;\r
 218         e.predator.regurgitate_prepare = 0;\r
 219         e.predator.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 220         Vore_Weight_apply(e.predator);\r
 221 \r
 222         // block firing for a small amount of time, or we'll be firing the next frame\r
 223         e.weapon_delay = time + button_delay_time;\r
 224         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 225         e.predator = world;\r
 226 }\r
 227 \r
 228 void Vore_Disconnect()\r
 229 {\r
 230         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 231 \r
 232         // prey disconnects or goes spectating while inside someone's belly\r
 233         if(self.predator.classname == "player")\r
 234                 Vore_Regurgitate(self);\r
 235 \r
 236         // pred disconnects or goes spectating with players in their belly\r
 237         else if(self.stomach_load > 0)\r
 238         {\r
 239                 entity head;\r
 240                 FOR_EACH_PLAYER(head)\r
 241                 {\r
 242                         if(head.predator == self)\r
 243                                 Vore_Regurgitate(head);\r
 244                 }\r
 245                 Vore_Gurglesound(); // stop the gurgling sound\r
 246         }\r
 247 \r
 248         self.stomach_load = self.gravity = 0; // prevents a bug\r
 249 }\r
 250 \r
 251 .float digestion_step;\r
 252 void Vore_Digest()\r
 253 {\r
 254         // apply digestion to prey\r
 255 \r
 256         if(!cvar("g_vore_digestion"))\r
 257                 return;\r
 258 \r
 259         if(time > self.predator.digestion_step)\r
 260         {\r
 261                 Damage(self, self.predator, self.predator, cvar("g_balance_vore_digestion_damage"), DEATH_DIGESTION, self.origin, '0 0 0');\r
 262                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 263                         self.predator.health += cvar("g_balance_vore_digestion_vampire");\r
 264 \r
 265                 if (self.predator.digestsound_finished < time)\r
 266                 {\r
 267                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 268                         self.predator.digestsound_finished = time + 0.5;\r
 269                 }\r
 270                 self.predator.digestion_step = time + steptime;\r
 271         }\r
 272 \r
 273         if(self.health <= 0)\r
 274         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 275                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 276 }\r
 277 \r
 278 .float teamheal_step;\r
 279 void Vore_Teamheal()\r
 280 {\r
 281         // apply teamheal\r
 282 \r
 283         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 284         if(time > self.teamheal_step)\r
 285         {\r
 286                 self.health += cvar("g_balance_vore_teamheal");\r
 287                 self.teamheal_step = time + steptime;\r
 288         }\r
 289 }\r
 290 \r
 291 .float stomachkick_delay;\r
 292 void Vore_StomachKick()\r
 293 {\r
 294         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 295 \r
 296         if(!cvar("g_vore_kick"))\r
 297                 return;\r
 298 \r
 299         if(time > self.stomachkick_delay)\r
 300         {\r
 301                 float damage;\r
 302                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 303                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, v_forward * cvar("g_balance_vore_kick_force"));\r
 304                 sound(self.predator, CHAN_PROJECTILE, "weapons/stomachkick.ogg", VOL_BASE, ATTN_NORM);\r
 305 \r
 306                 if(random() < cvar("g_balance_vore_kick_escapeprobability"))\r
 307                         Vore_Regurgitate(self);\r
 308 \r
 309                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 310         }\r
 311 }\r
 312 \r
 313 void Vore_StomachLeave()\r
 314 {\r
 315         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 316 \r
 317         if(Vore_CanLeave())\r
 318                 Vore_Regurgitate(self);\r
 319         else if(time > self.complain_vore)\r
 320         {\r
 321                 play2(self, "misc/unavailable.wav");\r
 322                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 323                 self.complain_vore = time + complain_delay_time;\r
 324         }\r
 325 }\r
 326 \r
 327 void Vore()\r
 328 {\r
 329         // main vore code, this is where it all happens\r
 330 \r
 331         if(!cvar("g_vore")) // the vore system is disabled\r
 332         {\r
 333                 Vore_Disconnect();\r
 334                 return;\r
 335         }\r
 336 \r
 337         // set all vore related stats\r
 338         if(self.predator.classname == "player")\r
 339         {\r
 340                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 341                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 342                 self.stat_eaten = num_for_edict(self.predator);\r
 343         }\r
 344         else\r
 345         {\r
 346                 self.stat_stomachload = self.stomach_load;\r
 347                 self.stat_digesting = self.digesting;\r
 348                 self.stat_eaten = 0;\r
 349         }\r
 350         self.stat_canleave = Vore_CanLeave();\r
 351 \r
 352         // don't allow a player inside a player inside another player :)\r
 353         // prevent this by checking if such has happened, and taking the proper measures\r
 354         // this code has a high priority and must not be stopped by any delay, so run it here\r
 355         if(self.predator.predator.classname == "player")\r
 356         {\r
 357                 entity target_predator, target_predator_predator, oldself;\r
 358                 target_predator = self.predator;\r
 359                 target_predator_predator = self.predator.predator;\r
 360 \r
 361                 Vore_Regurgitate(self);\r
 362 \r
 363                 // now steal our prey's prey if this probability applies\r
 364                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 365                 {\r
 366                         oldself = self;\r
 367                         self = target_predator_predator;\r
 368                         if(Swallow_condition_check(oldself))\r
 369                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 370                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 371                                 Vore_Swallow(oldself);\r
 372                         self = oldself;\r
 373                 }\r
 374         }\r
 375 \r
 376         // apply delays and skip the vore system under some circumstances\r
 377         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 378         {\r
 379                 Vore_Disconnect();\r
 380                 return;\r
 381         }\r
 382         if(self.spectatee_status)\r
 383                 return;\r
 384         if(time < self.system_delay)\r
 385                 return;\r
 386 \r
 387 // --------------------------------\r
 388 // Code that addresses predators:\r
 389 // --------------------------------\r
 390 \r
 391         entity prey;\r
 392         prey = Swallow_player_check();\r
 393 \r
 394         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 395         if(self.BUTTON_ATCK)\r
 396         if(Swallow_condition_check(prey))\r
 397                 Vore_Swallow(prey);\r
 398 \r
 399         // toggle digestion, if the player has someone in their stomach\r
 400         if(self.BUTTON_DIGEST)\r
 401         {\r
 402                 if(self.stomach_load)\r
 403                 {\r
 404                         if(time > self.digest_button_delay_time)\r
 405                         {\r
 406                                 self.digesting = !self.digesting;\r
 407                                 self.digest_button_delay_time = time + button_delay_time;\r
 408                         }\r
 409                 }\r
 410                 else if(time > self.complain_vore)\r
 411                 {\r
 412                         play2(self, "misc/unavailable.wav");\r
 413                         sprint(self, "There is nothing to digest\n");\r
 414                         self.complain_vore = time + complain_delay_time;\r
 415                 }\r
 416         }\r
 417         if(!self.stomach_load)\r
 418                 self.digesting = FALSE;\r
 419 \r
 420         // predator wishes to regurgitate his prey\r
 421         if(self.BUTTON_REGURGITATE)\r
 422         {\r
 423                 if(self.stomach_load)\r
 424                 {\r
 425                         if(time > self.regurgitate_button_delay_time)\r
 426                         {\r
 427                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 428                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 429                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 430                         }\r
 431                 }\r
 432                 else if(time > self.complain_vore)\r
 433                 {\r
 434                         play2(self, "misc/unavailable.wav");\r
 435                         sprint(self, "There is nothing to regurgitate\n");\r
 436                         self.complain_vore = time + complain_delay_time;\r
 437                 }\r
 438         }\r
 439 \r
 440         if(cvar("g_vore_gurglesound"))\r
 441                 Vore_Gurglesound();\r
 442 \r
 443 // --------------------------------\r
 444 // Code that addresses the prey:\r
 445 // --------------------------------\r
 446 \r
 447         if(self.predator.classname != "player")\r
 448                 return;\r
 449 \r
 450         if(self.deadflag || self.predator.deadflag)\r
 451                 Vore_Regurgitate(self);\r
 452         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap"))\r
 453                 Vore_Regurgitate(self);\r
 454 \r
 455         // apply delayed regurgitating if it was scheduled\r
 456         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 457         {\r
 458                 self.predator.regurgitate_prepare = 0;\r
 459                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 460                 Vore_Regurgitate(self);\r
 461         }\r
 462 \r
 463         // execute digesting and team healing\r
 464         if(self.predator.digesting == TRUE)\r
 465                 Vore_Digest();\r
 466         if(teams_matter && self.team == self.predator.team)\r
 467         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 468                 Vore_Teamheal();\r
 469 \r
 470         // execute prey commands\r
 471         if(self.BUTTON_ATCK)\r
 472                 Vore_StomachKick();\r
 473         if(self.BUTTON_JUMP)\r
 474                 Vore_StomachLeave();\r
 475 \r
 476         Vore_CameraEffect_Apply();\r
 477 }