Remove -Wno-pointer-to-int-cast
[xonotic/netradiant.git] / CMakeLists.txt
1 cmake_minimum_required(VERSION 2.8.12 FATAL_ERROR)
2 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
3 project(NetRadiant C CXX)
4
5 option(BUILD_RADIANT "Build the GUI" ON)
6
7 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
8     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
9 endif ()
10
11 #-----------------------------------------------------------------------
12 # Version
13 #-----------------------------------------------------------------------
14
15 # CMake 3.0+ would allow this in project()
16 set(NetRadiant_VERSION_MAJOR 1)
17 set(NetRadiant_VERSION_MINOR 5)
18 set(NetRadiant_VERSION_PATCH 0)
19 set(NetRadiant_VERSION "${NetRadiant_VERSION_MAJOR}.${NetRadiant_VERSION_MINOR}.${NetRadiant_VERSION_PATCH}")
20
21 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_MAJOR" ${NetRadiant_VERSION_MAJOR})
22 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_MINOR" ${NetRadiant_VERSION_MINOR})
23 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_PATCH" ${NetRadiant_VERSION_PATCH})
24
25 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
26
27 find_package(Git REQUIRED)
28 execute_process(
29         COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
30         WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
31         OUTPUT_VARIABLE GIT_VERSION
32         OUTPUT_STRIP_TRAILING_WHITESPACE
33 )
34 set(RADIANT_VERSION_STRING "${NetRadiant_VERSION}n")
35 if (GIT_VERSION)
36     set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
37 endif ()
38
39 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
40
41 #-----------------------------------------------------------------------
42 # Language standard
43 #-----------------------------------------------------------------------
44
45 set(CMAKE_CXX_STANDARD 11)
46 set(CMAKE_CXX_STANDARD_REQUIRED ON)
47 if (CMAKE_VERSION VERSION_LESS "3.1")
48     if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
49         include(CheckCXXCompilerFlag)
50         check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
51         if (STD_CXX)
52             set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
53         else ()
54             message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
55         endif ()
56     else ()
57         message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
58     endif ()
59 endif ()
60
61 #-----------------------------------------------------------------------
62 # Flags
63 #-----------------------------------------------------------------------
64
65 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
66 macro(addflags_c args)
67     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
68 endmacro()
69 macro(addflags_cxx args)
70     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
71 endmacro()
72 macro(addflags args)
73     addflags_c("${args}")
74     addflags_cxx("${args}")
75 endmacro()
76 addflags("-fno-strict-aliasing")
77 if (NOT WIN32)
78     addflags("-fvisibility=hidden")
79 endif ()
80
81 if ("${CMAKE_BUILD_TYPE}" STREQUAL "Debug")
82     addflags("-Werror")
83     addflags("-pedantic-errors")
84 endif ()
85
86 addflags("-Wall")
87 addflags("-Wextra")
88 addflags("-pedantic")
89
90 addflags_c("-Wno-deprecated-declarations") # vfs.c: g_strdown
91
92 addflags("-Wno-sign-compare")
93 addflags("-Wno-unused-function")
94 addflags("-Wno-unused-variable")
95 addflags("-Wno-unused-parameter")
96 addflags("-Wno-missing-field-initializers")
97
98 addflags_c("-Wno-incompatible-pointer-types")
99
100 set(CMAKE_POSITION_INDEPENDENT_CODE 1)
101 set(GTK_TARGET 2 CACHE STRING "GTK target")
102 add_definitions(-DGTK_TARGET=${GTK_TARGET})
103
104 #-----------------------------------------------------------------------
105 # Defs
106 #-----------------------------------------------------------------------
107
108 add_definitions(-DRADIANT_VERSION="${NetRadiant_VERSION}")
109 add_definitions(-DRADIANT_MAJOR_VERSION="${NetRadiant_VERSION_MAJOR}")
110 add_definitions(-DRADIANT_MINOR_VERSION="${NetRadiant_VERSION_MINOR}")
111 add_definitions(-DRADIANT_PATCH_VERSION="${NetRadiant_VERSION_PATCH}")
112
113 add_definitions(-DRADIANT_ABOUTMSG="${NetRadiant_ABOUT}")
114
115 if (NOT CMAKE_BUILD_TYPE MATCHES Release)
116     add_definitions(-D_DEBUG=1)
117 endif ()
118
119 macro(disable_deprecated name gtk2only)
120     add_definitions(-D${name}_DISABLE_SINGLE_INCLUDES)
121     if ((${gtk2only} EQUAL 0) OR (GTK_TARGET EQUAL 2))
122         add_definitions(-D${name}_DISABLE_DEPRECATED)
123     endif ()
124 endmacro()
125
126 disable_deprecated(ATK 0)
127 disable_deprecated(G 0)
128 disable_deprecated(GDK 0)
129 disable_deprecated(GDK_PIXBUF 0)
130 disable_deprecated(GTK 1)
131 disable_deprecated(PANGO 0)
132
133 if (APPLE)
134     option(XWINDOWS "Build against X11" ON)
135     add_definitions(
136             -DPOSIX=1
137     )
138 elseif (WIN32)
139     add_definitions(
140             -DWIN32=1
141             -D_WIN32=1
142     )
143 else ()
144     set(XWINDOWS ON)
145     add_definitions(
146             -DPOSIX=1
147     )
148 endif ()
149
150 if (XWINDOWS)
151     find_package(X11 REQUIRED)
152     include_directories(${X11_INCLUDE_DIR})
153     add_definitions(-DXWINDOWS=1)
154 endif ()
155
156 include_directories("${PROJECT_SOURCE_DIR}/include")
157 include_directories("${PROJECT_SOURCE_DIR}/libs")
158
159 if (WIN32 AND NOT CMAKE_CROSSCOMPILING)
160     set(BUNDLE_LIBRARIES_DEFAULT ON)
161 else ()
162     set(BUNDLE_LIBRARIES_DEFAULT OFF)
163 endif ()
164 option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
165
166 macro(copy_dlls target)
167     if (BUNDLE_LIBRARIES)
168         add_custom_command(TARGET ${target} POST_BUILD
169                 COMMAND bash
170                 ARGS -c "ldd '$<TARGET_FILE:${target}>' | grep -v /c/Windows | awk '{ print $1 }' | while read dll; do cp \"$(which $dll)\" '${PROJECT_BINARY_DIR}'; done"
171                 VERBATIM
172                 )
173     endif ()
174 endmacro()
175
176 #-----------------------------------------------------------------------
177 # Libraries
178 #-----------------------------------------------------------------------
179
180 add_subdirectory(libs)
181 add_subdirectory(include)
182
183 #-----------------------------------------------------------------------
184 # Plugins
185 #-----------------------------------------------------------------------
186
187 if (BUILD_RADIANT)
188     add_subdirectory(contrib)
189 endif ()
190
191 #-----------------------------------------------------------------------
192 # Modules
193 #-----------------------------------------------------------------------
194
195 if (BUILD_RADIANT)
196     add_subdirectory(plugins)
197 endif ()
198
199 #-----------------------------------------------------------------------
200 # Radiant
201 #-----------------------------------------------------------------------
202
203 if (CMAKE_EXECUTABLE_SUFFIX)
204     string(REGEX REPLACE "^[.]" "" RADIANT_EXECUTABLE ${CMAKE_EXECUTABLE_SUFFIX})
205 else ()
206     execute_process(
207             COMMAND uname -m
208             OUTPUT_VARIABLE RADIANT_EXECUTABLE
209             OUTPUT_STRIP_TRAILING_WHITESPACE
210     )
211 endif ()
212
213 macro(radiant_tool name)
214     add_executable(${name} ${ARGN})
215     install(
216             TARGETS ${name}
217             RUNTIME DESTINATION .
218     )
219     if (NOT (CMAKE_EXECUTABLE_SUFFIX STREQUAL ".${RADIANT_EXECUTABLE}"))
220         add_custom_command(TARGET ${name} POST_BUILD
221                 COMMAND ln -f -s "$<TARGET_FILE_NAME:${name}>" "${PROJECT_BINARY_DIR}/${name}.${RADIANT_EXECUTABLE}"
222                 VERBATIM
223                 )
224         install(CODE "execute_process(COMMAND ${CMAKE_COMMAND} -E create_symlink
225                 ${name}${CMAKE_EXECUTABLE_SUFFIX} ${CMAKE_INSTALL_PREFIX}/${name}.${RADIANT_EXECUTABLE})
226                 ")
227     endif ()
228 endmacro()
229
230 if (BUILD_RADIANT)
231     add_subdirectory(radiant _radiant)
232     set_target_properties(radiant PROPERTIES
233             COMPILE_DEFINITIONS RADIANT_EXECUTABLE="${RADIANT_EXECUTABLE}"
234             )
235 endif ()
236
237 #-----------------------------------------------------------------------
238 # Tools
239 #-----------------------------------------------------------------------
240
241 add_subdirectory(tools)
242
243 file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
244
245 if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
246     # Copy data files from sources to the build directory
247     message(STATUS "Copying data files")
248     file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
249 endif ()
250
251 #-----------------------------------------------------------------------
252 # Game packs
253 #-----------------------------------------------------------------------
254
255 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
256 add_custom_target(game_packs
257         COMMAND ${CMAKE_COMMAND} -E make_directory games
258         COMMAND DOWNLOAD_GAMEPACKS=yes SOURCE_DIR="${PROJECT_SOURCE_DIR}" "${PROJECT_SOURCE_DIR}/install-gamepacks.sh" "${PROJECT_BINARY_DIR}"
259         COMMENT "Downloading game packs"
260         )
261 if (DOWNLOAD_GAMEPACKS)
262     add_custom_target(game_packs_all ALL DEPENDS game_packs)
263 endif ()
264
265 #-----------------------------------------------------------------------
266 # Install
267 #-----------------------------------------------------------------------
268
269 install(
270         FILES
271         "${PROJECT_BINARY_DIR}/RADIANT_MAJOR"
272         "${PROJECT_BINARY_DIR}/RADIANT_MINOR"
273         "${PROJECT_BINARY_DIR}/RADIANT_PATCH"
274         DESTINATION .
275 )
276
277 install(
278         DIRECTORY
279         setup/data/tools/
280         docs
281         DESTINATION .
282 )
283
284 set(GAME_FILES
285         DarkPlaces
286         Nexuiz
287         OpenArena
288         Osirion
289         Q3
290         Quake2
291         Quake
292         Quetoo
293         Tremulous
294         UFOAI
295         Unvanquished
296         Warsow
297         Xonotic
298         )
299 unset(_tmp)
300 foreach (it ${GAME_FILES})
301     set(dir "${PROJECT_BINARY_DIR}/games/${it}Pack")
302     string(TOLOWER "${it}" it)
303     list(APPEND _tmp "${dir}/games")
304     list(APPEND _tmp "${dir}/${it}.game")
305 endforeach ()
306 set(GAME_FILES ${_tmp})
307
308 install(
309         DIRECTORY
310         ${GAME_FILES}
311         DESTINATION .
312         OPTIONAL
313 )
314
315 include(cmake/scripts/package.cmake)