CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.12 FATAL_ERROR)
   2 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
   3 project(NetRadiant C CXX)
   4
   5 option(BUILD_RADIANT "Build the GUI" ON)
   6
   7 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
   8     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
   9 endif ()
  10
  11 #-----------------------------------------------------------------------
  12 # Version
  13 #-----------------------------------------------------------------------
  14
  15 # CMake 3.0+ would allow this in project()
  16 set(NetRadiant_VERSION_MAJOR 1)
  17 set(NetRadiant_VERSION_MINOR 5)
  18 set(NetRadiant_VERSION_PATCH 0)
  19 set(NetRadiant_VERSION "${NetRadiant_VERSION_MAJOR}.${NetRadiant_VERSION_MINOR}.${NetRadiant_VERSION_PATCH}")
  20
  21 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_MAJOR" ${NetRadiant_VERSION_MAJOR})
  22 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_MINOR" ${NetRadiant_VERSION_MINOR})
  23 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_PATCH" ${NetRadiant_VERSION_PATCH})
  24
  25 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
  26
  27 find_package(Git REQUIRED)
  28 execute_process(
  29         COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
  30         WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
  31         OUTPUT_VARIABLE GIT_VERSION
  32         OUTPUT_STRIP_TRAILING_WHITESPACE
  33 )
  34 set(RADIANT_VERSION_STRING "${NetRadiant_VERSION}n")
  35 if (GIT_VERSION)
  36     set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
  37 endif ()
  38
  39 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
  40
  41 #-----------------------------------------------------------------------
  42 # Language standard
  43 #-----------------------------------------------------------------------
  44
  45 set(CMAKE_CXX_STANDARD 11)
  46 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  47 if (CMAKE_VERSION VERSION_LESS "3.1")
  48     if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
  49         include(CheckCXXCompilerFlag)
  50         check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
  51         if (STD_CXX)
  52             set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
  53         else ()
  54             message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
  55         endif ()
  56     else ()
  57         message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
  58     endif ()
  59 endif ()
  60
  61 #-----------------------------------------------------------------------
  62 # Flags
  63 #-----------------------------------------------------------------------
  64
  65 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
  66 macro(addflags_c args)
  67     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
  68 endmacro()
  69 macro(addflags_cxx args)
  70     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
  71 endmacro()
  72 macro(addflags args)
  73     addflags_c("${args}")
  74     addflags_cxx("${args}")
  75 endmacro()
  76 addflags("-fno-strict-aliasing")
  77 if (NOT WIN32)
  78     addflags("-fvisibility=hidden")
  79 endif ()
  80
  81 if ("${CMAKE_BUILD_TYPE}" STREQUAL "Debug")
  82     addflags("-Werror")
  83     addflags("-pedantic-errors")
  84 endif ()
  85
  86 addflags("-Wall")
  87 addflags("-Wextra")
  88 addflags("-pedantic")
  89
  90 addflags("-Wno-pedantic")
  91 addflags("-Wno-parentheses")
  92 addflags("-Wno-sign-compare")
  93 addflags("-Wno-write-strings")
  94 addflags("-Wno-unused-function")
  95 addflags("-Wno-unused-variable")
  96 addflags("-Wno-unused-parameter")
  97 addflags("-Wno-deprecated-declarations")
  98 addflags("-Wno-unused-but-set-variable")
  99 addflags("-Wno-missing-field-initializers")
 100
 101 addflags_c("-Wno-int-conversion")
 102 addflags_c("-Wno-pointer-to-int-cast")
 103 addflags_c("-Wno-incompatible-pointer-types")
 104
 105 addflags_cxx("-Wno-reorder")
 106 addflags_cxx("-Wno-delete-non-virtual-dtor")
 107
 108 set(CMAKE_POSITION_INDEPENDENT_CODE 1)
 109 set(GTK_TARGET 2 CACHE STRING "GTK target")
 110 add_definitions(-DGTK_TARGET=${GTK_TARGET})
 111
 112 #-----------------------------------------------------------------------
 113 # Defs
 114 #-----------------------------------------------------------------------
 115
 116 add_definitions(-DRADIANT_VERSION="${NetRadiant_VERSION}")
 117 add_definitions(-DRADIANT_MAJOR_VERSION="${NetRadiant_VERSION_MAJOR}")
 118 add_definitions(-DRADIANT_MINOR_VERSION="${NetRadiant_VERSION_MINOR}")
 119 add_definitions(-DRADIANT_PATCH_VERSION="${NetRadiant_VERSION_PATCH}")
 120
 121 add_definitions(-DRADIANT_ABOUTMSG="${NetRadiant_ABOUT}")
 122
 123 if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 124     add_definitions(-D_DEBUG=1)
 125 endif ()
 126
 127 macro(disable_deprecated name gtk2only)
 128     add_definitions(-D${name}_DISABLE_SINGLE_INCLUDES)
 129     if ((${gtk2only} EQUAL 0) OR (GTK_TARGET EQUAL 2))
 130         add_definitions(-D${name}_DISABLE_DEPRECATED)
 131     endif ()
 132 endmacro()
 133
 134 disable_deprecated(ATK 0)
 135 disable_deprecated(G 0)
 136 disable_deprecated(GDK 0)
 137 disable_deprecated(GDK_PIXBUF 0)
 138 disable_deprecated(GTK 1)
 139 disable_deprecated(PANGO 0)
 140
 141 if (APPLE)
 142     option(XWINDOWS "Build against X11" ON)
 143     add_definitions(
 144             -DPOSIX=1
 145     )
 146 elseif (WIN32)
 147     add_definitions(
 148             -DWIN32=1
 149             -D_WIN32=1
 150     )
 151 else ()
 152     set(XWINDOWS ON)
 153     add_definitions(
 154             -DPOSIX=1
 155     )
 156 endif ()
 157
 158 if (XWINDOWS)
 159     find_package(X11 REQUIRED)
 160     include_directories(${X11_INCLUDE_DIR})
 161     add_definitions(-DXWINDOWS=1)
 162 endif ()
 163
 164 include_directories("${PROJECT_SOURCE_DIR}/include")
 165 include_directories("${PROJECT_SOURCE_DIR}/libs")
 166
 167 if (WIN32 AND NOT CMAKE_CROSSCOMPILING)
 168     set(BUNDLE_LIBRARIES_DEFAULT ON)
 169 else ()
 170     set(BUNDLE_LIBRARIES_DEFAULT OFF)
 171 endif ()
 172 option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
 173
 174 macro(copy_dlls target)
 175     if (BUNDLE_LIBRARIES)
 176         add_custom_command(TARGET ${target} POST_BUILD
 177                 COMMAND bash
 178                 ARGS -c "ldd '$<TARGET_FILE:${target}>' | grep -v /c/Windows | awk '{ print $1 }' | while read dll; do cp \"$(which $dll)\" '${PROJECT_BINARY_DIR}'; done"
 179                 VERBATIM
 180                 )
 181     endif ()
 182 endmacro()
 183
 184 #-----------------------------------------------------------------------
 185 # Libraries
 186 #-----------------------------------------------------------------------
 187
 188 add_subdirectory(libs)
 189 add_subdirectory(include)
 190
 191 #-----------------------------------------------------------------------
 192 # Plugins
 193 #-----------------------------------------------------------------------
 194
 195 if (BUILD_RADIANT)
 196     add_subdirectory(contrib)
 197 endif ()
 198
 199 #-----------------------------------------------------------------------
 200 # Modules
 201 #-----------------------------------------------------------------------
 202
 203 if (BUILD_RADIANT)
 204     add_subdirectory(plugins)
 205 endif ()
 206
 207 #-----------------------------------------------------------------------
 208 # Radiant
 209 #-----------------------------------------------------------------------
 210
 211 if (CMAKE_EXECUTABLE_SUFFIX)
 212     string(REGEX REPLACE "^[.]" "" RADIANT_EXECUTABLE ${CMAKE_EXECUTABLE_SUFFIX})
 213 else ()
 214     execute_process(
 215             COMMAND uname -m
 216             OUTPUT_VARIABLE RADIANT_EXECUTABLE
 217             OUTPUT_STRIP_TRAILING_WHITESPACE
 218     )
 219 endif ()
 220
 221 macro(radiant_tool name)
 222     add_executable(${name} ${ARGN})
 223     install(
 224             TARGETS ${name}
 225             RUNTIME DESTINATION .
 226     )
 227     if (NOT (CMAKE_EXECUTABLE_SUFFIX STREQUAL ".${RADIANT_EXECUTABLE}"))
 228         add_custom_command(TARGET ${name} POST_BUILD
 229                 COMMAND ln -f -s "$<TARGET_FILE_NAME:${name}>" "${PROJECT_BINARY_DIR}/${name}.${RADIANT_EXECUTABLE}"
 230                 VERBATIM
 231                 )
 232         install(CODE "execute_process(COMMAND ${CMAKE_COMMAND} -E create_symlink
 233                 ${name}${CMAKE_EXECUTABLE_SUFFIX} ${CMAKE_INSTALL_PREFIX}/${name}.${RADIANT_EXECUTABLE})
 234                 ")
 235     endif ()
 236 endmacro()
 237
 238 if (BUILD_RADIANT)
 239     add_subdirectory(radiant _radiant)
 240     set_target_properties(radiant PROPERTIES
 241             COMPILE_DEFINITIONS RADIANT_EXECUTABLE="${RADIANT_EXECUTABLE}"
 242             )
 243 endif ()
 244
 245 #-----------------------------------------------------------------------
 246 # Tools
 247 #-----------------------------------------------------------------------
 248
 249 add_subdirectory(tools)
 250
 251 file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
 252
 253 if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
 254     # Copy data files from sources to the build directory
 255     message(STATUS "Copying data files")
 256     file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
 257 endif ()
 258
 259 #-----------------------------------------------------------------------
 260 # Game packs
 261 #-----------------------------------------------------------------------
 262
 263 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
 264 add_custom_target(game_packs
 265         COMMAND ${CMAKE_COMMAND} -E make_directory games
 266         COMMAND DOWNLOAD_GAMEPACKS=yes SOURCE_DIR="${PROJECT_SOURCE_DIR}" "${PROJECT_SOURCE_DIR}/install-gamepacks.sh" "${PROJECT_BINARY_DIR}"
 267         COMMENT "Downloading game packs"
 268         )
 269 if (DOWNLOAD_GAMEPACKS)
 270     add_custom_target(game_packs_all ALL DEPENDS game_packs)
 271 endif ()
 272
 273 #-----------------------------------------------------------------------
 274 # Install
 275 #-----------------------------------------------------------------------
 276
 277 install(
 278         FILES
 279         "${PROJECT_BINARY_DIR}/RADIANT_MAJOR"
 280         "${PROJECT_BINARY_DIR}/RADIANT_MINOR"
 281         "${PROJECT_BINARY_DIR}/RADIANT_PATCH"
 282         DESTINATION .
 283 )
 284
 285 install(
 286         DIRECTORY
 287         setup/data/tools/
 288         docs
 289         DESTINATION .
 290 )
 291
 292 set(GAME_FILES
 293         DarkPlaces
 294         Nexuiz
 295         OpenArena
 296         Osirion
 297         Q3
 298         Quake2
 299         Quake
 300         Quetoo
 301         Tremulous
 302         UFOAI
 303         Unvanquished
 304         Warsow
 305         Xonotic
 306         )
 307 unset(_tmp)
 308 foreach (it ${GAME_FILES})
 309     set(dir "${PROJECT_BINARY_DIR}/games/${it}Pack")
 310     string(TOLOWER "${it}" it)
 311     list(APPEND _tmp "${dir}/games")
 312     list(APPEND _tmp "${dir}/${it}.game")
 313 endforeach ()
 314 set(GAME_FILES ${_tmp})
 315
 316 install(
 317         DIRECTORY
 318         ${GAME_FILES}
 319         DESTINATION .
 320         OPTIONAL
 321 )
 322
 323 include(cmake/scripts/package.cmake)