qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49 #ifdef USE_FTE
  50 #pragma target ID
  51         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  52         if(!__engine_check)
  53         {
  54                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");
  55                 localcmd("\ndisconnect\n");
  56                 return;
  57         }
  58 #pragma target FTE
  59 #endif
  60
  61         check_unacceptable_compiler_bugs();
  62
  63 #ifdef WATERMARK
  64         print("^4CSQC Build information: ", WATERMARK(), "\n");
  65 #endif
  66
  67         float i;
  68         CSQC_CheckEngine();
  69
  70         binddb = db_create();
  71         tempdb = db_create();
  72         ClientProgsDB = db_load("client.db");
  73         compressShortVector_init();
  74
  75         drawfont = 0;
  76         menu_visible = FALSE;
  77         menu_show = menu_show_error;
  78         menu_action = menu_sub_null;
  79
  80         for(i = 0; i < 255; ++i)
  81                 if(getplayerkey(i, "viewentity") == "")
  82                         break;
  83         maxclients = i;
  84
  85         //ctf_temp_1 = "";
  86         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  87         //registercmd("ctf_menu");
  88         registercmd("ons_map");
  89         registercmd("hud_configure");
  90         registercmd("hud_save");
  91         //registercmd("menu_action");
  92
  93         registercmd("+button3");
  94         registercmd("-button3");
  95         registercmd("+button4");
  96         registercmd("-button4");
  97         registercmd("+showscores");registercmd("-showscores");
  98         registercmd("+showaccuracy");registercmd("-showaccuracy");
  99
 100 #ifndef CAMERATEST
 101         if(isdemo())
 102         {
 103 #endif
 104                 registercmd("+forward");registercmd("-forward");
 105                 registercmd("+back");registercmd("-back");
 106                 registercmd("+moveup");registercmd("-moveup");
 107                 registercmd("+movedown");registercmd("-movedown");
 108                 registercmd("+moveright");registercmd("-moveright");
 109                 registercmd("+moveleft");registercmd("-moveleft");
 110                 registercmd("+roll_right");registercmd("-roll_right");
 111                 registercmd("+roll_left");registercmd("-roll_left");
 112 #ifndef CAMERATEST
 113         }
 114 #endif
 115         registercvar("hud_usecsqc", "1");
 116         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 117
 118         gametype = 0;
 119
 120         // hud_fields uses strunzone on the titles!
 121         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 122                 hud_title[i] = strzone("(null)");
 123
 124         postinit = false;
 125
 126         calledhooks = 0;
 127
 128         teams = Sort_Spawn();
 129         players = Sort_Spawn();
 130
 131         GetTeam(COLOR_SPECTATOR, true); // add specs first
 132
 133         RegisterWeapons();
 134
 135         WaypointSprite_Load();
 136
 137         // precaches
 138         Projectile_Precache();
 139         GibSplash_Precache();
 140         Casings_Precache();
 141         DamageInfo_Precache();
 142         if(cvar_string("cl_announcer") != cl_announcer_prev) {
 143                 Announcer_Precache();
 144                 if(cl_announcer_prev)
 145                         strunzone(cl_announcer_prev);
 146                 cl_announcer_prev = strzone(cvar_string("cl_announcer"));
 147         }
 148         Tuba_Precache();
 149
 150 #ifdef UID
 151         {
 152                 // find the user ID
 153                 string uid;
 154                 registercvar("_cl_userid", "", CVAR_SAVE);
 155                 uid = cvar_string("_cl_userid");
 156                 if(strlen(uid) < 16)
 157                 {
 158                         uid = "";
 159                         for(i = 0; i < 4; ++i)
 160                                 uid = strcat(uid, substring(ftos(floor(10000 + random() * 10000)), 1, -1));
 161                 }
 162                 cvar_set("_cl_userid", uid);
 163                 localcmd(strcat("\ncmd uid ", uid, "\n"));
 164         }
 165 #endif
 166
 167         get_mi_min_max_texcoords(1); // try the CLEVER way first
 168         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 169         shortmapname = mi_shortname;
 170
 171         if(precache_pic(minimapname) == "")
 172         {
 173                 // but maybe we have a non-clever minimap
 174                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 175                 if(precache_pic(minimapname) == "")
 176                         minimapname = ""; // FAIL
 177                 else
 178                         get_mi_min_max_texcoords(0); // load new texcoords
 179         }
 180
 181         mi_center = (mi_min + mi_max) * 0.5;
 182         mi_scale = mi_max - mi_min;
 183         minimapname = strzone(minimapname);
 184
 185         WarpZone_Init();
 186         hud_configure_prev = -1;
 187 }
 188
 189 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 190 void CSQC_Shutdown(void)
 191 {
 192 #ifdef USE_FTE
 193 #pragma TARGET id
 194         if(!__engine_check)
 195                 return 0;
 196 #pragma TARGET fte
 197 #endif
 198
 199         WarpZone_Shutdown();
 200
 201         remove(teams);
 202         remove(players);
 203         db_close(binddb);
 204         db_close(tempdb);
 205         db_save(ClientProgsDB, "client.db");
 206         db_close(ClientProgsDB);
 207
 208         cvar_clientsettemp_restore();
 209
 210         if(camera_active)
 211                 cvar_set("chase_active",ftos(chase_active_backup));
 212
 213         if not(isdemo())
 214         {
 215                 if not(calledhooks & HOOK_START)
 216                         localcmd("\n_cl_hook_gamestart nop\n");
 217                 if not(calledhooks & HOOK_END)
 218                         localcmd("\ncl_hook_gameend\n");
 219         }
 220 }
 221
 222 .float has_team;
 223 float SetTeam(entity o, float Team)
 224 {
 225         entity tm;
 226         if(teamplay)
 227         {
 228                 switch(Team)
 229                 {
 230                         case -1:
 231                         case COLOR_TEAM1:
 232                         case COLOR_TEAM2:
 233                         case COLOR_TEAM3:
 234                         case COLOR_TEAM4:
 235                                 break;
 236                         default:
 237                                 if(GetTeam(Team, false) == NULL)
 238                                 {
 239                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
 240                                         Team = COLOR_SPECTATOR;
 241                                 }
 242                                 break;
 243                 }
 244         }
 245         else
 246         {
 247                 switch(Team)
 248                 {
 249                         case -1:
 250                         case 0:
 251                                 break;
 252                         default:
 253                                 if(GetTeam(Team, false) == NULL)
 254                                 {
 255                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
 256                                         Team = COLOR_SPECTATOR;
 257                                 }
 258                                 break;
 259                 }
 260         }
 261         if(Team == -1) // leave
 262         {
 263                 if(o.has_team)
 264                 {
 265                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");
 266                         tm = GetTeam(o.team, false);
 267                         tm.team_size -= 1;
 268                         o.has_team = 0;
 269                         return TRUE;
 270                 }
 271         }
 272         else
 273         {
 274                 if not(o.has_team)
 275                 {
 276                         //print("(CONNECT) enter team ", ftos(o.team), "\n");
 277                         o.team = Team;
 278                         tm = GetTeam(Team, true);
 279                         tm.team_size += 1;
 280                         o.has_team = 1;
 281                         return TRUE;
 282                 }
 283                 else if(Team != o.team)
 284                 {
 285                         //print("(CHANGE) leave team ", ftos(o.team), "\n");
 286                         tm = GetTeam(o.team, false);
 287                         tm.team_size -= 1;
 288                         o.team = Team;
 289                         //print("(CHANGE) enter team ", ftos(o.team), "\n");
 290                         tm = GetTeam(Team, true);
 291                         tm.team_size += 1;
 292                         return TRUE;
 293                 }
 294         }
 295         return FALSE;
 296 }
 297
 298 void Playerchecker_Think()
 299 {
 300         float i;
 301         entity e;
 302         for(i = 0; i < maxclients; ++i)
 303         {
 304                 e = playerslots[i];
 305                 if(GetPlayerName(i) == "")
 306                 {
 307                         if(e.sort_prev)
 308                         {
 309                                 //print("playerchecker: KILL KILL KILL\n");
 310                                 // player disconnected
 311                                 SetTeam(e, -1);
 312                                 RemovePlayer(e);
 313                                 e.sort_prev = world;
 314                                 //e.gotscores = 0;
 315                         }
 316                 }
 317                 else
 318                 {
 319                         if not(e.sort_prev)
 320                         {
 321                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");
 322                                 // player connected
 323                                 if not(e)
 324                                         playerslots[i] = e = spawn();
 325                                 e.sv_entnum = i;
 326                                 e.ping = 0;
 327                                 e.ping_packetloss = 0;
 328                                 e.ping_movementloss = 0;
 329                                 //e.gotscores = 0; // we might already have the scores...
 330                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 331                                 RegisterPlayer(e);
 332                                 HUD_UpdatePlayerPos(e);
 333                         }
 334                 }
 335         }
 336         self.nextthink = time + 0.2;
 337 }
 338
 339 void Porto_Init();
 340 void TrueAim_Init();
 341 void PostInit(void)
 342 {
 343         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));
 344         localcmd(strcat("\nscoreboard_columns_set ", cvar_string("scoreboard_columns"), ";\n"));
 345
 346         entity playerchecker;
 347         playerchecker = spawn();
 348         playerchecker.think = Playerchecker_Think;
 349         playerchecker.nextthink = time + 0.2;
 350
 351         Porto_Init();
 352         TrueAim_Init();
 353
 354         postinit = true;
 355 }
 356
 357 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 358 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 359 float button_zoom;
 360 void Cmd_HUD_SetFields(float);
 361 void Cmd_HUD_Help(float);
 362 float CSQC_ConsoleCommand(string strMessage)
 363 {
 364         float argc;
 365         // Tokenize String
 366         //argc = tokenize(strMessage);
 367         argc = tokenize_console(strMessage);
 368
 369         // Acquire Command
 370         local string strCmd;
 371         strCmd = argv(0);
 372
 373         if(strCmd == "hud_configure") { // config hud
 374                 cvar_set("_hud_configure", ftos(!cvar("_hud_configure")));
 375                 return true;
 376         } else if(strCmd == "hud_save") { // save hud config
 377                 if(argv(1) == "" || argv(2)) {
 378                         print("Usage:\n");
 379                         print("hud_save configname   (saves to hud_skinname_configname.cfg)\n");
 380                 }
 381                 else
 382                         HUD_Panel_ExportCfg(argv(1));
 383                 return true;
 384         } else if(strCmd == "+button4") { // zoom
 385                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
 386                 if(ignore_plus_zoom)
 387                 {
 388                         --ignore_plus_zoom;
 389                         return false;
 390                 }
 391                 button_zoom = 1;
 392                 return true;
 393         } else if(strCmd == "-button4") { // zoom
 394                 if(ignore_minus_zoom)
 395                 {
 396                         --ignore_minus_zoom;
 397                         return false;
 398                 }
 399                 button_zoom = 0;
 400                 return true;
 401         } else if(strCmd == "+button3") { // secondary
 402                 button_attack2 = 1;
 403                 return false;
 404         } else if(strCmd == "-button3") { // secondary
 405                 button_attack2 = 0;
 406                 return false;
 407         } else if(strCmd == "+showscores") {
 408                 scoreboard_showscores = true;
 409                 return true;
 410         } else if(strCmd == "-showscores") {
 411                 scoreboard_showscores = false;
 412                 return true;
 413         } else if(strCmd == "+showaccuracy") {
 414                 scoreboard_showaccuracy = true;
 415                 return true;
 416         } else if(strCmd == "-showaccuracy") {
 417                 scoreboard_showaccuracy = false;
 418                 return true;
 419         }
 420
 421         if(camera_active)
 422         if(strCmd == "+forward" || strCmd == "-back") {
 423                 ++camera_direction_x;
 424                 return true;
 425         } else if(strCmd == "-forward" || strCmd == "+back") {
 426                 --camera_direction_x;
 427                 return true;
 428         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 429                 --camera_direction_y;
 430                 return true;
 431         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 432                 ++camera_direction_y;
 433                 return true;
 434         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 435                 ++camera_direction_z;
 436                 return true;
 437         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 438                 --camera_direction_z;
 439                 return true;
 440         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 441                 ++camera_roll;
 442                 return true;
 443         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 444                 --camera_roll;
 445                 return true;
 446         }
 447
 448         return false;
 449 }
 450
 451 .vector view_ofs;
 452 entity debug_shotorg;
 453 void ShotOrg_Draw()
 454 {
 455         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 456         self.angles = view_angles;
 457         self.angles_x = -self.angles_x;
 458         if not(self.cnt)
 459                 R_AddEntity(self);
 460 }
 461 void ShotOrg_Draw2D()
 462 {
 463         vector coord2d_topleft, coord2d_topright, coord2d;
 464         string s;
 465         vector fs;
 466
 467         s = vtos(self.view_ofs);
 468         s = substring(s, 1, strlen(s) - 2);
 469         if(tokenize_console(s) == 3)
 470                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 471
 472         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 473         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 474
 475         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 476
 477         coord2d = coord2d_topleft;
 478         if(fs_x < 8)
 479         {
 480                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 481                 fs = '8 8 0';
 482         }
 483         coord2d_y -= fs_y;
 484         coord2d_z = 0;
 485         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 486 }
 487
 488 void ShotOrg_Spawn()
 489 {
 490         debug_shotorg = spawn();
 491         debug_shotorg.draw = ShotOrg_Draw;
 492         debug_shotorg.draw2d = ShotOrg_Draw2D;
 493         debug_shotorg.renderflags = RF_VIEWMODEL;
 494         debug_shotorg.effects = EF_FULLBRIGHT;
 495         precache_model("models/shotorg_adjuster.md3");
 496         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 497         debug_shotorg.scale = 2;
 498         debug_shotorg.view_ofs = '25 8 -8';
 499 }
 500
 501 void DrawDebugModel()
 502 {
 503         if(time - floor(time) > 0.5)
 504         {
 505                 PolyDrawModel(self);
 506         }
 507         else
 508         {
 509                 self.renderflags = 0;
 510                 R_AddEntity(self);
 511         }
 512 }
 513
 514 void GameCommand(string msg)
 515 {
 516         string s;
 517         float argc;
 518         entity e;
 519         argc = tokenize_console(msg);
 520
 521         if(argv(0) == "help" || argc == 0)
 522         {
 523                 print("Usage: cl_cmd COMMAND..., where possible commands are:\n");
 524                 print("  settemp cvar value\n");
 525                 print("  scoreboard_columns_set ...\n");
 526                 print("  scoreboard_columns_help\n");
 527                 GameCommand_Generic("help");
 528                 return;
 529         }
 530
 531         if(GameCommand_Generic(msg))
 532                 return;
 533
 534         string cmd;
 535         cmd = argv(0);
 536         if(cmd == "mv_download") {
 537                 Cmd_MapVote_MapDownload(argc);
 538         }
 539         else if(cmd == "settemp") {
 540                 cvar_clientsettemp(argv(1), argv(2));
 541         }
 542         else if(cmd == "scoreboard_columns_set") {
 543                 Cmd_HUD_SetFields(argc);
 544         }
 545         else if(cmd == "scoreboard_columns_help") {
 546                 Cmd_HUD_Help(argc);
 547         }
 548 #ifdef BLURTEST
 549         else if(cmd == "blurtest") {
 550                 blurtest_time0 = time;
 551                 blurtest_time1 = time + stof(argv(1));
 552                 blurtest_radius = stof(argv(2));
 553                 blurtest_power = stof(argv(3));
 554         }
 555 #endif
 556         else if(cmd == "shotorg_move") {
 557                 if(!debug_shotorg)
 558                         ShotOrg_Spawn();
 559                 else
 560                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 561                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 562         }
 563         else if(cmd == "shotorg_movez") {
 564                 if(!debug_shotorg)
 565                         ShotOrg_Spawn();
 566                 else
 567                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 568                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 569         }
 570         else if(cmd == "shotorg_set") {
 571                 if(!debug_shotorg)
 572                         ShotOrg_Spawn();
 573                 else
 574                         debug_shotorg.view_ofs = stov(argv(1));
 575                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 576         }
 577         else if(cmd == "shotorg_setz") {
 578                 if(!debug_shotorg)
 579                         ShotOrg_Spawn();
 580                 else
 581                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 582                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 583         }
 584         else if(cmd == "shotorg_toggle_hide") {
 585                 if(debug_shotorg)
 586                 {
 587                         debug_shotorg.cnt = !debug_shotorg.cnt;
 588                 }
 589         }
 590         else if(cmd == "shotorg_end") {
 591                 if(debug_shotorg)
 592                 {
 593                         print(vtos(debug_shotorg.view_ofs), "\n");
 594                         remove(debug_shotorg);
 595                         debug_shotorg = world;
 596                 }
 597                 localcmd("sv_cmd debug_shotorg\n");
 598         }
 599         else if(cmd == "sendcvar") {
 600                 // W_FixWeaponOrder will trash argv, so save what we need.
 601                 string thiscvar;
 602                 thiscvar = strzone(argv(1));
 603                 s = cvar_string(thiscvar);
 604                 if(thiscvar == "cl_weaponpriority")
 605                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 606                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 607                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 608                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 609                 strunzone(thiscvar);
 610         }
 611         else if(cmd == "spawn") {
 612                 s = argv(1);
 613                 e = spawn();
 614                 precache_model(s);
 615                 setmodel(e, s);
 616                 setorigin(e, view_origin);
 617                 e.angles = view_angles;
 618                 e.draw = DrawDebugModel;
 619                 e.classname = "debugmodel";
 620         }
 621         else
 622         {
 623                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 624         }
 625
 626         return;
 627 }
 628
 629 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 630 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 631 // All keys are in ascii.
 632 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 633 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 634 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 635 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 636 {
 637         local float bSkipKey;
 638         bSkipKey = false;
 639
 640         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 641                 return true;
 642
 643         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 644                 return true;
 645
 646         if(menu_visible)
 647                 if(menu_action(bInputType, nPrimary, nSecondary))
 648                         return TRUE;
 649         return bSkipKey;
 650 }
 651
 652 // END REQUIRED CSQC FUNCTIONS
 653 // --------------------------------------------------------------------------
 654
 655 // --------------------------------------------------------------------------
 656 // BEGIN OPTIONAL CSQC FUNCTIONS
 657 void Ent_ReadEntCS()
 658 {
 659         InterpolateOrigin_Undo();
 660
 661         self.classname = "entcs_receiver";
 662         self.sv_entnum = ReadByte() - 1;
 663         self.origin_x = ReadShort();
 664         self.origin_y = ReadShort();
 665         self.origin_z = ReadShort();
 666         self.angles_y = ReadByte() * 360.0 / 256;
 667         self.origin_z = self.angles_x = self.angles_z = 0;
 668
 669         InterpolateOrigin_Note();
 670 }
 671
 672 void Ent_Remove();
 673
 674 void Ent_RemovePlayerScore()
 675 {
 676         float i;
 677
 678         if(self.owner)
 679         {
 680                 SetTeam(self.owner, -1);
 681                 self.owner.gotscores = 0;
 682                 for(i = 0; i < MAX_SCORE; ++i)
 683                         self.owner.(scores[i]) = 0; // clear all scores
 684         }
 685 }
 686
 687 void Ent_ReadPlayerScore()
 688 {
 689         float i, n;
 690         float isNew;
 691         entity o;
 692
 693         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 694         // (no I've never heard of M-x replace-string, sed, or anything like that)
 695         isNew = !self.owner; // workaround for DP bug
 696         n = ReadByte()-1;
 697
 698 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 699         if(!isNew && n != self.sv_entnum)
 700         {
 701                 print("A CSQC entity changed its owner!\n");
 702                 isNew = true;
 703                 Ent_Remove();
 704                 self.enttype = ENT_CLIENT_SCORES;
 705         }
 706 #endif
 707
 708         self.sv_entnum = n;
 709
 710         if not(playerslots[self.sv_entnum])
 711                 playerslots[self.sv_entnum] = spawn();
 712         o = self.owner = playerslots[self.sv_entnum];
 713         o.sv_entnum = self.sv_entnum;
 714         o.gotscores = 1;
 715
 716         //if not(o.sort_prev)
 717         //      RegisterPlayer(o);
 718         //playerchecker will do this for us later, if it has not already done so
 719
 720         float sf, lf;
 721 #if MAX_SCORE <= 8
 722         sf = ReadByte();
 723         lf = ReadByte();
 724 #else
 725         sf = ReadShort();
 726         lf = ReadShort();
 727 #endif
 728         float p;
 729         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 730                 if(sf & p)
 731                 {
 732                         if(lf & p)
 733                                 o.(scores[i]) = ReadInt24_t();
 734                         else
 735                                 o.(scores[i]) = ReadChar();
 736                 }
 737
 738         if(o.sort_prev)
 739                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 740
 741         self.entremove = Ent_RemovePlayerScore;
 742 }
 743
 744 void Ent_ReadTeamScore()
 745 {
 746         float i;
 747         entity o;
 748
 749         self.team = ReadByte();
 750         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 751
 752         float sf, lf;
 753 #if MAX_TEAMSCORE <= 8
 754         sf = ReadByte();
 755         lf = ReadByte();
 756 #else
 757         sf = ReadShort();
 758         lf = ReadShort();
 759 #endif
 760         float p;
 761         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 762                 if(sf & p)
 763                 {
 764                         if(lf & p)
 765                                 o.(teamscores[i]) = ReadInt24_t();
 766                         else
 767                                 o.(teamscores[i]) = ReadChar();
 768                 }
 769
 770         HUD_UpdateTeamPos(o);
 771 }
 772
 773 void Net_Reset()
 774 {
 775 }
 776
 777 void Ent_ClientData()
 778 {
 779         float f;
 780         float newspectatee_status;
 781
 782         f = ReadByte();
 783
 784         scoreboard_showscores_force = (f & 1);
 785
 786         if(f & 2)
 787         {
 788                 newspectatee_status = ReadByte();
 789                 if(newspectatee_status == player_localentnum)
 790                         newspectatee_status = -1; // observing
 791         }
 792         else
 793                 newspectatee_status = 0;
 794
 795         spectatorbutton_zoom = (f & 4);
 796
 797         if(f & 8)
 798         {
 799                 angles_held_status = 1;
 800                 angles_held_x = ReadAngle();
 801                 angles_held_y = ReadAngle();
 802                 angles_held_z = 0;
 803         }
 804         else
 805                 angles_held_status = 0;
 806
 807         if(newspectatee_status != spectatee_status)
 808         {
 809                 float i;
 810                 // clear the weapon accuracy stats
 811                 for(i = WEP_FIRST; i <= WEP_LAST; ++i) {
 812                         weapon_hits[i] = 0;
 813                         weapon_fired[i] = 0;
 814                 }
 815
 816                 // clear race stuff
 817                 race_laptime = 0;
 818                 race_checkpointtime = 0;
 819         }
 820         spectatee_status = newspectatee_status;
 821 }
 822
 823 void Ent_Nagger()
 824 {
 825         float nags, i, j, b, f;
 826
 827         nags = ReadByte();
 828
 829         if(nags & 128)
 830         {
 831                 if(vote_called_vote)
 832                         strunzone(vote_called_vote);
 833                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 834         }
 835
 836         if(nags & 1)
 837         {
 838                 for(j = 0; j < maxclients; ++j)
 839                         if(playerslots[j])
 840                                 playerslots[j].ready = 1;
 841                 for(i = 1; i <= maxclients; i += 8)
 842                 {
 843                         f = ReadByte();
 844                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 845                                 if not(f & b)
 846                                         if(playerslots[j])
 847                                                 playerslots[j].ready = 0;
 848                 }
 849         }
 850
 851         ready_waiting = (nags & 1);
 852         ready_waiting_for_me = (nags & 2);
 853         vote_waiting = (nags & 4);
 854         vote_waiting_for_me = (nags & 8);
 855         warmup_stage = (nags & 16);
 856 }
 857
 858 void Ent_RandomSeed()
 859 {
 860         float s;
 861         prandom_debug();
 862         s = ReadShort();
 863         psrandom(s);
 864 }
 865
 866 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 867 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 868 void Ent_RadarLink();
 869 void Ent_Init();
 870 void Ent_ScoresInfo();
 871 void(float bIsNewEntity) CSQC_Ent_Update =
 872 {
 873         float t;
 874         float savetime;
 875         t = ReadByte();
 876
 877         // set up the "time" global for received entities to be correct for interpolation purposes
 878         savetime = time;
 879         if(servertime)
 880         {
 881                 time = servertime;
 882         }
 883         else
 884         {
 885                 serverprevtime = time;
 886                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 887                 time = serverprevtime + serverdeltatime;
 888         }
 889
 890 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 891         if(self.enttype)
 892                 if(t != self.enttype)
 893                 {
 894                         print("A CSQC entity changed its type!\n");
 895                         Ent_Remove();
 896                         bIsNewEntity = 1;
 897                 }
 898 #endif
 899         self.enttype = t;
 900         switch(t)
 901         {
 902                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 903                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 904                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 905                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 906                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 907                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 908                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 909                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 910                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 911                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 912                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 913                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 914                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 915                 case ENT_CLIENT_INIT: Ent_Init(); break;
 916                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 917                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 918                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 919                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 920                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 921                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 922                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 923                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 924                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 925                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 926                 default:
 927                         error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));
 928                         break;
 929         }
 930
 931         time = savetime;
 932 };
 933 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 934 // used when an entity changes its type. For an entity that someone interacts
 935 // with others, make sure it can no longer do so.
 936 void Ent_Remove()
 937 {
 938         if(self.entremove)
 939                 self.entremove();
 940
 941         self.enttype = 0;
 942         self.classname = "";
 943         self.draw = menu_sub_null;
 944         self.entremove = menu_sub_null;
 945         // TODO possibly set more stuff to defaults
 946 }
 947 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 948 void CSQC_Ent_Remove()
 949 {
 950         if(self.enttype)
 951                 Ent_Remove();
 952         remove(self);
 953 }
 954
 955 void Gamemode_Init()
 956 {
 957         if(gametype == GAME_ONSLAUGHT) {
 958                 print(strcat("Using ", minimapname, " as minimap.\n"));
 959                 precache_pic("gfx/ons-cp-neutral.tga");
 960                 precache_pic("gfx/ons-cp-red.tga");
 961                 precache_pic("gfx/ons-cp-blue.tga");
 962                 precache_pic("gfx/ons-frame.tga");
 963                 precache_pic("gfx/ons-frame-team.tga");
 964         }
 965
 966         if not(isdemo())
 967         {
 968                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
 969                 calledhooks |= HOOK_START;
 970         }
 971 }
 972 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 973 void CSQC_Parse_StuffCmd(string strMessage)
 974 {
 975         localcmd(strMessage);
 976 }
 977 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 978 void CSQC_Parse_Print(string strMessage)
 979 {
 980         print(ColorTranslateRGB(strMessage));
 981 }
 982
 983 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
 984 void CSQC_Parse_CenterPrint(string strMessage)
 985 {
 986         centerprint(strMessage);
 987 }
 988
 989 string notranslate_fogcmd1 = "\nfog ";
 990 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 991 void Fog_Force()
 992 {
 993         // TODO somehow thwart prvm_globalset client ...
 994
 995         if(forcefog != "")
 996                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 997 }
 998
 999 void Gamemode_Init();
1000 void Ent_ScoresInfo()
1001 {
1002         float i;
1003         self.classname = "ent_client_scores_info";
1004         gametype = ReadByte();
1005         for(i = 0; i < MAX_SCORE; ++i)
1006         {
1007                 scores_label[i] = strzone(ReadString());
1008                 scores_flags[i] = ReadByte();
1009         }
1010         for(i = 0; i < MAX_TEAMSCORE; ++i)
1011         {
1012                 teamscores_label[i] = strzone(ReadString());
1013                 teamscores_flags[i] = ReadByte();
1014         }
1015         HUD_InitScores();
1016         Gamemode_Init();
1017 }
1018
1019 void Ent_Init()
1020 {
1021         self.classname = "ent_client_init";
1022
1023         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1024
1025         hook_shotorigin_x = ReadCoord();
1026         hook_shotorigin_y = ReadCoord();
1027         hook_shotorigin_z = ReadCoord();
1028         electro_shotorigin_x = ReadCoord();
1029         electro_shotorigin_y = ReadCoord();
1030         electro_shotorigin_z = ReadCoord();
1031
1032         if(forcefog)
1033                 strunzone(forcefog);
1034         forcefog = strzone(ReadString());
1035
1036         armorblockpercent = ReadByte() / 255.0;
1037
1038         g_weaponswitchdelay = ReadByte() / 255.0;
1039
1040         g_balance_grenadelauncher_secondary_bouncefactor = ReadCoord();
1041         g_balance_grenadelauncher_secondary_bouncestop = ReadCoord();
1042
1043         if(!postinit)
1044                 PostInit();
1045 }
1046
1047 void Net_ReadRace()
1048 {
1049         float b;
1050
1051         b = ReadByte();
1052
1053         switch(b)
1054         {
1055                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1056                         race_checkpoint = ReadByte();
1057                         race_time = ReadInt24_t();
1058                         race_previousbesttime = ReadInt24_t();
1059                         if(race_previousbestname)
1060                                 strunzone(race_previousbestname);
1061                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1062
1063                         race_checkpointtime = time;
1064
1065                         if(race_checkpoint == 0 || race_checkpoint == 254)
1066                         {
1067                                 race_penaltyaccumulator = 0;
1068                                 race_laptime = time; // valid
1069                         }
1070
1071                         break;
1072
1073                 case RACE_NET_CHECKPOINT_CLEAR:
1074                         race_laptime = 0;
1075                         race_checkpointtime = 0;
1076                         break;
1077
1078                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1079                         race_laptime = ReadCoord();
1080                         race_checkpointtime = -99999;
1081                         // fall through
1082                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1083                         race_nextcheckpoint = ReadByte();
1084
1085                         race_nextbesttime = ReadInt24_t();
1086                         if(race_nextbestname)
1087                                 strunzone(race_nextbestname);
1088                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1089                         break;
1090
1091                 case RACE_NET_CHECKPOINT_HIT_RACE:
1092                         race_mycheckpoint = ReadByte();
1093                         race_mycheckpointtime = time;
1094                         race_mycheckpointdelta = ReadInt24_t();
1095                         race_mycheckpointlapsdelta = ReadByte();
1096                         if(race_mycheckpointlapsdelta >= 128)
1097                                 race_mycheckpointlapsdelta -= 256;
1098                         if(race_mycheckpointenemy)
1099                                 strunzone(race_mycheckpointenemy);
1100                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1101                         break;
1102
1103                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1104                         race_othercheckpoint = ReadByte();
1105                         race_othercheckpointtime = time;
1106                         race_othercheckpointdelta = ReadInt24_t();
1107                         race_othercheckpointlapsdelta = ReadByte();
1108                         if(race_othercheckpointlapsdelta >= 128)
1109                                 race_othercheckpointlapsdelta -= 256;
1110                         if(race_othercheckpointenemy)
1111                                 strunzone(race_othercheckpointenemy);
1112                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1113                         break;
1114
1115                 case RACE_NET_PENALTY_RACE:
1116                         race_penaltyeventtime = time;
1117                         race_penaltytime = ReadShort();
1118                         //race_penaltyaccumulator += race_penaltytime;
1119                         if(race_penaltyreason)
1120                                 strunzone(race_penaltyreason);
1121                         race_penaltyreason = strzone(ReadString());
1122                         break;
1123
1124                 case RACE_NET_PENALTY_QUALIFYING:
1125                         race_penaltyeventtime = time;
1126                         race_penaltytime = ReadShort();
1127                         race_penaltyaccumulator += race_penaltytime;
1128                         if(race_penaltyreason)
1129                                 strunzone(race_penaltyreason);
1130                         race_penaltyreason = strzone(ReadString());
1131                         break;
1132
1133                 case RACE_NET_SERVER_RECORD:
1134                         race_server_record = ReadInt24_t();
1135                         break;
1136                 case RACE_NET_SPEED_AWARD:
1137                         race_speedaward = ReadInt24_t();
1138                         if(race_speedaward_holder)
1139                                 strunzone(race_speedaward_holder);
1140                         race_speedaward_holder = strzone(ReadString());
1141                         break;
1142                 case RACE_NET_SPEED_AWARD_BEST:
1143                         race_speedaward_alltimebest = ReadInt24_t();
1144                         if(race_speedaward_alltimebest_holder)
1145                                 strunzone(race_speedaward_alltimebest_holder);
1146                         race_speedaward_alltimebest_holder = strzone(ReadString());
1147                         break;
1148                 case RACE_NET_SERVER_RANKINGS:
1149                         float pos, prevpos, del;
1150                         pos = ReadShort();
1151                         prevpos = ReadShort();
1152                         del = ReadShort();
1153
1154                         // move other rankings out of the way
1155                         float i;
1156                         if (prevpos) {
1157                                 for (i=prevpos-1;i>pos-1;--i) {
1158                                         grecordtime[i] = grecordtime[i-1];
1159                                         if(grecordholder[i])
1160                                                 strunzone(grecordholder[i]);
1161                                         grecordholder[i] = strzone(grecordholder[i-1]);
1162                                 }
1163                         } else if (del) { // a record has been deleted by the admin
1164                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1165                                         if (i == RANKINGS_CNT-1) { // clear out last record
1166                                                 grecordtime[i] = 0;
1167                                                 if (grecordholder[i])
1168                                                         strunzone(grecordholder[i]);
1169                                                 grecordholder[i] = string_null;
1170                                         }
1171                                         else {
1172                                                 grecordtime[i] = grecordtime[i+1];
1173                                                 if (grecordholder[i])
1174                                                         strunzone(grecordholder[i]);
1175                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1176                                         }
1177                                 }
1178                         } else { // player has no ranked record yet
1179                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1180                                         grecordtime[i] = grecordtime[i-1];
1181                                         if(grecordholder[i])
1182                                                 strunzone(grecordholder[i]);
1183                                         grecordholder[i] = strzone(grecordholder[i-1]);
1184                                 }
1185                         }
1186
1187                         // store new ranking
1188                         if(grecordholder[pos-1] != "")
1189                                 strunzone(grecordholder[pos-1]);
1190                         grecordholder[pos-1] = strzone(ReadString());
1191                         grecordtime[pos-1] = ReadInt24_t();
1192                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1193                                 race_myrank = pos;
1194                         break;
1195                 case RACE_NET_SERVER_STATUS:
1196                         race_status = ReadShort();
1197                         if(race_status_name)
1198                                 strunzone(race_status_name);
1199                         race_status_name = strzone(ReadString());
1200         }
1201 }
1202
1203 void Net_ReadSpawn()
1204 {
1205         zoomin_effect = 1;
1206         current_viewzoom = 0.6;
1207 }
1208
1209 void Net_TeamNagger()
1210 {
1211         teamnagger = 1;
1212 }
1213
1214 void Net_ReadPingPLReport()
1215 {
1216         float e, pi, pl, ml;
1217         e = ReadByte();
1218         pi = ReadShort();
1219         pl = ReadByte();
1220         ml = ReadByte();
1221         if not(playerslots[e])
1222                 return;
1223         playerslots[e].ping = pi;
1224         playerslots[e].ping_packetloss = pl / 255.0;
1225         playerslots[e].ping_movementloss = ml / 255.0;
1226 }
1227
1228 void Net_VoteDialog(float highlight) {
1229         if(highlight) {
1230                 vote_highlighted = ReadByte();
1231                 return;
1232         }
1233
1234         vote_yescount = ReadByte();
1235         vote_nocount = ReadByte();
1236         vote_needed = ReadByte();
1237         vote_active = 1;
1238 }
1239
1240 void Net_VoteDialogReset() {
1241         vote_active = 0;
1242 }
1243
1244 void Net_Notify() {
1245         float type;
1246         type = ReadByte();
1247
1248         if(type == CSQC_KILLNOTIFY)
1249         {
1250                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1251         }
1252         else if(type == CSQC_CENTERPRINT)
1253         {
1254                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1255         }
1256 }
1257
1258 void Net_WeaponComplain() {
1259         complain_weapon = ReadByte();
1260
1261         if(complain_weapon_name)
1262                 strunzone(complain_weapon_name);
1263         complain_weapon_name = strzone(ReadString());
1264
1265         complain_weapon_type = ReadByte();
1266
1267         complain_weapon_time = time;
1268 }
1269
1270 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1271 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1272 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1273 float CSQC_Parse_TempEntity()
1274 {
1275         local float bHandled;
1276                 bHandled  = true;
1277         // Acquire TE ID
1278         local float nTEID;
1279                 nTEID = ReadByte();
1280
1281                 // NOTE: Could just do return instead of break...
1282         switch(nTEID)
1283         {
1284                 case TE_CSQC_TARGET_MUSIC:
1285                         Net_TargetMusic();
1286                         bHandled = true;
1287                         break;
1288                 case TE_CSQC_PICTURE:
1289                         Net_MapVote_Picture();
1290                         bHandled = true;
1291                         break;
1292                 case TE_CSQC_RACE:
1293                         Net_ReadRace();
1294                         bHandled = true;
1295                         break;
1296                 case TE_CSQC_BEAM:
1297                         Net_GrapplingHook();
1298                         bHandled = true;
1299                         break;
1300                 case TE_CSQC_SPAWN:
1301                         Net_ReadSpawn();
1302                         bHandled = true;
1303                         break;
1304                 case TE_CSQC_ZCURVEPARTICLES:
1305                         Net_ReadZCurveParticles();
1306                         bHandled = true;
1307                         break;
1308                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1309                         Net_ReadNexgunBeamParticle();
1310                         bHandled = true;
1311                         break;
1312                 case TE_CSQC_TEAMNAGGER:
1313                         Net_TeamNagger();
1314                         bHandled = true;
1315                         break;
1316                 case TE_CSQC_VOTE:
1317                         Net_VoteDialog(ReadByte());
1318                         bHandled = true;
1319                         break;
1320                 case TE_CSQC_VOTERESET:
1321                         Net_VoteDialogReset();
1322                         bHandled = true;
1323                         break;
1324                 case TE_CSQC_LIGHTNINGARC:
1325                         Net_ReadLightningarc();
1326                         bHandled = true;
1327                         break;
1328                 case TE_CSQC_PINGPLREPORT:
1329                         Net_ReadPingPLReport();
1330                         bHandled = true;
1331                         break;
1332                 case TE_CSQC_ANNOUNCE:
1333                         announce_snd = strzone(ReadString());
1334                         bHandled = true;
1335                         break;
1336                 case TE_CSQC_NOTIFY:
1337                         Net_Notify();
1338                         bHandled = true;
1339                         break;
1340                 case TE_CSQC_WEAPONCOMPLAIN:
1341                         Net_WeaponComplain();
1342                         bHandled = true;
1343                         break;
1344                 default:
1345                         // No special logic for this temporary entity; return 0 so the engine can handle it
1346                         bHandled = false;
1347                         break;
1348         }
1349
1350         return bHandled;
1351 }
1352
1353 string getcommandkey(string text, string command)
1354 {
1355         string keys;
1356         float n, j, k, l;
1357
1358         if (!hud_showbinds)
1359                 return text;
1360
1361         keys = db_get(binddb, command);
1362         if (!keys)
1363         {
1364                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1365                 for(j = 0; j < n; ++j)
1366                 {
1367                         k = stof(argv(j));
1368                         if(k != -1)
1369                         {
1370                                 if ("" == keys)
1371                                         keys = keynumtostring(k);
1372                                 else
1373                                         keys = strcat(keys, ", ", keynumtostring(k));
1374
1375                                 ++l;
1376                                 if (hud_showbinds_limit > 0 && hud_showbinds_limit >= l) break;
1377                         }
1378
1379                 }
1380                 db_put(binddb, command, keys);
1381         }
1382
1383         if ("" == keys) {
1384                 if (hud_showbinds > 1)
1385                         return strcat(text, " (not bound)");
1386                 else
1387                         return text;
1388         }
1389         else if (hud_showbinds > 1)
1390                 return strcat(text, " (", keys, ")");
1391         else
1392                 return keys;
1393 }