CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.12 FATAL_ERROR)
   2 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
   3 project(NetRadiant C CXX)
   4
   5 option(BUILD_RADIANT "Build the GUI" ON)
   6
   7 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
   8     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
   9 endif ()
  10
  11 #-----------------------------------------------------------------------
  12 # Version
  13 #-----------------------------------------------------------------------
  14
  15 # CMake 3.0+ would allow this in project()
  16 set(NetRadiant_VERSION_MAJOR 1)
  17 set(NetRadiant_VERSION_MINOR 5)
  18 set(NetRadiant_VERSION_PATCH 0)
  19 set(NetRadiant_VERSION "${NetRadiant_VERSION_MAJOR}.${NetRadiant_VERSION_MINOR}.${NetRadiant_VERSION_PATCH}")
  20
  21 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_MAJOR" ${NetRadiant_VERSION_MAJOR})
  22 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_MINOR" ${NetRadiant_VERSION_MINOR})
  23 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_PATCH" ${NetRadiant_VERSION_PATCH})
  24
  25 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
  26
  27 find_package(Git REQUIRED)
  28 execute_process(
  29         COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
  30         WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
  31         OUTPUT_VARIABLE GIT_VERSION
  32         OUTPUT_STRIP_TRAILING_WHITESPACE
  33 )
  34 set(RADIANT_VERSION_STRING "${NetRadiant_VERSION}n")
  35 if (GIT_VERSION)
  36     set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
  37 endif ()
  38
  39 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
  40
  41 #-----------------------------------------------------------------------
  42 # Language standard
  43 #-----------------------------------------------------------------------
  44
  45 set(CMAKE_CXX_STANDARD 11)
  46 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  47 if (CMAKE_VERSION VERSION_LESS "3.1")
  48     if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
  49         include(CheckCXXCompilerFlag)
  50         check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
  51         if (STD_CXX)
  52             set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
  53         else ()
  54             message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
  55         endif ()
  56     else ()
  57         message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
  58     endif ()
  59 endif ()
  60
  61 #-----------------------------------------------------------------------
  62 # Flags
  63 #-----------------------------------------------------------------------
  64
  65 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
  66 macro(addflags args)
  67     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
  68     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
  69 endmacro()
  70 addflags("-fno-strict-aliasing")
  71 if (NOT WIN32)
  72     addflags("-fvisibility=hidden")
  73 endif ()
  74
  75 set(CMAKE_POSITION_INDEPENDENT_CODE 1)
  76 set(GTK_TARGET 2 CACHE STRING "GTK target")
  77 add_definitions(-DGTK_TARGET=${GTK_TARGET})
  78
  79 #-----------------------------------------------------------------------
  80 # Defs
  81 #-----------------------------------------------------------------------
  82
  83 add_definitions(-DRADIANT_VERSION="${NetRadiant_VERSION}")
  84 add_definitions(-DRADIANT_MAJOR_VERSION="${NetRadiant_VERSION_MAJOR}")
  85 add_definitions(-DRADIANT_MINOR_VERSION="${NetRadiant_VERSION_MINOR}")
  86 add_definitions(-DRADIANT_PATCH_VERSION="${NetRadiant_VERSION_PATCH}")
  87
  88 add_definitions(-DRADIANT_ABOUTMSG="${NetRadiant_ABOUT}")
  89
  90 if (NOT CMAKE_BUILD_TYPE MATCHES Release)
  91     add_definitions(-D_DEBUG=1)
  92 endif ()
  93
  94 macro(disable_deprecated name gtk2only)
  95     add_definitions(-D${name}_DISABLE_SINGLE_INCLUDES)
  96     if ((${gtk2only} EQUAL 0) OR (GTK_TARGET EQUAL 2))
  97         add_definitions(-D${name}_DISABLE_DEPRECATED)
  98     endif ()
  99 endmacro()
 100
 101 disable_deprecated(ATK 0)
 102 disable_deprecated(G 0)
 103 disable_deprecated(GDK 0)
 104 disable_deprecated(GDK_PIXBUF 0)
 105 disable_deprecated(GTK 1)
 106 disable_deprecated(PANGO 0)
 107
 108 if (APPLE)
 109     option(XWINDOWS "Build against X11" ON)
 110     add_definitions(
 111             -DPOSIX=1
 112     )
 113 elseif (WIN32)
 114     add_definitions(
 115             -DWIN32=1
 116             -D_WIN32=1
 117     )
 118 else ()
 119     set(XWINDOWS ON)
 120     add_definitions(
 121             -DPOSIX=1
 122     )
 123 endif ()
 124
 125 if (XWINDOWS)
 126     find_package(X11 REQUIRED)
 127     include_directories(${X11_INCLUDE_DIR})
 128     add_definitions(-DXWINDOWS=1)
 129 endif ()
 130
 131 include_directories("${PROJECT_SOURCE_DIR}/include")
 132 include_directories("${PROJECT_SOURCE_DIR}/libs")
 133
 134 if (WIN32 AND NOT CMAKE_CROSSCOMPILING)
 135     set(BUNDLE_LIBRARIES_DEFAULT ON)
 136 else ()
 137     set(BUNDLE_LIBRARIES_DEFAULT OFF)
 138 endif ()
 139 option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
 140
 141 macro(copy_dlls target)
 142     if (BUNDLE_LIBRARIES)
 143         add_custom_command(TARGET ${target} POST_BUILD
 144                 COMMAND bash
 145                 ARGS -c "ldd '$<TARGET_FILE:${target}>' | grep -v /c/Windows | awk '{ print $1 }' | while read dll; do cp \"$(which $dll)\" '${PROJECT_BINARY_DIR}'; done"
 146                 VERBATIM
 147                 )
 148     endif ()
 149 endmacro()
 150
 151 #-----------------------------------------------------------------------
 152 # Libraries
 153 #-----------------------------------------------------------------------
 154
 155 add_subdirectory(libs)
 156 add_subdirectory(include)
 157
 158 #-----------------------------------------------------------------------
 159 # Plugins
 160 #-----------------------------------------------------------------------
 161
 162 if (BUILD_RADIANT)
 163     add_subdirectory(contrib)
 164 endif ()
 165
 166 #-----------------------------------------------------------------------
 167 # Modules
 168 #-----------------------------------------------------------------------
 169
 170 if (BUILD_RADIANT)
 171     add_subdirectory(plugins)
 172 endif ()
 173
 174 #-----------------------------------------------------------------------
 175 # Radiant
 176 #-----------------------------------------------------------------------
 177
 178 if (CMAKE_EXECUTABLE_SUFFIX)
 179     string(REGEX REPLACE "^[.]" "" RADIANT_EXECUTABLE ${CMAKE_EXECUTABLE_SUFFIX})
 180 else ()
 181     execute_process(
 182             COMMAND uname -m
 183             OUTPUT_VARIABLE RADIANT_EXECUTABLE
 184             OUTPUT_STRIP_TRAILING_WHITESPACE
 185     )
 186 endif ()
 187
 188 macro(radiant_tool name)
 189     add_executable(${name} ${ARGN})
 190     install(
 191             TARGETS ${name}
 192             RUNTIME DESTINATION .
 193     )
 194     if (NOT (CMAKE_EXECUTABLE_SUFFIX STREQUAL ".${RADIANT_EXECUTABLE}"))
 195         add_custom_command(TARGET ${name} POST_BUILD
 196                 COMMAND ln -f -s "$<TARGET_FILE_NAME:${name}>" "${PROJECT_BINARY_DIR}/${name}.${RADIANT_EXECUTABLE}"
 197                 VERBATIM
 198                 )
 199         install(CODE "execute_process(COMMAND ${CMAKE_COMMAND} -E create_symlink
 200                 ${name}${CMAKE_EXECUTABLE_SUFFIX} ${CMAKE_INSTALL_PREFIX}/${name}.${RADIANT_EXECUTABLE})
 201                 ")
 202     endif ()
 203 endmacro()
 204
 205 if (BUILD_RADIANT)
 206     add_subdirectory(radiant _radiant)
 207     set_target_properties(radiant PROPERTIES
 208             COMPILE_DEFINITIONS RADIANT_EXECUTABLE="${RADIANT_EXECUTABLE}"
 209             )
 210 endif ()
 211
 212 #-----------------------------------------------------------------------
 213 # Tools
 214 #-----------------------------------------------------------------------
 215
 216 add_subdirectory(tools)
 217
 218 file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
 219
 220 if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
 221     # Copy data files from sources to the build directory
 222     message(STATUS "Copying data files")
 223     file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
 224 endif ()
 225
 226 #-----------------------------------------------------------------------
 227 # Game packs
 228 #-----------------------------------------------------------------------
 229
 230 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
 231 add_custom_target(game_packs
 232         COMMAND ${CMAKE_COMMAND} -E make_directory games
 233         COMMAND DOWNLOAD_GAMEPACKS=yes SOURCE_DIR="${PROJECT_SOURCE_DIR}" "${PROJECT_SOURCE_DIR}/install-gamepacks.sh" "${PROJECT_BINARY_DIR}"
 234         COMMENT "Downloading game packs"
 235         )
 236 if (DOWNLOAD_GAMEPACKS)
 237     add_custom_target(game_packs_all ALL DEPENDS game_packs)
 238 endif ()
 239
 240 #-----------------------------------------------------------------------
 241 # Install
 242 #-----------------------------------------------------------------------
 243
 244 install(
 245         FILES
 246         "${PROJECT_BINARY_DIR}/RADIANT_MAJOR"
 247         "${PROJECT_BINARY_DIR}/RADIANT_MINOR"
 248         "${PROJECT_BINARY_DIR}/RADIANT_PATCH"
 249         DESTINATION .
 250 )
 251
 252 install(
 253         DIRECTORY
 254         setup/data/tools/
 255         docs
 256         DESTINATION .
 257 )
 258
 259 set(GAME_FILES
 260         DarkPlaces
 261         Nexuiz
 262         OpenArena
 263         Osirion
 264         Q3
 265         Quake2
 266         Quake
 267         Quetoo
 268         Tremulous
 269         UFOAI
 270         Unvanquished
 271         Warsow
 272         Xonotic
 273         )
 274 unset(_tmp)
 275 foreach (it ${GAME_FILES})
 276     set(dir "${PROJECT_BINARY_DIR}/games/${it}Pack")
 277     string(TOLOWER "${it}" it)
 278     list(APPEND _tmp "${dir}/games")
 279     list(APPEND _tmp "${dir}/${it}.game")
 280 endforeach ()
 281 set(GAME_FILES ${_tmp})
 282
 283 install(
 284         DIRECTORY
 285         ${GAME_FILES}
 286         DESTINATION .
 287         OPTIONAL
 288 )
 289
 290 include(cmake/scripts/package.cmake)