Code for my last commit
[voretournament/voretournament.git] / data / qcsrc / server / w_grabber.qc
1 #ifdef REGISTER_WEAPON\r
2 REGISTER_WEAPON(GRABBER, w_grabber, IT_FUEL, 0, WEP_FLAG_CANCLIMB | WEP_TYPE_HITSCAN | WEP_FLAG_RELOADABLE, 0, "grabber", "grabber", "Grabber");\r
3 #else\r
4 .float dmg;\r
5 .float dmg_edge;\r
6 .float dmg_radius;\r
7 .float dmg_force;\r
8 .float grabber_refire;\r
9 .float grabber_time_grabbered;\r
10 .float grabber_time_fueldecrease;\r
11 \r
12 void W_Grabber_UpdateStats(entity e, float shot, float hit)\r
13 {\r
14         // this may not be entierly right, but for the time being we're handling grabber accuracy here\r
15         // this is likely needed for detecting if the hook has hit (linked to) another player, which is counted as a hit\r
16         if(shot)\r
17         {\r
18                 e.stats_fired[e.weapon - 1] += 1;\r
19                 e.stat_fired = e.weapon + 64 * floor(e.stats_fired[e.weapon - 1]);\r
20         }\r
21         if(hit)\r
22         {\r
23                 e.stats_hit[e.weapon - 1] += 1;\r
24                 e.stat_hit = e.weapon + 64 * floor(e.stats_hit[e.weapon - 1]);\r
25         }\r
26 }\r
27 \r
28 void W_Grabber_Touch2 (void)\r
29 {\r
30         PROJECTILE_TOUCH;\r
31         self.use();\r
32 }\r
33 \r
34 void W_Grabber_Attack2()\r
35 {\r
36         if(time < self.weapon_delay)\r
37                 return;\r
38 \r
39         W_SetupShot (self, TRUE, 0, "weapons/grabber_altfire.wav", cvar("g_balance_grabber_secondary_damage"));\r
40         W_Grabber_UpdateStats(self, TRUE, FALSE); // the hit is recorded below\r
41 \r
42         WarpZone_traceline_antilag(self, w_shotorg, w_shotorg + w_shotdir * cvar("g_balance_grabber_secondary_radius"), FALSE, self, ANTILAG_LATENCY(self));\r
43 \r
44         pointparticles(particleeffectnum("grabber_melee"), w_shotorg + w_shotdir * cvar("g_balance_grabber_secondary_radius"), '0 0 0', 1);\r
45 \r
46         if (trace_fraction < 1)\r
47         {\r
48                 Damage(trace_ent, self, self, cvar("g_balance_grabber_secondary_damage"), WEP_GRABBER | HITTYPE_SECONDARY, trace_endpos, cvar("g_balance_grabber_secondary_force") * w_shotdir);\r
49                 pointparticles(particleeffectnum("grabber_impact2"), trace_endpos, '0 0 0', 1);\r
50                 if(trace_ent.classname == "player")\r
51                         sound (self, CHAN_PROJECTILE, "weapons/grabber_impact2_player.wav", VOL_BASE, ATTN_NORM);\r
52                 else\r
53                         sound (self, CHAN_PROJECTILE, "weapons/grabber_impact2_world.wav", VOL_BASE, ATTN_NORM);\r
54 \r
55                 W_Grabber_UpdateStats(self, FALSE, TRUE); // the shot is recorded above\r
56         }\r
57 \r
58         if (!g_norecoil)\r
59                 self.punchangle_x -= cvar("g_balance_grabber_secondary_recoil");\r
60 \r
61         W_DecreaseAmmo(ammo_fuel, cvar("g_balance_grabber_secondary_ammo"), cvar("g_balance_grabber_reload_ammo"));\r
62 }\r
63 \r
64 void spawnfunc_weapon_grabber (void)\r
65 {\r
66         weapon_defaultspawnfunc(WEP_GRABBER);\r
67 }\r
68 \r
69 float w_grabber(float req)\r
70 {\r
71         if(self.stat_eaten) // we can't use weapons while in the stomach\r
72         {\r
73                 self.grabber_state |= GRABBER_REMOVING;\r
74                 return FALSE;\r
75         }\r
76 \r
77         float ammo_amount;\r
78         float grabbered_time_max, grabbered_fuel;\r
79                 \r
80         if (req == WR_AIM)\r
81         {\r
82                 // ... sorry ...\r
83         }\r
84         else if (req == WR_THINK)\r
85         {\r
86                 grabbered_fuel = cvar("g_balance_grabber_primary_grabbered_fuel");\r
87                 // forced reload\r
88                 if(cvar("g_balance_grabber_reload_ammo") && self.clip_load < min(cvar("g_balance_grabber_primary_ammo"), cvar("g_balance_grabber_secondary_ammo"))\r
89                 && !(self.clip_load >= (time - self.grabber_time_fueldecrease) * grabbered_fuel && self.BUTTON_ATCK)) // not while hooked and still have ammo to stay hooked\r
90                 {\r
91                         if(self.ammo_fuel >= 1) // we only have one weapon in VT, so nothing else to switch to if we're out of ammo\r
92                                 weapon_action(self.weapon, WR_RELOAD);\r
93                 }\r
94                 else if not(self.clip_load < 0) // we're not currently reloading\r
95                 {\r
96                         if (self.BUTTON_ATCK && weapon_action(self.weapon, WR_CHECKAMMO1))\r
97                         {\r
98                                 if(time < self.weapon_delay)\r
99                                         return FALSE;\r
100 \r
101                                 if(!self.grabber)\r
102                                 if not(self.grabber_state & GRABBER_WAITING_FOR_RELEASE)\r
103                                 if not(self.grabber_state & GRABBER_FIRING)\r
104                                 if (time > self.grabber_refire)\r
105                                 if (weapon_prepareattack(0, -1))\r
106                                 {\r
107                                         if (!g_norecoil)\r
108                                                 self.punchangle_x -= cvar("g_balance_grabber_primary_recoil");\r
109                                         W_DecreaseAmmo(ammo_fuel, cvar("g_balance_grabber_primary_ammo"), cvar("g_balance_grabber_reload_ammo"));\r
110                                         self.grabber_state |= GRABBER_FIRING;\r
111                                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_grabber_primary_animtime"), w_ready);                               \r
112                                 }\r
113                         }\r
114                         if (self.BUTTON_ATCK2 && weapon_action(self.weapon, WR_CHECKAMMO2))\r
115                         {\r
116                                 if (weapon_prepareattack(1, cvar("g_balance_grabber_secondary_refire")))\r
117                                 {\r
118                                         W_Grabber_Attack2();\r
119                                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_grabber_secondary_animtime"), w_ready);\r
120                                         sound (self, CHAN_WEAPON2, "weapons/grabber_swing.wav", VOL_BASE, ATTN_NORM);\r
121                                 }\r
122                         }\r
123                 }\r
124 \r
125                 if(self.grabber)\r
126                 {\r
127                         // if grabbered, no melee attacks, and increase the timer\r
128                         self.grabber_refire = max(self.grabber_refire, time + cvar("g_balance_grabber_primary_refire"));\r
129 \r
130                         // grabber also inhibits health regeneration, but only for 1 second\r
131                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)\r
132                                 self.pauseregenhealth_finished = max(self.pauseregenhealth_finished, time + cvar("g_balance_pause_fuel_regen"));\r
133                 }\r
134 \r
135                 if(self.grabber && self.grabber.state == 1)\r
136                 {\r
137                         grabbered_time_max = cvar("g_balance_grabber_primary_grabbered_time_max");                      \r
138                         if (grabbered_time_max > 0)\r
139                         {\r
140                                 if ( time > self.grabber_time_grabbered + grabbered_time_max )\r
141                                         self.grabber_state |= GRABBER_REMOVING;\r
142                         }\r
143 \r
144                         if (grabbered_fuel > 0)\r
145                         {\r
146                                 if ( time > self.grabber_time_fueldecrease )\r
147                                 {\r
148                                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)\r
149                                         {\r
150                                                 float active_ammo;\r
151                                                 if(cvar("g_balance_grabber_reload_ammo"))\r
152                                                         active_ammo = self.clip_load;\r
153                                                 else\r
154                                                         active_ammo = self.ammo_fuel;\r
155 \r
156                                                 if (active_ammo >= (time - self.grabber_time_fueldecrease) * grabbered_fuel )\r
157                                                 {\r
158                                                         W_DecreaseAmmo(ammo_fuel, (time - self.grabber_time_fueldecrease) * grabbered_fuel, cvar("g_balance_grabber_reload_ammo"));\r
159                                                         self.grabber_time_fueldecrease = time;\r
160                                                         // decrease next frame again\r
161                                                 }\r
162                                                 else\r
163                                                 {\r
164                                                         self.grabber_state |= GRABBER_REMOVING;\r
165                                                         W_SwitchWeapon_Force(self, w_getbestweapon(self));\r
166                                                 }\r
167                                         }\r
168                                 }\r
169                         }\r
170                 }\r
171                 else\r
172                 {\r
173                         self.grabber_time_grabbered = time;                             \r
174                         self.grabber_time_fueldecrease = time + cvar("g_balance_grabber_primary_grabbered_time_free");\r
175                 }\r
176 \r
177                 if (self.BUTTON_CROUCH)\r
178                 {\r
179                         self.grabber_state &~= GRABBER_PULLING;\r
180                         if (self.BUTTON_ATCK)\r
181                                 self.grabber_state &~= GRABBER_RELEASING;\r
182                         else\r
183                                 self.grabber_state |= GRABBER_RELEASING;\r
184                 }\r
185                 else\r
186                 {\r
187                         self.grabber_state |= GRABBER_PULLING;\r
188                         self.grabber_state &~= GRABBER_RELEASING;\r
189 \r
190                         if (self.BUTTON_ATCK)\r
191                         {\r
192                                 // already fired\r
193                                 if(self.grabber)\r
194                                         self.grabber_state |= GRABBER_WAITING_FOR_RELEASE;\r
195                         }\r
196                         else\r
197                         {\r
198                                 self.grabber_state |= GRABBER_REMOVING;\r
199                                 self.grabber_state &~= GRABBER_WAITING_FOR_RELEASE;\r
200                         }\r
201                 }\r
202         }\r
203         else if (req == WR_PRECACHE)\r
204         {\r
205                 precache_model ("models/weapons/g_grabber.md3");\r
206                 precache_model ("models/weapons/v_grabber.md3");\r
207                 precache_model ("models/weapons/h_grabber.iqm");\r
208                 precache_sound ("weapons/grabber_impact_player.wav");\r
209                 precache_sound ("weapons/grabber_impact_world.wav");\r
210                 precache_sound ("weapons/grabber_impact2_player.wav");\r
211                 precache_sound ("weapons/grabber_impact2_world.wav");\r
212                 precache_sound ("weapons/grabber_fire.wav");\r
213                 precache_sound ("weapons/grabber_altfire.wav");\r
214                 precache_sound ("weapons/grabber_swing.wav");\r
215                 precache_sound ("weapons/reload.wav");\r
216         }\r
217         else if (req == WR_SETUP)\r
218         {\r
219                 weapon_setup(WEP_GRABBER);\r
220                 self.grabber_state &~= GRABBER_WAITING_FOR_RELEASE;\r
221                 self.current_ammo = ammo_fuel;\r
222         }\r
223         else if (req == WR_CHECKAMMO1)\r
224         {\r
225                 if(self.grabber)\r
226                 {\r
227                         ammo_amount = self.ammo_fuel > 0;\r
228                         ammo_amount += self.weapon_load[WEP_GRABBER] > 0;\r
229                 }\r
230                 else\r
231                 {\r
232                         ammo_amount = self.ammo_fuel >= cvar("g_balance_grabber_primary_ammo");\r
233                         ammo_amount += self.weapon_load[WEP_GRABBER] >= cvar("g_balance_grabber_primary_ammo");\r
234                 }\r
235                 return ammo_amount;\r
236         }\r
237         else if (req == WR_CHECKAMMO2)\r
238         {\r
239                 ammo_amount = self.ammo_fuel >= cvar("g_balance_grabber_secondary_ammo");\r
240                 ammo_amount += self.weapon_load[WEP_GRABBER] >= cvar("g_balance_grabber_secondary_ammo");\r
241                 return ammo_amount;\r
242         }\r
243         else if (req == WR_RELOAD)\r
244         {\r
245                 self.grabber_state |= GRABBER_REMOVING;\r
246                 W_Reload(min(cvar("g_balance_grabber_primary_ammo"), cvar("g_balance_grabber_secondary_ammo")), cvar("g_balance_grabber_reload_ammo"), cvar("g_balance_grabber_reload_time"), "weapons/reload.wav");\r
247         }\r
248         else if (req == WR_SUICIDEMESSAGE)\r
249                 w_deathtypestring = "did the impossible";\r
250         else if (req == WR_KILLMESSAGE)\r
251                 w_deathtypestring = "has run into #'s paws";\r
252         else if (req == WR_RESETPLAYER)\r
253         {\r
254                 self.grabber_refire = time;\r
255         }\r
256         return TRUE;\r
257 };\r
258 #endif\r