#ifdef INTERFACE
CLASS(VoretGametypeButton) EXTENDS(RadioButton)
	METHOD(VoretGametypeButton, configureVoretGametypeButton, void(entity, float, string, string))
	METHOD(VoretGametypeButton, setChecked, void(entity, float))
	ATTRIB(VoretGametypeButton, fontSize, float, SKINFONTSIZE_NORMAL)
	ATTRIB(VoretGametypeButton, image, string, SKINGFX_BUTTON_BIG)
	ATTRIB(VoretGametypeButton, color, vector, SKINCOLOR_BUTTON_N)
	ATTRIB(VoretGametypeButton, colorC, vector, SKINCOLOR_BUTTON_C)
	ATTRIB(VoretGametypeButton, colorF, vector, SKINCOLOR_BUTTON_F)
	ATTRIB(VoretGametypeButton, colorD, vector, SKINCOLOR_BUTTON_D)
	ATTRIB(VoretGametypeButton, srcMulti, float, 1)
	ATTRIB(VoretGametypeButton, useDownAsChecked, float, 1)

	ATTRIB(VoretGametypeButton, cvarName, string, string_null)
	METHOD(VoretGametypeButton, loadCvars, void(entity))
	METHOD(VoretGametypeButton, saveCvars, void(entity))

	ATTRIB(VoretGametypeButton, alpha, float, SKINALPHA_TEXT)
	ATTRIB(VoretGametypeButton, disabledAlpha, float, SKINALPHA_DISABLED)
ENDCLASS(VoretGametypeButton)
entity makeVoretGametypeButton(float, string, string);
#endif

#ifdef IMPLEMENTATION
void GameTypeButton_Click(entity me, entity other);
entity makeVoretGametypeButton(float theGroup, string theCvar, string theText)
{
	entity me;
	me = spawnVoretGametypeButton();
	me.configureVoretGametypeButton(me, theGroup, theCvar, theText);
	return me;
}
void configureVoretGametypeButtonVoretGametypeButton(entity me, float theGroup, string theCvar, string theText)
{
	if(theCvar)
	{
		me.cvarName = theCvar;
		me.tooltip = getZonedTooltipForIdentifier(theCvar);
		me.loadCvars(me);
	}
	me.configureRadioButton(me, theText, me.fontSize, me.image, theGroup, 0);
	me.align = 0.5;
	me.onClick = GameTypeButton_Click;
	me.onClickEntity = NULL;
}
void setCheckedVoretGametypeButton(entity me, float val)
{
	if(val != me.checked)
	{
		me.checked = val;
		me.saveCvars(me);
	}
}
void loadCvarsVoretGametypeButton(entity me)
{
	if not(me.cvarName)
		return;

	me.checked = cvar(me.cvarName);
}
void saveCvarsVoretGametypeButton(entity me)
{
	if not(me.cvarName)
		return;

	cvar_set(me.cvarName, ftos(me.checked));
}
void GameTypeButton_Click(entity me, entity other)
{
	RadioButton_Click(me, other);
	me.parent.gameTypeChangeNotify(me.parent);
}
#endif