CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.12 FATAL_ERROR)
   2 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
   3 project(NetRadiant C CXX)
   4
   5 option(BUILD_RADIANT "Build the GUI" ON)
   6 option(BUILD_TOOLS "Build the tools" ON)
   7 option(BUILD_CRUNCH "Build Crunch image support" OFF)
   8 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
   9 option(USE_WERROR "Build with -Werror -pedantic-errors" OFF)
  10 option(FHS_INSTALL "Install according to Filesystem Hierarchy Standard" OFF)
  11
  12 set(BUILD_BINARIES OFF CACHE INTERNAL "...")
  13 if (BUILD_RADIANT OR BUILD_TOOLS)
  14     set(BUILD_BINARIES ON)
  15 endif ()
  16
  17 #-----------------------------------------------------------------------
  18 # Paths
  19 #-----------------------------------------------------------------------
  20
  21 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  22     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
  23 endif ()
  24
  25 set(RADIANT_NAME "NetRadiant" CACHE INTERNAL "...")
  26 add_definitions(-DRADIANT_NAME="${RADIANT_NAME}")
  27 set(RADIANT_BASENAME "netradiant" CACHE INTERNAL "...")
  28 add_definitions(-DRADIANT_BASENAME="${RADIANT_BASENAME}")
  29
  30 set(RADIANT_LIB_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  31 set(RADIANT_BIN_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  32 set(RADIANT_DATA_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  33
  34 if (FHS_INSTALL)
  35     set(RADIANT_LIB_DIR ${CMAKE_INSTALL_PREFIX}/lib/${RADIANT_BASENAME})
  36     set(RADIANT_BIN_DIR ${CMAKE_INSTALL_PREFIX}/bin)
  37     set(RADIANT_DATA_DIR ${CMAKE_INSTALL_PREFIX}/share/${RADIANT_BASENAME})
  38 endif ()
  39
  40 set(GAMEPACKS_DOWNLOAD_DIR ${PROJECT_BINARY_DIR}/download CACHE PATH "Where to store downloaded game packs")
  41
  42 #-----------------------------------------------------------------------
  43 # Version
  44 #-----------------------------------------------------------------------
  45
  46 # CMake 3.0+ would allow this in project()
  47 set(RADIANT_VERSION_MAJOR 1)
  48 set(RADIANT_VERSION_MINOR 5)
  49 set(RADIANT_VERSION_PATCH 0)
  50 set(RADIANT_VERSION "${RADIANT_VERSION_MAJOR}.${RADIANT_VERSION_MINOR}.${RADIANT_VERSION_PATCH}")
  51
  52 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
  53
  54 find_package(Git REQUIRED)
  55
  56 execute_process(
  57      COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
  58      WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
  59      OUTPUT_VARIABLE GIT_VERSION
  60      OUTPUT_STRIP_TRAILING_WHITESPACE
  61 )
  62
  63 set(RADIANT_VERSION_STRING "${RADIANT_VERSION}n")
  64
  65 if (GIT_VERSION)
  66     set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
  67 endif ()
  68
  69 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
  70
  71 #-----------------------------------------------------------------------
  72 # Language standard
  73 #-----------------------------------------------------------------------
  74
  75 if (BUILD_BINARIES)
  76     set(CMAKE_CXX_STANDARD 11)
  77     set(CMAKE_CXX_STANDARD_REQUIRED ON)
  78     set(CMAKE_CXX_EXTENSIONS OFF)
  79
  80     if (CMAKE_VERSION VERSION_LESS "3.1")
  81         if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
  82             include(CheckCXXCompilerFlag)
  83             check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
  84             if (STD_CXX)
  85                 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
  86             else ()
  87                 message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
  88             endif ()
  89         else ()
  90             message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
  91         endif ()
  92     endif ()
  93 endif ()
  94
  95 #-----------------------------------------------------------------------
  96 # Flags
  97 #-----------------------------------------------------------------------
  98
  99 if (BUILD_BINARIES)
 100     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
 101
 102     macro (addflags_c args)
 103         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
 104     endmacro ()
 105
 106     macro (addflags_cxx args)
 107         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
 108     endmacro ()
 109
 110     macro (addflags args)
 111         addflags_c("${args}")
 112         addflags_cxx("${args}")
 113     endmacro ()
 114
 115     addflags("-fno-strict-aliasing")
 116     if (NOT WIN32)
 117         addflags("-fvisibility=hidden")
 118     endif ()
 119
 120     if (USE_WERROR)
 121         addflags("-Werror")
 122         addflags("-pedantic-errors")
 123     endif ()
 124
 125     addflags("-Wall")
 126     addflags("-Wextra")
 127     addflags("-pedantic")
 128
 129     addflags_c("-Wno-deprecated-declarations") # vfs.c: g_strdown
 130
 131     addflags("-Wno-unused-function")
 132     addflags("-Wno-unused-variable")
 133     addflags("-Wno-unused-parameter")
 134
 135     set(CMAKE_POSITION_INDEPENDENT_CODE 1)
 136 endif ()
 137
 138 if (BUILD_RADIANT)
 139     set(GTK_TARGET 2 CACHE STRING "GTK target")
 140     add_definitions(-DGTK_TARGET=${GTK_TARGET})
 141 endif ()
 142
 143 #-----------------------------------------------------------------------
 144 # Defs
 145 #-----------------------------------------------------------------------
 146
 147 if (BUILD_BINARIES)
 148     add_definitions(-DRADIANT_VERSION="${RADIANT_VERSION}")
 149     add_definitions(-DRADIANT_VERSION_STRING="${RADIANT_VERSION_STRING}")
 150
 151     if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 152         add_definitions(-D_DEBUG=1)
 153     endif ()
 154 endif ()
 155
 156 if (BUILD_RADIANT)
 157     add_definitions(-DRADIANT_ABOUTMSG="${RADIANT_ABOUTMSG}")
 158
 159     macro (disable_deprecated name gtk2only)
 160         add_definitions(-D${name}_DISABLE_SINGLE_INCLUDES)
 161         if ((${gtk2only} EQUAL 0) OR (GTK_TARGET EQUAL 2))
 162             add_definitions(-D${name}_DISABLE_DEPRECATED)
 163         endif ()
 164     endmacro ()
 165
 166     disable_deprecated(ATK 0)
 167     disable_deprecated(G 0)
 168     disable_deprecated(GDK 0)
 169     disable_deprecated(GDK_PIXBUF 0)
 170     disable_deprecated(GTK 1)
 171     disable_deprecated(PANGO 0)
 172 endif ()
 173
 174 if (BUILD_BINARIES)
 175     if(APPLE OR ${CMAKE_SYSTEM_NAME} STREQUAL "FreeBSD")
 176         link_directories(
 177             /usr/local/lib
 178         )
 179     endif ()
 180
 181     if (WIN32)
 182         add_definitions(
 183             -DWIN32=1
 184             -D_WIN32=1
 185         )
 186     else ()
 187         add_definitions(
 188             -DPOSIX=1
 189         )
 190     endif ()
 191 endif ()
 192
 193 if (BUILD_RADIANT AND NOT APPLE AND NOT WIN32)
 194     set(XWINDOWS ON)
 195     find_package(X11 REQUIRED)
 196     include_directories(${X11_INCLUDE_DIR})
 197     add_definitions(-DXWINDOWS=1)
 198 endif ()
 199
 200 if (BUILD_BINARIES)
 201     include_directories("${PROJECT_SOURCE_DIR}/include")
 202     include_directories("${PROJECT_SOURCE_DIR}/libs")
 203
 204     if (WIN32 AND NOT CMAKE_CROSSCOMPILING)
 205         set(BUNDLE_LIBRARIES_DEFAULT ON)
 206     else ()
 207         set(BUNDLE_LIBRARIES_DEFAULT OFF)
 208     endif ()
 209
 210     option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
 211
 212     macro (copy_dlls target)
 213         if (BUNDLE_LIBRARIES AND WIN32)
 214             add_custom_command(TARGET ${target} POST_BUILD
 215                 COMMAND bash
 216                 ARGS -c "ldd '$<TARGET_FILE:${target}>' | egrep -i '\\.dll ' | grep -iv '/c/Windows' | awk '{ print $1 }' | while read dll; do dllbasename=\"$(which \"$dll\")\"; [ -f \"${PROJECT_BINARY_DIR}/$dllbasename\" ] || cp --preserve=timestamps \"$dllbasename\" '${PROJECT_BINARY_DIR}'; done"
 217                 VERBATIM
 218         )
 219         endif ()
 220     endmacro ()
 221
 222     macro (bundle_stuff target)
 223         if (BUNDLE_LIBRARIES AND WIN32)
 224             add_custom_command(TARGET ${target} POST_BUILD
 225                 COMMAND bash
 226                 ARGS -c "mkdir -p '${PROJECT_BINARY_DIR}/share/themes'; mkdir -p '${PROJECT_BINARY_DIR}/lib'; mingw=\"$(echo '${CMAKE_C_COMPILER}' | sed -e 's|/bin/.*||')\"; [ -d '${PROJECT_BINARY_DIR}/share/themes/MS-Windows' ] || cp -r --preserve=timestamps \"$mingw/share/themes/MS-Windows\" '${PROJECT_BINARY_DIR}/share/themes/'; [ -d '${PROJECT_BINARY_DIR}/lib/gdk-pixbuf-2.0' ] || cp -r --preserve=timestamps \"$mingw/lib/gdk-pixbuf-2.0\" '${PROJECT_BINARY_DIR}/lib/'; [ -d '${PROJECT_BINARY_DIR}/lib/gtk-2.0' ] || cp -r --preserve=timestamps \"$mingw/lib/gtk-2.0\" '${PROJECT_BINARY_DIR}/lib/'"
 227                 VERBATIM
 228         )
 229
 230         file(GLOB DLL_FILES ${PROJECT_BINARY_DIR}/*.dll)
 231
 232         install(FILES
 233             ${DLL_FILES}
 234             DESTINATION ${CMAKE_INSTALL_PREFIX}
 235         )
 236
 237         install(DIRECTORY
 238             ${PROJECT_BINARY_DIR}/lib
 239             ${PROJECT_BINARY_DIR}/share
 240             DESTINATION ${CMAKE_INSTALL_PREFIX}
 241         )
 242         endif ()
 243     endmacro ()
 244 endif ()
 245
 246 #-----------------------------------------------------------------------
 247 # Libraries
 248 #-----------------------------------------------------------------------
 249
 250 if (BUILD_BINARIES)
 251     add_subdirectory(libs)
 252 endif ()
 253
 254 if (BUILD_RADIANT)
 255     add_subdirectory(include)
 256 endif ()
 257
 258 #-----------------------------------------------------------------------
 259 # Plugins
 260 #-----------------------------------------------------------------------
 261
 262 if (BUILD_RADIANT)
 263     add_subdirectory(contrib)
 264 endif ()
 265
 266 #-----------------------------------------------------------------------
 267 # Modules
 268 #-----------------------------------------------------------------------
 269
 270 if (BUILD_RADIANT)
 271     add_subdirectory(plugins)
 272 endif ()
 273
 274 #-----------------------------------------------------------------------
 275 # Radiant
 276 #-----------------------------------------------------------------------
 277
 278 if (BUILD_BINARIES)
 279     if (CMAKE_EXECUTABLE_SUFFIX)
 280         string(REGEX REPLACE "^[.]" "" RADIANT_EXECUTABLE ${CMAKE_EXECUTABLE_SUFFIX})
 281     endif ()
 282
 283     macro (radiant_tool name)
 284         add_executable(${name} ${ARGN})
 285
 286         copy_dlls(${name})
 287
 288         install(
 289             TARGETS ${name}
 290             RUNTIME DESTINATION ${RADIANT_BIN_DIR}
 291         )
 292     endmacro ()
 293
 294     if (BUILD_RADIANT)
 295         add_subdirectory(radiant)
 296         set_target_properties(${RADIANT_BASENAME} PROPERTIES
 297         COMPILE_DEFINITIONS RADIANT_EXECUTABLE="${RADIANT_EXECUTABLE}"
 298     )
 299     endif ()
 300 endif ()
 301
 302 #-----------------------------------------------------------------------
 303 # Tools
 304 #-----------------------------------------------------------------------
 305
 306 if (BUILD_TOOLS)
 307     add_subdirectory(tools)
 308
 309     file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
 310
 311     if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
 312         # Copy data files from sources to the build directory
 313         message(STATUS "Copying data files")
 314         file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
 315     endif ()
 316 endif ()
 317
 318 #-----------------------------------------------------------------------
 319 # Game packs
 320 #-----------------------------------------------------------------------
 321
 322 set(GAMEPACKS_LICENSE_LIST free CACHE STRING "Download game packs by license")
 323 set(GAMEPACKS_NAME_LIST none CACHE STRING "Download game packs by name")
 324
 325 if (DOWNLOAD_GAMEPACKS)
 326     add_custom_target(game_packs ALL
 327        COMMAND "${PROJECT_SOURCE_DIR}/gamepack-manager" --license ${GAMEPACKS_LICENSE_LIST} --name ${GAMEPACKS_NAME_LIST} --download-dir "${GAMEPACKS_DOWNLOAD_DIR}" --install-dir "${PROJECT_BINARY_DIR}/gamepacks" --download --install
 328        COMMENT "Downloading game packs"
 329     )
 330 endif ()
 331
 332 #-----------------------------------------------------------------------
 333 # Install
 334 #-----------------------------------------------------------------------
 335
 336 if (BUILD_BINARIES)
 337     install(DIRECTORY
 338         setup/data/tools/base
 339         setup/data/tools/bitmaps
 340         setup/data/tools/gl
 341         setup/data/tools/plugins
 342         docs
 343         DESTINATION ${RADIANT_DATA_DIR}
 344     )
 345 endif ()
 346
 347 if (DOWNLOAD_GAMEPACKS)
 348     if (FHS_INSTALL)
 349        set(GAME_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/share/netradiant")
 350     else ()
 351        set(GAME_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}")
 352     endif ()
 353
 354     install(DIRECTORY
 355         ${PROJECT_BINARY_DIR}/gamepacks
 356         DESTINATION ${RADIANT_DATA_DIR}
 357     )
 358 endif ()
 359
 360 if(BUILD_BINARIES AND FHS_INSTALL AND NOT WIN32 AND NOT APPLE)
 361     install(FILES
 362         ${PROJECT_SOURCE_DIR}/icons/netradiant.png
 363         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/pixmaps
 364     )
 365     install(FILES
 366         ${PROJECT_SOURCE_DIR}/icons/netradiant.desktop
 367         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/applications
 368     )
 369     install(FILES
 370         ${PROJECT_SOURCE_DIR}/icons/mime/map.xml
 371         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/mime/model
 372     )
 373 endif ()
 374
 375 include(cmake/scripts/package.cmake)