CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.12 FATAL_ERROR)
   2 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
   3 project(NetRadiant C CXX)
   4
   5 option(BUILD_RADIANT "Build the GUI" ON)
   6
   7 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
   8     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
   9 endif ()
  10
  11 #-----------------------------------------------------------------------
  12 # Version
  13 #-----------------------------------------------------------------------
  14
  15 # CMake 3.0+ would allow this in project()
  16 set(NetRadiant_VERSION_MAJOR 1)
  17 set(NetRadiant_VERSION_MINOR 5)
  18 set(NetRadiant_VERSION_PATCH 0)
  19 set(NetRadiant_VERSION "${NetRadiant_VERSION_MAJOR}.${NetRadiant_VERSION_MINOR}.${NetRadiant_VERSION_PATCH}")
  20
  21 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_MAJOR" ${NetRadiant_VERSION_MAJOR})
  22 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_MINOR" ${NetRadiant_VERSION_MINOR})
  23 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_PATCH" ${NetRadiant_VERSION_PATCH})
  24
  25 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
  26
  27 find_package(Git REQUIRED)
  28 execute_process(
  29         COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
  30         WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
  31         OUTPUT_VARIABLE GIT_VERSION
  32         OUTPUT_STRIP_TRAILING_WHITESPACE
  33 )
  34 set(RADIANT_VERSION_STRING "${NetRadiant_VERSION}n")
  35 if (GIT_VERSION)
  36     set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
  37 endif ()
  38
  39 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
  40
  41 #-----------------------------------------------------------------------
  42 # Language standard
  43 #-----------------------------------------------------------------------
  44
  45 set(CMAKE_CXX_STANDARD 11)
  46 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  47 if (CMAKE_VERSION VERSION_LESS "3.1")
  48     if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
  49         include(CheckCXXCompilerFlag)
  50         check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
  51         if (STD_CXX)
  52             set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
  53         else ()
  54             message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
  55         endif ()
  56     else ()
  57         message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
  58     endif ()
  59 endif ()
  60
  61 #-----------------------------------------------------------------------
  62 # Flags
  63 #-----------------------------------------------------------------------
  64
  65 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
  66 macro(addflags_c args)
  67     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
  68 endmacro()
  69 macro(addflags_cxx args)
  70     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
  71 endmacro()
  72 macro(addflags args)
  73     addflags_c("${args}")
  74     addflags_cxx("${args}")
  75 endmacro()
  76 addflags("-fno-strict-aliasing")
  77 if (NOT WIN32)
  78     addflags("-fvisibility=hidden")
  79 endif ()
  80
  81 if ("${CMAKE_BUILD_TYPE}" STREQUAL "Debug")
  82     addflags("-Werror")
  83     addflags("-pedantic-errors")
  84 endif ()
  85
  86 addflags("-Wall")
  87 addflags("-Wextra")
  88 addflags("-pedantic")
  89
  90 addflags_c("-Wno-deprecated-declarations") # vfs.c: g_strdown
  91
  92 addflags("-Wno-sign-compare")
  93 addflags("-Wno-unused-function")
  94 addflags("-Wno-unused-variable")
  95 addflags("-Wno-unused-parameter")
  96 addflags("-Wno-missing-field-initializers")
  97
  98 addflags_c("-Wno-pointer-to-int-cast")
  99 addflags_c("-Wno-incompatible-pointer-types")
 100
 101 set(CMAKE_POSITION_INDEPENDENT_CODE 1)
 102 set(GTK_TARGET 2 CACHE STRING "GTK target")
 103 add_definitions(-DGTK_TARGET=${GTK_TARGET})
 104
 105 #-----------------------------------------------------------------------
 106 # Defs
 107 #-----------------------------------------------------------------------
 108
 109 add_definitions(-DRADIANT_VERSION="${NetRadiant_VERSION}")
 110 add_definitions(-DRADIANT_MAJOR_VERSION="${NetRadiant_VERSION_MAJOR}")
 111 add_definitions(-DRADIANT_MINOR_VERSION="${NetRadiant_VERSION_MINOR}")
 112 add_definitions(-DRADIANT_PATCH_VERSION="${NetRadiant_VERSION_PATCH}")
 113
 114 add_definitions(-DRADIANT_ABOUTMSG="${NetRadiant_ABOUT}")
 115
 116 if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 117     add_definitions(-D_DEBUG=1)
 118 endif ()
 119
 120 macro(disable_deprecated name gtk2only)
 121     add_definitions(-D${name}_DISABLE_SINGLE_INCLUDES)
 122     if ((${gtk2only} EQUAL 0) OR (GTK_TARGET EQUAL 2))
 123         add_definitions(-D${name}_DISABLE_DEPRECATED)
 124     endif ()
 125 endmacro()
 126
 127 disable_deprecated(ATK 0)
 128 disable_deprecated(G 0)
 129 disable_deprecated(GDK 0)
 130 disable_deprecated(GDK_PIXBUF 0)
 131 disable_deprecated(GTK 1)
 132 disable_deprecated(PANGO 0)
 133
 134 if (APPLE)
 135     option(XWINDOWS "Build against X11" ON)
 136     add_definitions(
 137             -DPOSIX=1
 138     )
 139 elseif (WIN32)
 140     add_definitions(
 141             -DWIN32=1
 142             -D_WIN32=1
 143     )
 144 else ()
 145     set(XWINDOWS ON)
 146     add_definitions(
 147             -DPOSIX=1
 148     )
 149 endif ()
 150
 151 if (XWINDOWS)
 152     find_package(X11 REQUIRED)
 153     include_directories(${X11_INCLUDE_DIR})
 154     add_definitions(-DXWINDOWS=1)
 155 endif ()
 156
 157 include_directories("${PROJECT_SOURCE_DIR}/include")
 158 include_directories("${PROJECT_SOURCE_DIR}/libs")
 159
 160 if (WIN32 AND NOT CMAKE_CROSSCOMPILING)
 161     set(BUNDLE_LIBRARIES_DEFAULT ON)
 162 else ()
 163     set(BUNDLE_LIBRARIES_DEFAULT OFF)
 164 endif ()
 165 option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
 166
 167 macro(copy_dlls target)
 168     if (BUNDLE_LIBRARIES)
 169         add_custom_command(TARGET ${target} POST_BUILD
 170                 COMMAND bash
 171                 ARGS -c "ldd '$<TARGET_FILE:${target}>' | grep -v /c/Windows | awk '{ print $1 }' | while read dll; do cp \"$(which $dll)\" '${PROJECT_BINARY_DIR}'; done"
 172                 VERBATIM
 173                 )
 174     endif ()
 175 endmacro()
 176
 177 #-----------------------------------------------------------------------
 178 # Libraries
 179 #-----------------------------------------------------------------------
 180
 181 add_subdirectory(libs)
 182 add_subdirectory(include)
 183
 184 #-----------------------------------------------------------------------
 185 # Plugins
 186 #-----------------------------------------------------------------------
 187
 188 if (BUILD_RADIANT)
 189     add_subdirectory(contrib)
 190 endif ()
 191
 192 #-----------------------------------------------------------------------
 193 # Modules
 194 #-----------------------------------------------------------------------
 195
 196 if (BUILD_RADIANT)
 197     add_subdirectory(plugins)
 198 endif ()
 199
 200 #-----------------------------------------------------------------------
 201 # Radiant
 202 #-----------------------------------------------------------------------
 203
 204 if (CMAKE_EXECUTABLE_SUFFIX)
 205     string(REGEX REPLACE "^[.]" "" RADIANT_EXECUTABLE ${CMAKE_EXECUTABLE_SUFFIX})
 206 else ()
 207     execute_process(
 208             COMMAND uname -m
 209             OUTPUT_VARIABLE RADIANT_EXECUTABLE
 210             OUTPUT_STRIP_TRAILING_WHITESPACE
 211     )
 212 endif ()
 213
 214 macro(radiant_tool name)
 215     add_executable(${name} ${ARGN})
 216     install(
 217             TARGETS ${name}
 218             RUNTIME DESTINATION .
 219     )
 220     if (NOT (CMAKE_EXECUTABLE_SUFFIX STREQUAL ".${RADIANT_EXECUTABLE}"))
 221         add_custom_command(TARGET ${name} POST_BUILD
 222                 COMMAND ln -f -s "$<TARGET_FILE_NAME:${name}>" "${PROJECT_BINARY_DIR}/${name}.${RADIANT_EXECUTABLE}"
 223                 VERBATIM
 224                 )
 225         install(CODE "execute_process(COMMAND ${CMAKE_COMMAND} -E create_symlink
 226                 ${name}${CMAKE_EXECUTABLE_SUFFIX} ${CMAKE_INSTALL_PREFIX}/${name}.${RADIANT_EXECUTABLE})
 227                 ")
 228     endif ()
 229 endmacro()
 230
 231 if (BUILD_RADIANT)
 232     add_subdirectory(radiant _radiant)
 233     set_target_properties(radiant PROPERTIES
 234             COMPILE_DEFINITIONS RADIANT_EXECUTABLE="${RADIANT_EXECUTABLE}"
 235             )
 236 endif ()
 237
 238 #-----------------------------------------------------------------------
 239 # Tools
 240 #-----------------------------------------------------------------------
 241
 242 add_subdirectory(tools)
 243
 244 file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
 245
 246 if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
 247     # Copy data files from sources to the build directory
 248     message(STATUS "Copying data files")
 249     file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
 250 endif ()
 251
 252 #-----------------------------------------------------------------------
 253 # Game packs
 254 #-----------------------------------------------------------------------
 255
 256 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
 257 add_custom_target(game_packs
 258         COMMAND ${CMAKE_COMMAND} -E make_directory games
 259         COMMAND DOWNLOAD_GAMEPACKS=yes SOURCE_DIR="${PROJECT_SOURCE_DIR}" "${PROJECT_SOURCE_DIR}/install-gamepacks.sh" "${PROJECT_BINARY_DIR}"
 260         COMMENT "Downloading game packs"
 261         )
 262 if (DOWNLOAD_GAMEPACKS)
 263     add_custom_target(game_packs_all ALL DEPENDS game_packs)
 264 endif ()
 265
 266 #-----------------------------------------------------------------------
 267 # Install
 268 #-----------------------------------------------------------------------
 269
 270 install(
 271         FILES
 272         "${PROJECT_BINARY_DIR}/RADIANT_MAJOR"
 273         "${PROJECT_BINARY_DIR}/RADIANT_MINOR"
 274         "${PROJECT_BINARY_DIR}/RADIANT_PATCH"
 275         DESTINATION .
 276 )
 277
 278 install(
 279         DIRECTORY
 280         setup/data/tools/
 281         docs
 282         DESTINATION .
 283 )
 284
 285 set(GAME_FILES
 286         DarkPlaces
 287         Nexuiz
 288         OpenArena
 289         Osirion
 290         Q3
 291         Quake2
 292         Quake
 293         Quetoo
 294         Tremulous
 295         UFOAI
 296         Unvanquished
 297         Warsow
 298         Xonotic
 299         )
 300 unset(_tmp)
 301 foreach (it ${GAME_FILES})
 302     set(dir "${PROJECT_BINARY_DIR}/games/${it}Pack")
 303     string(TOLOWER "${it}" it)
 304     list(APPEND _tmp "${dir}/games")
 305     list(APPEND _tmp "${dir}/${it}.game")
 306 endforeach ()
 307 set(GAME_FILES ${_tmp})
 308
 309 install(
 310         DIRECTORY
 311         ${GAME_FILES}
 312         DESTINATION .
 313         OPTIONAL
 314 )
 315
 316 include(cmake/scripts/package.cmake)