Merge branch 'master' into Mario/showspecs
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / Main.qc
1 // --------------------------------------------------------------------------
2 // BEGIN REQUIRED CSQC FUNCTIONS
3 //include "main.qh"
4
5 entity clearentity_ent;
6 void clearentity(entity e)
7 {
8         if (!clearentity_ent)
9         {
10                 clearentity_ent = spawn();
11                 clearentity_ent.classname = "clearentity";
12         }
13         float n = e.entnum;
14         copyentity(clearentity_ent, e);
15         e.entnum = n;
16 }
17
18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
19 void menu_show_error()
20 {
21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
22 }
23
24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
25 // Useful for precaching things
26
27 void menu_sub_null()
28 {
29 }
30
31 #ifdef USE_FTE
32 float __engine_check;
33 #endif
34
35 string forcefog;
36 void WaypointSprite_Load();
37 void ConsoleCommand_macro_init();
38 void CSQC_Init(void)
39 {
40         prvm_language = cvar_string("prvm_language");
41 #ifdef USE_FTE
42 #pragma target ID
43         __engine_check = checkextension("DP_SV_WRITEPICTURE");
44         if(!__engine_check)
45         {
46                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
47                 localcmd("\ndisconnect\n");
48                 return;
49         }
50 #pragma target FTE
51 #endif
52
53         check_unacceptable_compiler_bugs();
54
55 #ifdef WATERMARK
56         printf(_("^4CSQC Build information: ^1%s\n"), WATERMARK);
57 #endif
58
59         float i;
60
61 #ifdef COMPAT_XON050_ENGINE
62         // old engine lacks implementation of player_localnum
63         player_localnum = player_localentnum - 1;
64 #endif
65
66         binddb = db_create();
67         tempdb = db_create();
68         ClientProgsDB = db_load("client.db");
69         compressShortVector_init();
70
71         draw_endBoldFont();
72         menu_visible = FALSE;
73         menu_show = menu_show_error;
74         menu_action = func_null;
75
76         for(i = 0; i < 255; ++i)
77                 if(getplayerkeyvalue(i, "viewentity") == "")
78                         break;
79         maxclients = i;
80
81         //registercommand("hud_configure");
82         //registercommand("hud_save");
83         //registercommand("menu_action");
84
85         ConsoleCommand_macro_init();
86
87         registercvar("hud_usecsqc", "1");
88         registercvar("scoreboard_columns", "default");
89
90         gametype = 0;
91
92         // hud_fields uses strunzone on the titles!
93         for(i = 0; i < MAX_HUD_FIELDS; ++i)
94                 hud_title[i] = strzone("(null)");
95
96         postinit = false;
97
98         calledhooks = 0;
99
100         teams = Sort_Spawn();
101         players = Sort_Spawn();
102
103         GetTeam(NUM_SPECTATOR, true); // add specs first
104
105         // needs to be done so early because of the constants they create
106         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
107         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
108         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
109         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
110         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
111         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
112
113         WaypointSprite_Load();
114
115         // precaches
116         precache_model("null");
117         precache_sound("misc/hit.wav");
118         precache_sound("misc/typehit.wav");
119
120         Projectile_Precache();
121         Hook_Precache();
122         GibSplash_Precache();
123         Casings_Precache();
124         DamageInfo_Precache();
125         Vehicles_Precache();
126         turrets_precache();
127         Tuba_Precache();
128         CSQCPlayer_Precache();
129
130         if(autocvar_cl_reticle)
131         {
132                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
133                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
134         }
135
136         get_mi_min_max_texcoords(1); // try the CLEVER way first
137         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
138         shortmapname = mi_shortname;
139
140         if(precache_pic(minimapname) == "")
141         {
142                 // but maybe we have a non-clever minimap
143                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
144                 if(precache_pic(minimapname) == "")
145                         minimapname = ""; // FAIL
146                 else
147                         get_mi_min_max_texcoords(0); // load new texcoords
148         }
149
150         mi_center = (mi_min + mi_max) * 0.5;
151         mi_scale = mi_max - mi_min;
152         minimapname = strzone(minimapname);
153
154         WarpZone_Init();
155
156         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
157         hud_configure_prev = -1;
158
159         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
160 }
161
162 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
163 void Shutdown(void)
164 {
165 #ifdef USE_FTE
166 #pragma TARGET id
167         if(!__engine_check)
168                 return 0;
169 #pragma TARGET fte
170 #endif
171
172         WarpZone_Shutdown();
173
174         remove(teams);
175         remove(players);
176         db_close(binddb);
177         db_close(tempdb);
178         if(autocvar_cl_db_saveasdump)
179                 db_dump(ClientProgsDB, "client.db");
180         else
181                 db_save(ClientProgsDB, "client.db");
182         db_close(ClientProgsDB);
183
184         if(camera_active)
185                 cvar_set("chase_active",ftos(chase_active_backup));
186
187         // unset the event chasecam's chase_active
188         if(autocvar_chase_active < 0)
189                 cvar_set("chase_active", "0");
190
191         if (!isdemo())
192         {
193                 if (!(calledhooks & HOOK_START))
194                         localcmd("\n_cl_hook_gamestart nop\n");
195                 if (!(calledhooks & HOOK_END))
196                         localcmd("\ncl_hook_gameend\n");
197         }
198 }
199
200 .float has_team;
201 float SetTeam(entity o, float Team)
202 {
203         entity tm;
204         if(teamplay)
205         {
206                 switch(Team)
207                 {
208                         case -1:
209                         case NUM_TEAM_1:
210                         case NUM_TEAM_2:
211                         case NUM_TEAM_3:
212                         case NUM_TEAM_4:
213                                 break;
214                         default:
215                                 if(GetTeam(Team, false) == world)
216                                 {
217                                         printf(_("trying to switch to unsupported team %d\n"), Team);
218                                         Team = NUM_SPECTATOR;
219                                 }
220                                 break;
221                 }
222         }
223         else
224         {
225                 switch(Team)
226                 {
227                         case -1:
228                         case 0:
229                                 break;
230                         default:
231                                 if(GetTeam(Team, false) == world)
232                                 {
233                                         printf(_("trying to switch to unsupported team %d\n"), Team);
234                                         Team = NUM_SPECTATOR;
235                                 }
236                                 break;
237                 }
238         }
239         if(Team == -1) // leave
240         {
241                 if(o.has_team)
242                 {
243                         tm = GetTeam(o.team, false);
244                         tm.team_size -= 1;
245                         o.has_team = 0;
246                         return TRUE;
247                 }
248         }
249         else
250         {
251                 if (!o.has_team)
252                 {
253                         o.team = Team;
254                         tm = GetTeam(Team, true);
255                         tm.team_size += 1;
256                         o.has_team = 1;
257                         return TRUE;
258                 }
259                 else if(Team != o.team)
260                 {
261                         tm = GetTeam(o.team, false);
262                         tm.team_size -= 1;
263                         o.team = Team;
264                         tm = GetTeam(Team, true);
265                         tm.team_size += 1;
266                         return TRUE;
267                 }
268         }
269         return FALSE;
270 }
271
272 void Playerchecker_Think()
273 {
274         float i;
275         entity e;
276         for(i = 0; i < maxclients; ++i)
277         {
278                 e = playerslots[i];
279                 if(GetPlayerName(i) == "")
280                 {
281                         if(e.sort_prev)
282                         {
283                                 // player disconnected
284                                 SetTeam(e, -1);
285                                 RemovePlayer(e);
286                                 e.sort_prev = world;
287                                 //e.gotscores = 0;
288                         }
289                 }
290                 else
291                 {
292                         if (!e.sort_prev)
293                         {
294                                 // player connected
295                                 if (!e)
296                                         playerslots[i] = e = spawn();
297                                 e.sv_entnum = i;
298                                 e.ping = 0;
299                                 e.ping_packetloss = 0;
300                                 e.ping_movementloss = 0;
301                                 //e.gotscores = 0; // we might already have the scores...
302                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
303                                 RegisterPlayer(e);
304                                 HUD_UpdatePlayerPos(e);
305                         }
306                 }
307         }
308         self.nextthink = time + 0.2;
309 }
310
311 void Porto_Init();
312 void TrueAim_Init();
313 void PostInit(void)
314 {
315         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
316
317         entity playerchecker;
318         playerchecker = spawn();
319         playerchecker.think = Playerchecker_Think;
320         playerchecker.nextthink = time + 0.2;
321
322         Porto_Init();
323         TrueAim_Init();
324
325         postinit = true;
326 }
327
328 float button_zoom;
329
330 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
331 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
332 // All keys are in ascii.
333 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
334 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
335 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
336 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
337 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
338 {
339         float bSkipKey;
340         bSkipKey = false;
341
342         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
343                 return true;
344
345         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
346                 return true;
347
348         if(menu_visible && menu_action)
349                 if(menu_action(bInputType, nPrimary, nSecondary))
350                         return TRUE;
351
352         return bSkipKey;
353 }
354
355 // END REQUIRED CSQC FUNCTIONS
356 // --------------------------------------------------------------------------
357
358 // --------------------------------------------------------------------------
359 // BEGIN OPTIONAL CSQC FUNCTIONS
360 void Ent_RemoveEntCS()
361 {
362         entcs_receiver[self.sv_entnum] = world;
363 }
364 void Ent_ReadEntCS()
365 {
366         float sf;
367         InterpolateOrigin_Undo();
368
369         self.classname = "entcs_receiver";
370         sf = ReadByte();
371
372         if(sf & 1)
373                 self.sv_entnum = ReadByte();
374         if(sf & 2)
375         {
376                 self.origin_x = ReadShort();
377                 self.origin_y = ReadShort();
378                 self.origin_z = ReadShort();
379                 setorigin(self, self.origin);
380         }
381         if(sf & 4)
382         {
383                 self.angles_y = ReadByte() * 360.0 / 256;
384                 self.angles_x = self.angles_z = 0;
385         }
386         if(sf & 8)
387                 self.healthvalue = ReadByte() * 10;
388         if(sf & 16)
389                 self.armorvalue = ReadByte() * 10;
390
391         entcs_receiver[self.sv_entnum] = self;
392         self.entremove = Ent_RemoveEntCS;
393         self.iflags |= IFLAG_ORIGIN;
394
395         InterpolateOrigin_Note();
396 }
397
398 void Ent_Remove();
399
400 void Ent_RemovePlayerScore()
401 {
402         float i;
403
404         if(self.owner)
405         {
406                 SetTeam(self.owner, -1);
407                 self.owner.gotscores = 0;
408                 for(i = 0; i < MAX_SCORE; ++i)
409                         self.owner.(scores[i]) = 0; // clear all scores
410         }
411 }
412
413 void Ent_ReadPlayerScore()
414 {
415         float i, n;
416         float isNew;
417         entity o;
418
419         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
420         // (no I've never heard of M-x replace-string, sed, or anything like that)
421         isNew = !self.owner; // workaround for DP bug
422         n = ReadByte()-1;
423
424 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
425         if(!isNew && n != self.sv_entnum)
426         {
427                 //print("A CSQC entity changed its owner!\n");
428                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
429                 isNew = true;
430                 Ent_Remove();
431                 self.enttype = ENT_CLIENT_SCORES;
432         }
433 #endif
434
435         self.sv_entnum = n;
436
437         if (!(playerslots[self.sv_entnum]))
438                 playerslots[self.sv_entnum] = spawn();
439         o = self.owner = playerslots[self.sv_entnum];
440         o.sv_entnum = self.sv_entnum;
441         o.gotscores = 1;
442
443         //if (!o.sort_prev)
444         //      RegisterPlayer(o);
445         //playerchecker will do this for us later, if it has not already done so
446
447         float sf, lf;
448 #if MAX_SCORE <= 8
449         sf = ReadByte();
450         lf = ReadByte();
451 #else
452         sf = ReadShort();
453         lf = ReadShort();
454 #endif
455         float p;
456         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
457                 if(sf & p)
458                 {
459                         if(lf & p)
460                                 o.(scores[i]) = ReadInt24_t();
461                         else
462                                 o.(scores[i]) = ReadChar();
463                 }
464
465         if(o.sort_prev)
466                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
467
468         self.entremove = Ent_RemovePlayerScore;
469 }
470
471 void Ent_ReadTeamScore()
472 {
473         float i;
474         entity o;
475
476         self.team = ReadByte();
477         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
478
479         float sf, lf;
480 #if MAX_TEAMSCORE <= 8
481         sf = ReadByte();
482         lf = ReadByte();
483 #else
484         sf = ReadShort();
485         lf = ReadShort();
486 #endif
487         float p;
488         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
489                 if(sf & p)
490                 {
491                         if(lf & p)
492                                 o.(teamscores[i]) = ReadInt24_t();
493                         else
494                                 o.(teamscores[i]) = ReadChar();
495                 }
496
497         HUD_UpdateTeamPos(o);
498 }
499
500 void Ent_ClientData()
501 {
502         float f;
503         float newspectatee_status;
504
505         f = ReadByte();
506
507         scoreboard_showscores_force = (f & 1);
508
509         if(f & 2)
510         {
511                 newspectatee_status = ReadByte();
512                 if(newspectatee_status == player_localnum + 1)
513                         newspectatee_status = -1; // observing
514         }
515         else
516                 newspectatee_status = 0;
517
518         spectatorbutton_zoom = (f & 4);
519
520         if(f & 8)
521         {
522                 angles_held_status = 1;
523                 angles_held_x = ReadAngle();
524                 angles_held_y = ReadAngle();
525                 angles_held_z = 0;
526         }
527         else
528                 angles_held_status = 0;
529
530         if(newspectatee_status != spectatee_status)
531         {
532                 // clear race stuff
533                 race_laptime = 0;
534                 race_checkpointtime = 0;
535         }
536         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
537         {
538                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
539                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
540                 )
541                         prev_p_health = -1;
542                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
543                         prev_health = -1;
544         }
545         spectatee_status = newspectatee_status;
546
547         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
548 }
549
550 void Ent_Nagger()
551 {
552         float nags, i, j, b, f;
553
554         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
555
556         if(!(nags & 4))
557         {
558                 if(vote_called_vote)
559                         strunzone(vote_called_vote);
560                 vote_called_vote = string_null;
561                 vote_active = 0;
562         }
563         else
564         {
565                 vote_active = 1;
566         }
567
568         if(nags & 64)
569         {
570                 vote_yescount = ReadByte();
571                 vote_nocount = ReadByte();
572                 vote_needed = ReadByte();
573                 vote_highlighted = ReadChar();
574         }
575
576         if(nags & 128)
577         {
578                 if(vote_called_vote)
579                         strunzone(vote_called_vote);
580                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
581         }
582
583         if(nags & 1)
584         {
585                 for(j = 0; j < maxclients; ++j)
586                         if(playerslots[j])
587                                 playerslots[j].ready = 1;
588                 for(i = 1; i <= maxclients; i += 8)
589                 {
590                         f = ReadByte();
591                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
592                                 if (!(f & b))
593                                         if(playerslots[j])
594                                                 playerslots[j].ready = 0;
595                 }
596         }
597
598         ready_waiting = (nags & 1);
599         ready_waiting_for_me = (nags & 2);
600         vote_waiting = (nags & 4);
601         vote_waiting_for_me = (nags & 8);
602         warmup_stage = (nags & 16);
603 }
604
605 void Ent_RandomSeed()
606 {
607         float s;
608         prandom_debug();
609         s = ReadShort();
610         psrandom(s);
611 }
612
613 void Ent_ReadAccuracy(void)
614 {
615         float sf, f, w, b;
616         sf = ReadInt24_t();
617         if(sf == 0)
618         {
619                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
620                         weapon_accuracy[w] = -1;
621                 return;
622         }
623
624         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
625         {
626                 if(sf & f)
627                 {
628                         b = ReadByte();
629                         if(b == 0)
630                                 weapon_accuracy[w] = -1;
631                         else if(b == 255)
632                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
633                         else
634                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
635                 }
636                 if(f == 0x800000)
637                         f = 1;
638                 else
639                         f *= 2;
640         }
641 }
642
643 void Spawn_Draw(void)
644 {
645         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
646 }
647
648 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
649 {
650         float teamnum = (ReadByte() - 1);
651         vector spn_origin;
652         spn_origin_x = ReadShort();
653         spn_origin_y = ReadShort();
654         spn_origin_z = ReadShort();
655
656         if(is_new)
657         {
658                 self.origin = spn_origin;
659                 setsize(self, PL_MIN, PL_MAX);
660                 droptofloor();
661
662                 /*if(autocvar_cl_spawn_point_model) // needs a model first
663                 {
664                         self.mdl = "models/spawnpoint.md3";
665                         self.colormod = Team_ColorRGB(teamnum);
666                         precache_model(self.mdl);
667                         setmodel(self, self.mdl);
668                         self.drawmask = MASK_NORMAL;
669                         //self.movetype = MOVETYPE_NOCLIP;
670                         //self.draw = Spawn_Draw;
671                 }*/
672                 if(autocvar_cl_spawn_point_particles)
673                 {
674                         if((serverflags & SERVERFLAG_TEAMPLAY))
675                         {
676                                 switch(teamnum)
677                                 {
678                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
679                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
680                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
681                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
682                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
683                                 }
684                         }
685                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
686
687                         self.draw = Spawn_Draw;
688                 }
689         }
690
691         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
692 }
693
694 void Ent_ReadSpawnEvent(float is_new)
695 {
696         // If entnum is 0, ONLY do the local spawn actions
697         // this way the server can disable the sending of
698         // spawn origin or such to clients if wanted.
699         float entnum = ReadByte();
700
701         if(entnum)
702         {
703                 self.origin_x = ReadShort();
704                 self.origin_y = ReadShort();
705                 self.origin_z = ReadShort();
706
707                 if(is_new)
708                 {
709                         float teamnum = GetPlayerColor(entnum - 1);
710
711                         if(autocvar_cl_spawn_event_particles)
712                         {
713                                 switch(teamnum)
714                                 {
715                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
716                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
717                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
718                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
719                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
720                                 }
721                         }
722                         if(autocvar_cl_spawn_event_sound)
723                         {
724                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
725                         }
726                 }
727         }
728
729         // local spawn actions
730         if(is_new && (!entnum || (entnum == player_localentnum)))
731         {
732                 zoomin_effect = 1;
733                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
734
735                 if(autocvar_cl_unpress_zoom_on_spawn)
736                 {
737                         localcmd("-zoom\n");
738                         button_zoom = FALSE;
739                 }
740         }
741
742         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
743 }
744
745 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
746 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
747 void Ent_RadarLink();
748 void Ent_Init();
749 void Ent_ScoresInfo();
750 void CSQC_Ent_Update(float bIsNewEntity)
751 {
752         float t;
753         float savetime;
754         t = ReadByte();
755
756         if(autocvar_developer_csqcentities)
757                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
758
759         // set up the "time" global for received entities to be correct for interpolation purposes
760         savetime = time;
761         if(servertime)
762         {
763                 time = servertime;
764         }
765         else
766         {
767                 serverprevtime = time;
768                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
769                 time = serverprevtime + serverdeltatime;
770         }
771
772 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
773         if(self.enttype)
774         {
775                 if(t != self.enttype || bIsNewEntity)
776                 {
777                         //print("A CSQC entity changed its type!\n");
778                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
779                         Ent_Remove();
780                         clearentity(self);
781                         bIsNewEntity = 1;
782                 }
783         }
784         else
785         {
786                 if(!bIsNewEntity)
787                 {
788                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
789                         bIsNewEntity = 1;
790                 }
791         }
792 #endif
793         self.enttype = t;
794         switch(t)
795         {
796                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
797                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
798                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
799                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
800                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
801                 case ENT_CLIENT_LASER: Ent_Laser(); break;
802                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
803                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
804                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
805                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
806                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
807                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
808                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
809                 case ENT_CLIENT_INIT: Ent_Init(); break;
810                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
811                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
812                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
813                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
814                 case ENT_CLIENT_WALL: Ent_Wall(); break;
815                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
816                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
817                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
818                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
819                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
820                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
821                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
822                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
823                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
824                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
825                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
826                 case ENT_CLIENT_TURRET: ent_turret(); break;
827                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
828                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
829                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
830                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
831                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
832                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
833
834                 default:
835                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
836                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
837                         break;
838         }
839
840         time = savetime;
841 }
842 // Destructor, but does NOT deallocate the entity by calling remove(). Also
843 // used when an entity changes its type. For an entity that someone interacts
844 // with others, make sure it can no longer do so.
845 void Ent_Remove()
846 {
847         if(self.entremove)
848                 self.entremove();
849
850         if(self.skeletonindex)
851         {
852                 skel_delete(self.skeletonindex);
853                 self.skeletonindex = 0;
854         }
855
856         if(self.snd_looping > 0)
857         {
858                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
859                 self.snd_looping = 0;
860         }
861
862         self.enttype = 0;
863         self.classname = "";
864         self.draw = menu_sub_null;
865         self.entremove = menu_sub_null;
866         // TODO possibly set more stuff to defaults
867 }
868 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
869 void CSQC_Ent_Remove()
870 {
871         if(autocvar_developer_csqcentities)
872                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
873
874         if(wasfreed(self))
875         {
876                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
877                 return;
878         }
879         if(self.enttype)
880                 Ent_Remove();
881         remove(self);
882 }
883
884 void Gamemode_Init()
885 {
886         if (!isdemo())
887         {
888                 if(!(calledhooks & HOOK_START))
889                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
890                 calledhooks |= HOOK_START;
891         }
892 }
893 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
894 void CSQC_Parse_StuffCmd(string strMessage)
895 {
896         if(autocvar_developer_csqcentities)
897                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
898
899         localcmd(strMessage);
900 }
901 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
902 void CSQC_Parse_Print(string strMessage)
903 {
904         if(autocvar_developer_csqcentities)
905                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
906
907         print(ColorTranslateRGB(strMessage));
908 }
909
910 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
911 void CSQC_Parse_CenterPrint(string strMessage)
912 {
913         if(autocvar_developer_csqcentities)
914                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
915
916         centerprint_hud(strMessage);
917 }
918
919 string notranslate_fogcmd1 = "\nfog ";
920 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
921 void Fog_Force()
922 {
923         // TODO somehow thwart prvm_globalset client ...
924
925         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
926                 { localcmd("\nr_drawfog 0\n"); }
927         else if(forcefog != "")
928                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
929 }
930
931 void Gamemode_Init();
932 void Ent_ScoresInfo()
933 {
934         float i;
935         self.classname = "ent_client_scores_info";
936         gametype = ReadInt24_t();
937         for(i = 0; i < MAX_SCORE; ++i)
938         {
939                 scores_label[i] = strzone(ReadString());
940                 scores_flags[i] = ReadByte();
941         }
942         for(i = 0; i < MAX_TEAMSCORE; ++i)
943         {
944                 teamscores_label[i] = strzone(ReadString());
945                 teamscores_flags[i] = ReadByte();
946         }
947         HUD_InitScores();
948         Gamemode_Init();
949 }
950
951 void Ent_Init()
952 {
953         self.classname = "ent_client_init";
954
955         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
956
957         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
958         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
959         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
960         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
961         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
962         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
963         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
964         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
965         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
966         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
967         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
968         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
969
970         if(forcefog)
971                 strunzone(forcefog);
972         forcefog = strzone(ReadString());
973
974         armorblockpercent = ReadByte() / 255.0;
975
976         g_balance_grenadelauncher_bouncefactor = ReadCoord();
977         g_balance_grenadelauncher_bouncestop = ReadCoord();
978         g_balance_electro_secondary_bouncefactor = ReadCoord();
979         g_balance_electro_secondary_bouncestop = ReadCoord();
980
981         nex_scope = !ReadByte();
982         rifle_scope = !ReadByte();
983
984         serverflags = ReadByte();
985
986         minelayer_maxmines = ReadByte();
987
988         hagar_maxrockets = ReadByte();
989
990         g_trueaim_minrange = ReadCoord();
991         g_balance_porto_secondary = ReadByte();
992
993         if(!postinit)
994                 PostInit();
995 }
996
997 void Net_ReadRace()
998 {
999         float b;
1000
1001         b = ReadByte();
1002
1003         switch(b)
1004         {
1005                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1006                         race_checkpoint = ReadByte();
1007                         race_time = ReadInt24_t();
1008                         race_previousbesttime = ReadInt24_t();
1009                         if(race_previousbestname)
1010                                 strunzone(race_previousbestname);
1011                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1012
1013                         race_checkpointtime = time;
1014
1015                         if(race_checkpoint == 0 || race_checkpoint == 254)
1016                         {
1017                                 race_penaltyaccumulator = 0;
1018                                 race_laptime = time; // valid
1019                         }
1020
1021                         break;
1022
1023                 case RACE_NET_CHECKPOINT_CLEAR:
1024                         race_laptime = 0;
1025                         race_checkpointtime = 0;
1026                         break;
1027
1028                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1029                         race_laptime = ReadCoord();
1030                         race_checkpointtime = -99999;
1031                         // fall through
1032                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1033                         race_nextcheckpoint = ReadByte();
1034
1035                         race_nextbesttime = ReadInt24_t();
1036                         if(race_nextbestname)
1037                                 strunzone(race_nextbestname);
1038                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1039                         break;
1040
1041                 case RACE_NET_CHECKPOINT_HIT_RACE:
1042                         race_mycheckpoint = ReadByte();
1043                         race_mycheckpointtime = time;
1044                         race_mycheckpointdelta = ReadInt24_t();
1045                         race_mycheckpointlapsdelta = ReadByte();
1046                         if(race_mycheckpointlapsdelta >= 128)
1047                                 race_mycheckpointlapsdelta -= 256;
1048                         if(race_mycheckpointenemy)
1049                                 strunzone(race_mycheckpointenemy);
1050                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1051                         break;
1052
1053                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1054                         race_othercheckpoint = ReadByte();
1055                         race_othercheckpointtime = time;
1056                         race_othercheckpointdelta = ReadInt24_t();
1057                         race_othercheckpointlapsdelta = ReadByte();
1058                         if(race_othercheckpointlapsdelta >= 128)
1059                                 race_othercheckpointlapsdelta -= 256;
1060                         if(race_othercheckpointenemy)
1061                                 strunzone(race_othercheckpointenemy);
1062                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1063                         break;
1064
1065                 case RACE_NET_PENALTY_RACE:
1066                         race_penaltyeventtime = time;
1067                         race_penaltytime = ReadShort();
1068                         //race_penaltyaccumulator += race_penaltytime;
1069                         if(race_penaltyreason)
1070                                 strunzone(race_penaltyreason);
1071                         race_penaltyreason = strzone(ReadString());
1072                         break;
1073
1074                 case RACE_NET_PENALTY_QUALIFYING:
1075                         race_penaltyeventtime = time;
1076                         race_penaltytime = ReadShort();
1077                         race_penaltyaccumulator += race_penaltytime;
1078                         if(race_penaltyreason)
1079                                 strunzone(race_penaltyreason);
1080                         race_penaltyreason = strzone(ReadString());
1081                         break;
1082
1083                 case RACE_NET_SERVER_RECORD:
1084                         race_server_record = ReadInt24_t();
1085                         break;
1086                 case RACE_NET_SPEED_AWARD:
1087                         race_speedaward = ReadInt24_t();
1088                         if(race_speedaward_holder)
1089                                 strunzone(race_speedaward_holder);
1090                         race_speedaward_holder = strzone(ReadString());
1091                         break;
1092                 case RACE_NET_SPEED_AWARD_BEST:
1093                         race_speedaward_alltimebest = ReadInt24_t();
1094                         if(race_speedaward_alltimebest_holder)
1095                                 strunzone(race_speedaward_alltimebest_holder);
1096                         race_speedaward_alltimebest_holder = strzone(ReadString());
1097                         break;
1098                 case RACE_NET_SERVER_RANKINGS:
1099                         float pos, prevpos, del;
1100                         pos = ReadShort();
1101                         prevpos = ReadShort();
1102                         del = ReadShort();
1103
1104                         // move other rankings out of the way
1105                         float i;
1106                         if (prevpos) {
1107                                 for (i=prevpos-1;i>pos-1;--i) {
1108                                         grecordtime[i] = grecordtime[i-1];
1109                                         if(grecordholder[i])
1110                                                 strunzone(grecordholder[i]);
1111                                         grecordholder[i] = strzone(grecordholder[i-1]);
1112                                 }
1113                         } else if (del) { // a record has been deleted by the admin
1114                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1115                                         if (i == RANKINGS_CNT-1) { // clear out last record
1116                                                 grecordtime[i] = 0;
1117                                                 if (grecordholder[i])
1118                                                         strunzone(grecordholder[i]);
1119                                                 grecordholder[i] = string_null;
1120                                         }
1121                                         else {
1122                                                 grecordtime[i] = grecordtime[i+1];
1123                                                 if (grecordholder[i])
1124                                                         strunzone(grecordholder[i]);
1125                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1126                                         }
1127                                 }
1128                         } else { // player has no ranked record yet
1129                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1130                                         grecordtime[i] = grecordtime[i-1];
1131                                         if(grecordholder[i])
1132                                                 strunzone(grecordholder[i]);
1133                                         grecordholder[i] = strzone(grecordholder[i-1]);
1134                                 }
1135                         }
1136
1137                         // store new ranking
1138                         if(grecordholder[pos-1] != "")
1139                                 strunzone(grecordholder[pos-1]);
1140                         grecordholder[pos-1] = strzone(ReadString());
1141                         grecordtime[pos-1] = ReadInt24_t();
1142                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1143                                 race_myrank = pos;
1144                         break;
1145                 case RACE_NET_SERVER_STATUS:
1146                         race_status = ReadShort();
1147                         if(race_status_name)
1148                                 strunzone(race_status_name);
1149                         race_status_name = strzone(ReadString());
1150         }
1151 }
1152
1153 void Net_TeamNagger()
1154 {
1155         teamnagger = 1;
1156 }
1157
1158 void Net_ReadPingPLReport()
1159 {
1160         float e, pi, pl, ml;
1161         e = ReadByte();
1162         pi = ReadShort();
1163         pl = ReadByte();
1164         ml = ReadByte();
1165         if (!(playerslots[e]))
1166                 return;
1167         playerslots[e].ping = pi;
1168         playerslots[e].ping_packetloss = pl / 255.0;
1169         playerslots[e].ping_movementloss = ml / 255.0;
1170 }
1171
1172 void Net_WeaponComplain()
1173 {
1174         complain_weapon = ReadByte();
1175
1176         if(complain_weapon_name)
1177                 strunzone(complain_weapon_name);
1178         complain_weapon_name = strzone(ReadString());
1179
1180         complain_weapon_type = ReadByte();
1181
1182         complain_weapon_time = time;
1183         weapontime = time; // ping the weapon panel
1184
1185         switch(complain_weapon_type)
1186         {
1187                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1188                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1189                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1190         }
1191 }
1192
1193 void Net_ReadSpecInfo()
1194 {
1195         float i;
1196         
1197         num_spectators = ReadByte();
1198         for(i = 0; i < num_spectators; ++i)
1199         {
1200                 local float slot = ReadByte();
1201                 if(i < MAX_SPECTATORS)
1202                         spectatorlist[i] = slot - 1;
1203         }
1204 }
1205
1206 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1207 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1208 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1209 float CSQC_Parse_TempEntity()
1210 {
1211         float bHandled;
1212                 bHandled  = true;
1213         // Acquire TE ID
1214         float nTEID;
1215                 nTEID = ReadByte();
1216
1217         if(autocvar_developer_csqcentities)
1218                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1219
1220                 // NOTE: Could just do return instead of break...
1221         switch(nTEID)
1222         {
1223                 case TE_CSQC_TARGET_MUSIC:
1224                         Net_TargetMusic();
1225                         bHandled = true;
1226                         break;
1227                 case TE_CSQC_PICTURE:
1228                         Net_MapVote_Picture();
1229                         bHandled = true;
1230                         break;
1231                 case TE_CSQC_RACE:
1232                         Net_ReadRace();
1233                         bHandled = true;
1234                         break;
1235                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1236                         Net_ReadNexgunBeamParticle();
1237                         bHandled = true;
1238                         break;
1239                 case TE_CSQC_TEAMNAGGER:
1240                         Net_TeamNagger();
1241                         bHandled = true;
1242                         break;
1243                 case TE_CSQC_LIGHTNINGARC:
1244                         Net_ReadLightningarc();
1245                         bHandled = true;
1246                         break;
1247                 case TE_CSQC_PINGPLREPORT:
1248                         Net_ReadPingPLReport();
1249                         bHandled = true;
1250                         break;
1251                 case TE_CSQC_WEAPONCOMPLAIN:
1252                         Net_WeaponComplain();
1253                         bHandled = true;
1254                         break;
1255                 case TE_CSQC_VEHICLESETUP:
1256                         Net_VehicleSetup();
1257                         bHandled = true;
1258                         break;
1259                 case TE_CSQC_SVNOTICE:
1260                         cl_notice_read();
1261                         bHandled = true;
1262                         break;
1263                 case TE_CSQC_SPECINFO:
1264                         Net_ReadSpecInfo();
1265                         bHandled = true;
1266                         break;
1267                 default:
1268                         // No special logic for this temporary entity; return 0 so the engine can handle it
1269                         bHandled = false;
1270                         break;
1271         }
1272
1273         return bHandled;
1274 }
1275
1276 string getcommandkey(string text, string command)
1277 {
1278         string keys;
1279         float n, j, k, l = 0;
1280
1281         if (!autocvar_hud_showbinds)
1282                 return text;
1283
1284         keys = db_get(binddb, command);
1285         if (keys == "")
1286         {
1287                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1288                 for(j = 0; j < n; ++j)
1289                 {
1290                         k = stof(argv(j));
1291                         if(k != -1)
1292                         {
1293                                 if ("" == keys)
1294                                         keys = keynumtostring(k);
1295                                 else
1296                                         keys = strcat(keys, ", ", keynumtostring(k));
1297
1298                                 ++l;
1299                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1300                                         break;
1301                         }
1302
1303                 }
1304                 if (keys == "")
1305                         keys = "NO_KEY";
1306                 db_put(binddb, command, keys);
1307         }
1308
1309         if (keys == "NO_KEY") {
1310                 if (autocvar_hud_showbinds > 1)
1311                         return sprintf(_("%s (not bound)"), text);
1312                 else
1313                         return text;
1314         }
1315         else if (autocvar_hud_showbinds > 1)
1316                 return sprintf(_("%s (%s)"), text, keys);
1317         else
1318                 return keys;
1319 }