Remove a wrong and never executed piece of code within minstagib_items.
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / Main.qc
1 // --------------------------------------------------------------------------
2 // BEGIN REQUIRED CSQC FUNCTIONS
3 //include "main.qh"
4
5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
6
7 void cvar_clientsettemp(string cv, string val)
8 {
9         entity e;
10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
11                 if(e.netname == cv)
12                         goto saved;
13         e = spawn();
14         e.classname = "saved_cvar_value";
15         e.netname = strzone(cv);
16         e.message = strzone(cvar_string(cv));
17 :saved
18         cvar_set(cv, val);
19 }
20
21 void cvar_clientsettemp_restore()
22 {
23         entity e;
24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
25                         cvar_set(e.netname, e.message);
26 }
27
28 void() menu_show_error =
29 {
30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);
31 };
32
33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
34 // Useful for precaching things
35
36 void() menu_sub_null =
37 {
38 };
39
40 #ifdef USE_FTE
41 float __engine_check;
42 #endif
43
44 string forcefog;
45 string cl_announcer_prev;
46 void WaypointSprite_Load();
47 void CSQC_Init(void)
48 {
49 #ifdef USE_FTE
50 #pragma target ID
51         __engine_check = checkextension("DP_SV_WRITEPICTURE");
52         if(!__engine_check)
53         {
54                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");
55                 localcmd("\ndisconnect\n");
56                 return;
57         }
58 #pragma target FTE
59 #endif
60         
61         check_unacceptable_compiler_bugs();
62
63 #ifdef WATERMARK
64         print("^4CSQC Build information: ", WATERMARK(), "\n");
65 #endif
66
67         float i;
68         CSQC_CheckEngine();
69
70         binddb = db_create();
71         tempdb = db_create();
72         ClientProgsDB = db_load("client.db");
73         compressShortVector_init();
74
75         drawfont = 0;
76         menu_visible = FALSE;
77         menu_show = menu_show_error;
78         menu_action = menu_sub_null;
79
80         for(i = 0; i < 255; ++i)
81                 if(getplayerkey(i, "viewentity") == "")
82                         break;
83         maxclients = i;
84
85         //ctf_temp_1 = "";
86         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
87         //registercmd("ctf_menu");
88         registercmd("ons_map");
89         registercmd("hud_configure");
90         registercmd("hud_save");
91         //registercmd("menu_action");
92
93         registercmd("+button3");
94         registercmd("-button3");
95         registercmd("+button4");
96         registercmd("-button4");
97         registercmd("+showscores");registercmd("-showscores");
98         registercmd("+showaccuracy");registercmd("-showaccuracy");
99
100 #ifndef CAMERATEST
101         if(isdemo())
102         {
103 #endif
104                 registercmd("+forward");registercmd("-forward");
105                 registercmd("+back");registercmd("-back");
106                 registercmd("+moveup");registercmd("-moveup");
107                 registercmd("+movedown");registercmd("-movedown");
108                 registercmd("+moveright");registercmd("-moveright");
109                 registercmd("+moveleft");registercmd("-moveleft");
110                 registercmd("+roll_right");registercmd("-roll_right");
111                 registercmd("+roll_left");registercmd("-roll_left");
112 #ifndef CAMERATEST
113         }
114 #endif
115         registercvar("hud_usecsqc", "1");
116         registercvar("scoreboard_columns", "default", CVAR_SAVE);
117
118         gametype = 0;
119
120         // hud_fields uses strunzone on the titles!
121         for(i = 0; i < MAX_HUD_FIELDS; ++i)
122                 hud_title[i] = strzone("(null)");
123
124         postinit = false;
125
126         calledhooks = 0;
127
128         teams = Sort_Spawn();
129         players = Sort_Spawn();
130
131         GetTeam(COLOR_SPECTATOR, true); // add specs first
132
133         RegisterWeapons();
134
135         WaypointSprite_Load();
136
137         // precaches
138         Projectile_Precache();
139         GibSplash_Precache();
140         Casings_Precache();
141         DamageInfo_Precache();
142         if(cvar_string("cl_announcer") != cl_announcer_prev) {
143                 Announcer_Precache();
144                 if(cl_announcer_prev)
145                         strunzone(cl_announcer_prev);
146                 cl_announcer_prev = strzone(cvar_string("cl_announcer"));
147         }
148         Tuba_Precache();
149
150 #ifdef UID
151         {
152                 // find the user ID
153                 string uid;
154                 registercvar("_cl_userid", "", CVAR_SAVE);
155                 uid = cvar_string("_cl_userid");
156                 if(strlen(uid) < 16)
157                 {
158                         uid = "";
159                         for(i = 0; i < 4; ++i)
160                                 uid = strcat(uid, substring(ftos(floor(10000 + random() * 10000)), 1, -1));
161                 }
162                 cvar_set("_cl_userid", uid);
163                 localcmd(strcat("\ncmd uid ", uid, "\n"));
164         }
165 #endif
166
167         get_mi_min_max_texcoords(1); // try the CLEVER way first
168         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
169         shortmapname = mi_shortname;
170
171         if(precache_pic(minimapname) == "")
172         {
173                 // but maybe we have a non-clever minimap
174                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
175                 if(precache_pic(minimapname) == "")
176                         minimapname = ""; // FAIL
177                 else
178                         get_mi_min_max_texcoords(0); // load new texcoords
179         }
180
181         mi_center = (mi_min + mi_max) * 0.5;
182         mi_scale = mi_max - mi_min;
183         minimapname = strzone(minimapname);
184
185         WarpZone_Init();
186 }
187
188 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
189 void CSQC_Shutdown(void)
190 {
191 #ifdef USE_FTE
192 #pragma TARGET id
193         if(!__engine_check)
194                 return 0;
195 #pragma TARGET fte
196 #endif
197
198         WarpZone_Shutdown();
199
200         remove(teams);
201         remove(players);
202         db_close(binddb);
203         db_close(tempdb);
204         db_save(ClientProgsDB, "client.db");
205         db_close(ClientProgsDB);
206
207         cvar_clientsettemp_restore();
208
209         if(camera_active)
210                 cvar_set("chase_active",ftos(chase_active_backup));
211
212         if not(isdemo())
213         {
214                 if not(calledhooks & HOOK_START)
215                         localcmd("\n_cl_hook_gamestart nop\n");
216                 if not(calledhooks & HOOK_END)
217                         localcmd("\ncl_hook_gameend\n");
218         }
219 }
220
221 .float has_team;
222 float SetTeam(entity o, float Team)
223 {
224         entity tm;
225         if(teamplay)
226         {
227                 switch(Team)
228                 {
229                         case -1:
230                         case COLOR_TEAM1:
231                         case COLOR_TEAM2:
232                         case COLOR_TEAM3:
233                         case COLOR_TEAM4:
234                                 break;
235                         default:
236                                 if(GetTeam(Team, false) == NULL)
237                                 {
238                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
239                                         Team = COLOR_SPECTATOR;
240                                 }
241                                 break;
242                 }
243         }
244         else
245         {
246                 switch(Team)
247                 {
248                         case -1:
249                         case 0:
250                                 break;
251                         default:
252                                 if(GetTeam(Team, false) == NULL)
253                                 {
254                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
255                                         Team = COLOR_SPECTATOR;
256                                 }
257                                 break;
258                 }
259         }
260         if(Team == -1) // leave
261         {
262                 if(o.has_team)
263                 {
264                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");
265                         tm = GetTeam(o.team, false);
266                         tm.team_size -= 1;
267                         o.has_team = 0;
268                         return TRUE;
269                 }
270         }
271         else
272         {
273                 if not(o.has_team)
274                 {
275                         //print("(CONNECT) enter team ", ftos(o.team), "\n");
276                         o.team = Team;
277                         tm = GetTeam(Team, true);
278                         tm.team_size += 1;
279                         o.has_team = 1;
280                         return TRUE;
281                 }
282                 else if(Team != o.team)
283                 {
284                         //print("(CHANGE) leave team ", ftos(o.team), "\n");
285                         tm = GetTeam(o.team, false);
286                         tm.team_size -= 1;
287                         o.team = Team;
288                         //print("(CHANGE) enter team ", ftos(o.team), "\n");
289                         tm = GetTeam(Team, true);
290                         tm.team_size += 1;
291                         return TRUE;
292                 }
293         }
294         return FALSE;
295 }
296
297 void Playerchecker_Think()
298 {
299         float i;
300         entity e;
301         for(i = 0; i < maxclients; ++i)
302         {
303                 e = playerslots[i];
304                 if(GetPlayerName(i) == "")
305                 {
306                         if(e.sort_prev)
307                         {
308                                 //print("playerchecker: KILL KILL KILL\n");
309                                 // player disconnected
310                                 SetTeam(e, -1);
311                                 RemovePlayer(e);
312                                 e.sort_prev = world;
313                                 //e.gotscores = 0;
314                         }
315                 }
316                 else
317                 {
318                         if not(e.sort_prev)
319                         {
320                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");
321                                 // player connected
322                                 if not(e)
323                                         playerslots[i] = e = spawn();
324                                 e.sv_entnum = i;
325                                 e.ping = 0;
326                                 e.ping_packetloss = 0;
327                                 e.ping_movementloss = 0;
328                                 //e.gotscores = 0; // we might already have the scores...
329                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
330                                 RegisterPlayer(e);
331                                 HUD_UpdatePlayerPos(e);
332                         }
333                 }
334         }
335         self.nextthink = time + 0.2;
336 }
337
338 void Porto_Init();
339 void TrueAim_Init();
340 void PostInit(void)
341 {
342         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));
343         localcmd(strcat("\nscoreboard_columns_set ", cvar_string("scoreboard_columns"), ";\n"));
344
345         entity playerchecker;
346         playerchecker = spawn();
347         playerchecker.think = Playerchecker_Think;
348         playerchecker.nextthink = time + 0.2;
349
350         Porto_Init();
351         TrueAim_Init();
352
353         postinit = true;
354 }
355
356 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
357 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
358 float button_zoom;
359 void Cmd_HUD_SetFields(float);
360 void Cmd_HUD_Help(float);
361 float CSQC_ConsoleCommand(string strMessage)
362 {
363         float argc;
364         // Tokenize String
365         //argc = tokenize(strMessage);
366         argc = tokenize_console(strMessage);
367
368         // Acquire Command
369         local string strCmd;
370         strCmd = argv(0);
371
372         if(strCmd == "hud_configure") { // config hud
373                 cvar_set("_hud_configure", ftos(!cvar("_hud_configure")));
374                 return true;
375         } else if(strCmd == "hud_save") { // save hud config
376                 if(argv(1) == "" || argv(2)) {
377                         print("Usage:\n");
378                         print("hud_save configname   (saves to hud_skinname_configname.cfg)\n");
379                 }
380                 else
381                         HUD_Panel_ExportCfg(argv(1));
382                 return true;
383         } else if(strCmd == "+button4") { // zoom
384                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
385                 if(ignore_plus_zoom)
386                 {
387                         --ignore_plus_zoom;
388                         return false;
389                 }
390                 button_zoom = 1;
391                 return true;
392         } else if(strCmd == "-button4") { // zoom
393                 if(ignore_minus_zoom)
394                 {
395                         --ignore_minus_zoom;
396                         return false;
397                 }
398                 button_zoom = 0;
399                 return true;
400         } else if(strCmd == "+button3") { // secondary
401                 button_attack2 = 1;
402                 return false;
403         } else if(strCmd == "-button3") { // secondary
404                 button_attack2 = 0;
405                 return false;
406         } else if(strCmd == "+showscores") {
407                 scoreboard_showscores = true;
408                 return true;
409         } else if(strCmd == "-showscores") {
410                 scoreboard_showscores = false;
411                 return true;
412         } else if(strCmd == "+showaccuracy") {
413                 scoreboard_showaccuracy = true;
414                 return true;
415         } else if(strCmd == "-showaccuracy") {
416                 scoreboard_showaccuracy = false;
417                 return true;
418         }
419
420         if(camera_active)
421         if(strCmd == "+forward" || strCmd == "-back") {
422                 ++camera_direction_x;
423                 return true;
424         } else if(strCmd == "-forward" || strCmd == "+back") {
425                 --camera_direction_x;
426                 return true;
427         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
428                 --camera_direction_y;
429                 return true;
430         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
431                 ++camera_direction_y;
432                 return true;
433         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
434                 ++camera_direction_z;
435                 return true;
436         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
437                 --camera_direction_z;
438                 return true;
439         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
440                 ++camera_roll;
441                 return true;
442         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
443                 --camera_roll;
444                 return true;
445         }
446
447         return false;
448 }
449
450 .vector view_ofs;
451 entity debug_shotorg;
452 void ShotOrg_Draw()
453 {
454         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
455         self.angles = view_angles;
456         self.angles_x = -self.angles_x;
457         if not(self.cnt)
458                 R_AddEntity(self);
459 }
460 void ShotOrg_Draw2D()
461 {
462         vector coord2d_topleft, coord2d_topright, coord2d;
463         string s;
464         vector fs;
465
466         s = vtos(self.view_ofs);
467         s = substring(s, 1, strlen(s) - 2);
468         if(tokenize_console(s) == 3)
469                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
470
471         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
472         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
473
474         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
475
476         coord2d = coord2d_topleft;
477         if(fs_x < 8)
478         {
479                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
480                 fs = '8 8 0';
481         }
482         coord2d_y -= fs_y;
483         coord2d_z = 0;
484         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
485 }
486
487 void ShotOrg_Spawn()
488 {
489         debug_shotorg = spawn();
490         debug_shotorg.draw = ShotOrg_Draw;
491         debug_shotorg.draw2d = ShotOrg_Draw2D;
492         debug_shotorg.renderflags = RF_VIEWMODEL;
493         debug_shotorg.effects = EF_FULLBRIGHT;
494         precache_model("models/shotorg_adjuster.md3");
495         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
496         debug_shotorg.scale = 2;
497         debug_shotorg.view_ofs = '25 8 -8';
498 }
499
500 void DrawDebugModel()
501 {
502         if(time - floor(time) > 0.5)
503         {
504                 PolyDrawModel(self);
505         }
506         else
507         {
508                 self.renderflags = 0;
509                 R_AddEntity(self);
510         }
511 }
512
513 void GameCommand(string msg)
514 {
515         string s;
516         float argc;
517         entity e;
518         argc = tokenize_console(msg);
519
520         if(argv(0) == "help" || argc == 0)
521         {
522                 print("Usage: cl_cmd COMMAND..., where possible commands are:\n");
523                 print("  settemp cvar value\n");
524                 print("  scoreboard_columns_set ...\n");
525                 print("  scoreboard_columns_help\n");
526                 GameCommand_Generic("help");
527                 return;
528         }
529
530         if(GameCommand_Generic(msg))
531                 return;
532
533         string cmd;
534         cmd = argv(0);
535         if(cmd == "mv_download") {
536                 Cmd_MapVote_MapDownload(argc);
537         }
538         else if(cmd == "settemp") {
539                 cvar_clientsettemp(argv(1), argv(2));
540         }
541         else if(cmd == "scoreboard_columns_set") {
542                 Cmd_HUD_SetFields(argc);
543         }
544         else if(cmd == "scoreboard_columns_help") {
545                 Cmd_HUD_Help(argc);
546         }
547 #ifdef BLURTEST
548         else if(cmd == "blurtest") {
549                 blurtest_time0 = time;
550                 blurtest_time1 = time + stof(argv(1));
551                 blurtest_radius = stof(argv(2));
552                 blurtest_power = stof(argv(3));
553         }
554 #endif
555         else if(cmd == "shotorg_move") {
556                 if(!debug_shotorg)
557                         ShotOrg_Spawn();
558                 else
559                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
560                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
561         }
562         else if(cmd == "shotorg_movez") {
563                 if(!debug_shotorg)
564                         ShotOrg_Spawn();
565                 else
566                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
567                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
568         }
569         else if(cmd == "shotorg_set") {
570                 if(!debug_shotorg)
571                         ShotOrg_Spawn();
572                 else
573                         debug_shotorg.view_ofs = stov(argv(1));
574                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
575         }
576         else if(cmd == "shotorg_setz") {
577                 if(!debug_shotorg)
578                         ShotOrg_Spawn();
579                 else
580                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
581                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
582         }
583         else if(cmd == "shotorg_toggle_hide") {
584                 if(debug_shotorg)
585                 {
586                         debug_shotorg.cnt = !debug_shotorg.cnt;
587                 }
588         }
589         else if(cmd == "shotorg_end") {
590                 if(debug_shotorg)
591                 {
592                         print(vtos(debug_shotorg.view_ofs), "\n");
593                         remove(debug_shotorg);
594                         debug_shotorg = world;
595                 }
596                 localcmd("sv_cmd debug_shotorg\n");
597         }
598         else if(cmd == "sendcvar") {
599                 // W_FixWeaponOrder will trash argv, so save what we need.
600                 string thiscvar;
601                 thiscvar = strzone(argv(1));
602                 s = cvar_string(thiscvar);
603                 if(thiscvar == "cl_weaponpriority")
604                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
605                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
606                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
607                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
608                 strunzone(thiscvar);
609         }
610         else if(cmd == "spawn") {
611                 s = argv(1);
612                 e = spawn();
613                 precache_model(s);
614                 setmodel(e, s);
615                 setorigin(e, view_origin);
616                 e.angles = view_angles;
617                 e.draw = DrawDebugModel;
618                 e.classname = "debugmodel";
619         }
620         else
621         {
622                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
623         }
624
625         return;
626 }
627
628 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
629 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
630 // All keys are in ascii.
631 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
632 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
633 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
634 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
635 {
636         local float bSkipKey;
637         bSkipKey = false;
638
639         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
640                 return true;
641
642         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
643                 return true;
644
645         if(menu_visible)
646                 if(menu_action(bInputType, nPrimary, nSecondary))
647                         return TRUE;
648         return bSkipKey;
649 }
650
651 // END REQUIRED CSQC FUNCTIONS
652 // --------------------------------------------------------------------------
653
654 // --------------------------------------------------------------------------
655 // BEGIN OPTIONAL CSQC FUNCTIONS
656 void Ent_ReadEntCS()
657 {
658         InterpolateOrigin_Undo();
659
660         self.classname = "entcs_receiver";
661         self.sv_entnum = ReadByte() - 1;
662         self.origin_x = ReadShort();
663         self.origin_y = ReadShort();
664         self.origin_z = ReadShort();
665         self.angles_y = ReadByte() * 360.0 / 256;
666         self.origin_z = self.angles_x = self.angles_z = 0;
667
668         InterpolateOrigin_Note();
669 }
670
671 void Ent_Remove();
672
673 void Ent_RemovePlayerScore()
674 {
675         float i;
676
677         if(self.owner)
678         {
679                 SetTeam(self.owner, -1);
680                 self.owner.gotscores = 0;
681                 for(i = 0; i < MAX_SCORE; ++i)
682                         self.owner.(scores[i]) = 0; // clear all scores
683         }
684 }
685
686 void Ent_ReadPlayerScore()
687 {
688         float i, n;
689         float isNew;
690         entity o;
691
692         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
693         // (no I've never heard of M-x replace-string, sed, or anything like that)
694         isNew = !self.owner; // workaround for DP bug
695         n = ReadByte()-1;
696
697 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
698         if(!isNew && n != self.sv_entnum)
699         {
700                 print("A CSQC entity changed its owner!\n");
701                 isNew = true;
702                 Ent_Remove();
703                 self.enttype = ENT_CLIENT_SCORES;
704         }
705 #endif
706
707         self.sv_entnum = n;
708
709         if not(playerslots[self.sv_entnum])
710                 playerslots[self.sv_entnum] = spawn();
711         o = self.owner = playerslots[self.sv_entnum];
712         o.sv_entnum = self.sv_entnum;
713         o.gotscores = 1;
714
715         //if not(o.sort_prev)
716         //      RegisterPlayer(o);
717         //playerchecker will do this for us later, if it has not already done so
718
719         float sf, lf;
720 #if MAX_SCORE <= 8
721         sf = ReadByte();
722         lf = ReadByte();
723 #else
724         sf = ReadShort();
725         lf = ReadShort();
726 #endif
727         float p;
728         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
729                 if(sf & p)
730                 {
731                         if(lf & p)
732                                 o.(scores[i]) = ReadInt24_t();
733                         else
734                                 o.(scores[i]) = ReadChar();
735                 }
736
737         if(o.sort_prev)
738                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
739
740         self.entremove = Ent_RemovePlayerScore;
741 }
742
743 void Ent_ReadTeamScore()
744 {
745         float i;
746         entity o;
747
748         self.team = ReadByte();
749         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
750
751         float sf, lf;
752 #if MAX_TEAMSCORE <= 8
753         sf = ReadByte();
754         lf = ReadByte();
755 #else
756         sf = ReadShort();
757         lf = ReadShort();
758 #endif
759         float p;
760         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
761                 if(sf & p)
762                 {
763                         if(lf & p)
764                                 o.(teamscores[i]) = ReadInt24_t();
765                         else
766                                 o.(teamscores[i]) = ReadChar();
767                 }
768
769         HUD_UpdateTeamPos(o);
770 }
771
772 void Net_Reset()
773 {
774 }
775
776 void Ent_ClientData()
777 {
778         float f;
779         float newspectatee_status;
780
781         f = ReadByte();
782
783         scoreboard_showscores_force = (f & 1);
784
785         if(f & 2)
786         {
787                 newspectatee_status = ReadByte();
788                 if(newspectatee_status == player_localentnum)
789                         newspectatee_status = -1; // observing
790         }
791         else
792                 newspectatee_status = 0;
793
794         spectatorbutton_zoom = (f & 4);
795
796         if(f & 8)
797         {
798                 angles_held_status = 1;
799                 angles_held_x = ReadAngle();
800                 angles_held_y = ReadAngle();
801                 angles_held_z = 0;
802         }
803         else
804                 angles_held_status = 0;
805
806         if(newspectatee_status != spectatee_status)
807         {
808                 float i;
809                 // clear the weapon accuracy stats
810                 for(i = WEP_FIRST; i <= WEP_LAST; ++i) {
811                         weapon_hits[i] = 0;
812                         weapon_fired[i] = 0;
813                 }
814
815                 // clear race stuff
816                 race_laptime = 0;
817                 race_checkpointtime = 0;
818         }
819         spectatee_status = newspectatee_status;
820 }
821
822 void Ent_Nagger()
823 {
824         float nags, i, j, b, f;
825
826         nags = ReadByte();
827
828         if(nags & 128)
829         {
830                 if(vote_called_vote)
831                         strunzone(vote_called_vote);
832                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
833         }
834
835         if(nags & 1)
836         {
837                 for(j = 0; j < maxclients; ++j)
838                         if(playerslots[j])
839                                 playerslots[j].ready = 1;
840                 for(i = 1; i <= maxclients; i += 8)
841                 {
842                         f = ReadByte();
843                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
844                                 if not(f & b)
845                                         if(playerslots[j])
846                                                 playerslots[j].ready = 0;
847                 }
848         }
849
850         ready_waiting = (nags & 1);
851         ready_waiting_for_me = (nags & 2);
852         vote_waiting = (nags & 4);
853         vote_waiting_for_me = (nags & 8);
854         warmup_stage = (nags & 16);
855 }
856
857 void Ent_RandomSeed()
858 {
859         float s;
860         prandom_debug();
861         s = ReadShort();
862         psrandom(s);
863 }
864
865 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
866 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
867 void Ent_RadarLink();
868 void Ent_Init();
869 void Ent_ScoresInfo();
870 void(float bIsNewEntity) CSQC_Ent_Update =
871 {
872         float t;
873         float savetime;
874         t = ReadByte();
875
876         // set up the "time" global for received entities to be correct for interpolation purposes
877         savetime = time;
878         if(servertime)
879         {
880                 time = servertime;
881         }
882         else
883         {
884                 serverprevtime = time;
885                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
886                 time = serverprevtime + serverdeltatime;
887         }
888
889 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
890         if(self.enttype)
891                 if(t != self.enttype)
892                 {
893                         print("A CSQC entity changed its type!\n");
894                         Ent_Remove();
895                         bIsNewEntity = 1;
896                 }
897 #endif
898         self.enttype = t;
899         switch(t)
900         {
901                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
902                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
903                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
904                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
905                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
906                 case ENT_CLIENT_LASER: Ent_Laser(); break;
907                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
908                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
909                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
910                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
911                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
912                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
913                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
914                 case ENT_CLIENT_INIT: Ent_Init(); break;
915                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
916                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
917                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
918                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
919                 case ENT_CLIENT_WALL: Ent_Wall(); break;
920                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
921                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
922                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
923                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
924                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
925                 default:
926                         error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));
927                         break;
928         }
929
930         time = savetime;
931 };
932 // Destructor, but does NOT deallocate the entity by calling remove(). Also
933 // used when an entity changes its type. For an entity that someone interacts
934 // with others, make sure it can no longer do so.
935 void Ent_Remove()
936 {
937         if(self.entremove)
938                 self.entremove();
939
940         self.enttype = 0;
941         self.classname = "";
942         self.draw = menu_sub_null;
943         self.entremove = menu_sub_null;
944         // TODO possibly set more stuff to defaults
945 }
946 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
947 void CSQC_Ent_Remove()
948 {
949         if(self.enttype)
950                 Ent_Remove();
951         remove(self);
952 }
953
954 void Gamemode_Init()
955 {
956         if(gametype == GAME_ONSLAUGHT) {
957                 print(strcat("Using ", minimapname, " as minimap.\n"));
958                 precache_pic("gfx/ons-cp-neutral.tga");
959                 precache_pic("gfx/ons-cp-red.tga");
960                 precache_pic("gfx/ons-cp-blue.tga");
961                 precache_pic("gfx/ons-frame.tga");
962                 precache_pic("gfx/ons-frame-team.tga");
963         }
964
965         if not(isdemo())
966         {
967                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
968                 calledhooks |= HOOK_START;
969         }
970 }
971 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
972 void CSQC_Parse_StuffCmd(string strMessage)
973 {
974         localcmd(strMessage);
975 }
976 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
977 void CSQC_Parse_Print(string strMessage)
978 {
979         print(ColorTranslateRGB(strMessage));
980 }
981
982 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
983 void CSQC_Parse_CenterPrint(string strMessage)
984 {
985         centerprint(strMessage);
986 }
987
988 string notranslate_fogcmd1 = "\nfog ";
989 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
990 void Fog_Force()
991 {
992         // TODO somehow thwart prvm_globalset client ...
993
994         if(forcefog != "")
995                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
996 }
997
998 void Gamemode_Init();
999 void Ent_ScoresInfo()
1000 {
1001         float i;
1002         self.classname = "ent_client_scores_info";
1003         gametype = ReadByte();
1004         for(i = 0; i < MAX_SCORE; ++i)
1005         {
1006                 scores_label[i] = strzone(ReadString());
1007                 scores_flags[i] = ReadByte();
1008         }
1009         for(i = 0; i < MAX_TEAMSCORE; ++i)
1010         {
1011                 teamscores_label[i] = strzone(ReadString());
1012                 teamscores_flags[i] = ReadByte();
1013         }
1014         HUD_InitScores();
1015         Gamemode_Init();
1016 }
1017
1018 void Ent_Init()
1019 {
1020         self.classname = "ent_client_init";
1021
1022         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1023
1024         hook_shotorigin_x = ReadCoord();
1025         hook_shotorigin_y = ReadCoord();
1026         hook_shotorigin_z = ReadCoord();
1027
1028         if(forcefog)
1029                 strunzone(forcefog);
1030         forcefog = strzone(ReadString());
1031
1032         armorblockpercent = ReadByte() / 255.0;
1033
1034         g_weaponswitchdelay = ReadByte() / 255.0;
1035
1036         g_balance_grenadelauncher_secondary_bouncefactor = ReadCoord();
1037         g_balance_grenadelauncher_secondary_bouncestop = ReadCoord();
1038
1039         if(!postinit)
1040                 PostInit();
1041 }
1042
1043 void Net_ReadRace()
1044 {
1045         float b;
1046
1047         b = ReadByte();
1048
1049         switch(b)
1050         {
1051                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1052                         race_checkpoint = ReadByte();
1053                         race_time = ReadInt24_t();
1054                         race_previousbesttime = ReadInt24_t();
1055                         if(race_previousbestname)
1056                                 strunzone(race_previousbestname);
1057                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1058
1059                         race_checkpointtime = time;
1060
1061                         if(race_checkpoint == 0 || race_checkpoint == 254)
1062                         {
1063                                 race_penaltyaccumulator = 0;
1064                                 race_laptime = time; // valid
1065                         }
1066
1067                         break;
1068
1069                 case RACE_NET_CHECKPOINT_CLEAR:
1070                         race_laptime = 0;
1071                         race_checkpointtime = 0;
1072                         break;
1073
1074                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1075                         race_laptime = ReadCoord();
1076                         race_checkpointtime = -99999;
1077                         // fall through
1078                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1079                         race_nextcheckpoint = ReadByte();
1080
1081                         race_nextbesttime = ReadInt24_t();
1082                         if(race_nextbestname)
1083                                 strunzone(race_nextbestname);
1084                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1085                         break;
1086
1087                 case RACE_NET_CHECKPOINT_HIT_RACE:
1088                         race_mycheckpoint = ReadByte();
1089                         race_mycheckpointtime = time;
1090                         race_mycheckpointdelta = ReadInt24_t();
1091                         race_mycheckpointlapsdelta = ReadByte();
1092                         if(race_mycheckpointlapsdelta >= 128)
1093                                 race_mycheckpointlapsdelta -= 256;
1094                         if(race_mycheckpointenemy)
1095                                 strunzone(race_mycheckpointenemy);
1096                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1097                         break;
1098
1099                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1100                         race_othercheckpoint = ReadByte();
1101                         race_othercheckpointtime = time;
1102                         race_othercheckpointdelta = ReadInt24_t();
1103                         race_othercheckpointlapsdelta = ReadByte();
1104                         if(race_othercheckpointlapsdelta >= 128)
1105                                 race_othercheckpointlapsdelta -= 256;
1106                         if(race_othercheckpointenemy)
1107                                 strunzone(race_othercheckpointenemy);
1108                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1109                         break;
1110
1111                 case RACE_NET_PENALTY_RACE:
1112                         race_penaltyeventtime = time;
1113                         race_penaltytime = ReadShort();
1114                         //race_penaltyaccumulator += race_penaltytime;
1115                         if(race_penaltyreason)
1116                                 strunzone(race_penaltyreason);
1117                         race_penaltyreason = strzone(ReadString());
1118                         break;
1119
1120                 case RACE_NET_PENALTY_QUALIFYING:
1121                         race_penaltyeventtime = time;
1122                         race_penaltytime = ReadShort();
1123                         race_penaltyaccumulator += race_penaltytime;
1124                         if(race_penaltyreason)
1125                                 strunzone(race_penaltyreason);
1126                         race_penaltyreason = strzone(ReadString());
1127                         break;
1128
1129                 case RACE_NET_SERVER_RECORD:
1130                         race_server_record = ReadInt24_t();
1131                         break;
1132                 case RACE_NET_SPEED_AWARD:
1133                         race_speedaward = ReadInt24_t();
1134                         if(race_speedaward_holder)
1135                                 strunzone(race_speedaward_holder);
1136                         race_speedaward_holder = strzone(ReadString());
1137                         break;
1138                 case RACE_NET_SPEED_AWARD_BEST:
1139                         race_speedaward_alltimebest = ReadInt24_t();
1140                         if(race_speedaward_alltimebest_holder)
1141                                 strunzone(race_speedaward_alltimebest_holder);
1142                         race_speedaward_alltimebest_holder = strzone(ReadString());
1143                         break;
1144                 case RACE_NET_SERVER_RANKINGS:
1145                         float pos, prevpos, del;
1146                         pos = ReadShort();
1147                         prevpos = ReadShort();
1148                         del = ReadShort();
1149
1150                         // move other rankings out of the way
1151                         float i;
1152                         if (prevpos) {
1153                                 for (i=prevpos-1;i>pos-1;--i) {
1154                                         grecordtime[i] = grecordtime[i-1];
1155                                         if(grecordholder[i])
1156                                                 strunzone(grecordholder[i]);
1157                                         grecordholder[i] = strzone(grecordholder[i-1]);
1158                                 }
1159                         } else if (del) { // a record has been deleted by the admin
1160                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1161                                         if (i == RANKINGS_CNT-1) { // clear out last record
1162                                                 grecordtime[i] = 0;
1163                                                 if (grecordholder[i])
1164                                                         strunzone(grecordholder[i]);
1165                                                 grecordholder[i] = string_null;
1166                                         }
1167                                         else {
1168                                                 grecordtime[i] = grecordtime[i+1];
1169                                                 if (grecordholder[i])
1170                                                         strunzone(grecordholder[i]);
1171                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1172                                         }
1173                                 }
1174                         } else { // player has no ranked record yet
1175                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1176                                         grecordtime[i] = grecordtime[i-1];
1177                                         if(grecordholder[i])
1178                                                 strunzone(grecordholder[i]);
1179                                         grecordholder[i] = strzone(grecordholder[i-1]);
1180                                 }
1181                         }
1182
1183                         // store new ranking
1184                         if(grecordholder[pos-1] != "")
1185                                 strunzone(grecordholder[pos-1]);
1186                         grecordholder[pos-1] = strzone(ReadString());
1187                         grecordtime[pos-1] = ReadInt24_t();
1188                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1189                                 race_myrank = pos;
1190                         break;
1191                 case RACE_NET_SERVER_STATUS:
1192                         race_status = ReadShort();
1193                         if(race_status_name)
1194                                 strunzone(race_status_name);
1195                         race_status_name = strzone(ReadString());
1196         }
1197 }
1198
1199 void Net_ReadSpawn()
1200 {
1201         zoomin_effect = 1;
1202         current_viewzoom = 0.6;
1203 }
1204
1205 void Net_TeamNagger()
1206 {
1207         teamnagger = 1;
1208 }
1209
1210 void Net_ReadPingPLReport()
1211 {
1212         float e, pi, pl, ml;
1213         e = ReadByte();
1214         pi = ReadShort();
1215         pl = ReadByte();
1216         ml = ReadByte();
1217         if not(playerslots[e])
1218                 return;
1219         playerslots[e].ping = pi;
1220         playerslots[e].ping_packetloss = pl / 255.0;
1221         playerslots[e].ping_movementloss = ml / 255.0;
1222 }
1223
1224 void Net_VoteDialog(float highlight) {
1225         if(highlight) {
1226                 vote_highlighted = ReadShort();
1227                 return;
1228         }
1229
1230         vote_yescount = ReadShort();
1231         vote_nocount = ReadShort();
1232         vote_needed = ReadShort();
1233         vote_active = 1;
1234 }
1235
1236 void Net_VoteDialogReset() {
1237         vote_active = 0;
1238 }
1239
1240 void Net_Notify() {
1241         float type;
1242         type = ReadByte();
1243
1244         if(type == CSQC_KILLNOTIFY)
1245         {
1246                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1247         }
1248         else if(type == CSQC_CENTERPRINT)
1249         {
1250                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1251         }
1252 }
1253
1254 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1255 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1256 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1257 float CSQC_Parse_TempEntity()
1258 {
1259         local float bHandled;
1260                 bHandled  = true;
1261         // Acquire TE ID
1262         local float nTEID;
1263                 nTEID = ReadByte();
1264
1265                 // NOTE: Could just do return instead of break...
1266         switch(nTEID)
1267         {
1268                 case TE_CSQC_TARGET_MUSIC:
1269                         Net_TargetMusic();
1270                         bHandled = true;
1271                         break;
1272                 case TE_CSQC_PICTURE:
1273                         Net_MapVote_Picture();
1274                         bHandled = true;
1275                         break;
1276                 case TE_CSQC_RACE:
1277                         Net_ReadRace();
1278                         bHandled = true;
1279                         break;
1280                 case 13: // TE_BEAM
1281                         Net_GrapplingHook();
1282                         bHandled = true;
1283                         break;
1284                 case TE_CSQC_SPAWN:
1285                         Net_ReadSpawn();
1286                         bHandled = true;
1287                         break;
1288                 case TE_CSQC_ZCURVEPARTICLES:
1289                         Net_ReadZCurveParticles();
1290                         bHandled = true;
1291                         break;
1292                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1293                         Net_ReadNexgunBeamParticle();
1294                         bHandled = true;
1295                         break;
1296                 case TE_CSQC_TEAMNAGGER:
1297                         Net_TeamNagger();
1298                         bHandled = true;
1299                         break;
1300                 case TE_CSQC_VOTE:
1301                         Net_VoteDialog(ReadByte());
1302                         bHandled = true;
1303                         break;
1304                 case TE_CSQC_VOTERESET:
1305                         Net_VoteDialogReset();
1306                         bHandled = true;
1307                         break;
1308                 case TE_CSQC_LIGHTNINGARC:
1309                         Net_ReadLightningarc();
1310                         bHandled = true;
1311                         break;
1312                 case TE_CSQC_PINGPLREPORT:
1313                         Net_ReadPingPLReport();
1314                         bHandled = true;
1315                         break;
1316                 case TE_CSQC_ANNOUNCE:
1317                         announce_snd = strzone(ReadString());
1318                         bHandled = true;
1319                         break;
1320                 case TE_CSQC_NOTIFY:
1321                         Net_Notify();
1322                         bHandled = true;
1323                         break;
1324                 default:
1325                         // No special logic for this temporary entity; return 0 so the engine can handle it
1326                         bHandled = false;
1327                         break;
1328         }
1329
1330         return bHandled;
1331 }
1332
1333 string getcommandkey(string text, string command)
1334 {
1335         string keys;
1336         float n, j, k, l;
1337
1338         if (!hud_showbinds)
1339                 return text;
1340
1341         keys = db_get(binddb, command);
1342         if (!keys)
1343         {
1344                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1345                 for(j = 0; j < n; ++j)
1346                 {
1347                         k = stof(argv(j));
1348                         if(k != -1)
1349                         {
1350                                 if ("" == keys)
1351                                         keys = keynumtostring(k);
1352                                 else
1353                                         keys = strcat(keys, ", ", keynumtostring(k));
1354
1355                                 ++l;
1356                                 if (hud_showbinds_limit > 0 && hud_showbinds_limit >= l) break;
1357                         }
1358
1359                 }
1360                 db_put(binddb, command, keys);
1361         }
1362
1363         if ("" == keys) {
1364                 if (hud_showbinds > 1)
1365                         return strcat(text, " (not bound)");
1366                 else
1367                         return text;
1368         }
1369         else if (hud_showbinds > 1)
1370                 return strcat(text, " (", keys, ")");
1371         else
1372                 return keys;
1373 }