CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.12 FATAL_ERROR)
   2 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
   3 project(NetRadiant C CXX)
   4
   5 option(BUILD_RADIANT "Build the GUI" ON)
   6
   7 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
   8     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
   9 endif ()
  10
  11 #-----------------------------------------------------------------------
  12 # Version
  13 #-----------------------------------------------------------------------
  14
  15 # CMake 3.0+ would allow this in project()
  16 set(NetRadiant_VERSION_MAJOR 1)
  17 set(NetRadiant_VERSION_MINOR 5)
  18 set(NetRadiant_VERSION_PATCH 0)
  19 set(NetRadiant_VERSION "${NetRadiant_VERSION_MAJOR}.${NetRadiant_VERSION_MINOR}.${NetRadiant_VERSION_PATCH}")
  20
  21 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_MAJOR" ${NetRadiant_VERSION_MAJOR})
  22 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_MINOR" ${NetRadiant_VERSION_MINOR})
  23 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_PATCH" ${NetRadiant_VERSION_PATCH})
  24
  25 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
  26
  27 find_package(Git REQUIRED)
  28 execute_process(
  29         COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
  30         WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
  31         OUTPUT_VARIABLE GIT_VERSION
  32         OUTPUT_STRIP_TRAILING_WHITESPACE
  33 )
  34 set(RADIANT_VERSION_STRING "${NetRadiant_VERSION}n")
  35 if (GIT_VERSION)
  36     set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
  37 endif ()
  38
  39 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
  40
  41 #-----------------------------------------------------------------------
  42 # Language standard
  43 #-----------------------------------------------------------------------
  44
  45 set(CMAKE_CXX_STANDARD 11)
  46 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  47 if (CMAKE_VERSION VERSION_LESS "3.1")
  48     if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
  49         include(CheckCXXCompilerFlag)
  50         check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
  51         if (STD_CXX)
  52             set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
  53         else ()
  54             message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
  55         endif ()
  56     else ()
  57         message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
  58     endif ()
  59 endif ()
  60
  61 #-----------------------------------------------------------------------
  62 # Flags
  63 #-----------------------------------------------------------------------
  64
  65 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
  66 macro(addflags_c args)
  67     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
  68 endmacro()
  69 macro(addflags_cxx args)
  70     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
  71 endmacro()
  72 macro(addflags args)
  73     addflags_c("${args}")
  74     addflags_cxx("${args}")
  75 endmacro()
  76 addflags("-fno-strict-aliasing")
  77 if (NOT WIN32)
  78     addflags("-fvisibility=hidden")
  79 endif ()
  80
  81 if ("${CMAKE_BUILD_TYPE}" STREQUAL "Debug")
  82     addflags("-Werror")
  83     addflags("-pedantic-errors")
  84 endif ()
  85
  86 addflags("-Wall")
  87 addflags("-Wextra")
  88 addflags("-pedantic")
  89
  90 addflags_c("-Wno-deprecated-declarations") # vfs.c: g_strdown
  91
  92 addflags("-Wno-unused-function")
  93 addflags("-Wno-unused-variable")
  94 addflags("-Wno-unused-parameter")
  95
  96 set(CMAKE_POSITION_INDEPENDENT_CODE 1)
  97 set(GTK_TARGET 2 CACHE STRING "GTK target")
  98 add_definitions(-DGTK_TARGET=${GTK_TARGET})
  99
 100 #-----------------------------------------------------------------------
 101 # Defs
 102 #-----------------------------------------------------------------------
 103
 104 add_definitions(-DRADIANT_VERSION="${NetRadiant_VERSION}")
 105 add_definitions(-DRADIANT_MAJOR_VERSION="${NetRadiant_VERSION_MAJOR}")
 106 add_definitions(-DRADIANT_MINOR_VERSION="${NetRadiant_VERSION_MINOR}")
 107 add_definitions(-DRADIANT_PATCH_VERSION="${NetRadiant_VERSION_PATCH}")
 108
 109 add_definitions(-DRADIANT_ABOUTMSG="${NetRadiant_ABOUT}")
 110
 111 if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 112     add_definitions(-D_DEBUG=1)
 113 endif ()
 114
 115 macro(disable_deprecated name gtk2only)
 116     add_definitions(-D${name}_DISABLE_SINGLE_INCLUDES)
 117     if ((${gtk2only} EQUAL 0) OR (GTK_TARGET EQUAL 2))
 118         add_definitions(-D${name}_DISABLE_DEPRECATED)
 119     endif ()
 120 endmacro()
 121
 122 disable_deprecated(ATK 0)
 123 disable_deprecated(G 0)
 124 disable_deprecated(GDK 0)
 125 disable_deprecated(GDK_PIXBUF 0)
 126 disable_deprecated(GTK 1)
 127 disable_deprecated(PANGO 0)
 128
 129 if (APPLE)
 130     option(XWINDOWS "Build against X11" ON)
 131     add_definitions(
 132             -DPOSIX=1
 133     )
 134 elseif (WIN32)
 135     add_definitions(
 136             -DWIN32=1
 137             -D_WIN32=1
 138     )
 139 else ()
 140     set(XWINDOWS ON)
 141     add_definitions(
 142             -DPOSIX=1
 143     )
 144 endif ()
 145
 146 if (XWINDOWS)
 147     find_package(X11 REQUIRED)
 148     include_directories(${X11_INCLUDE_DIR})
 149     add_definitions(-DXWINDOWS=1)
 150 endif ()
 151
 152 include_directories("${PROJECT_SOURCE_DIR}/include")
 153 include_directories("${PROJECT_SOURCE_DIR}/libs")
 154
 155 if (WIN32 AND NOT CMAKE_CROSSCOMPILING)
 156     set(BUNDLE_LIBRARIES_DEFAULT ON)
 157 else ()
 158     set(BUNDLE_LIBRARIES_DEFAULT OFF)
 159 endif ()
 160 option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
 161
 162 macro(copy_dlls target)
 163     if (BUNDLE_LIBRARIES)
 164         add_custom_command(TARGET ${target} POST_BUILD
 165                 COMMAND bash
 166                 ARGS -c "ldd '$<TARGET_FILE:${target}>' | grep -v /c/Windows | awk '{ print $1 }' | while read dll; do cp \"$(which $dll)\" '${PROJECT_BINARY_DIR}'; done"
 167                 VERBATIM
 168                 )
 169     endif ()
 170 endmacro()
 171
 172 #-----------------------------------------------------------------------
 173 # Libraries
 174 #-----------------------------------------------------------------------
 175
 176 add_subdirectory(libs)
 177 add_subdirectory(include)
 178
 179 #-----------------------------------------------------------------------
 180 # Plugins
 181 #-----------------------------------------------------------------------
 182
 183 if (BUILD_RADIANT)
 184     add_subdirectory(contrib)
 185 endif ()
 186
 187 #-----------------------------------------------------------------------
 188 # Modules
 189 #-----------------------------------------------------------------------
 190
 191 if (BUILD_RADIANT)
 192     add_subdirectory(plugins)
 193 endif ()
 194
 195 #-----------------------------------------------------------------------
 196 # Radiant
 197 #-----------------------------------------------------------------------
 198
 199 if (CMAKE_EXECUTABLE_SUFFIX)
 200     string(REGEX REPLACE "^[.]" "" RADIANT_EXECUTABLE ${CMAKE_EXECUTABLE_SUFFIX})
 201 else ()
 202     execute_process(
 203             COMMAND uname -m
 204             OUTPUT_VARIABLE RADIANT_EXECUTABLE
 205             OUTPUT_STRIP_TRAILING_WHITESPACE
 206     )
 207 endif ()
 208
 209 macro(radiant_tool name)
 210     add_executable(${name} ${ARGN})
 211     install(
 212             TARGETS ${name}
 213             RUNTIME DESTINATION .
 214     )
 215     if (NOT (CMAKE_EXECUTABLE_SUFFIX STREQUAL ".${RADIANT_EXECUTABLE}"))
 216         add_custom_command(TARGET ${name} POST_BUILD
 217                 COMMAND ln -f -s "$<TARGET_FILE_NAME:${name}>" "${PROJECT_BINARY_DIR}/${name}.${RADIANT_EXECUTABLE}"
 218                 VERBATIM
 219                 )
 220         install(CODE "execute_process(COMMAND ${CMAKE_COMMAND} -E create_symlink
 221                 ${name}${CMAKE_EXECUTABLE_SUFFIX} ${CMAKE_INSTALL_PREFIX}/${name}.${RADIANT_EXECUTABLE})
 222                 ")
 223     endif ()
 224 endmacro()
 225
 226 if (BUILD_RADIANT)
 227     add_subdirectory(radiant _radiant)
 228     set_target_properties(radiant PROPERTIES
 229             COMPILE_DEFINITIONS RADIANT_EXECUTABLE="${RADIANT_EXECUTABLE}"
 230             )
 231 endif ()
 232
 233 #-----------------------------------------------------------------------
 234 # Tools
 235 #-----------------------------------------------------------------------
 236
 237 add_subdirectory(tools)
 238
 239 file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
 240
 241 if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
 242     # Copy data files from sources to the build directory
 243     message(STATUS "Copying data files")
 244     file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
 245 endif ()
 246
 247 #-----------------------------------------------------------------------
 248 # Game packs
 249 #-----------------------------------------------------------------------
 250
 251 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
 252 if (DOWNLOAD_GAMEPACKS)
 253     add_custom_target(game_packs
 254             COMMAND ${CMAKE_COMMAND} -E make_directory games
 255             COMMAND DOWNLOAD_GAMEPACKS=yes SOURCE_DIR="${PROJECT_SOURCE_DIR}" "${PROJECT_SOURCE_DIR}/install-gamepacks.sh" "${PROJECT_BINARY_DIR}"
 256             COMMENT "Downloading free game packs"
 257             )
 258
 259     add_custom_target(game_packs_all
 260             COMMAND ${CMAKE_COMMAND} -E make_directory games
 261             COMMAND DOWNLOAD_GAMEPACKS=all SOURCE_DIR="${PROJECT_SOURCE_DIR}" "${PROJECT_SOURCE_DIR}/install-gamepacks.sh" "${PROJECT_BINARY_DIR}"
 262             COMMENT "Downloading all game packs"
 263             )
 264 endif ()
 265
 266 #-----------------------------------------------------------------------
 267 # Install
 268 #-----------------------------------------------------------------------
 269
 270 install(
 271         FILES
 272         "${PROJECT_BINARY_DIR}/RADIANT_MAJOR"
 273         "${PROJECT_BINARY_DIR}/RADIANT_MINOR"
 274         "${PROJECT_BINARY_DIR}/RADIANT_PATCH"
 275         DESTINATION .
 276 )
 277
 278 install(
 279         DIRECTORY
 280         setup/data/tools/
 281         docs
 282         DESTINATION .
 283 )
 284
 285 set(GAME_FILES
 286         DarkPlaces
 287         Nexuiz
 288         OpenArena
 289         Osirion
 290         Q3
 291         Quake2
 292         Quake
 293         Quetoo
 294         Tremulous
 295         UFOAI
 296         Unvanquished
 297         Warsow
 298         Xonotic
 299         )
 300 unset(_tmp)
 301 foreach (it ${GAME_FILES})
 302     set(dir "${PROJECT_BINARY_DIR}/games/${it}Pack")
 303     string(TOLOWER "${it}" it)
 304     list(APPEND _tmp "${dir}/games")
 305     list(APPEND _tmp "${dir}/${it}.game")
 306 endforeach ()
 307 set(GAME_FILES ${_tmp})
 308
 309 install(
 310         DIRECTORY
 311         ${GAME_FILES}
 312         DESTINATION .
 313         OPTIONAL
 314 )
 315
 316 include(cmake/scripts/package.cmake)