Declare more ints as ints
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / Main.qc
1 // --------------------------------------------------------------------------
2 // BEGIN REQUIRED CSQC FUNCTIONS
3 //include "main.qh"
4
5 entity clearentity_ent;
6 void clearentity(entity e)
7 {
8         if (!clearentity_ent)
9         {
10                 clearentity_ent = spawn();
11                 clearentity_ent.classname = "clearentity";
12         }
13         int n = e.entnum;
14         copyentity(clearentity_ent, e);
15         e.entnum = n;
16 }
17
18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
19 void menu_show_error()
20 {
21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
22 }
23
24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
25 // Useful for precaching things
26
27 void menu_sub_null()
28 {
29 }
30
31 string forcefog;
32 void WaypointSprite_Load();
33 void ConsoleCommand_macro_init();
34 void CSQC_Init(void)
35 {
36         prvm_language = cvar_string("prvm_language");
37
38 #ifdef WATERMARK
39         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
40 #endif
41
42         int i;
43
44         binddb = db_create();
45         tempdb = db_create();
46         ClientProgsDB = db_load("client.db");
47         compressShortVector_init();
48
49         draw_endBoldFont();
50         menu_visible = false;
51         menu_show = menu_show_error;
52         menu_action = func_null;
53
54         for(i = 0; i < 255; ++i)
55                 if(getplayerkeyvalue(i, "viewentity") == "")
56                         break;
57         maxclients = i;
58
59         //registercommand("hud_configure");
60         //registercommand("hud_save");
61         //registercommand("menu_action");
62
63         ConsoleCommand_macro_init();
64
65         registercvar("hud_usecsqc", "1");
66         registercvar("scoreboard_columns", "default");
67
68         registercvar("cl_nade_type", "3");
69         registercvar("cl_pokenade_type", "zombie");
70
71         gametype = 0;
72
73         // hud_fields uses strunzone on the titles!
74         for(i = 0; i < MAX_HUD_FIELDS; ++i)
75                 hud_title[i] = strzone("(null)");
76
77         Cmd_HUD_SetFields(0);
78
79         postinit = false;
80
81         calledhooks = 0;
82
83         teams = Sort_Spawn();
84         players = Sort_Spawn();
85
86         GetTeam(NUM_SPECTATOR, true); // add specs first
87
88         // needs to be done so early because of the constants they create
89         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
90         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
91         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
92         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
93         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
94         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
95         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
96
97         WaypointSprite_Load();
98
99         // precaches
100         precache_model("null");
101         precache_sound("misc/hit.wav");
102         precache_sound("misc/typehit.wav");
103
104         Projectile_Precache();
105         Hook_Precache();
106         GibSplash_Precache();
107         Casings_Precache();
108         Vehicles_Precache();
109         turrets_precache();
110         Tuba_Precache();
111         CSQCPlayer_Precache();
112
113         if(autocvar_cl_reticle)
114         {
115                 precache_pic("gfx/reticle_normal");
116                 // weapon reticles are precached in weapon files
117         }
118
119         get_mi_min_max_texcoords(1); // try the CLEVER way first
120         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
121         shortmapname = mi_shortname;
122
123         if(precache_pic(minimapname) == "")
124         {
125                 // but maybe we have a non-clever minimap
126                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
127                 if(precache_pic(minimapname) == "")
128                         minimapname = ""; // FAIL
129                 else
130                         get_mi_min_max_texcoords(0); // load new texcoords
131         }
132
133         mi_center = (mi_min + mi_max) * 0.5;
134         mi_scale = mi_max - mi_min;
135         minimapname = strzone(minimapname);
136
137         WarpZone_Init();
138
139         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
140         hud_configure_prev = -1;
141
142         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
143 }
144
145 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
146 void Shutdown(void)
147 {
148         WarpZone_Shutdown();
149
150         remove(teams);
151         remove(players);
152         db_close(binddb);
153         db_close(tempdb);
154         if(autocvar_cl_db_saveasdump)
155                 db_dump(ClientProgsDB, "client.db");
156         else
157                 db_save(ClientProgsDB, "client.db");
158         db_close(ClientProgsDB);
159
160         if(camera_active)
161                 cvar_set("chase_active",ftos(chase_active_backup));
162
163         // unset the event chasecam's chase_active
164         if(autocvar_chase_active < 0)
165                 cvar_set("chase_active", "0");
166
167         if (!isdemo())
168         {
169                 if (!(calledhooks & HOOK_START))
170                         localcmd("\n_cl_hook_gamestart nop\n");
171                 if (!(calledhooks & HOOK_END))
172                         localcmd("\ncl_hook_gameend\n");
173         }
174 }
175
176 .float has_team;
177 float SetTeam(entity o, int Team)
178 {
179         entity tm;
180         if(teamplay)
181         {
182                 switch(Team)
183                 {
184                         case -1:
185                         case NUM_TEAM_1:
186                         case NUM_TEAM_2:
187                         case NUM_TEAM_3:
188                         case NUM_TEAM_4:
189                                 break;
190                         default:
191                                 if(GetTeam(Team, false) == world)
192                                 {
193                                         dprintf("trying to switch to unsupported team %d\n", Team);
194                                         Team = NUM_SPECTATOR;
195                                 }
196                                 break;
197                 }
198         }
199         else
200         {
201                 switch(Team)
202                 {
203                         case -1:
204                         case 0:
205                                 break;
206                         default:
207                                 if(GetTeam(Team, false) == world)
208                                 {
209                                         dprintf("trying to switch to unsupported team %d\n", Team);
210                                         Team = NUM_SPECTATOR;
211                                 }
212                                 break;
213                 }
214         }
215         if(Team == -1) // leave
216         {
217                 if(o.has_team)
218                 {
219                         tm = GetTeam(o.team, false);
220                         tm.team_size -= 1;
221                         o.has_team = 0;
222                         return true;
223                 }
224         }
225         else
226         {
227                 if (!o.has_team)
228                 {
229                         o.team = Team;
230                         tm = GetTeam(Team, true);
231                         tm.team_size += 1;
232                         o.has_team = 1;
233                         return true;
234                 }
235                 else if(Team != o.team)
236                 {
237                         tm = GetTeam(o.team, false);
238                         tm.team_size -= 1;
239                         o.team = Team;
240                         tm = GetTeam(Team, true);
241                         tm.team_size += 1;
242                         return true;
243                 }
244         }
245         return false;
246 }
247
248 void Playerchecker_Think()
249 {
250     int i;
251         entity e;
252         for(i = 0; i < maxclients; ++i)
253         {
254                 e = playerslots[i];
255                 if(GetPlayerName(i) == "")
256                 {
257                         if(e.sort_prev)
258                         {
259                                 // player disconnected
260                                 SetTeam(e, -1);
261                                 RemovePlayer(e);
262                                 e.sort_prev = world;
263                                 //e.gotscores = 0;
264                         }
265                 }
266                 else
267                 {
268                         if (!e.sort_prev)
269                         {
270                                 // player connected
271                                 if (!e)
272                                         playerslots[i] = e = spawn();
273                                 e.sv_entnum = i;
274                                 e.ping = 0;
275                                 e.ping_packetloss = 0;
276                                 e.ping_movementloss = 0;
277                                 //e.gotscores = 0; // we might already have the scores...
278                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
279                                 RegisterPlayer(e);
280                                 HUD_UpdatePlayerPos(e);
281                         }
282                 }
283         }
284         self.nextthink = time + 0.2;
285 }
286
287 void Porto_Init();
288 void TrueAim_Init();
289 void PostInit(void)
290 {
291         entity playerchecker;
292         playerchecker = spawn();
293         playerchecker.think = Playerchecker_Think;
294         playerchecker.nextthink = time + 0.2;
295
296         Porto_Init();
297         TrueAim_Init();
298
299         postinit = true;
300 }
301
302 float button_zoom;
303
304 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
305 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
306 // All keys are in ascii.
307 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
308 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
309 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
310 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
311 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
312 {
313         float bSkipKey;
314         bSkipKey = false;
315
316         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
317                 return true;
318
319         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
320                 return true;
321
322         if(menu_visible && menu_action)
323                 if(menu_action(bInputType, nPrimary, nSecondary))
324                         return true;
325
326         return bSkipKey;
327 }
328
329 // END REQUIRED CSQC FUNCTIONS
330 // --------------------------------------------------------------------------
331
332 // --------------------------------------------------------------------------
333 // BEGIN OPTIONAL CSQC FUNCTIONS
334 void Ent_RemoveEntCS()
335 {
336         entcs_receiver[self.sv_entnum] = world;
337 }
338 void Ent_ReadEntCS()
339 {
340     int sf;
341         InterpolateOrigin_Undo();
342
343         self.classname = "entcs_receiver";
344         sf = ReadByte();
345
346         if(sf & 1)
347                 self.sv_entnum = ReadByte();
348         if(sf & 2)
349         {
350                 self.origin_x = ReadShort();
351                 self.origin_y = ReadShort();
352                 self.origin_z = ReadShort();
353                 setorigin(self, self.origin);
354         }
355         if(sf & 4)
356         {
357                 self.angles_y = ReadByte() * 360.0 / 256;
358                 self.angles_x = self.angles_z = 0;
359         }
360         if(sf & 8)
361                 self.healthvalue = ReadByte() * 10;
362         if(sf & 16)
363                 self.armorvalue = ReadByte() * 10;
364
365         entcs_receiver[self.sv_entnum] = self;
366         self.entremove = Ent_RemoveEntCS;
367         self.iflags |= IFLAG_ORIGIN;
368
369         InterpolateOrigin_Note();
370 }
371
372 void Ent_Remove();
373
374 void Ent_RemovePlayerScore()
375 {
376         float i;
377
378         if(self.owner)
379         {
380                 SetTeam(self.owner, -1);
381                 self.owner.gotscores = 0;
382                 for(i = 0; i < MAX_SCORE; ++i)
383                         self.owner.(scores[i]) = 0; // clear all scores
384         }
385 }
386
387 void Ent_ReadPlayerScore()
388 {
389         int i, n;
390         bool isNew;
391         entity o;
392
393         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
394         // (no I've never heard of M-x replace-string, sed, or anything like that)
395         isNew = !self.owner; // workaround for DP bug
396         n = ReadByte()-1;
397
398 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
399         if(!isNew && n != self.sv_entnum)
400         {
401                 //print("A CSQC entity changed its owner!\n");
402                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
403                 isNew = true;
404                 Ent_Remove();
405                 self.enttype = ENT_CLIENT_SCORES;
406         }
407 #endif
408
409         self.sv_entnum = n;
410
411         if (!(playerslots[self.sv_entnum]))
412                 playerslots[self.sv_entnum] = spawn();
413         o = self.owner = playerslots[self.sv_entnum];
414         o.sv_entnum = self.sv_entnum;
415         o.gotscores = 1;
416
417         //if (!o.sort_prev)
418         //      RegisterPlayer(o);
419         //playerchecker will do this for us later, if it has not already done so
420
421     int sf, lf;
422 #if MAX_SCORE <= 8
423         sf = ReadByte();
424         lf = ReadByte();
425 #else
426         sf = ReadShort();
427         lf = ReadShort();
428 #endif
429     int p;
430         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
431                 if(sf & p)
432                 {
433                         if(lf & p)
434                                 o.(scores[i]) = ReadInt24_t();
435                         else
436                                 o.(scores[i]) = ReadChar();
437                 }
438
439         if(o.sort_prev)
440                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
441
442         self.entremove = Ent_RemovePlayerScore;
443 }
444
445 void Ent_ReadTeamScore()
446 {
447         int i;
448         entity o;
449
450         self.team = ReadByte();
451         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
452
453     int sf, lf;
454 #if MAX_TEAMSCORE <= 8
455         sf = ReadByte();
456         lf = ReadByte();
457 #else
458         sf = ReadShort();
459         lf = ReadShort();
460 #endif
461         int p;
462         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
463                 if(sf & p)
464                 {
465                         if(lf & p)
466                                 o.(teamscores[i]) = ReadInt24_t();
467                         else
468                                 o.(teamscores[i]) = ReadChar();
469                 }
470
471         HUD_UpdateTeamPos(o);
472 }
473
474 void Ent_ClientData()
475 {
476         float newspectatee_status;
477
478     int f = ReadByte();
479
480         scoreboard_showscores_force = (f & 1);
481
482         if(f & 2)
483         {
484                 newspectatee_status = ReadByte();
485                 if(newspectatee_status == player_localnum + 1)
486                         newspectatee_status = -1; // observing
487         }
488         else
489                 newspectatee_status = 0;
490
491         spectatorbutton_zoom = (f & 4);
492
493         if(f & 8)
494         {
495                 angles_held_status = 1;
496                 angles_held_x = ReadAngle();
497                 angles_held_y = ReadAngle();
498                 angles_held_z = 0;
499         }
500         else
501                 angles_held_status = 0;
502
503         if(newspectatee_status != spectatee_status)
504         {
505                 // clear race stuff
506                 race_laptime = 0;
507                 race_checkpointtime = 0;
508         }
509         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
510         {
511                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
512                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
513                 )
514                         prev_p_health = -1;
515                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
516                         prev_health = -1;
517         }
518         spectatee_status = newspectatee_status;
519
520         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
521 }
522
523 void Ent_Nagger()
524 {
525     int i, j, b, f;
526
527     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
528
529         if(!(nags & 4))
530         {
531                 if(vote_called_vote)
532                         strunzone(vote_called_vote);
533                 vote_called_vote = string_null;
534                 vote_active = 0;
535         }
536         else
537         {
538                 vote_active = 1;
539         }
540
541         if(nags & 64)
542         {
543                 vote_yescount = ReadByte();
544                 vote_nocount = ReadByte();
545                 vote_needed = ReadByte();
546                 vote_highlighted = ReadChar();
547         }
548
549         if(nags & 128)
550         {
551                 if(vote_called_vote)
552                         strunzone(vote_called_vote);
553                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
554         }
555
556         if(nags & 1)
557         {
558                 for(j = 0; j < maxclients; ++j)
559                         if(playerslots[j])
560                                 playerslots[j].ready = 1;
561                 for(i = 1; i <= maxclients; i += 8)
562                 {
563                         f = ReadByte();
564                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
565                                 if (!(f & b))
566                                         if(playerslots[j])
567                                                 playerslots[j].ready = 0;
568                 }
569         }
570
571         ready_waiting = (nags & 1);
572         ready_waiting_for_me = (nags & 2);
573         vote_waiting = (nags & 4);
574         vote_waiting_for_me = (nags & 8);
575         warmup_stage = (nags & 16);
576 }
577
578 void Ent_EliminatedPlayers()
579 {
580     int i, j, b, f;
581
582     int sf = ReadByte();
583         if(sf & 1)
584         {
585                 for(j = 0; j < maxclients; ++j)
586                         if(playerslots[j])
587                                 playerslots[j].eliminated = 1;
588                 for(i = 1; i <= maxclients; i += 8)
589                 {
590                         f = ReadByte();
591                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
592                                 if (!(f & b))
593                                         if(playerslots[j])
594                                                 playerslots[j].eliminated = 0;
595                 }
596         }
597 }
598
599 void Ent_RandomSeed()
600 {
601         float s;
602         prandom_debug();
603         s = ReadShort();
604         psrandom(s);
605 }
606
607 void Ent_ReadAccuracy(void)
608 {
609     int f, w;
610     int sf = ReadInt24_t();
611         if(sf == 0)
612         {
613                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
614                         weapon_accuracy[w] = -1;
615                 return;
616         }
617
618         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
619         {
620                 if(sf & f)
621                 {
622             int b = ReadByte();
623                         if(b == 0)
624                                 weapon_accuracy[w] = -1;
625                         else if(b == 255)
626                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
627                         else
628                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
629                 }
630                 if(f == 0x800000)
631                         f = 1;
632                 else
633                         f *= 2;
634         }
635 }
636
637 void Spawn_Draw(void)
638 {
639         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
640 }
641
642 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
643 {
644         float teamnum = (ReadByte() - 1);
645         vector spn_origin;
646         spn_origin_x = ReadShort();
647         spn_origin_y = ReadShort();
648         spn_origin_z = ReadShort();
649
650         if(is_new)
651         {
652                 self.origin = spn_origin;
653                 setsize(self, PL_MIN, PL_MAX);
654                 droptofloor();
655
656                 /*if(autocvar_cl_spawn_point_model) // needs a model first
657                 {
658                         self.mdl = "models/spawnpoint.md3";
659                         self.colormod = Team_ColorRGB(teamnum);
660                         precache_model(self.mdl);
661                         setmodel(self, self.mdl);
662                         self.drawmask = MASK_NORMAL;
663                         //self.movetype = MOVETYPE_NOCLIP;
664                         //self.draw = Spawn_Draw;
665                 }*/
666                 if(autocvar_cl_spawn_point_particles)
667                 {
668                         if((serverflags & SERVERFLAG_TEAMPLAY))
669                         {
670                                 switch(teamnum)
671                                 {
672                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
673                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
674                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
675                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
676                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
677                                 }
678                         }
679                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
680
681                         self.draw = Spawn_Draw;
682                 }
683         }
684
685         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
686 }
687
688 void Ent_ReadSpawnEvent(float is_new)
689 {
690         // If entnum is 0, ONLY do the local spawn actions
691         // this way the server can disable the sending of
692         // spawn origin or such to clients if wanted.
693         float entnum = ReadByte();
694
695         if(entnum)
696         {
697                 self.origin_x = ReadShort();
698                 self.origin_y = ReadShort();
699                 self.origin_z = ReadShort();
700
701                 if(is_new)
702                 {
703                         float teamnum = GetPlayerColor(entnum - 1);
704
705                         if(autocvar_cl_spawn_event_particles)
706                         {
707                                 switch(teamnum)
708                                 {
709                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
710                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
711                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
712                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
713                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
714                                 }
715                         }
716                         if(autocvar_cl_spawn_event_sound)
717                         {
718                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
719                         }
720                 }
721         }
722
723         // local spawn actions
724         if(is_new && (!entnum || (entnum == player_localentnum)))
725         {
726                 zoomin_effect = 1;
727                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
728
729                 if(autocvar_cl_unpress_zoom_on_spawn)
730                 {
731                         localcmd("-zoom\n");
732                         button_zoom = false;
733                 }
734         }
735
736         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
737 }
738
739 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
740 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
741 void Ent_RadarLink();
742 void Ent_Init();
743 void Ent_ScoresInfo();
744 void CSQC_Ent_Update(float bIsNewEntity)
745 {
746         float t;
747         float savetime;
748         t = ReadByte();
749
750         if(autocvar_developer_csqcentities)
751                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
752
753         // set up the "time" global for received entities to be correct for interpolation purposes
754         savetime = time;
755         if(servertime)
756         {
757                 time = servertime;
758         }
759         else
760         {
761                 serverprevtime = time;
762                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
763                 time = serverprevtime + serverdeltatime;
764         }
765
766 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
767         if(self.enttype)
768         {
769                 if(t != self.enttype || bIsNewEntity)
770                 {
771                         //print("A CSQC entity changed its type!\n");
772                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
773                         Ent_Remove();
774                         clearentity(self);
775                         bIsNewEntity = 1;
776                 }
777         }
778         else
779         {
780                 if(!bIsNewEntity)
781                 {
782                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
783                         bIsNewEntity = 1;
784                 }
785         }
786 #endif
787         self.enttype = t;
788         switch(t)
789         {
790                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
791                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
792                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
793                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
794                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
795                 case ENT_CLIENT_LASER: Ent_Laser(); break;
796                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
797                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
798                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
799                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
800                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
801                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
802                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
803                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
804                 case ENT_CLIENT_INIT: Ent_Init(); break;
805                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
806                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
807                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
808                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
809                 case ENT_CLIENT_WALL: Ent_Wall(); break;
810                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
811                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
812                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
813                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
814                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
815                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
816                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
817                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
818                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
819                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
820                 case ENT_CLIENT_TURRET: ent_turret(); break;
821                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
822                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
823                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
824                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
825                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
826                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
827                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
828
829                 default:
830                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
831                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
832                         break;
833         }
834
835         time = savetime;
836 }
837 // Destructor, but does NOT deallocate the entity by calling remove(). Also
838 // used when an entity changes its type. For an entity that someone interacts
839 // with others, make sure it can no longer do so.
840 void Ent_Remove()
841 {
842         if(self.entremove)
843                 self.entremove();
844
845         if(self.skeletonindex)
846         {
847                 skel_delete(self.skeletonindex);
848                 self.skeletonindex = 0;
849         }
850
851         if(self.snd_looping > 0)
852         {
853                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
854                 self.snd_looping = 0;
855         }
856
857         self.enttype = 0;
858         self.classname = "";
859         self.draw = menu_sub_null;
860         self.entremove = menu_sub_null;
861         // TODO possibly set more stuff to defaults
862 }
863 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
864 void CSQC_Ent_Remove()
865 {
866         if(autocvar_developer_csqcentities)
867                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
868
869         if(wasfreed(self))
870         {
871                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
872                 return;
873         }
874         if(self.enttype)
875                 Ent_Remove();
876         remove(self);
877 }
878
879 void Gamemode_Init()
880 {
881         if (!isdemo())
882         {
883                 if(!(calledhooks & HOOK_START))
884                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
885                 calledhooks |= HOOK_START;
886         }
887 }
888 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
889 void CSQC_Parse_StuffCmd(string strMessage)
890 {
891         if(autocvar_developer_csqcentities)
892                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
893
894         localcmd(strMessage);
895 }
896 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
897 void CSQC_Parse_Print(string strMessage)
898 {
899         if(autocvar_developer_csqcentities)
900                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
901
902         print(ColorTranslateRGB(strMessage));
903 }
904
905 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
906 void CSQC_Parse_CenterPrint(string strMessage)
907 {
908         if(autocvar_developer_csqcentities)
909                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
910
911         centerprint_hud(strMessage);
912 }
913
914 string notranslate_fogcmd1 = "\nfog ";
915 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
916 void Fog_Force()
917 {
918         // TODO somehow thwart prvm_globalset client ...
919
920         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
921                 { localcmd("\nr_drawfog 0\n"); }
922         else if(forcefog != "")
923                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
924 }
925
926 void Gamemode_Init();
927 void Ent_ScoresInfo()
928 {
929     int i;
930         self.classname = "ent_client_scores_info";
931         gametype = ReadInt24_t();
932         HUD_ModIcons_SetFunc();
933         for(i = 0; i < MAX_SCORE; ++i)
934         {
935                 if(scores_label[i])
936                         strunzone(scores_label[i]);
937                 scores_label[i] = strzone(ReadString());
938                 scores_flags[i] = ReadByte();
939         }
940         for(i = 0; i < MAX_TEAMSCORE; ++i)
941         {
942                 if(teamscores_label[i])
943                         strunzone(teamscores_label[i]);
944                 teamscores_label[i] = strzone(ReadString());
945                 teamscores_flags[i] = ReadByte();
946         }
947         HUD_InitScores();
948         Gamemode_Init();
949 }
950
951 void Ent_Init()
952 {
953         self.classname = "ent_client_init";
954
955         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
956
957         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
958         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
959         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
960         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
961         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
962         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
963         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
964         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
965
966         if(forcefog)
967                 strunzone(forcefog);
968         forcefog = strzone(ReadString());
969
970         armorblockpercent = ReadByte() / 255.0;
971
972         g_balance_mortar_bouncefactor = ReadCoord();
973         g_balance_mortar_bouncestop = ReadCoord();
974         g_balance_electro_secondary_bouncefactor = ReadCoord();
975         g_balance_electro_secondary_bouncestop = ReadCoord();
976
977         vortex_scope = !ReadByte();
978         rifle_scope = !ReadByte();
979
980         serverflags = ReadByte();
981
982         minelayer_maxmines = ReadByte();
983
984         hagar_maxrockets = ReadByte();
985
986         g_trueaim_minrange = ReadCoord();
987         g_balance_porto_secondary = ReadByte();
988
989         if(!postinit)
990                 PostInit();
991 }
992
993 void Net_ReadRace()
994 {
995         float b;
996
997         b = ReadByte();
998
999         switch(b)
1000         {
1001                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1002                         race_checkpoint = ReadByte();
1003                         race_time = ReadInt24_t();
1004                         race_previousbesttime = ReadInt24_t();
1005                         if(race_previousbestname)
1006                                 strunzone(race_previousbestname);
1007                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1008
1009                         race_checkpointtime = time;
1010
1011                         if(race_checkpoint == 0 || race_checkpoint == 254)
1012                         {
1013                                 race_penaltyaccumulator = 0;
1014                                 race_laptime = time; // valid
1015                         }
1016
1017                         break;
1018
1019                 case RACE_NET_CHECKPOINT_CLEAR:
1020                         race_laptime = 0;
1021                         race_checkpointtime = 0;
1022                         break;
1023
1024                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1025                         race_laptime = ReadCoord();
1026                         race_checkpointtime = -99999;
1027                         // fall through
1028                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1029                         race_nextcheckpoint = ReadByte();
1030
1031                         race_nextbesttime = ReadInt24_t();
1032                         if(race_nextbestname)
1033                                 strunzone(race_nextbestname);
1034                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1035                         break;
1036
1037                 case RACE_NET_CHECKPOINT_HIT_RACE:
1038                         race_mycheckpoint = ReadByte();
1039                         race_mycheckpointtime = time;
1040                         race_mycheckpointdelta = ReadInt24_t();
1041                         race_mycheckpointlapsdelta = ReadByte();
1042                         if(race_mycheckpointlapsdelta >= 128)
1043                                 race_mycheckpointlapsdelta -= 256;
1044                         if(race_mycheckpointenemy)
1045                                 strunzone(race_mycheckpointenemy);
1046                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1047                         break;
1048
1049                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1050                         race_othercheckpoint = ReadByte();
1051                         race_othercheckpointtime = time;
1052                         race_othercheckpointdelta = ReadInt24_t();
1053                         race_othercheckpointlapsdelta = ReadByte();
1054                         if(race_othercheckpointlapsdelta >= 128)
1055                                 race_othercheckpointlapsdelta -= 256;
1056                         if(race_othercheckpointenemy)
1057                                 strunzone(race_othercheckpointenemy);
1058                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1059                         break;
1060
1061                 case RACE_NET_PENALTY_RACE:
1062                         race_penaltyeventtime = time;
1063                         race_penaltytime = ReadShort();
1064                         //race_penaltyaccumulator += race_penaltytime;
1065                         if(race_penaltyreason)
1066                                 strunzone(race_penaltyreason);
1067                         race_penaltyreason = strzone(ReadString());
1068                         break;
1069
1070                 case RACE_NET_PENALTY_QUALIFYING:
1071                         race_penaltyeventtime = time;
1072                         race_penaltytime = ReadShort();
1073                         race_penaltyaccumulator += race_penaltytime;
1074                         if(race_penaltyreason)
1075                                 strunzone(race_penaltyreason);
1076                         race_penaltyreason = strzone(ReadString());
1077                         break;
1078
1079                 case RACE_NET_SERVER_RECORD:
1080                         race_server_record = ReadInt24_t();
1081                         break;
1082                 case RACE_NET_SPEED_AWARD:
1083                         race_speedaward = ReadInt24_t();
1084                         if(race_speedaward_holder)
1085                                 strunzone(race_speedaward_holder);
1086                         race_speedaward_holder = strzone(ReadString());
1087                         break;
1088                 case RACE_NET_SPEED_AWARD_BEST:
1089                         race_speedaward_alltimebest = ReadInt24_t();
1090                         if(race_speedaward_alltimebest_holder)
1091                                 strunzone(race_speedaward_alltimebest_holder);
1092                         race_speedaward_alltimebest_holder = strzone(ReadString());
1093                         break;
1094                 case RACE_NET_SERVER_RANKINGS:
1095                         float prevpos, del;
1096             int pos = ReadShort();
1097                         prevpos = ReadShort();
1098                         del = ReadShort();
1099
1100                         // move other rankings out of the way
1101             int i;
1102                         if (prevpos) {
1103                                 for (i=prevpos-1;i>pos-1;--i) {
1104                                         grecordtime[i] = grecordtime[i-1];
1105                                         if(grecordholder[i])
1106                                                 strunzone(grecordholder[i]);
1107                                         grecordholder[i] = strzone(grecordholder[i-1]);
1108                                 }
1109                         } else if (del) { // a record has been deleted by the admin
1110                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1111                                         if (i == RANKINGS_CNT-1) { // clear out last record
1112                                                 grecordtime[i] = 0;
1113                                                 if (grecordholder[i])
1114                                                         strunzone(grecordholder[i]);
1115                                                 grecordholder[i] = string_null;
1116                                         }
1117                                         else {
1118                                                 grecordtime[i] = grecordtime[i+1];
1119                                                 if (grecordholder[i])
1120                                                         strunzone(grecordholder[i]);
1121                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1122                                         }
1123                                 }
1124                         } else { // player has no ranked record yet
1125                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1126                                         grecordtime[i] = grecordtime[i-1];
1127                                         if(grecordholder[i])
1128                                                 strunzone(grecordholder[i]);
1129                                         grecordholder[i] = strzone(grecordholder[i-1]);
1130                                 }
1131                         }
1132
1133                         // store new ranking
1134                         if(grecordholder[pos-1] != "")
1135                                 strunzone(grecordholder[pos-1]);
1136                         grecordholder[pos-1] = strzone(ReadString());
1137                         grecordtime[pos-1] = ReadInt24_t();
1138                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1139                                 race_myrank = pos;
1140                         break;
1141                 case RACE_NET_SERVER_STATUS:
1142                         race_status = ReadShort();
1143                         if(race_status_name)
1144                                 strunzone(race_status_name);
1145                         race_status_name = strzone(ReadString());
1146         }
1147 }
1148
1149 void Net_TeamNagger()
1150 {
1151         teamnagger = 1;
1152 }
1153
1154 void Net_ReadPingPLReport()
1155 {
1156         int e, pi, pl, ml;
1157         e = ReadByte();
1158         pi = ReadShort();
1159         pl = ReadByte();
1160         ml = ReadByte();
1161         if (!(playerslots[e]))
1162                 return;
1163         playerslots[e].ping = pi;
1164         playerslots[e].ping_packetloss = pl / 255.0;
1165         playerslots[e].ping_movementloss = ml / 255.0;
1166 }
1167
1168 void Net_WeaponComplain()
1169 {
1170         complain_weapon = ReadByte();
1171
1172         if(complain_weapon_name)
1173                 strunzone(complain_weapon_name);
1174         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1175
1176         complain_weapon_type = ReadByte();
1177
1178         complain_weapon_time = time;
1179         weapontime = time; // ping the weapon panel
1180
1181         switch(complain_weapon_type)
1182         {
1183                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1184                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1185                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1186         }
1187 }
1188
1189 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1190 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1191 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1192 float CSQC_Parse_TempEntity()
1193 {
1194         float bHandled;
1195                 bHandled  = true;
1196         // Acquire TE ID
1197         float nTEID;
1198                 nTEID = ReadByte();
1199
1200         if(autocvar_developer_csqcentities)
1201                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1202
1203                 // NOTE: Could just do return instead of break...
1204         switch(nTEID)
1205         {
1206                 case TE_CSQC_TARGET_MUSIC:
1207                         Net_TargetMusic();
1208                         bHandled = true;
1209                         break;
1210                 case TE_CSQC_PICTURE:
1211                         Net_MapVote_Picture();
1212                         bHandled = true;
1213                         break;
1214                 case TE_CSQC_RACE:
1215                         Net_ReadRace();
1216                         bHandled = true;
1217                         break;
1218                 case TE_CSQC_VORTEXBEAMPARTICLE:
1219                         Net_ReadVortexBeamParticle();
1220                         bHandled = true;
1221                         break;
1222                 case TE_CSQC_TEAMNAGGER:
1223                         Net_TeamNagger();
1224                         bHandled = true;
1225                         break;
1226                 case TE_CSQC_ARC:
1227                         Net_ReadArc();
1228                         bHandled = true;
1229                         break;
1230                 case TE_CSQC_PINGPLREPORT:
1231                         Net_ReadPingPLReport();
1232                         bHandled = true;
1233                         break;
1234                 case TE_CSQC_WEAPONCOMPLAIN:
1235                         Net_WeaponComplain();
1236                         bHandled = true;
1237                         break;
1238                 case TE_CSQC_VEHICLESETUP:
1239                         Net_VehicleSetup();
1240                         bHandled = true;
1241                         break;
1242                 case TE_CSQC_SVNOTICE:
1243                         cl_notice_read();
1244                         bHandled = true;
1245                         break;
1246                 case TE_CSQC_SHOCKWAVEPARTICLE:
1247                         Net_ReadShockwaveParticle();
1248                         bHandled = true;
1249                         break;
1250                 default:
1251                         // No special logic for this temporary entity; return 0 so the engine can handle it
1252                         bHandled = false;
1253                         break;
1254         }
1255
1256         return bHandled;
1257 }
1258
1259 string getcommandkey(string text, string command)
1260 {
1261         string keys;
1262         float n, j, k, l = 0;
1263
1264         if (!autocvar_hud_showbinds)
1265                 return text;
1266
1267         keys = db_get(binddb, command);
1268         if (keys == "")
1269         {
1270                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1271                 for(j = 0; j < n; ++j)
1272                 {
1273                         k = stof(argv(j));
1274                         if(k != -1)
1275                         {
1276                                 if ("" == keys)
1277                                         keys = keynumtostring(k);
1278                                 else
1279                                         keys = strcat(keys, ", ", keynumtostring(k));
1280
1281                                 ++l;
1282                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1283                                         break;
1284                         }
1285
1286                 }
1287                 if (keys == "")
1288                         keys = "NO_KEY";
1289                 db_put(binddb, command, keys);
1290         }
1291
1292         if (keys == "NO_KEY") {
1293                 if (autocvar_hud_showbinds > 1)
1294                         return sprintf(_("%s (not bound)"), text);
1295                 else
1296                         return text;
1297         }
1298         else if (autocvar_hud_showbinds > 1)
1299                 return sprintf("%s (%s)", text, keys);
1300         else
1301                 return keys;
1302 }