qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void menu_show_error()
  29 {
  30         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  31 }
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void menu_sub_null()
  37 {
  38 }
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 void WaypointSprite_Load();
  46 void CSQC_Init(void)
  47 {
  48         prvm_language = cvar_string("prvm_language");
  49
  50 #ifdef USE_FTE
  51 #pragma target ID
  52         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  53         if(!__engine_check)
  54         {
  55                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  56                 localcmd("\ndisconnect\n");
  57                 return;
  58         }
  59 #pragma target FTE
  60 #endif
  61
  62         check_unacceptable_compiler_bugs();
  63
  64 #ifdef WATERMARK
  65         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK()));
  66 #endif
  67
  68         float i;
  69
  70         binddb = db_create();
  71         tempdb = db_create();
  72         ClientProgsDB = db_load("client.db");
  73         compressShortVector_init();
  74
  75         drawfont = FONT_USER+1;
  76         menu_visible = FALSE;
  77         menu_show = menu_show_error;
  78         menu_action = menu_sub_null;
  79
  80         for(i = 0; i < 255; ++i)
  81                 if(getplayerkey(i, "viewentity") == "")
  82                         break;
  83         maxclients = i;
  84
  85         registercmd("hud_configure");
  86         registercmd("hud_save");
  87         //registercmd("menu_action");
  88
  89         registercmd("+showscores");registercmd("-showscores");
  90         registercmd("+showaccuracy");registercmd("-showaccuracy");
  91
  92 #ifndef CAMERATEST
  93         if(isdemo())
  94         {
  95 #endif
  96                 registercmd("+forward");registercmd("-forward");
  97                 registercmd("+back");registercmd("-back");
  98                 registercmd("+moveup");registercmd("-moveup");
  99                 registercmd("+movedown");registercmd("-movedown");
 100                 registercmd("+moveright");registercmd("-moveright");
 101                 registercmd("+moveleft");registercmd("-moveleft");
 102                 registercmd("+roll_right");registercmd("-roll_right");
 103                 registercmd("+roll_left");registercmd("-roll_left");
 104 #ifndef CAMERATEST
 105         }
 106 #endif
 107         registercvar("hud_usecsqc", "1");
 108         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 109
 110         gametype = 0;
 111
 112         // hud_fields uses strunzone on the titles!
 113         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 114                 hud_title[i] = strzone("(null)");
 115
 116         postinit = false;
 117
 118         calledhooks = 0;
 119
 120         teams = Sort_Spawn();
 121         players = Sort_Spawn();
 122
 123         GetTeam(COLOR_SPECTATOR, true); // add specs first
 124
 125         RegisterWeapons();
 126
 127         WaypointSprite_Load();
 128
 129         // precaches
 130         precache_sound("misc/hit.wav");
 131         precache_sound("misc/typehit.wav");
 132         Projectile_Precache();
 133         Hook_Precache();
 134         GibSplash_Precache();
 135         Casings_Precache();
 136         DamageInfo_Precache();
 137         Vehicles_Precache();
 138         turrets_precache();
 139   Announcer_Precache();
 140         Tuba_Precache();
 141
 142         if(autocvar_cl_reticle)
 143         {
 144                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 145                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 146         }
 147
 148         get_mi_min_max_texcoords(1); // try the CLEVER way first
 149         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 150         shortmapname = mi_shortname;
 151
 152         if(precache_pic(minimapname) == "")
 153         {
 154                 // but maybe we have a non-clever minimap
 155                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 156                 if(precache_pic(minimapname) == "")
 157                         minimapname = ""; // FAIL
 158                 else
 159                         get_mi_min_max_texcoords(0); // load new texcoords
 160         }
 161
 162         mi_center = (mi_min + mi_max) * 0.5;
 163         mi_scale = mi_max - mi_min;
 164         minimapname = strzone(minimapname);
 165
 166         WarpZone_Init();
 167
 168         hud_configure_prev = -1;
 169         tab_panel = -1;
 170 }
 171
 172 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 173 void CSQC_Shutdown(void)
 174 {
 175 #ifdef USE_FTE
 176 #pragma TARGET id
 177         if(!__engine_check)
 178                 return 0;
 179 #pragma TARGET fte
 180 #endif
 181
 182         WarpZone_Shutdown();
 183
 184         remove(teams);
 185         remove(players);
 186         db_close(binddb);
 187         db_close(tempdb);
 188         if(autocvar_cl_db_saveasdump)
 189                 db_dump(ClientProgsDB, "client.db");
 190         else
 191                 db_save(ClientProgsDB, "client.db");
 192         db_close(ClientProgsDB);
 193
 194         cvar_clientsettemp_restore();
 195
 196         if(camera_active)
 197                 cvar_set("chase_active",ftos(chase_active_backup));
 198
 199         // unset the event chasecam's chase_active
 200         if(autocvar_chase_active < 0)
 201                 cvar_set("chase_active", "0");
 202
 203         if not(isdemo())
 204         {
 205                 if not(calledhooks & HOOK_START)
 206                         localcmd("\n_cl_hook_gamestart nop\n");
 207                 if not(calledhooks & HOOK_END)
 208                         localcmd("\ncl_hook_gameend\n");
 209         }
 210 }
 211
 212 .float has_team;
 213 float SetTeam(entity o, float Team)
 214 {
 215         entity tm;
 216         if(teamplay)
 217         {
 218                 switch(Team)
 219                 {
 220                         case -1:
 221                         case COLOR_TEAM1:
 222                         case COLOR_TEAM2:
 223                         case COLOR_TEAM3:
 224                         case COLOR_TEAM4:
 225                                 break;
 226                         default:
 227                                 if(GetTeam(Team, false) == NULL)
 228                                 {
 229                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 230                                         Team = COLOR_SPECTATOR;
 231                                 }
 232                                 break;
 233                 }
 234         }
 235         else
 236         {
 237                 switch(Team)
 238                 {
 239                         case -1:
 240                         case 0:
 241                                 break;
 242                         default:
 243                                 if(GetTeam(Team, false) == NULL)
 244                                 {
 245                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 246                                         Team = COLOR_SPECTATOR;
 247                                 }
 248                                 break;
 249                 }
 250         }
 251         if(Team == -1) // leave
 252         {
 253                 if(o.has_team)
 254                 {
 255                         tm = GetTeam(o.team, false);
 256                         tm.team_size -= 1;
 257                         o.has_team = 0;
 258                         return TRUE;
 259                 }
 260         }
 261         else
 262         {
 263                 if not(o.has_team)
 264                 {
 265                         o.team = Team;
 266                         tm = GetTeam(Team, true);
 267                         tm.team_size += 1;
 268                         o.has_team = 1;
 269                         return TRUE;
 270                 }
 271                 else if(Team != o.team)
 272                 {
 273                         tm = GetTeam(o.team, false);
 274                         tm.team_size -= 1;
 275                         o.team = Team;
 276                         tm = GetTeam(Team, true);
 277                         tm.team_size += 1;
 278                         return TRUE;
 279                 }
 280         }
 281         return FALSE;
 282 }
 283
 284 void Playerchecker_Think()
 285 {
 286         float i;
 287         entity e;
 288         for(i = 0; i < maxclients; ++i)
 289         {
 290                 e = playerslots[i];
 291                 if(GetPlayerName(i) == "")
 292                 {
 293                         if(e.sort_prev)
 294                         {
 295                                 // player disconnected
 296                                 SetTeam(e, -1);
 297                                 RemovePlayer(e);
 298                                 e.sort_prev = world;
 299                                 //e.gotscores = 0;
 300                         }
 301                 }
 302                 else
 303                 {
 304                         if not(e.sort_prev)
 305                         {
 306                                 // player connected
 307                                 if not(e)
 308                                         playerslots[i] = e = spawn();
 309                                 e.sv_entnum = i;
 310                                 e.ping = 0;
 311                                 e.ping_packetloss = 0;
 312                                 e.ping_movementloss = 0;
 313                                 //e.gotscores = 0; // we might already have the scores...
 314                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 315                                 RegisterPlayer(e);
 316                                 HUD_UpdatePlayerPos(e);
 317                         }
 318                 }
 319         }
 320         self.nextthink = time + 0.2;
 321 }
 322
 323 void Porto_Init();
 324 void TrueAim_Init();
 325 void PostInit(void)
 326 {
 327         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 328
 329         entity playerchecker;
 330         playerchecker = spawn();
 331         playerchecker.think = Playerchecker_Think;
 332         playerchecker.nextthink = time + 0.2;
 333
 334         Porto_Init();
 335         TrueAim_Init();
 336
 337         postinit = true;
 338 }
 339
 340 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 341 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 342 float button_zoom;
 343 void Cmd_HUD_SetFields(float);
 344 void Cmd_HUD_Help(float);
 345 float CSQC_ConsoleCommand(string strMessage)
 346 {
 347         float argc;
 348         // Tokenize String
 349         argc = tokenize_console(strMessage);
 350
 351         // Acquire Command
 352         string strCmd;
 353         strCmd = argv(0);
 354
 355         if(strCmd == "hud_configure") { // config hud
 356                 cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 357                 return true;
 358         } else if(strCmd == "hud_save") { // save hud config
 359                 if(argv(1) == "" || argv(2)) {
 360                         print(_("Usage:\n"));
 361                         print(_("hud_save configname   (saves to hud_skinname_configname.cfg)\n"));
 362                 }
 363                 else
 364                         HUD_Panel_ExportCfg(argv(1));
 365                 return true;
 366         } else if(strCmd == "+showscores") {
 367                 scoreboard_showscores = true;
 368                 return true;
 369         } else if(strCmd == "-showscores") {
 370                 scoreboard_showscores = false;
 371                 return true;
 372         } else if(strCmd == "+showaccuracy") {
 373                 scoreboard_showaccuracy = true;
 374                 return true;
 375         } else if(strCmd == "-showaccuracy") {
 376                 scoreboard_showaccuracy = false;
 377                 return true;
 378         }
 379
 380         if(camera_active)
 381         if(strCmd == "+forward" || strCmd == "-back") {
 382                 ++camera_direction_x;
 383                 return true;
 384         } else if(strCmd == "-forward" || strCmd == "+back") {
 385                 --camera_direction_x;
 386                 return true;
 387         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 388                 --camera_direction_y;
 389                 return true;
 390         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 391                 ++camera_direction_y;
 392                 return true;
 393         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 394                 ++camera_direction_z;
 395                 return true;
 396         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 397                 --camera_direction_z;
 398                 return true;
 399         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 400                 ++camera_roll;
 401                 return true;
 402         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 403                 --camera_roll;
 404                 return true;
 405         }
 406
 407         return false;
 408 }
 409
 410 .vector view_ofs;
 411 entity debug_shotorg;
 412 void ShotOrg_Draw()
 413 {
 414         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 415         self.angles = view_angles;
 416         self.angles_x = -self.angles_x;
 417         if not(self.cnt)
 418                 self.drawmask = MASK_NORMAL;
 419         else
 420                 self.drawmask = 0;
 421 }
 422 void ShotOrg_Draw2D()
 423 {
 424         vector coord2d_topleft, coord2d_topright, coord2d;
 425         string s;
 426         vector fs;
 427
 428         s = vtos(self.view_ofs);
 429         s = substring(s, 1, strlen(s) - 2);
 430         if(tokenize_console(s) == 3)
 431                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 432
 433         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 434         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 435
 436         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 437
 438         coord2d = coord2d_topleft;
 439         if(fs_x < 8)
 440         {
 441                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 442                 fs = '8 8 0';
 443         }
 444         coord2d_y -= fs_y;
 445         coord2d_z = 0;
 446         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 447 }
 448
 449 void ShotOrg_Spawn()
 450 {
 451         debug_shotorg = spawn();
 452         debug_shotorg.draw = ShotOrg_Draw;
 453         debug_shotorg.draw2d = ShotOrg_Draw2D;
 454         debug_shotorg.renderflags = RF_VIEWMODEL;
 455         debug_shotorg.effects = EF_FULLBRIGHT;
 456         precache_model("models/shotorg_adjuster.md3");
 457         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 458         debug_shotorg.scale = 2;
 459         debug_shotorg.view_ofs = '25 8 -8';
 460 }
 461
 462 void DrawDebugModel()
 463 {
 464         if(time - floor(time) > 0.5)
 465         {
 466                 PolyDrawModel(self);
 467                 self.drawmask = 0;
 468         }
 469         else
 470         {
 471                 self.renderflags = 0;
 472                 self.drawmask = MASK_NORMAL;
 473         }
 474 }
 475
 476 void GameCommand(string msg)
 477 {
 478         string s;
 479         float argc;
 480         entity e;
 481         argc = tokenize_console(msg);
 482
 483         if(argv(0) == "help" || argc == 0)
 484         {
 485                 print(_("Usage: cl_cmd COMMAND..., where possible commands are:\n"));
 486                 print(_("  settemp cvar value\n"));
 487                 print(_("  scoreboard_columns_set ...\n"));
 488                 print(_("  scoreboard_columns_help\n"));
 489                 GameCommand_Generic("help");
 490                 return;
 491         }
 492
 493         if(GameCommand_Generic(msg))
 494                 return;
 495
 496         string cmd;
 497         cmd = argv(0);
 498         if(cmd == "mv_download") {
 499                 Cmd_MapVote_MapDownload(argc);
 500         }
 501         else if(cmd == "hud_panel_radar_maximized")
 502         {
 503                 if(argc == 1)
 504                         hud_panel_radar_maximized = !hud_panel_radar_maximized;
 505                 else
 506                         hud_panel_radar_maximized = (stof(argv(1)) != 0);
 507         }
 508         else if(cmd == "settemp") {
 509                 cvar_clientsettemp(argv(1), argv(2));
 510         }
 511         else if(cmd == "scoreboard_columns_set") {
 512                 Cmd_HUD_SetFields(argc);
 513         }
 514         else if(cmd == "scoreboard_columns_help") {
 515                 Cmd_HUD_Help(argc);
 516         }
 517 #ifdef BLURTEST
 518         else if(cmd == "blurtest") {
 519                 blurtest_time0 = time;
 520                 blurtest_time1 = time + stof(argv(1));
 521                 blurtest_radius = stof(argv(2));
 522                 blurtest_power = stof(argv(3));
 523         }
 524 #endif
 525         else if(cmd == "shotorg_move") {
 526                 if(!debug_shotorg)
 527                         ShotOrg_Spawn();
 528                 else
 529                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 530                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 531         }
 532         else if(cmd == "shotorg_movez") {
 533                 if(!debug_shotorg)
 534                         ShotOrg_Spawn();
 535                 else
 536                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 537                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 538         }
 539         else if(cmd == "shotorg_set") {
 540                 if(!debug_shotorg)
 541                         ShotOrg_Spawn();
 542                 else
 543                         debug_shotorg.view_ofs = stov(argv(1));
 544                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 545         }
 546         else if(cmd == "shotorg_setz") {
 547                 if(!debug_shotorg)
 548                         ShotOrg_Spawn();
 549                 else
 550                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 551                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 552         }
 553         else if(cmd == "shotorg_toggle_hide") {
 554                 if(debug_shotorg)
 555                 {
 556                         debug_shotorg.cnt = !debug_shotorg.cnt;
 557                 }
 558         }
 559         else if(cmd == "shotorg_end") {
 560                 if(debug_shotorg)
 561                 {
 562                         print(vtos(debug_shotorg.view_ofs), "\n");
 563                         remove(debug_shotorg);
 564                         debug_shotorg = world;
 565                 }
 566                 localcmd("sv_cmd debug_shotorg\n");
 567         }
 568         else if(cmd == "sendcvar") {
 569                 // W_FixWeaponOrder will trash argv, so save what we need.
 570                 string thiscvar;
 571                 thiscvar = strzone(argv(1));
 572                 s = cvar_string(thiscvar);
 573                 if(thiscvar == "cl_weaponpriority")
 574                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 575                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 576                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 577                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 578                 strunzone(thiscvar);
 579         }
 580         else if(cmd == "spawn") {
 581                 s = argv(1);
 582                 e = spawn();
 583                 precache_model(s);
 584                 setmodel(e, s);
 585                 setorigin(e, view_origin);
 586                 e.angles = view_angles;
 587                 e.draw = DrawDebugModel;
 588                 e.classname = "debugmodel";
 589         }
 590     else if(cmd == "vyes")
 591     {
 592         if(uid2name_dialog)
 593         {
 594             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
 595             vote_prev = 0;
 596             localcmd("setreport cl_allow_uid2name 1\n");
 597             vote_change = -9999;
 598                         uid2name_dialog = 0;
 599         }
 600         else
 601         {
 602             localcmd("cmd vote yes\n");
 603         }
 604     }
 605     else if(cmd == "vno")
 606     {
 607         if(uid2name_dialog)
 608         {
 609             vote_active = 0;
 610             vote_prev = 0;
 611             localcmd("setreport cl_allow_uid2name 0\n");
 612             vote_change = -9999;
 613                         uid2name_dialog = 0;
 614         }
 615         else
 616         {
 617             localcmd("cmd vote no\n");
 618         }
 619     }
 620
 621         else
 622         {
 623                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 624         }
 625
 626         return;
 627 }
 628
 629 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 630 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 631 // All keys are in ascii.
 632 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 633 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 634 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 635 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 636 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 637 {
 638         float bSkipKey;
 639         bSkipKey = false;
 640
 641         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 642                 return true;
 643
 644         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 645                 return true;
 646
 647         if(menu_visible)
 648                 if(menu_action(bInputType, nPrimary, nSecondary))
 649                         return TRUE;
 650
 651         return bSkipKey;
 652 }
 653
 654 // END REQUIRED CSQC FUNCTIONS
 655 // --------------------------------------------------------------------------
 656
 657 // --------------------------------------------------------------------------
 658 // BEGIN OPTIONAL CSQC FUNCTIONS
 659 void Ent_RemoveEntCS()
 660 {
 661         entcs_receiver[self.sv_entnum] = world;
 662 }
 663 void Ent_ReadEntCS()
 664 {
 665         float sf;
 666         InterpolateOrigin_Undo();
 667
 668         self.classname = "entcs_receiver";
 669         sf = ReadByte();
 670
 671         if(sf & 1)
 672                 self.sv_entnum = ReadByte();
 673         if(sf & 2)
 674         {
 675                 self.origin_x = ReadShort();
 676                 self.origin_y = ReadShort();
 677                 self.origin_z = ReadShort();
 678         }
 679         if(sf & 4)
 680         {
 681                 self.angles_y = ReadByte() * 360.0 / 256;
 682                 self.angles_x = self.angles_z = 0;
 683         }
 684         if(sf & 8)
 685                 self.healthvalue = ReadByte() * 10;
 686         if(sf & 16)
 687                 self.armorvalue = ReadByte() * 10;
 688
 689         entcs_receiver[self.sv_entnum] = self;
 690         self.entremove = Ent_RemoveEntCS;
 691
 692         InterpolateOrigin_Note();
 693 }
 694
 695 void Ent_Remove();
 696
 697 void Ent_RemovePlayerScore()
 698 {
 699         float i;
 700
 701         if(self.owner)
 702         {
 703                 SetTeam(self.owner, -1);
 704                 self.owner.gotscores = 0;
 705                 for(i = 0; i < MAX_SCORE; ++i)
 706                         self.owner.(scores[i]) = 0; // clear all scores
 707         }
 708 }
 709
 710 void Ent_ReadPlayerScore()
 711 {
 712         float i, n;
 713         float isNew;
 714         entity o;
 715
 716         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 717         // (no I've never heard of M-x replace-string, sed, or anything like that)
 718         isNew = !self.owner; // workaround for DP bug
 719         n = ReadByte()-1;
 720
 721 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 722         if(!isNew && n != self.sv_entnum)
 723         {
 724                 //print(_("A CSQC entity changed its owner!\n"));
 725                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 726                 isNew = true;
 727                 Ent_Remove();
 728                 self.enttype = ENT_CLIENT_SCORES;
 729         }
 730 #endif
 731
 732         self.sv_entnum = n;
 733
 734         if not(playerslots[self.sv_entnum])
 735                 playerslots[self.sv_entnum] = spawn();
 736         o = self.owner = playerslots[self.sv_entnum];
 737         o.sv_entnum = self.sv_entnum;
 738         o.gotscores = 1;
 739
 740         //if not(o.sort_prev)
 741         //      RegisterPlayer(o);
 742         //playerchecker will do this for us later, if it has not already done so
 743
 744         float sf, lf;
 745 #if MAX_SCORE <= 8
 746         sf = ReadByte();
 747         lf = ReadByte();
 748 #else
 749         sf = ReadShort();
 750         lf = ReadShort();
 751 #endif
 752         float p;
 753         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 754                 if(sf & p)
 755                 {
 756                         if(lf & p)
 757                                 o.(scores[i]) = ReadInt24_t();
 758                         else
 759                                 o.(scores[i]) = ReadChar();
 760                 }
 761
 762         if(o.sort_prev)
 763                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 764
 765         self.entremove = Ent_RemovePlayerScore;
 766 }
 767
 768 void Ent_ReadTeamScore()
 769 {
 770         float i;
 771         entity o;
 772
 773         self.team = ReadByte();
 774         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 775
 776         float sf, lf;
 777 #if MAX_TEAMSCORE <= 8
 778         sf = ReadByte();
 779         lf = ReadByte();
 780 #else
 781         sf = ReadShort();
 782         lf = ReadShort();
 783 #endif
 784         float p;
 785         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 786                 if(sf & p)
 787                 {
 788                         if(lf & p)
 789                                 o.(teamscores[i]) = ReadInt24_t();
 790                         else
 791                                 o.(teamscores[i]) = ReadChar();
 792                 }
 793
 794         HUD_UpdateTeamPos(o);
 795 }
 796
 797 void Ent_ClientData()
 798 {
 799         float f;
 800         float newspectatee_status;
 801
 802         f = ReadByte();
 803
 804         scoreboard_showscores_force = (f & 1);
 805
 806         if(f & 2)
 807         {
 808                 newspectatee_status = ReadByte();
 809                 if(newspectatee_status == player_localentnum)
 810                         newspectatee_status = -1; // observing
 811         }
 812         else
 813                 newspectatee_status = 0;
 814
 815         spectatorbutton_zoom = (f & 4);
 816
 817         if(f & 8)
 818         {
 819                 angles_held_status = 1;
 820                 angles_held_x = ReadAngle();
 821                 angles_held_y = ReadAngle();
 822                 angles_held_z = 0;
 823         }
 824         else
 825                 angles_held_status = 0;
 826
 827         if(newspectatee_status != spectatee_status)
 828         {
 829                 // clear race stuff
 830                 race_laptime = 0;
 831                 race_checkpointtime = 0;
 832         }
 833         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 834         {
 835                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 836                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 837                 )
 838                         prev_p_health = -1;
 839                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 840                         prev_health = -1;
 841         }
 842         spectatee_status = newspectatee_status;
 843 }
 844
 845 void Ent_Nagger()
 846 {
 847         float nags, i, j, b, f;
 848
 849         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 850
 851         if(!(nags & 4))
 852         {
 853                 if(vote_called_vote)
 854                         strunzone(vote_called_vote);
 855                 vote_called_vote = string_null;
 856                 vote_active = 0;
 857         }
 858         else
 859         {
 860                 vote_active = 1;
 861         }
 862
 863         if(nags & 64)
 864         {
 865                 vote_yescount = ReadByte();
 866                 vote_nocount = ReadByte();
 867                 vote_needed = ReadByte();
 868                 vote_highlighted = ReadChar();
 869         }
 870
 871         if(nags & 128)
 872         {
 873                 if(vote_called_vote)
 874                         strunzone(vote_called_vote);
 875                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 876         }
 877
 878         if(nags & 1)
 879         {
 880                 for(j = 0; j < maxclients; ++j)
 881                         if(playerslots[j])
 882                                 playerslots[j].ready = 1;
 883                 for(i = 1; i <= maxclients; i += 8)
 884                 {
 885                         f = ReadByte();
 886                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 887                                 if not(f & b)
 888                                         if(playerslots[j])
 889                                                 playerslots[j].ready = 0;
 890                 }
 891         }
 892
 893         ready_waiting = (nags & 1);
 894         ready_waiting_for_me = (nags & 2);
 895         vote_waiting = (nags & 4);
 896         vote_waiting_for_me = (nags & 8);
 897         warmup_stage = (nags & 16);
 898 }
 899
 900 void Ent_RandomSeed()
 901 {
 902         float s;
 903         prandom_debug();
 904         s = ReadShort();
 905         psrandom(s);
 906 }
 907
 908 void Ent_ReadAccuracy(void)
 909 {
 910         float sf, f, w, b;
 911         sf = ReadInt24_t();
 912         if(sf == 0)
 913         {
 914                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 915                         weapon_accuracy[w] = -1;
 916                 return;
 917         }
 918
 919         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 920         {
 921                 if(sf & f)
 922                 {
 923                         b = ReadByte();
 924                         if(b == 0)
 925                                 weapon_accuracy[w] = -1;
 926                         else if(b == 255)
 927                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 928                         else
 929                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 930                 }
 931         }
 932 }
 933
 934 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 935 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 936 void Ent_RadarLink();
 937 void Ent_Init();
 938 void Ent_ScoresInfo();
 939 void CSQC_Ent_Update(float bIsNewEntity)
 940 {
 941         float t;
 942         float savetime;
 943         t = ReadByte();
 944
 945         // set up the "time" global for received entities to be correct for interpolation purposes
 946         savetime = time;
 947         if(servertime)
 948         {
 949                 time = servertime;
 950         }
 951         else
 952         {
 953                 serverprevtime = time;
 954                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 955                 time = serverprevtime + serverdeltatime;
 956         }
 957
 958 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 959         if(self.enttype)
 960         {
 961                 if(t != self.enttype || bIsNewEntity)
 962                 {
 963                         //print(_("A CSQC entity changed its type!\n"));
 964                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n"), num_for_edict(self), self.entnum, self.enttype, t));
 965                         Ent_Remove();
 966                         bIsNewEntity = 1;
 967                 }
 968         }
 969         else
 970         {
 971                 if(!bIsNewEntity)
 972                 {
 973                         print(sprintf(_("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n"), num_for_edict(self), self.entnum, t));
 974                         bIsNewEntity = 1;
 975                 }
 976         }
 977 #endif
 978         self.enttype = t;
 979         switch(t)
 980         {
 981                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 982                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 983                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 984                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 985                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 986                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 987                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 988                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 989                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 990                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 991                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 992                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 993                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 994                 case ENT_CLIENT_INIT: Ent_Init(); break;
 995                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 996                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 997                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 998                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 999                 case ENT_CLIENT_WALL: Ent_Wall(); break;
1000                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
1001                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
1002                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
1003                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
1004                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
1005                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
1006                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
1007                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
1008                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
1009                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
1010                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
1011                 case ENT_CLIENT_TURRET: ent_turret(); break;
1012                 default:
1013                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
1014                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
1015                         break;
1016         }
1017
1018         time = savetime;
1019 }
1020 // Destructor, but does NOT deallocate the entity by calling remove(). Also
1021 // used when an entity changes its type. For an entity that someone interacts
1022 // with others, make sure it can no longer do so.
1023 void Ent_Remove()
1024 {
1025         if(self.entremove)
1026                 self.entremove();
1027
1028         self.enttype = 0;
1029         self.classname = "";
1030         self.draw = menu_sub_null;
1031         self.entremove = menu_sub_null;
1032         // TODO possibly set more stuff to defaults
1033 }
1034 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
1035 void CSQC_Ent_Remove()
1036 {
1037         if(self.enttype)
1038                 Ent_Remove();
1039         remove(self);
1040 }
1041
1042 void Gamemode_Init()
1043 {
1044         if not(isdemo())
1045         {
1046                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
1047                 calledhooks |= HOOK_START;
1048         }
1049 }
1050 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1051 void CSQC_Parse_StuffCmd(string strMessage)
1052 {
1053         localcmd(strMessage);
1054 }
1055 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1056 void CSQC_Parse_Print(string strMessage)
1057 {
1058         print(ColorTranslateRGB(strMessage));
1059 }
1060
1061 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1062 void CSQC_Parse_CenterPrint(string strMessage)
1063 {
1064         centerprint(strMessage);
1065 }
1066
1067 string notranslate_fogcmd1 = "\nfog ";
1068 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1069 void Fog_Force()
1070 {
1071         // TODO somehow thwart prvm_globalset client ...
1072
1073         if(forcefog != "")
1074                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1075 }
1076
1077 void Gamemode_Init();
1078 void Ent_ScoresInfo()
1079 {
1080         float i;
1081         self.classname = "ent_client_scores_info";
1082         gametype = ReadByte();
1083         for(i = 0; i < MAX_SCORE; ++i)
1084         {
1085                 scores_label[i] = strzone(ReadString());
1086                 scores_flags[i] = ReadByte();
1087         }
1088         for(i = 0; i < MAX_TEAMSCORE; ++i)
1089         {
1090                 teamscores_label[i] = strzone(ReadString());
1091                 teamscores_flags[i] = ReadByte();
1092         }
1093         HUD_InitScores();
1094         Gamemode_Init();
1095 }
1096
1097 void Ent_Init()
1098 {
1099         self.classname = "ent_client_init";
1100
1101         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1102
1103         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1104         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1105         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1106         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1107         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1108         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1109         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1110         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1111         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1112         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1113         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1114         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1115
1116         if(forcefog)
1117                 strunzone(forcefog);
1118         forcefog = strzone(ReadString());
1119
1120         armorblockpercent = ReadByte() / 255.0;
1121
1122         g_weaponswitchdelay = ReadByte() / 255.0;
1123
1124         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1125         g_balance_grenadelauncher_bouncestop = ReadCoord();
1126         g_balance_electro_secondary_bouncefactor = ReadCoord();
1127         g_balance_electro_secondary_bouncestop = ReadCoord();
1128
1129         nex_scope = !ReadByte();
1130         rifle_scope = !ReadByte();
1131
1132         serverflags = ReadByte();
1133
1134         minelayer_maxmines = ReadByte();
1135
1136         hagar_maxrockets = ReadByte();
1137
1138         g_trueaim_minrange = ReadCoord();
1139
1140         if(!postinit)
1141                 PostInit();
1142 }
1143
1144 void Net_ReadRace()
1145 {
1146         float b;
1147
1148         b = ReadByte();
1149
1150         switch(b)
1151         {
1152                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1153                         race_checkpoint = ReadByte();
1154                         race_time = ReadInt24_t();
1155                         race_previousbesttime = ReadInt24_t();
1156                         if(race_previousbestname)
1157                                 strunzone(race_previousbestname);
1158                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1159
1160                         race_checkpointtime = time;
1161
1162                         if(race_checkpoint == 0 || race_checkpoint == 254)
1163                         {
1164                                 race_penaltyaccumulator = 0;
1165                                 race_laptime = time; // valid
1166                         }
1167
1168                         break;
1169
1170                 case RACE_NET_CHECKPOINT_CLEAR:
1171                         race_laptime = 0;
1172                         race_checkpointtime = 0;
1173                         break;
1174
1175                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1176                         race_laptime = ReadCoord();
1177                         race_checkpointtime = -99999;
1178                         // fall through
1179                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1180                         race_nextcheckpoint = ReadByte();
1181
1182                         race_nextbesttime = ReadInt24_t();
1183                         if(race_nextbestname)
1184                                 strunzone(race_nextbestname);
1185                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1186                         break;
1187
1188                 case RACE_NET_CHECKPOINT_HIT_RACE:
1189                         race_mycheckpoint = ReadByte();
1190                         race_mycheckpointtime = time;
1191                         race_mycheckpointdelta = ReadInt24_t();
1192                         race_mycheckpointlapsdelta = ReadByte();
1193                         if(race_mycheckpointlapsdelta >= 128)
1194                                 race_mycheckpointlapsdelta -= 256;
1195                         if(race_mycheckpointenemy)
1196                                 strunzone(race_mycheckpointenemy);
1197                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1198                         break;
1199
1200                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1201                         race_othercheckpoint = ReadByte();
1202                         race_othercheckpointtime = time;
1203                         race_othercheckpointdelta = ReadInt24_t();
1204                         race_othercheckpointlapsdelta = ReadByte();
1205                         if(race_othercheckpointlapsdelta >= 128)
1206                                 race_othercheckpointlapsdelta -= 256;
1207                         if(race_othercheckpointenemy)
1208                                 strunzone(race_othercheckpointenemy);
1209                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1210                         break;
1211
1212                 case RACE_NET_PENALTY_RACE:
1213                         race_penaltyeventtime = time;
1214                         race_penaltytime = ReadShort();
1215                         //race_penaltyaccumulator += race_penaltytime;
1216                         if(race_penaltyreason)
1217                                 strunzone(race_penaltyreason);
1218                         race_penaltyreason = strzone(ReadString());
1219                         break;
1220
1221                 case RACE_NET_PENALTY_QUALIFYING:
1222                         race_penaltyeventtime = time;
1223                         race_penaltytime = ReadShort();
1224                         race_penaltyaccumulator += race_penaltytime;
1225                         if(race_penaltyreason)
1226                                 strunzone(race_penaltyreason);
1227                         race_penaltyreason = strzone(ReadString());
1228                         break;
1229
1230                 case RACE_NET_SERVER_RECORD:
1231                         race_server_record = ReadInt24_t();
1232                         break;
1233                 case RACE_NET_SPEED_AWARD:
1234                         race_speedaward = ReadInt24_t();
1235                         if(race_speedaward_holder)
1236                                 strunzone(race_speedaward_holder);
1237                         race_speedaward_holder = strzone(ReadString());
1238                         break;
1239                 case RACE_NET_SPEED_AWARD_BEST:
1240                         race_speedaward_alltimebest = ReadInt24_t();
1241                         if(race_speedaward_alltimebest_holder)
1242                                 strunzone(race_speedaward_alltimebest_holder);
1243                         race_speedaward_alltimebest_holder = strzone(ReadString());
1244                         break;
1245                 case RACE_NET_SERVER_RANKINGS:
1246                         float pos, prevpos, del;
1247                         pos = ReadShort();
1248                         prevpos = ReadShort();
1249                         del = ReadShort();
1250
1251                         // move other rankings out of the way
1252                         float i;
1253                         if (prevpos) {
1254                                 for (i=prevpos-1;i>pos-1;--i) {
1255                                         grecordtime[i] = grecordtime[i-1];
1256                                         if(grecordholder[i])
1257                                                 strunzone(grecordholder[i]);
1258                                         grecordholder[i] = strzone(grecordholder[i-1]);
1259                                 }
1260                         } else if (del) { // a record has been deleted by the admin
1261                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1262                                         if (i == RANKINGS_CNT-1) { // clear out last record
1263                                                 grecordtime[i] = 0;
1264                                                 if (grecordholder[i])
1265                                                         strunzone(grecordholder[i]);
1266                                                 grecordholder[i] = string_null;
1267                                         }
1268                                         else {
1269                                                 grecordtime[i] = grecordtime[i+1];
1270                                                 if (grecordholder[i])
1271                                                         strunzone(grecordholder[i]);
1272                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1273                                         }
1274                                 }
1275                         } else { // player has no ranked record yet
1276                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1277                                         grecordtime[i] = grecordtime[i-1];
1278                                         if(grecordholder[i])
1279                                                 strunzone(grecordholder[i]);
1280                                         grecordholder[i] = strzone(grecordholder[i-1]);
1281                                 }
1282                         }
1283
1284                         // store new ranking
1285                         if(grecordholder[pos-1] != "")
1286                                 strunzone(grecordholder[pos-1]);
1287                         grecordholder[pos-1] = strzone(ReadString());
1288                         grecordtime[pos-1] = ReadInt24_t();
1289                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1290                                 race_myrank = pos;
1291                         break;
1292                 case RACE_NET_SERVER_STATUS:
1293                         race_status = ReadShort();
1294                         if(race_status_name)
1295                                 strunzone(race_status_name);
1296                         race_status_name = strzone(ReadString());
1297         }
1298 }
1299
1300 void Net_ReadSpawn()
1301 {
1302         zoomin_effect = 1;
1303         current_viewzoom = 0.6;
1304 }
1305
1306 void Net_TeamNagger()
1307 {
1308         teamnagger = 1;
1309 }
1310
1311 void Net_ReadPingPLReport()
1312 {
1313         float e, pi, pl, ml;
1314         e = ReadByte();
1315         pi = ReadShort();
1316         pl = ReadByte();
1317         ml = ReadByte();
1318         if not(playerslots[e])
1319                 return;
1320         playerslots[e].ping = pi;
1321         playerslots[e].ping_packetloss = pl / 255.0;
1322         playerslots[e].ping_movementloss = ml / 255.0;
1323 }
1324
1325 void Net_WeaponComplain() {
1326         complain_weapon = ReadByte();
1327
1328         if(complain_weapon_name)
1329                 strunzone(complain_weapon_name);
1330         complain_weapon_name = strzone(ReadString());
1331
1332         complain_weapon_type = ReadByte();
1333
1334         complain_weapon_time = time;
1335         weapontime = time; // ping the weapon panel
1336 }
1337
1338 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1339 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1340 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1341 float CSQC_Parse_TempEntity()
1342 {
1343         float bHandled;
1344                 bHandled  = true;
1345         // Acquire TE ID
1346         float nTEID;
1347                 nTEID = ReadByte();
1348
1349                 // NOTE: Could just do return instead of break...
1350         switch(nTEID)
1351         {
1352                 case TE_CSQC_TARGET_MUSIC:
1353                         Net_TargetMusic();
1354                         bHandled = true;
1355                         break;
1356                 case TE_CSQC_PICTURE:
1357                         Net_MapVote_Picture();
1358                         bHandled = true;
1359                         break;
1360                 case TE_CSQC_RACE:
1361                         Net_ReadRace();
1362                         bHandled = true;
1363                         break;
1364                 case TE_CSQC_SPAWN:
1365                         Net_ReadSpawn();
1366                         bHandled = true;
1367                         break;
1368                 case TE_CSQC_ZCURVEPARTICLES:
1369                         Net_ReadZCurveParticles();
1370                         bHandled = true;
1371                         break;
1372                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1373                         Net_ReadNexgunBeamParticle();
1374                         bHandled = true;
1375                         break;
1376                 case TE_CSQC_TEAMNAGGER:
1377                         Net_TeamNagger();
1378                         bHandled = true;
1379                         break;
1380                 case TE_CSQC_LIGHTNINGARC:
1381                         Net_ReadLightningarc();
1382                         bHandled = true;
1383                         break;
1384                 case TE_CSQC_PINGPLREPORT:
1385                         Net_ReadPingPLReport();
1386                         bHandled = true;
1387                         break;
1388                 case TE_CSQC_ANNOUNCE:
1389                         Announcer_Play(ReadString());
1390                         bHandled = true;
1391                         break;
1392                 case TE_CSQC_KILLNOTIFY:
1393                         HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1394                         bHandled = true;
1395                         break;
1396                 case TE_CSQC_KILLCENTERPRINT:
1397                         HUD_KillCenterprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1398                         bHandled = true;
1399                         break;
1400                 case TE_CSQC_CENTERPRINT_GENERIC:
1401                         float id;
1402                         string s;
1403                         id = ReadByte();
1404                         s = ReadString();
1405                         if (id != 0 && s != "")
1406                                 centerprint_generic(id, s, ReadByte(), ReadByte());
1407                         else
1408                                 centerprint_generic(id, s, 0, 0);
1409                         bHandled = true;
1410                         break;
1411                 case TE_CSQC_WEAPONCOMPLAIN:
1412                         Net_WeaponComplain();
1413                         bHandled = true;
1414                         break;
1415                 case TE_CSQC_VEHICLESETUP:
1416                         Net_VehicleSetup();
1417                         bHandled = true;
1418                         break;
1419                 default:
1420                         // No special logic for this temporary entity; return 0 so the engine can handle it
1421                         bHandled = false;
1422                         break;
1423         }
1424
1425         return bHandled;
1426 }
1427
1428 string getcommandkey(string text, string command)
1429 {
1430         string keys;
1431         float n, j, k, l;
1432
1433         if (!autocvar_hud_showbinds)
1434                 return text;
1435
1436         keys = db_get(binddb, command);
1437         if (!keys)
1438         {
1439                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1440                 for(j = 0; j < n; ++j)
1441                 {
1442                         k = stof(argv(j));
1443                         if(k != -1)
1444                         {
1445                                 if ("" == keys)
1446                                         keys = keynumtostring(k);
1447                                 else
1448                                         keys = strcat(keys, ", ", keynumtostring(k));
1449
1450                                 ++l;
1451                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1452                         }
1453
1454                 }
1455                 db_put(binddb, command, keys);
1456         }
1457
1458         if ("" == keys) {
1459                 if (autocvar_hud_showbinds > 1)
1460                         return sprintf(_("%s (not bound)"), text);
1461                 else
1462                         return text;
1463         }
1464         else if (autocvar_hud_showbinds > 1)
1465                 return sprintf(_("%s (%s)"), text, keys);
1466         else
1467                 return keys;
1468 }