CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.11 FATAL_ERROR)
   2 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
   3
   4 project(NetRadiant C CXX)
   5 option(BUILD_RADIANT "Build the gui" ON)
   6
   7 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
   8     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
   9 endif ()
  10
  11 #-----------------------------------------------------------------------
  12 # Version
  13 #-----------------------------------------------------------------------
  14
  15 # CMake 3.0+ would allow this in project()
  16 set(NetRadiant_VERSION_MAJOR 1)
  17 set(NetRadiant_VERSION_MINOR 5)
  18 set(NetRadiant_VERSION_PATCH 0)
  19 set(NetRadiant_VERSION "${NetRadiant_VERSION_MAJOR}.${NetRadiant_VERSION_MINOR}.${NetRadiant_VERSION_PATCH}")
  20
  21 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_MAJOR" ${NetRadiant_VERSION_MAJOR})
  22 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_MINOR" ${NetRadiant_VERSION_MINOR})
  23 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_PATCH" ${NetRadiant_VERSION_PATCH})
  24
  25 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
  26
  27 find_package(Git REQUIRED)
  28 execute_process(
  29         COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
  30         WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
  31         OUTPUT_VARIABLE GIT_VERSION
  32         OUTPUT_STRIP_TRAILING_WHITESPACE
  33 )
  34 set(RADIANT_VERSION_STRING "${NetRadiant_VERSION}n")
  35 if (GIT_VERSION)
  36     set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
  37 endif ()
  38
  39 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
  40
  41 #-----------------------------------------------------------------------
  42 # Language standard
  43 #-----------------------------------------------------------------------
  44
  45 set(CMAKE_CXX_STANDARD 11)
  46 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  47 # For some reason the above flags don't really work...
  48 if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
  49     include(CheckCXXCompilerFlag)
  50     check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
  51     if (STD_CXX)
  52         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
  53     else ()
  54         message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
  55     endif ()
  56 else ()
  57     message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
  58 endif ()
  59
  60 #-----------------------------------------------------------------------
  61 # Flags
  62 #-----------------------------------------------------------------------
  63
  64 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
  65 macro(addflags args)
  66     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
  67     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
  68 endmacro()
  69 addflags("-fno-strict-aliasing")
  70 if (NOT WIN32)
  71     addflags("-fvisibility=hidden")
  72 endif ()
  73
  74 set(CMAKE_POSITION_INDEPENDENT_CODE 1)
  75 set(GTK_NS "GTK2" CACHE STRING "GTK variable prefix")
  76
  77 #-----------------------------------------------------------------------
  78 # Defs
  79 #-----------------------------------------------------------------------
  80
  81 add_definitions(-DRADIANT_VERSION="${NetRadiant_VERSION}")
  82 add_definitions(-DRADIANT_MAJOR_VERSION="${NetRadiant_VERSION_MAJOR}")
  83 add_definitions(-DRADIANT_MINOR_VERSION="${NetRadiant_VERSION_MINOR}")
  84 add_definitions(-DRADIANT_PATCH_VERSION="${NetRadiant_VERSION_PATCH}")
  85
  86 add_definitions(-DRADIANT_ABOUTMSG="${NetRadiant_ABOUT}")
  87
  88 if (NOT CMAKE_BUILD_TYPE MATCHES Release)
  89     add_definitions(-D_DEBUG=1)
  90 endif ()
  91
  92 if (APPLE)
  93     option(XWINDOWS "Build against X11" ON)
  94     add_definitions(
  95             -DPOSIX=1
  96     )
  97 elseif (WIN32)
  98     add_definitions(
  99             -DWIN32=1
 100             -D_WIN32=1
 101     )
 102 else ()
 103     set(XWINDOWS ON)
 104     add_definitions(
 105             -DPOSIX=1
 106     )
 107 endif ()
 108
 109 if (XWINDOWS)
 110     find_package(X11 REQUIRED)
 111     include_directories(${X11_INCLUDE_DIR})
 112     add_definitions(-DXWINDOWS=1)
 113 endif ()
 114
 115 include_directories("${PROJECT_SOURCE_DIR}/include")
 116 include_directories("${PROJECT_SOURCE_DIR}/libs")
 117
 118 if (WIN32 AND NOT CMAKE_CROSSCOMPILING)
 119     set(BUNDLE_LIBRARIES_DEFAULT ON)
 120 else ()
 121     set(BUNDLE_LIBRARIES_DEFAULT OFF)
 122 endif ()
 123 option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
 124
 125 macro(copy_dlls target)
 126     if (BUNDLE_LIBRARIES)
 127         add_custom_command(TARGET ${target} POST_BUILD
 128                 COMMAND bash
 129                 ARGS -c "ldd '$<TARGET_FILE:${target}>' | grep -v /c/Windows | awk '{ print $1 }' | while read dll; do cp \"$(which $dll)\" '${PROJECT_BINARY_DIR}'; done"
 130                 VERBATIM
 131                 )
 132     endif ()
 133 endmacro()
 134
 135 #-----------------------------------------------------------------------
 136 # Libraries
 137 #-----------------------------------------------------------------------
 138
 139 add_subdirectory(libs)
 140 add_subdirectory(include)
 141
 142 #-----------------------------------------------------------------------
 143 # Plugins
 144 #-----------------------------------------------------------------------
 145
 146 if (BUILD_RADIANT)
 147     add_subdirectory(contrib)
 148 endif ()
 149
 150 #-----------------------------------------------------------------------
 151 # Modules
 152 #-----------------------------------------------------------------------
 153
 154 if (BUILD_RADIANT)
 155     add_subdirectory(plugins)
 156 endif ()
 157
 158 #-----------------------------------------------------------------------
 159 # Radiant
 160 #-----------------------------------------------------------------------
 161
 162 if (CMAKE_EXECUTABLE_SUFFIX)
 163     string(REGEX REPLACE "^[.]" "" RADIANT_EXECUTABLE ${CMAKE_EXECUTABLE_SUFFIX})
 164 else ()
 165     execute_process(
 166             COMMAND uname -m
 167             OUTPUT_VARIABLE RADIANT_EXECUTABLE
 168             OUTPUT_STRIP_TRAILING_WHITESPACE
 169     )
 170 endif ()
 171
 172 macro(radiant_tool name)
 173     add_executable(${name} ${ARGN})
 174     install(
 175             TARGETS ${name}
 176             RUNTIME DESTINATION .
 177     )
 178     if (NOT (CMAKE_EXECUTABLE_SUFFIX STREQUAL ".${RADIANT_EXECUTABLE}"))
 179         add_custom_command(TARGET ${name} POST_BUILD
 180                 COMMAND ln -f -s "$<TARGET_FILE_NAME:${name}>" "${PROJECT_BINARY_DIR}/${name}.${RADIANT_EXECUTABLE}"
 181                 VERBATIM
 182                 )
 183         install(CODE "execute_process(COMMAND ${CMAKE_COMMAND} -E create_symlink \
 184             ${name}${CMAKE_EXECUTABLE_SUFFIX} \
 185             ${CMAKE_INSTALL_PREFIX}/${name}.${RADIANT_EXECUTABLE} \
 186         )")
 187     endif ()
 188 endmacro()
 189
 190 if (BUILD_RADIANT)
 191     add_subdirectory(radiant build)
 192     set_target_properties(radiant PROPERTIES
 193             COMPILE_DEFINITIONS RADIANT_EXECUTABLE="${RADIANT_EXECUTABLE}"
 194             )
 195 endif ()
 196
 197 #-----------------------------------------------------------------------
 198 # Tools
 199 #-----------------------------------------------------------------------
 200
 201 add_subdirectory(tools)
 202
 203 file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
 204
 205 if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
 206     # Copy data files from sources to the build directory
 207     message(STATUS "Copying data files")
 208     file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
 209 endif ()
 210
 211 #-----------------------------------------------------------------------
 212 # Game packs
 213 #-----------------------------------------------------------------------
 214
 215 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
 216 add_custom_target(game_packs
 217         COMMAND ${CMAKE_COMMAND} -E make_directory games
 218         COMMAND DOWNLOAD_GAMEPACKS=yes SOURCE_DIR="${PROJECT_SOURCE_DIR}" "${PROJECT_SOURCE_DIR}/install-gamepacks.sh" "${PROJECT_BINARY_DIR}"
 219         COMMENT "Downloading game packs"
 220         )
 221 if (DOWNLOAD_GAMEPACKS)
 222     add_custom_target(game_packs_all ALL DEPENDS game_packs)
 223 endif ()
 224
 225 #-----------------------------------------------------------------------
 226 # Install
 227 #-----------------------------------------------------------------------
 228
 229 install(
 230         FILES
 231         "${PROJECT_BINARY_DIR}/RADIANT_MAJOR"
 232         "${PROJECT_BINARY_DIR}/RADIANT_MINOR"
 233         "${PROJECT_BINARY_DIR}/RADIANT_PATCH"
 234         DESTINATION ${CMAKE_INSTALL_PREFIX}
 235 )
 236
 237 install(
 238         DIRECTORY
 239         ${PROJECT_SOURCE_DIR}/setup/data/tools/
 240         ${PROJECT_SOURCE_DIR}/docs
 241         DESTINATION ${CMAKE_INSTALL_PREFIX}
 242 )
 243
 244 set(GAME_FILES
 245         DarkPlaces
 246         Nexuiz
 247         OpenArena
 248         Osirion
 249         Q3
 250         Quake2
 251         Quake
 252         Quetoo
 253         Tremulous
 254         UFOAI
 255         Unvanquished
 256         Warsow
 257         Xonotic
 258         )
 259 unset(_tmp)
 260 foreach (it ${GAME_FILES})
 261     set(dir "${PROJECT_BINARY_DIR}/games/${it}Pack")
 262     string(TOLOWER "${it}" it)
 263     list(APPEND _tmp "${dir}/games")
 264     list(APPEND _tmp "${dir}/${it}.game")
 265 endforeach ()
 266 set(GAME_FILES ${_tmp})
 267
 268 install(
 269         DIRECTORY
 270         ${GAME_FILES}
 271         DESTINATION ${CMAKE_INSTALL_PREFIX}
 272         OPTIONAL
 273 )