#ifdef INTERFACE
CLASS(VoretTextSlider) EXTENDS(TextSlider)
	METHOD(VoretTextSlider, configureVoretTextSlider, void(entity, string))
	METHOD(VoretTextSlider, setValue, void(entity, float))
	METHOD(VoretTextSlider, configureVoretTextSliderValues, void(entity))
	ATTRIB(VoretTextSlider, fontSize, float, SKINFONTSIZE_NORMAL)
	ATTRIB(VoretTextSlider, valueSpace, float, SKINWIDTH_SLIDERTEXT)
	ATTRIB(VoretTextSlider, image, string, SKINGFX_SLIDER)
	ATTRIB(VoretSlider, tolerance, vector, SKINTOLERANCE_SLIDER)
	ATTRIB(VoretTextSlider, align, float, 0.5)
	ATTRIB(VoretSlider, color, vector, SKINCOLOR_SLIDER_N)
	ATTRIB(VoretSlider, colorC, vector, SKINCOLOR_SLIDER_C)
	ATTRIB(VoretSlider, colorF, vector, SKINCOLOR_SLIDER_F)
	ATTRIB(VoretSlider, colorD, vector, SKINCOLOR_SLIDER_D)
	ATTRIB(VoretSlider, color2, vector, SKINCOLOR_SLIDER_S)

	ATTRIB(VoretTextSlider, cvarName, string, string_null)
	METHOD(VoretTextSlider, loadCvars, void(entity))
	METHOD(VoretTextSlider, saveCvars, void(entity))

	ATTRIB(VoretTextSlider, alpha, float, SKINALPHA_TEXT)
	ATTRIB(VoretTextSlider, disabledAlpha, float, SKINALPHA_DISABLED)
ENDCLASS(VoretTextSlider)
entity makeVoretTextSlider(string); // note: you still need to call addValue and configureVoretTextSliderValues!
#endif

#ifdef IMPLEMENTATION
entity makeVoretTextSlider(string theCvar)
{
	entity me;
	me = spawnVoretTextSlider();
	me.configureVoretTextSlider(me, theCvar);
	return me;
}
void configureVoretTextSliderVoretTextSlider(entity me, string theCvar)
{
	me.configureSliderVisuals(me, me.fontSize, me.align, me.valueSpace, me.image);
	if(theCvar)
	{
		me.cvarName = theCvar;
		me.tooltip = getZonedTooltipForIdentifier(theCvar);
		// don't load it yet
	}
}
void setValueVoretTextSlider(entity me, float val)
{
	if(val != me.value)
	{
		me.value = val;
		me.saveCvars(me);
	}
}
void loadCvarsVoretTextSlider(entity me)
{
	if not(me.cvarName)
		return;

	var float n = tokenize_console(me.cvarName);
	var string s = cvar_string(argv(0));
	float i;
	for(i = 1; i < n; ++i)
		s = strcat(s, " ", cvar_string(argv(i)));
	me.setValueFromIdentifier(me, s);
}
void saveCvarsVoretTextSlider(entity me)
{
	if not(me.cvarName)
		return;

	if(me.value >= 0 && me.value < me.nValues)
	{
		var float n = tokenize_console(me.cvarName);
		if(n == 1)
		{
			// this is a special case to allow spaces in the identifiers
			cvar_set(argv(0), me.getIdentifier(me));
		}
		else
		{
			float i;
			var float m = tokenize_console(strcat(me.cvarName, " ", me.getIdentifier(me)));
			if(m == n + 1)
			{
				for(i = 0; i < n; ++i)
					cvar_set(argv(i), argv(n));
			}
			else if(m == n * 2)
			{
				for(i = 0; i < n; ++i)
					cvar_set(argv(i), argv(i + n));
			}
			else
				error("VoretTextSlider: invalid identifier ", me.getIdentifier(me), " does not match cvar list ", me.cvarName);
		}
	}
}
void configureVoretTextSliderValuesVoretTextSlider(entity me)
{
	me.configureTextSliderValues(me, string_null);
	me.loadCvars(me);
}
#endif