Merge branch 'terencehill/scoreboard_fixes'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / Main.qc
1 // --------------------------------------------------------------------------
2 // BEGIN REQUIRED CSQC FUNCTIONS
3 //include "main.qh"
4
5 entity clearentity_ent;
6 void clearentity(entity e)
7 {
8         if (!clearentity_ent)
9         {
10                 clearentity_ent = spawn();
11                 clearentity_ent.classname = "clearentity";
12         }
13         float n = e.entnum;
14         copyentity(clearentity_ent, e);
15         e.entnum = n;
16 }
17
18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
19 void menu_show_error()
20 {
21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
22 }
23
24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
25 // Useful for precaching things
26
27 void menu_sub_null()
28 {
29 }
30
31 #ifdef USE_FTE
32 float __engine_check;
33 #endif
34
35 string forcefog;
36 void WaypointSprite_Load();
37 void ConsoleCommand_macro_init();
38 void CSQC_Init(void)
39 {
40         prvm_language = cvar_string("prvm_language");
41 #ifdef USE_FTE
42 #pragma target ID
43         __engine_check = checkextension("DP_SV_WRITEPICTURE");
44         if(!__engine_check)
45         {
46                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
47                 localcmd("\ndisconnect\n");
48                 return;
49         }
50 #pragma target FTE
51 #endif
52
53         check_unacceptable_compiler_bugs();
54
55 #ifdef WATERMARK
56         printf(_("^4CSQC Build information: ^1%s\n"), WATERMARK);
57 #endif
58
59         float i;
60
61 #ifdef COMPAT_XON050_ENGINE
62         // old engine lacks implementation of player_localnum
63         player_localnum = player_localentnum - 1;
64 #endif
65
66         binddb = db_create();
67         tempdb = db_create();
68         ClientProgsDB = db_load("client.db");
69         compressShortVector_init();
70
71         draw_endBoldFont();
72         menu_visible = FALSE;
73         menu_show = menu_show_error;
74         menu_action = func_null;
75
76         for(i = 0; i < 255; ++i)
77                 if(getplayerkeyvalue(i, "viewentity") == "")
78                         break;
79         maxclients = i;
80
81         //registercommand("hud_configure");
82         //registercommand("hud_save");
83         //registercommand("menu_action");
84
85         ConsoleCommand_macro_init();
86
87         registercvar("hud_usecsqc", "1");
88         registercvar("scoreboard_columns", "default");
89
90         registercvar("cl_nade_type", "3");
91         registercvar("cl_pokenade_type", "zombie");
92
93         gametype = 0;
94
95         // hud_fields uses strunzone on the titles!
96         for(i = 0; i < MAX_HUD_FIELDS; ++i)
97                 hud_title[i] = strzone("(null)");
98
99         Cmd_HUD_SetFields(0);
100
101         postinit = false;
102
103         calledhooks = 0;
104
105         teams = Sort_Spawn();
106         players = Sort_Spawn();
107
108         GetTeam(NUM_SPECTATOR, true); // add specs first
109
110         // needs to be done so early because of the constants they create
111         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
112         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
113         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
114         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
115         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
116         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
117         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
118
119         WaypointSprite_Load();
120
121         // precaches
122         precache_model("null");
123         precache_sound("misc/hit.wav");
124         precache_sound("misc/typehit.wav");
125
126         Projectile_Precache();
127         Hook_Precache();
128         GibSplash_Precache();
129         Casings_Precache();
130         DamageInfo_Precache();
131         Vehicles_Precache();
132         turrets_precache();
133         Tuba_Precache();
134         CSQCPlayer_Precache();
135
136         if(autocvar_cl_reticle)
137         {
138                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
139                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
140         }
141
142         get_mi_min_max_texcoords(1); // try the CLEVER way first
143         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
144         shortmapname = mi_shortname;
145
146         if(precache_pic(minimapname) == "")
147         {
148                 // but maybe we have a non-clever minimap
149                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
150                 if(precache_pic(minimapname) == "")
151                         minimapname = ""; // FAIL
152                 else
153                         get_mi_min_max_texcoords(0); // load new texcoords
154         }
155
156         mi_center = (mi_min + mi_max) * 0.5;
157         mi_scale = mi_max - mi_min;
158         minimapname = strzone(minimapname);
159
160         WarpZone_Init();
161
162         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
163         hud_configure_prev = -1;
164
165         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
166 }
167
168 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
169 void Shutdown(void)
170 {
171 #ifdef USE_FTE
172 #pragma TARGET id
173         if(!__engine_check)
174                 return 0;
175 #pragma TARGET fte
176 #endif
177
178         WarpZone_Shutdown();
179
180         remove(teams);
181         remove(players);
182         db_close(binddb);
183         db_close(tempdb);
184         if(autocvar_cl_db_saveasdump)
185                 db_dump(ClientProgsDB, "client.db");
186         else
187                 db_save(ClientProgsDB, "client.db");
188         db_close(ClientProgsDB);
189
190         if(camera_active)
191                 cvar_set("chase_active",ftos(chase_active_backup));
192
193         // unset the event chasecam's chase_active
194         if(autocvar_chase_active < 0)
195                 cvar_set("chase_active", "0");
196
197         if (!isdemo())
198         {
199                 if (!(calledhooks & HOOK_START))
200                         localcmd("\n_cl_hook_gamestart nop\n");
201                 if (!(calledhooks & HOOK_END))
202                         localcmd("\ncl_hook_gameend\n");
203         }
204 }
205
206 .float has_team;
207 float SetTeam(entity o, float Team)
208 {
209         entity tm;
210         if(teamplay)
211         {
212                 switch(Team)
213                 {
214                         case -1:
215                         case NUM_TEAM_1:
216                         case NUM_TEAM_2:
217                         case NUM_TEAM_3:
218                         case NUM_TEAM_4:
219                                 break;
220                         default:
221                                 if(GetTeam(Team, false) == world)
222                                 {
223                                         dprintf("trying to switch to unsupported team %d\n", Team);
224                                         Team = NUM_SPECTATOR;
225                                 }
226                                 break;
227                 }
228         }
229         else
230         {
231                 switch(Team)
232                 {
233                         case -1:
234                         case 0:
235                                 break;
236                         default:
237                                 if(GetTeam(Team, false) == world)
238                                 {
239                                         dprintf("trying to switch to unsupported team %d\n", Team);
240                                         Team = NUM_SPECTATOR;
241                                 }
242                                 break;
243                 }
244         }
245         if(Team == -1) // leave
246         {
247                 if(o.has_team)
248                 {
249                         tm = GetTeam(o.team, false);
250                         tm.team_size -= 1;
251                         o.has_team = 0;
252                         return TRUE;
253                 }
254         }
255         else
256         {
257                 if (!o.has_team)
258                 {
259                         o.team = Team;
260                         tm = GetTeam(Team, true);
261                         tm.team_size += 1;
262                         o.has_team = 1;
263                         return TRUE;
264                 }
265                 else if(Team != o.team)
266                 {
267                         tm = GetTeam(o.team, false);
268                         tm.team_size -= 1;
269                         o.team = Team;
270                         tm = GetTeam(Team, true);
271                         tm.team_size += 1;
272                         return TRUE;
273                 }
274         }
275         return FALSE;
276 }
277
278 void Playerchecker_Think()
279 {
280         float i;
281         entity e;
282         for(i = 0; i < maxclients; ++i)
283         {
284                 e = playerslots[i];
285                 if(GetPlayerName(i) == "")
286                 {
287                         if(e.sort_prev)
288                         {
289                                 // player disconnected
290                                 SetTeam(e, -1);
291                                 RemovePlayer(e);
292                                 e.sort_prev = world;
293                                 //e.gotscores = 0;
294                         }
295                 }
296                 else
297                 {
298                         if (!e.sort_prev)
299                         {
300                                 // player connected
301                                 if (!e)
302                                         playerslots[i] = e = spawn();
303                                 e.sv_entnum = i;
304                                 e.ping = 0;
305                                 e.ping_packetloss = 0;
306                                 e.ping_movementloss = 0;
307                                 //e.gotscores = 0; // we might already have the scores...
308                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
309                                 RegisterPlayer(e);
310                                 HUD_UpdatePlayerPos(e);
311                         }
312                 }
313         }
314         self.nextthink = time + 0.2;
315 }
316
317 void Porto_Init();
318 void TrueAim_Init();
319 void PostInit(void)
320 {
321         entity playerchecker;
322         playerchecker = spawn();
323         playerchecker.think = Playerchecker_Think;
324         playerchecker.nextthink = time + 0.2;
325
326         Porto_Init();
327         TrueAim_Init();
328
329         postinit = true;
330 }
331
332 float button_zoom;
333
334 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
335 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
336 // All keys are in ascii.
337 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
338 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
339 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
340 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
341 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
342 {
343         float bSkipKey;
344         bSkipKey = false;
345
346         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
347                 return true;
348
349         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
350                 return true;
351
352         if(menu_visible && menu_action)
353                 if(menu_action(bInputType, nPrimary, nSecondary))
354                         return TRUE;
355
356         return bSkipKey;
357 }
358
359 // END REQUIRED CSQC FUNCTIONS
360 // --------------------------------------------------------------------------
361
362 // --------------------------------------------------------------------------
363 // BEGIN OPTIONAL CSQC FUNCTIONS
364 void Ent_RemoveEntCS()
365 {
366         entcs_receiver[self.sv_entnum] = world;
367 }
368 void Ent_ReadEntCS()
369 {
370         float sf;
371         InterpolateOrigin_Undo();
372
373         self.classname = "entcs_receiver";
374         sf = ReadByte();
375
376         if(sf & 1)
377                 self.sv_entnum = ReadByte();
378         if(sf & 2)
379         {
380                 self.origin_x = ReadShort();
381                 self.origin_y = ReadShort();
382                 self.origin_z = ReadShort();
383                 setorigin(self, self.origin);
384         }
385         if(sf & 4)
386         {
387                 self.angles_y = ReadByte() * 360.0 / 256;
388                 self.angles_x = self.angles_z = 0;
389         }
390         if(sf & 8)
391                 self.healthvalue = ReadByte() * 10;
392         if(sf & 16)
393                 self.armorvalue = ReadByte() * 10;
394
395         entcs_receiver[self.sv_entnum] = self;
396         self.entremove = Ent_RemoveEntCS;
397         self.iflags |= IFLAG_ORIGIN;
398
399         InterpolateOrigin_Note();
400 }
401
402 void Ent_Remove();
403
404 void Ent_RemovePlayerScore()
405 {
406         float i;
407
408         if(self.owner)
409         {
410                 SetTeam(self.owner, -1);
411                 self.owner.gotscores = 0;
412                 for(i = 0; i < MAX_SCORE; ++i)
413                         self.owner.(scores[i]) = 0; // clear all scores
414         }
415 }
416
417 void Ent_ReadPlayerScore()
418 {
419         float i, n;
420         float isNew;
421         entity o;
422
423         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
424         // (no I've never heard of M-x replace-string, sed, or anything like that)
425         isNew = !self.owner; // workaround for DP bug
426         n = ReadByte()-1;
427
428 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
429         if(!isNew && n != self.sv_entnum)
430         {
431                 //print("A CSQC entity changed its owner!\n");
432                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
433                 isNew = true;
434                 Ent_Remove();
435                 self.enttype = ENT_CLIENT_SCORES;
436         }
437 #endif
438
439         self.sv_entnum = n;
440
441         if (!(playerslots[self.sv_entnum]))
442                 playerslots[self.sv_entnum] = spawn();
443         o = self.owner = playerslots[self.sv_entnum];
444         o.sv_entnum = self.sv_entnum;
445         o.gotscores = 1;
446
447         //if (!o.sort_prev)
448         //      RegisterPlayer(o);
449         //playerchecker will do this for us later, if it has not already done so
450
451         float sf, lf;
452 #if MAX_SCORE <= 8
453         sf = ReadByte();
454         lf = ReadByte();
455 #else
456         sf = ReadShort();
457         lf = ReadShort();
458 #endif
459         float p;
460         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
461                 if(sf & p)
462                 {
463                         if(lf & p)
464                                 o.(scores[i]) = ReadInt24_t();
465                         else
466                                 o.(scores[i]) = ReadChar();
467                 }
468
469         if(o.sort_prev)
470                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
471
472         self.entremove = Ent_RemovePlayerScore;
473 }
474
475 void Ent_ReadTeamScore()
476 {
477         float i;
478         entity o;
479
480         self.team = ReadByte();
481         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
482
483         float sf, lf;
484 #if MAX_TEAMSCORE <= 8
485         sf = ReadByte();
486         lf = ReadByte();
487 #else
488         sf = ReadShort();
489         lf = ReadShort();
490 #endif
491         float p;
492         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
493                 if(sf & p)
494                 {
495                         if(lf & p)
496                                 o.(teamscores[i]) = ReadInt24_t();
497                         else
498                                 o.(teamscores[i]) = ReadChar();
499                 }
500
501         HUD_UpdateTeamPos(o);
502 }
503
504 void Ent_ClientData()
505 {
506         float f;
507         float newspectatee_status;
508
509         f = ReadByte();
510
511         scoreboard_showscores_force = (f & 1);
512
513         if(f & 2)
514         {
515                 newspectatee_status = ReadByte();
516                 if(newspectatee_status == player_localnum + 1)
517                         newspectatee_status = -1; // observing
518         }
519         else
520                 newspectatee_status = 0;
521
522         spectatorbutton_zoom = (f & 4);
523
524         if(f & 8)
525         {
526                 angles_held_status = 1;
527                 angles_held_x = ReadAngle();
528                 angles_held_y = ReadAngle();
529                 angles_held_z = 0;
530         }
531         else
532                 angles_held_status = 0;
533
534         if(newspectatee_status != spectatee_status)
535         {
536                 // clear race stuff
537                 race_laptime = 0;
538                 race_checkpointtime = 0;
539         }
540         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
541         {
542                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
543                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
544                 )
545                         prev_p_health = -1;
546                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
547                         prev_health = -1;
548         }
549         spectatee_status = newspectatee_status;
550
551         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
552 }
553
554 void Ent_Nagger()
555 {
556         float nags, i, j, b, f;
557
558         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
559
560         if(!(nags & 4))
561         {
562                 if(vote_called_vote)
563                         strunzone(vote_called_vote);
564                 vote_called_vote = string_null;
565                 vote_active = 0;
566         }
567         else
568         {
569                 vote_active = 1;
570         }
571
572         if(nags & 64)
573         {
574                 vote_yescount = ReadByte();
575                 vote_nocount = ReadByte();
576                 vote_needed = ReadByte();
577                 vote_highlighted = ReadChar();
578         }
579
580         if(nags & 128)
581         {
582                 if(vote_called_vote)
583                         strunzone(vote_called_vote);
584                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
585         }
586
587         if(nags & 1)
588         {
589                 for(j = 0; j < maxclients; ++j)
590                         if(playerslots[j])
591                                 playerslots[j].ready = 1;
592                 for(i = 1; i <= maxclients; i += 8)
593                 {
594                         f = ReadByte();
595                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
596                                 if (!(f & b))
597                                         if(playerslots[j])
598                                                 playerslots[j].ready = 0;
599                 }
600         }
601
602         ready_waiting = (nags & 1);
603         ready_waiting_for_me = (nags & 2);
604         vote_waiting = (nags & 4);
605         vote_waiting_for_me = (nags & 8);
606         warmup_stage = (nags & 16);
607 }
608
609 void Ent_RandomSeed()
610 {
611         float s;
612         prandom_debug();
613         s = ReadShort();
614         psrandom(s);
615 }
616
617 void Ent_ReadAccuracy(void)
618 {
619         float sf, f, w, b;
620         sf = ReadInt24_t();
621         if(sf == 0)
622         {
623                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
624                         weapon_accuracy[w] = -1;
625                 return;
626         }
627
628         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
629         {
630                 if(sf & f)
631                 {
632                         b = ReadByte();
633                         if(b == 0)
634                                 weapon_accuracy[w] = -1;
635                         else if(b == 255)
636                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
637                         else
638                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
639                 }
640                 if(f == 0x800000)
641                         f = 1;
642                 else
643                         f *= 2;
644         }
645 }
646
647 void Spawn_Draw(void)
648 {
649         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
650 }
651
652 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
653 {
654         float teamnum = (ReadByte() - 1);
655         vector spn_origin;
656         spn_origin_x = ReadShort();
657         spn_origin_y = ReadShort();
658         spn_origin_z = ReadShort();
659
660         if(is_new)
661         {
662                 self.origin = spn_origin;
663                 setsize(self, PL_MIN, PL_MAX);
664                 droptofloor();
665
666                 /*if(autocvar_cl_spawn_point_model) // needs a model first
667                 {
668                         self.mdl = "models/spawnpoint.md3";
669                         self.colormod = Team_ColorRGB(teamnum);
670                         precache_model(self.mdl);
671                         setmodel(self, self.mdl);
672                         self.drawmask = MASK_NORMAL;
673                         //self.movetype = MOVETYPE_NOCLIP;
674                         //self.draw = Spawn_Draw;
675                 }*/
676                 if(autocvar_cl_spawn_point_particles)
677                 {
678                         if((serverflags & SERVERFLAG_TEAMPLAY))
679                         {
680                                 switch(teamnum)
681                                 {
682                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
683                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
684                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
685                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
686                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
687                                 }
688                         }
689                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
690
691                         self.draw = Spawn_Draw;
692                 }
693         }
694
695         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
696 }
697
698 void Ent_ReadSpawnEvent(float is_new)
699 {
700         // If entnum is 0, ONLY do the local spawn actions
701         // this way the server can disable the sending of
702         // spawn origin or such to clients if wanted.
703         float entnum = ReadByte();
704
705         if(entnum)
706         {
707                 self.origin_x = ReadShort();
708                 self.origin_y = ReadShort();
709                 self.origin_z = ReadShort();
710
711                 if(is_new)
712                 {
713                         float teamnum = GetPlayerColor(entnum - 1);
714
715                         if(autocvar_cl_spawn_event_particles)
716                         {
717                                 switch(teamnum)
718                                 {
719                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
720                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
721                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
722                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
723                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
724                                 }
725                         }
726                         if(autocvar_cl_spawn_event_sound)
727                         {
728                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
729                         }
730                 }
731         }
732
733         // local spawn actions
734         if(is_new && (!entnum || (entnum == player_localentnum)))
735         {
736                 zoomin_effect = 1;
737                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
738
739                 if(autocvar_cl_unpress_zoom_on_spawn)
740                 {
741                         localcmd("-zoom\n");
742                         button_zoom = FALSE;
743                 }
744         }
745
746         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
747 }
748
749 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
750 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
751 void Ent_RadarLink();
752 void Ent_Init();
753 void Ent_ScoresInfo();
754 void CSQC_Ent_Update(float bIsNewEntity)
755 {
756         float t;
757         float savetime;
758         t = ReadByte();
759
760         if(autocvar_developer_csqcentities)
761                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
762
763         // set up the "time" global for received entities to be correct for interpolation purposes
764         savetime = time;
765         if(servertime)
766         {
767                 time = servertime;
768         }
769         else
770         {
771                 serverprevtime = time;
772                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
773                 time = serverprevtime + serverdeltatime;
774         }
775
776 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
777         if(self.enttype)
778         {
779                 if(t != self.enttype || bIsNewEntity)
780                 {
781                         //print("A CSQC entity changed its type!\n");
782                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
783                         Ent_Remove();
784                         clearentity(self);
785                         bIsNewEntity = 1;
786                 }
787         }
788         else
789         {
790                 if(!bIsNewEntity)
791                 {
792                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
793                         bIsNewEntity = 1;
794                 }
795         }
796 #endif
797         self.enttype = t;
798         switch(t)
799         {
800                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
801                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
802                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
803                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
804                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
805                 case ENT_CLIENT_LASER: Ent_Laser(); break;
806                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
807                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
808                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
809                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
810                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
811                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
812                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
813                 case ENT_CLIENT_INIT: Ent_Init(); break;
814                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
815                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
816                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
817                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
818                 case ENT_CLIENT_WALL: Ent_Wall(); break;
819                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
820                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
821                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
822                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
823                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
824                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
825                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
826                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
827                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
828                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
829                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
830                 case ENT_CLIENT_TURRET: ent_turret(); break;
831                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
832                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
833                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
834                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
835                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
836                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
837                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
838
839                 default:
840                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
841                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
842                         break;
843         }
844
845         time = savetime;
846 }
847 // Destructor, but does NOT deallocate the entity by calling remove(). Also
848 // used when an entity changes its type. For an entity that someone interacts
849 // with others, make sure it can no longer do so.
850 void Ent_Remove()
851 {
852         if(self.entremove)
853                 self.entremove();
854
855         if(self.skeletonindex)
856         {
857                 skel_delete(self.skeletonindex);
858                 self.skeletonindex = 0;
859         }
860
861         if(self.snd_looping > 0)
862         {
863                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
864                 self.snd_looping = 0;
865         }
866
867         self.enttype = 0;
868         self.classname = "";
869         self.draw = menu_sub_null;
870         self.entremove = menu_sub_null;
871         // TODO possibly set more stuff to defaults
872 }
873 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
874 void CSQC_Ent_Remove()
875 {
876         if(autocvar_developer_csqcentities)
877                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
878
879         if(wasfreed(self))
880         {
881                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
882                 return;
883         }
884         if(self.enttype)
885                 Ent_Remove();
886         remove(self);
887 }
888
889 void Gamemode_Init()
890 {
891         if (!isdemo())
892         {
893                 if(!(calledhooks & HOOK_START))
894                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
895                 calledhooks |= HOOK_START;
896         }
897 }
898 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
899 void CSQC_Parse_StuffCmd(string strMessage)
900 {
901         if(autocvar_developer_csqcentities)
902                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
903
904         localcmd(strMessage);
905 }
906 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
907 void CSQC_Parse_Print(string strMessage)
908 {
909         if(autocvar_developer_csqcentities)
910                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
911
912         print(ColorTranslateRGB(strMessage));
913 }
914
915 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
916 void CSQC_Parse_CenterPrint(string strMessage)
917 {
918         if(autocvar_developer_csqcentities)
919                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
920
921         centerprint_hud(strMessage);
922 }
923
924 string notranslate_fogcmd1 = "\nfog ";
925 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
926 void Fog_Force()
927 {
928         // TODO somehow thwart prvm_globalset client ...
929
930         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
931                 { localcmd("\nr_drawfog 0\n"); }
932         else if(forcefog != "")
933                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
934 }
935
936 void Gamemode_Init();
937 void Ent_ScoresInfo()
938 {
939         float i;
940         self.classname = "ent_client_scores_info";
941         gametype = ReadInt24_t();
942         HUD_ModIcons_SetFunc();
943         for(i = 0; i < MAX_SCORE; ++i)
944         {
945                 if(scores_label[i])
946                         strunzone(scores_label[i]);
947                 scores_label[i] = strzone(ReadString());
948                 scores_flags[i] = ReadByte();
949         }
950         for(i = 0; i < MAX_TEAMSCORE; ++i)
951         {
952                 if(teamscores_label[i])
953                         strunzone(teamscores_label[i]);
954                 teamscores_label[i] = strzone(ReadString());
955                 teamscores_flags[i] = ReadByte();
956         }
957         HUD_InitScores();
958         Gamemode_Init();
959 }
960
961 void Ent_Init()
962 {
963         self.classname = "ent_client_init";
964
965         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
966
967         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
968         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
969         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
970         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
971         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
972         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
973         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
974         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
975         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
976         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
977         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
978         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
979
980         if(forcefog)
981                 strunzone(forcefog);
982         forcefog = strzone(ReadString());
983
984         armorblockpercent = ReadByte() / 255.0;
985
986         g_balance_grenadelauncher_bouncefactor = ReadCoord();
987         g_balance_grenadelauncher_bouncestop = ReadCoord();
988         g_balance_electro_secondary_bouncefactor = ReadCoord();
989         g_balance_electro_secondary_bouncestop = ReadCoord();
990
991         nex_scope = !ReadByte();
992         rifle_scope = !ReadByte();
993
994         serverflags = ReadByte();
995
996         minelayer_maxmines = ReadByte();
997
998         hagar_maxrockets = ReadByte();
999
1000         g_trueaim_minrange = ReadCoord();
1001         g_balance_porto_secondary = ReadByte();
1002
1003         if(!postinit)
1004                 PostInit();
1005 }
1006
1007 void Net_ReadRace()
1008 {
1009         float b;
1010
1011         b = ReadByte();
1012
1013         switch(b)
1014         {
1015                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1016                         race_checkpoint = ReadByte();
1017                         race_time = ReadInt24_t();
1018                         race_previousbesttime = ReadInt24_t();
1019                         if(race_previousbestname)
1020                                 strunzone(race_previousbestname);
1021                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1022
1023                         race_checkpointtime = time;
1024
1025                         if(race_checkpoint == 0 || race_checkpoint == 254)
1026                         {
1027                                 race_penaltyaccumulator = 0;
1028                                 race_laptime = time; // valid
1029                         }
1030
1031                         break;
1032
1033                 case RACE_NET_CHECKPOINT_CLEAR:
1034                         race_laptime = 0;
1035                         race_checkpointtime = 0;
1036                         break;
1037
1038                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1039                         race_laptime = ReadCoord();
1040                         race_checkpointtime = -99999;
1041                         // fall through
1042                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1043                         race_nextcheckpoint = ReadByte();
1044
1045                         race_nextbesttime = ReadInt24_t();
1046                         if(race_nextbestname)
1047                                 strunzone(race_nextbestname);
1048                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1049                         break;
1050
1051                 case RACE_NET_CHECKPOINT_HIT_RACE:
1052                         race_mycheckpoint = ReadByte();
1053                         race_mycheckpointtime = time;
1054                         race_mycheckpointdelta = ReadInt24_t();
1055                         race_mycheckpointlapsdelta = ReadByte();
1056                         if(race_mycheckpointlapsdelta >= 128)
1057                                 race_mycheckpointlapsdelta -= 256;
1058                         if(race_mycheckpointenemy)
1059                                 strunzone(race_mycheckpointenemy);
1060                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1061                         break;
1062
1063                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1064                         race_othercheckpoint = ReadByte();
1065                         race_othercheckpointtime = time;
1066                         race_othercheckpointdelta = ReadInt24_t();
1067                         race_othercheckpointlapsdelta = ReadByte();
1068                         if(race_othercheckpointlapsdelta >= 128)
1069                                 race_othercheckpointlapsdelta -= 256;
1070                         if(race_othercheckpointenemy)
1071                                 strunzone(race_othercheckpointenemy);
1072                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1073                         break;
1074
1075                 case RACE_NET_PENALTY_RACE:
1076                         race_penaltyeventtime = time;
1077                         race_penaltytime = ReadShort();
1078                         //race_penaltyaccumulator += race_penaltytime;
1079                         if(race_penaltyreason)
1080                                 strunzone(race_penaltyreason);
1081                         race_penaltyreason = strzone(ReadString());
1082                         break;
1083
1084                 case RACE_NET_PENALTY_QUALIFYING:
1085                         race_penaltyeventtime = time;
1086                         race_penaltytime = ReadShort();
1087                         race_penaltyaccumulator += race_penaltytime;
1088                         if(race_penaltyreason)
1089                                 strunzone(race_penaltyreason);
1090                         race_penaltyreason = strzone(ReadString());
1091                         break;
1092
1093                 case RACE_NET_SERVER_RECORD:
1094                         race_server_record = ReadInt24_t();
1095                         break;
1096                 case RACE_NET_SPEED_AWARD:
1097                         race_speedaward = ReadInt24_t();
1098                         if(race_speedaward_holder)
1099                                 strunzone(race_speedaward_holder);
1100                         race_speedaward_holder = strzone(ReadString());
1101                         break;
1102                 case RACE_NET_SPEED_AWARD_BEST:
1103                         race_speedaward_alltimebest = ReadInt24_t();
1104                         if(race_speedaward_alltimebest_holder)
1105                                 strunzone(race_speedaward_alltimebest_holder);
1106                         race_speedaward_alltimebest_holder = strzone(ReadString());
1107                         break;
1108                 case RACE_NET_SERVER_RANKINGS:
1109                         float pos, prevpos, del;
1110                         pos = ReadShort();
1111                         prevpos = ReadShort();
1112                         del = ReadShort();
1113
1114                         // move other rankings out of the way
1115                         float i;
1116                         if (prevpos) {
1117                                 for (i=prevpos-1;i>pos-1;--i) {
1118                                         grecordtime[i] = grecordtime[i-1];
1119                                         if(grecordholder[i])
1120                                                 strunzone(grecordholder[i]);
1121                                         grecordholder[i] = strzone(grecordholder[i-1]);
1122                                 }
1123                         } else if (del) { // a record has been deleted by the admin
1124                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1125                                         if (i == RANKINGS_CNT-1) { // clear out last record
1126                                                 grecordtime[i] = 0;
1127                                                 if (grecordholder[i])
1128                                                         strunzone(grecordholder[i]);
1129                                                 grecordholder[i] = string_null;
1130                                         }
1131                                         else {
1132                                                 grecordtime[i] = grecordtime[i+1];
1133                                                 if (grecordholder[i])
1134                                                         strunzone(grecordholder[i]);
1135                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1136                                         }
1137                                 }
1138                         } else { // player has no ranked record yet
1139                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1140                                         grecordtime[i] = grecordtime[i-1];
1141                                         if(grecordholder[i])
1142                                                 strunzone(grecordholder[i]);
1143                                         grecordholder[i] = strzone(grecordholder[i-1]);
1144                                 }
1145                         }
1146
1147                         // store new ranking
1148                         if(grecordholder[pos-1] != "")
1149                                 strunzone(grecordholder[pos-1]);
1150                         grecordholder[pos-1] = strzone(ReadString());
1151                         grecordtime[pos-1] = ReadInt24_t();
1152                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1153                                 race_myrank = pos;
1154                         break;
1155                 case RACE_NET_SERVER_STATUS:
1156                         race_status = ReadShort();
1157                         if(race_status_name)
1158                                 strunzone(race_status_name);
1159                         race_status_name = strzone(ReadString());
1160         }
1161 }
1162
1163 void Net_TeamNagger()
1164 {
1165         teamnagger = 1;
1166 }
1167
1168 void Net_ReadPingPLReport()
1169 {
1170         float e, pi, pl, ml;
1171         e = ReadByte();
1172         pi = ReadShort();
1173         pl = ReadByte();
1174         ml = ReadByte();
1175         if (!(playerslots[e]))
1176                 return;
1177         playerslots[e].ping = pi;
1178         playerslots[e].ping_packetloss = pl / 255.0;
1179         playerslots[e].ping_movementloss = ml / 255.0;
1180 }
1181
1182 void Net_WeaponComplain()
1183 {
1184         complain_weapon = ReadByte();
1185
1186         if(complain_weapon_name)
1187                 strunzone(complain_weapon_name);
1188         complain_weapon_name = strzone(ReadString());
1189
1190         complain_weapon_type = ReadByte();
1191
1192         complain_weapon_time = time;
1193         weapontime = time; // ping the weapon panel
1194
1195         switch(complain_weapon_type)
1196         {
1197                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1198                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1199                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1200         }
1201 }
1202
1203 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1204 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1205 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1206 float CSQC_Parse_TempEntity()
1207 {
1208         float bHandled;
1209                 bHandled  = true;
1210         // Acquire TE ID
1211         float nTEID;
1212                 nTEID = ReadByte();
1213
1214         if(autocvar_developer_csqcentities)
1215                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1216
1217                 // NOTE: Could just do return instead of break...
1218         switch(nTEID)
1219         {
1220                 case TE_CSQC_TARGET_MUSIC:
1221                         Net_TargetMusic();
1222                         bHandled = true;
1223                         break;
1224                 case TE_CSQC_PICTURE:
1225                         Net_MapVote_Picture();
1226                         bHandled = true;
1227                         break;
1228                 case TE_CSQC_RACE:
1229                         Net_ReadRace();
1230                         bHandled = true;
1231                         break;
1232                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1233                         Net_ReadNexgunBeamParticle();
1234                         bHandled = true;
1235                         break;
1236                 case TE_CSQC_TEAMNAGGER:
1237                         Net_TeamNagger();
1238                         bHandled = true;
1239                         break;
1240                 case TE_CSQC_LIGHTNINGARC:
1241                         Net_ReadLightningarc();
1242                         bHandled = true;
1243                         break;
1244                 case TE_CSQC_PINGPLREPORT:
1245                         Net_ReadPingPLReport();
1246                         bHandled = true;
1247                         break;
1248                 case TE_CSQC_WEAPONCOMPLAIN:
1249                         Net_WeaponComplain();
1250                         bHandled = true;
1251                         break;
1252                 case TE_CSQC_VEHICLESETUP:
1253                         Net_VehicleSetup();
1254                         bHandled = true;
1255                         break;
1256                 case TE_CSQC_SVNOTICE:
1257                         cl_notice_read();
1258                         bHandled = true;
1259                         break;
1260                 default:
1261                         // No special logic for this temporary entity; return 0 so the engine can handle it
1262                         bHandled = false;
1263                         break;
1264         }
1265
1266         return bHandled;
1267 }
1268
1269 string getcommandkey(string text, string command)
1270 {
1271         string keys;
1272         float n, j, k, l = 0;
1273
1274         if (!autocvar_hud_showbinds)
1275                 return text;
1276
1277         keys = db_get(binddb, command);
1278         if (keys == "")
1279         {
1280                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1281                 for(j = 0; j < n; ++j)
1282                 {
1283                         k = stof(argv(j));
1284                         if(k != -1)
1285                         {
1286                                 if ("" == keys)
1287                                         keys = keynumtostring(k);
1288                                 else
1289                                         keys = strcat(keys, ", ", keynumtostring(k));
1290
1291                                 ++l;
1292                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1293                                         break;
1294                         }
1295
1296                 }
1297                 if (keys == "")
1298                         keys = "NO_KEY";
1299                 db_put(binddb, command, keys);
1300         }
1301
1302         if (keys == "NO_KEY") {
1303                 if (autocvar_hud_showbinds > 1)
1304                         return sprintf(_("%s (not bound)"), text);
1305                 else
1306                         return text;
1307         }
1308         else if (autocvar_hud_showbinds > 1)
1309                 return sprintf(_("%s (%s)"), text, keys);
1310         else
1311                 return keys;
1312 }