Fix an issue with forced reloading. It shouldn't force reload while you are hooked...
[voretournament/voretournament.git] / data / qcsrc / server / w_grabber.qc
1 #ifdef REGISTER_WEAPON\r
2 REGISTER_WEAPON(GRABBER, w_grabber, IT_FUEL, 0, WEP_FLAG_CANCLIMB | WEP_TYPE_HITSCAN | WEP_FLAG_RELOADABLE, 0, "grabber", "grabber", "Grabber");\r
3 #else\r
4 .float dmg;\r
5 .float dmg_edge;\r
6 .float dmg_radius;\r
7 .float dmg_force;\r
8 .float grabber_refire;\r
9 .float grabber_time_grabbered;\r
10 .float grabber_time_fueldecrease;\r
11 \r
12 void W_Grabber_UpdateStats(entity e, float shot, float hit)\r
13 {\r
14         // this may not be entierly right, but for the time being we're handling grabber accuracy here\r
15         // this is likely needed for detecting if the hook has hit (linked to) another player, which is counted as a hit\r
16         if(shot)\r
17         {\r
18                 e.stats_fired[e.weapon - 1] += 1;\r
19                 e.stat_fired = e.weapon + 64 * floor(e.stats_fired[e.weapon - 1]);\r
20         }\r
21         if(hit)\r
22         {\r
23                 e.stats_hit[e.weapon - 1] += 1;\r
24                 e.stat_hit = e.weapon + 64 * floor(e.stats_hit[e.weapon - 1]);\r
25         }\r
26 }\r
27 \r
28 void W_Grabber_Touch2 (void)\r
29 {\r
30         PROJECTILE_TOUCH;\r
31         self.use();\r
32 }\r
33 \r
34 void W_Grabber_Attack2()\r
35 {\r
36         if(time < self.weapon_delay)\r
37                 return;\r
38 \r
39         W_SetupShot (self, TRUE, 0, "weapons/grabber_altfire.wav", cvar("g_balance_grabber_secondary_damage"));\r
40         W_Grabber_UpdateStats(self, TRUE, FALSE); // the hit is recorded below\r
41 \r
42         WarpZone_traceline_antilag(self, w_shotorg, w_shotorg + w_shotdir * cvar("g_balance_grabber_secondary_radius"), FALSE, self, ANTILAG_LATENCY(self));\r
43 \r
44         pointparticles(particleeffectnum("grabber_melee"), w_shotorg + w_shotdir * cvar("g_balance_grabber_secondary_radius"), '0 0 0', 1);\r
45 \r
46         if (trace_fraction < 1)\r
47         {\r
48                 Damage(trace_ent, self, self, cvar("g_balance_grabber_secondary_damage"), WEP_GRABBER | HITTYPE_SECONDARY, trace_endpos, cvar("g_balance_grabber_secondary_force") * w_shotdir);\r
49                 W_Grabber_UpdateStats(self, FALSE, TRUE); // the shot is recorded above\r
50         }\r
51 \r
52         W_DecreaseAmmo(ammo_fuel, cvar("g_balance_grabber_secondary_ammo"), cvar("g_balance_grabber_reload_ammo"));\r
53 }\r
54 \r
55 void spawnfunc_weapon_grabber (void)\r
56 {\r
57         weapon_defaultspawnfunc(WEP_GRABBER);\r
58 }\r
59 \r
60 float w_grabber(float req)\r
61 {\r
62         if(self.predator.classname == "player") // we can't use weapons while in the stomach\r
63         {\r
64                 self.grabber_state |= GRABBER_REMOVING;\r
65                 return FALSE;\r
66         }\r
67 \r
68         float ammo_amount;\r
69         float grabbered_time_max, grabbered_fuel;\r
70                 \r
71         if (req == WR_AIM)\r
72         {\r
73                 // ... sorry ...\r
74         }\r
75         else if (req == WR_THINK)\r
76         {\r
77                 grabbered_fuel = cvar("g_balance_grabber_primary_grabbered_fuel");\r
78                 // forced reload\r
79                 if(cvar("g_balance_grabber_reload_ammo") && self.clip_load < min(cvar("g_balance_grabber_primary_ammo"), cvar("g_balance_grabber_secondary_ammo"))\r
80                 && !(self.clip_load >= (time - self.grabber_time_fueldecrease) * grabbered_fuel && self.BUTTON_ATCK)) // not while hooked and still have ammo to stay hooked\r
81                 {\r
82                         if(self.ammo_fuel >= 1) // we only have one weapon in VT, so nothing else to switch to if we're out of ammo\r
83                                 weapon_action(self.weapon, WR_RELOAD);\r
84                 }\r
85                 else if (self.BUTTON_ATCK || (!(self.items & IT_JETPACK) && self.BUTTON_JETPACK))\r
86                 {\r
87                         if(time < self.weapon_delay)\r
88                                 return FALSE;\r
89 \r
90                         if(!self.grabber)\r
91                         if not(self.grabber_state & GRABBER_WAITING_FOR_RELEASE)\r
92                         if not(self.grabber_state & GRABBER_FIRING)\r
93                         if (time > self.grabber_refire)\r
94                         if (weapon_prepareattack(0, -1))\r
95                         {\r
96                                 W_DecreaseAmmo(ammo_fuel, cvar("g_balance_grabber_primary_ammo"), cvar("g_balance_grabber_reload_ammo"));\r
97                                 self.grabber_state |= GRABBER_FIRING;\r
98                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_grabber_primary_animtime"), w_ready);                               \r
99                         }\r
100                 }\r
101                 else if (self.BUTTON_ATCK2)\r
102                 {\r
103                         if (weapon_prepareattack(1, cvar("g_balance_grabber_secondary_refire")))\r
104                         {\r
105                                 W_Grabber_Attack2();\r
106                                 weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_grabber_secondary_animtime"), w_ready);\r
107                         }\r
108                 }\r
109 \r
110                 if(self.grabber)\r
111                 {\r
112                         // if grabbered, no melee attacks, and increase the timer\r
113                         self.grabber_refire = max(self.grabber_refire, time + cvar("g_balance_grabber_primary_refire"));\r
114 \r
115                         // grabber also inhibits health regeneration, but only for 1 second\r
116                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)\r
117                                 self.pauseregenhealth_finished = max(self.pauseregenhealth_finished, time + cvar("g_balance_pause_fuel_regen"));\r
118                 }\r
119 \r
120                 if(self.grabber && self.grabber.state == 1)\r
121                 {\r
122                         grabbered_time_max = cvar("g_balance_grabber_primary_grabbered_time_max");                      \r
123                         if (grabbered_time_max > 0)\r
124                         {\r
125                                 if ( time > self.grabber_time_grabbered + grabbered_time_max )\r
126                                         self.grabber_state |= GRABBER_REMOVING;\r
127                         }\r
128 \r
129                         if (grabbered_fuel > 0)\r
130                         {\r
131                                 if ( time > self.grabber_time_fueldecrease )\r
132                                 {\r
133                                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)\r
134                                         {\r
135                                                 if ( self.ammo_fuel >= (time - self.grabber_time_fueldecrease) * grabbered_fuel )\r
136                                                 {\r
137                                                         W_DecreaseAmmo(ammo_fuel, (time - self.grabber_time_fueldecrease) * grabbered_fuel, cvar("g_balance_grabber_reload_ammo"));\r
138                                                         self.grabber_time_fueldecrease = time;\r
139                                                         // decrease next frame again\r
140                                                 }\r
141                                                 else\r
142                                                 {\r
143                                                         self.grabber_state |= GRABBER_REMOVING;\r
144                                                         W_SwitchWeapon_Force(self, w_getbestweapon(self));\r
145                                                 }\r
146                                         }\r
147                                 }\r
148                         }\r
149                 }\r
150                 else\r
151                 {\r
152                         self.grabber_time_grabbered = time;                             \r
153                         self.grabber_time_fueldecrease = time + cvar("g_balance_grabber_primary_grabbered_time_free");\r
154                 }\r
155 \r
156                 if (self.BUTTON_CROUCH)\r
157                 {\r
158                         self.grabber_state &~= GRABBER_PULLING;\r
159                         if (self.BUTTON_ATCK || (!(self.items & IT_JETPACK) && self.BUTTON_JETPACK))\r
160                                 self.grabber_state &~= GRABBER_RELEASING;\r
161                         else\r
162                                 self.grabber_state |= GRABBER_RELEASING;\r
163                 }\r
164                 else\r
165                 {\r
166                         self.grabber_state |= GRABBER_PULLING;\r
167                         self.grabber_state &~= GRABBER_RELEASING;\r
168 \r
169                         if (self.BUTTON_ATCK || (!(self.items & IT_JETPACK) && self.BUTTON_JETPACK))\r
170                         {\r
171                                 // already fired\r
172                                 if(self.grabber)\r
173                                         self.grabber_state |= GRABBER_WAITING_FOR_RELEASE;\r
174                         }\r
175                         else\r
176                         {\r
177                                 self.grabber_state |= GRABBER_REMOVING;\r
178                                 self.grabber_state &~= GRABBER_WAITING_FOR_RELEASE;\r
179                         }\r
180                 }\r
181         }\r
182         else if (req == WR_PRECACHE)\r
183         {\r
184                 precache_model ("models/weapons/g_grabber.md3");\r
185                 precache_model ("models/weapons/v_grabber.md3");\r
186                 precache_model ("models/weapons/h_grabber.dpm");\r
187                 precache_sound ("weapons/grabber_impact.wav"); // done by g_grabber.qc\r
188                 precache_sound ("weapons/grabber_fire.wav");\r
189                 precache_sound ("weapons/grabber_altfire.wav");\r
190                 precache_sound ("weapons/reload.wav");\r
191         }\r
192         else if (req == WR_SETUP)\r
193         {\r
194                 weapon_setup(WEP_GRABBER);\r
195                 self.grabber_state &~= GRABBER_WAITING_FOR_RELEASE;\r
196                 self.current_ammo = ammo_fuel;\r
197         }\r
198         else if (req == WR_CHECKAMMO1)\r
199         {\r
200                 if(self.grabber)\r
201                 {\r
202                         ammo_amount = self.ammo_fuel > 0;\r
203                         ammo_amount += self.weapon_load[WEP_GRABBER] > 0;\r
204                 }\r
205                 else\r
206                 {\r
207                         ammo_amount = self.ammo_fuel >= cvar("g_balance_grabber_primary_ammo");\r
208                         ammo_amount += self.weapon_load[WEP_GRABBER] >= cvar("g_balance_grabber_primary_ammo");\r
209                 }\r
210                 return ammo_amount;\r
211         }\r
212         else if (req == WR_CHECKAMMO2)\r
213         {\r
214                 ammo_amount = self.ammo_fuel >= cvar("g_balance_grabber_secondary_ammo");\r
215                 ammo_amount += self.weapon_load[WEP_GRABBER] >= cvar("g_balance_grabber_secondary_ammo");\r
216                 return ammo_amount;\r
217         }\r
218         else if (req == WR_RELOAD)\r
219         {\r
220                 self.grabber_state |= GRABBER_REMOVING;\r
221                 W_Reload(min(cvar("g_balance_grabber_primary_ammo"), cvar("g_balance_grabber_secondary_ammo")), cvar("g_balance_grabber_reload_ammo"), cvar("g_balance_grabber_reload_time"), "weapons/reload.wav");\r
222         }\r
223         else if (req == WR_SUICIDEMESSAGE)\r
224                 w_deathtypestring = "did the impossible";\r
225         else if (req == WR_KILLMESSAGE)\r
226                 w_deathtypestring = "has run into #'s paws";\r
227         else if (req == WR_RESETPLAYER)\r
228         {\r
229                 self.grabber_refire = time;\r
230         }\r
231         return TRUE;\r
232 };\r
233 #endif\r