Remove -Wno-pedantic
[xonotic/netradiant.git] / CMakeLists.txt
1 cmake_minimum_required(VERSION 2.8.12 FATAL_ERROR)
2 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
3 project(NetRadiant C CXX)
4
5 option(BUILD_RADIANT "Build the GUI" ON)
6
7 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
8     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
9 endif ()
10
11 #-----------------------------------------------------------------------
12 # Version
13 #-----------------------------------------------------------------------
14
15 # CMake 3.0+ would allow this in project()
16 set(NetRadiant_VERSION_MAJOR 1)
17 set(NetRadiant_VERSION_MINOR 5)
18 set(NetRadiant_VERSION_PATCH 0)
19 set(NetRadiant_VERSION "${NetRadiant_VERSION_MAJOR}.${NetRadiant_VERSION_MINOR}.${NetRadiant_VERSION_PATCH}")
20
21 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_MAJOR" ${NetRadiant_VERSION_MAJOR})
22 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_MINOR" ${NetRadiant_VERSION_MINOR})
23 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_PATCH" ${NetRadiant_VERSION_PATCH})
24
25 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
26
27 find_package(Git REQUIRED)
28 execute_process(
29         COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
30         WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
31         OUTPUT_VARIABLE GIT_VERSION
32         OUTPUT_STRIP_TRAILING_WHITESPACE
33 )
34 set(RADIANT_VERSION_STRING "${NetRadiant_VERSION}n")
35 if (GIT_VERSION)
36     set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
37 endif ()
38
39 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
40
41 #-----------------------------------------------------------------------
42 # Language standard
43 #-----------------------------------------------------------------------
44
45 set(CMAKE_CXX_STANDARD 11)
46 set(CMAKE_CXX_STANDARD_REQUIRED ON)
47 if (CMAKE_VERSION VERSION_LESS "3.1")
48     if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
49         include(CheckCXXCompilerFlag)
50         check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
51         if (STD_CXX)
52             set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
53         else ()
54             message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
55         endif ()
56     else ()
57         message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
58     endif ()
59 endif ()
60
61 #-----------------------------------------------------------------------
62 # Flags
63 #-----------------------------------------------------------------------
64
65 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
66 macro(addflags_c args)
67     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
68 endmacro()
69 macro(addflags_cxx args)
70     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
71 endmacro()
72 macro(addflags args)
73     addflags_c("${args}")
74     addflags_cxx("${args}")
75 endmacro()
76 addflags("-fno-strict-aliasing")
77 if (NOT WIN32)
78     addflags("-fvisibility=hidden")
79 endif ()
80
81 if ("${CMAKE_BUILD_TYPE}" STREQUAL "Debug")
82     addflags("-Werror")
83     addflags("-pedantic-errors")
84 endif ()
85
86 addflags("-Wall")
87 addflags("-Wextra")
88 addflags("-pedantic")
89
90 addflags("-Wno-parentheses")
91 addflags("-Wno-sign-compare")
92 addflags("-Wno-write-strings")
93 addflags("-Wno-unused-function")
94 addflags("-Wno-unused-variable")
95 addflags("-Wno-unused-parameter")
96 addflags("-Wno-deprecated-declarations")
97 addflags("-Wno-unused-but-set-variable")
98 addflags("-Wno-missing-field-initializers")
99
100 addflags_c("-Wno-int-conversion")
101 addflags_c("-Wno-pointer-to-int-cast")
102 addflags_c("-Wno-incompatible-pointer-types")
103
104 addflags_cxx("-Wno-reorder")
105 addflags_cxx("-Wno-delete-non-virtual-dtor")
106
107 set(CMAKE_POSITION_INDEPENDENT_CODE 1)
108 set(GTK_TARGET 2 CACHE STRING "GTK target")
109 add_definitions(-DGTK_TARGET=${GTK_TARGET})
110
111 #-----------------------------------------------------------------------
112 # Defs
113 #-----------------------------------------------------------------------
114
115 add_definitions(-DRADIANT_VERSION="${NetRadiant_VERSION}")
116 add_definitions(-DRADIANT_MAJOR_VERSION="${NetRadiant_VERSION_MAJOR}")
117 add_definitions(-DRADIANT_MINOR_VERSION="${NetRadiant_VERSION_MINOR}")
118 add_definitions(-DRADIANT_PATCH_VERSION="${NetRadiant_VERSION_PATCH}")
119
120 add_definitions(-DRADIANT_ABOUTMSG="${NetRadiant_ABOUT}")
121
122 if (NOT CMAKE_BUILD_TYPE MATCHES Release)
123     add_definitions(-D_DEBUG=1)
124 endif ()
125
126 macro(disable_deprecated name gtk2only)
127     add_definitions(-D${name}_DISABLE_SINGLE_INCLUDES)
128     if ((${gtk2only} EQUAL 0) OR (GTK_TARGET EQUAL 2))
129         add_definitions(-D${name}_DISABLE_DEPRECATED)
130     endif ()
131 endmacro()
132
133 disable_deprecated(ATK 0)
134 disable_deprecated(G 0)
135 disable_deprecated(GDK 0)
136 disable_deprecated(GDK_PIXBUF 0)
137 disable_deprecated(GTK 1)
138 disable_deprecated(PANGO 0)
139
140 if (APPLE)
141     option(XWINDOWS "Build against X11" ON)
142     add_definitions(
143             -DPOSIX=1
144     )
145 elseif (WIN32)
146     add_definitions(
147             -DWIN32=1
148             -D_WIN32=1
149     )
150 else ()
151     set(XWINDOWS ON)
152     add_definitions(
153             -DPOSIX=1
154     )
155 endif ()
156
157 if (XWINDOWS)
158     find_package(X11 REQUIRED)
159     include_directories(${X11_INCLUDE_DIR})
160     add_definitions(-DXWINDOWS=1)
161 endif ()
162
163 include_directories("${PROJECT_SOURCE_DIR}/include")
164 include_directories("${PROJECT_SOURCE_DIR}/libs")
165
166 if (WIN32 AND NOT CMAKE_CROSSCOMPILING)
167     set(BUNDLE_LIBRARIES_DEFAULT ON)
168 else ()
169     set(BUNDLE_LIBRARIES_DEFAULT OFF)
170 endif ()
171 option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
172
173 macro(copy_dlls target)
174     if (BUNDLE_LIBRARIES)
175         add_custom_command(TARGET ${target} POST_BUILD
176                 COMMAND bash
177                 ARGS -c "ldd '$<TARGET_FILE:${target}>' | grep -v /c/Windows | awk '{ print $1 }' | while read dll; do cp \"$(which $dll)\" '${PROJECT_BINARY_DIR}'; done"
178                 VERBATIM
179                 )
180     endif ()
181 endmacro()
182
183 #-----------------------------------------------------------------------
184 # Libraries
185 #-----------------------------------------------------------------------
186
187 add_subdirectory(libs)
188 add_subdirectory(include)
189
190 #-----------------------------------------------------------------------
191 # Plugins
192 #-----------------------------------------------------------------------
193
194 if (BUILD_RADIANT)
195     add_subdirectory(contrib)
196 endif ()
197
198 #-----------------------------------------------------------------------
199 # Modules
200 #-----------------------------------------------------------------------
201
202 if (BUILD_RADIANT)
203     add_subdirectory(plugins)
204 endif ()
205
206 #-----------------------------------------------------------------------
207 # Radiant
208 #-----------------------------------------------------------------------
209
210 if (CMAKE_EXECUTABLE_SUFFIX)
211     string(REGEX REPLACE "^[.]" "" RADIANT_EXECUTABLE ${CMAKE_EXECUTABLE_SUFFIX})
212 else ()
213     execute_process(
214             COMMAND uname -m
215             OUTPUT_VARIABLE RADIANT_EXECUTABLE
216             OUTPUT_STRIP_TRAILING_WHITESPACE
217     )
218 endif ()
219
220 macro(radiant_tool name)
221     add_executable(${name} ${ARGN})
222     install(
223             TARGETS ${name}
224             RUNTIME DESTINATION .
225     )
226     if (NOT (CMAKE_EXECUTABLE_SUFFIX STREQUAL ".${RADIANT_EXECUTABLE}"))
227         add_custom_command(TARGET ${name} POST_BUILD
228                 COMMAND ln -f -s "$<TARGET_FILE_NAME:${name}>" "${PROJECT_BINARY_DIR}/${name}.${RADIANT_EXECUTABLE}"
229                 VERBATIM
230                 )
231         install(CODE "execute_process(COMMAND ${CMAKE_COMMAND} -E create_symlink
232                 ${name}${CMAKE_EXECUTABLE_SUFFIX} ${CMAKE_INSTALL_PREFIX}/${name}.${RADIANT_EXECUTABLE})
233                 ")
234     endif ()
235 endmacro()
236
237 if (BUILD_RADIANT)
238     add_subdirectory(radiant _radiant)
239     set_target_properties(radiant PROPERTIES
240             COMPILE_DEFINITIONS RADIANT_EXECUTABLE="${RADIANT_EXECUTABLE}"
241             )
242 endif ()
243
244 #-----------------------------------------------------------------------
245 # Tools
246 #-----------------------------------------------------------------------
247
248 add_subdirectory(tools)
249
250 file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
251
252 if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
253     # Copy data files from sources to the build directory
254     message(STATUS "Copying data files")
255     file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
256 endif ()
257
258 #-----------------------------------------------------------------------
259 # Game packs
260 #-----------------------------------------------------------------------
261
262 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
263 add_custom_target(game_packs
264         COMMAND ${CMAKE_COMMAND} -E make_directory games
265         COMMAND DOWNLOAD_GAMEPACKS=yes SOURCE_DIR="${PROJECT_SOURCE_DIR}" "${PROJECT_SOURCE_DIR}/install-gamepacks.sh" "${PROJECT_BINARY_DIR}"
266         COMMENT "Downloading game packs"
267         )
268 if (DOWNLOAD_GAMEPACKS)
269     add_custom_target(game_packs_all ALL DEPENDS game_packs)
270 endif ()
271
272 #-----------------------------------------------------------------------
273 # Install
274 #-----------------------------------------------------------------------
275
276 install(
277         FILES
278         "${PROJECT_BINARY_DIR}/RADIANT_MAJOR"
279         "${PROJECT_BINARY_DIR}/RADIANT_MINOR"
280         "${PROJECT_BINARY_DIR}/RADIANT_PATCH"
281         DESTINATION .
282 )
283
284 install(
285         DIRECTORY
286         setup/data/tools/
287         docs
288         DESTINATION .
289 )
290
291 set(GAME_FILES
292         DarkPlaces
293         Nexuiz
294         OpenArena
295         Osirion
296         Q3
297         Quake2
298         Quake
299         Quetoo
300         Tremulous
301         UFOAI
302         Unvanquished
303         Warsow
304         Xonotic
305         )
306 unset(_tmp)
307 foreach (it ${GAME_FILES})
308     set(dir "${PROJECT_BINARY_DIR}/games/${it}Pack")
309     string(TOLOWER "${it}" it)
310     list(APPEND _tmp "${dir}/games")
311     list(APPEND _tmp "${dir}/${it}.game")
312 endforeach ()
313 set(GAME_FILES ${_tmp})
314
315 install(
316         DIRECTORY
317         ${GAME_FILES}
318         DESTINATION .
319         OPTIONAL
320 )
321
322 include(cmake/scripts/package.cmake)