Merge branch 'master' into Mario/weapons
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / Main.qc
1 // --------------------------------------------------------------------------
2 // BEGIN REQUIRED CSQC FUNCTIONS
3 //include "main.qh"
4
5 entity clearentity_ent;
6 void clearentity(entity e)
7 {
8         if (!clearentity_ent)
9         {
10                 clearentity_ent = spawn();
11                 clearentity_ent.classname = "clearentity";
12         }
13         float n = e.entnum;
14         copyentity(clearentity_ent, e);
15         e.entnum = n;
16 }
17
18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
19 void menu_show_error()
20 {
21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
22 }
23
24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
25 // Useful for precaching things
26
27 void menu_sub_null()
28 {
29 }
30
31 #ifdef USE_FTE
32 float __engine_check;
33 #endif
34
35 string forcefog;
36 void WaypointSprite_Load();
37 void ConsoleCommand_macro_init();
38 void CSQC_Init(void)
39 {
40         prvm_language = cvar_string("prvm_language");
41 #ifdef USE_FTE
42 #pragma target ID
43         __engine_check = checkextension("DP_SV_WRITEPICTURE");
44         if(!__engine_check)
45         {
46                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
47                 localcmd("\ndisconnect\n");
48                 return;
49         }
50 #pragma target FTE
51 #endif
52
53         check_unacceptable_compiler_bugs();
54
55 #ifdef WATERMARK
56         printf(_("^4CSQC Build information: ^1%s\n"), WATERMARK);
57 #endif
58
59         float i;
60
61 #ifdef COMPAT_XON050_ENGINE
62         // old engine lacks implementation of player_localnum
63         player_localnum = player_localentnum - 1;
64 #endif
65
66         binddb = db_create();
67         tempdb = db_create();
68         ClientProgsDB = db_load("client.db");
69         compressShortVector_init();
70
71         draw_endBoldFont();
72         menu_visible = FALSE;
73         menu_show = menu_show_error;
74         menu_action = func_null;
75
76         for(i = 0; i < 255; ++i)
77                 if(getplayerkeyvalue(i, "viewentity") == "")
78                         break;
79         maxclients = i;
80
81         //registercommand("hud_configure");
82         //registercommand("hud_save");
83         //registercommand("menu_action");
84
85         ConsoleCommand_macro_init();
86
87         registercvar("hud_usecsqc", "1");
88         registercvar("scoreboard_columns", "default");
89
90         gametype = 0;
91
92         // hud_fields uses strunzone on the titles!
93         for(i = 0; i < MAX_HUD_FIELDS; ++i)
94                 hud_title[i] = strzone("(null)");
95
96         postinit = false;
97
98         calledhooks = 0;
99
100         teams = Sort_Spawn();
101         players = Sort_Spawn();
102
103         GetTeam(NUM_SPECTATOR, true); // add specs first
104
105         // needs to be done so early because of the constants they create
106         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
107         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
108         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
109         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
110         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
111         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
112
113         WaypointSprite_Load();
114
115         // precaches
116         precache_model("null");
117         precache_sound("misc/hit.wav");
118         precache_sound("misc/typehit.wav");
119
120         Projectile_Precache();
121         Hook_Precache();
122         GibSplash_Precache();
123         Casings_Precache();
124         Vehicles_Precache();
125         turrets_precache();
126         Tuba_Precache();
127         CSQCPlayer_Precache();
128
129         if(autocvar_cl_reticle)
130         {
131                 precache_pic("gfx/reticle_normal");
132                 // weapon reticles are precached in weapon files
133         }
134
135         get_mi_min_max_texcoords(1); // try the CLEVER way first
136         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
137         shortmapname = mi_shortname;
138
139         if(precache_pic(minimapname) == "")
140         {
141                 // but maybe we have a non-clever minimap
142                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
143                 if(precache_pic(minimapname) == "")
144                         minimapname = ""; // FAIL
145                 else
146                         get_mi_min_max_texcoords(0); // load new texcoords
147         }
148
149         mi_center = (mi_min + mi_max) * 0.5;
150         mi_scale = mi_max - mi_min;
151         minimapname = strzone(minimapname);
152
153         WarpZone_Init();
154
155         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
156         hud_configure_prev = -1;
157
158         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
159 }
160
161 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
162 void Shutdown(void)
163 {
164 #ifdef USE_FTE
165 #pragma TARGET id
166         if(!__engine_check)
167                 return 0;
168 #pragma TARGET fte
169 #endif
170
171         WarpZone_Shutdown();
172
173         remove(teams);
174         remove(players);
175         db_close(binddb);
176         db_close(tempdb);
177         if(autocvar_cl_db_saveasdump)
178                 db_dump(ClientProgsDB, "client.db");
179         else
180                 db_save(ClientProgsDB, "client.db");
181         db_close(ClientProgsDB);
182
183         if(camera_active)
184                 cvar_set("chase_active",ftos(chase_active_backup));
185
186         // unset the event chasecam's chase_active
187         if(autocvar_chase_active < 0)
188                 cvar_set("chase_active", "0");
189
190         if (!isdemo())
191         {
192                 if (!(calledhooks & HOOK_START))
193                         localcmd("\n_cl_hook_gamestart nop\n");
194                 if (!(calledhooks & HOOK_END))
195                         localcmd("\ncl_hook_gameend\n");
196         }
197 }
198
199 .float has_team;
200 float SetTeam(entity o, float Team)
201 {
202         entity tm;
203         if(teamplay)
204         {
205                 switch(Team)
206                 {
207                         case -1:
208                         case NUM_TEAM_1:
209                         case NUM_TEAM_2:
210                         case NUM_TEAM_3:
211                         case NUM_TEAM_4:
212                                 break;
213                         default:
214                                 if(GetTeam(Team, false) == world)
215                                 {
216                                         dprintf("trying to switch to unsupported team %d\n", Team);
217                                         Team = NUM_SPECTATOR;
218                                 }
219                                 break;
220                 }
221         }
222         else
223         {
224                 switch(Team)
225                 {
226                         case -1:
227                         case 0:
228                                 break;
229                         default:
230                                 if(GetTeam(Team, false) == world)
231                                 {
232                                         dprintf("trying to switch to unsupported team %d\n", Team);
233                                         Team = NUM_SPECTATOR;
234                                 }
235                                 break;
236                 }
237         }
238         if(Team == -1) // leave
239         {
240                 if(o.has_team)
241                 {
242                         tm = GetTeam(o.team, false);
243                         tm.team_size -= 1;
244                         o.has_team = 0;
245                         return TRUE;
246                 }
247         }
248         else
249         {
250                 if (!o.has_team)
251                 {
252                         o.team = Team;
253                         tm = GetTeam(Team, true);
254                         tm.team_size += 1;
255                         o.has_team = 1;
256                         return TRUE;
257                 }
258                 else if(Team != o.team)
259                 {
260                         tm = GetTeam(o.team, false);
261                         tm.team_size -= 1;
262                         o.team = Team;
263                         tm = GetTeam(Team, true);
264                         tm.team_size += 1;
265                         return TRUE;
266                 }
267         }
268         return FALSE;
269 }
270
271 void Playerchecker_Think()
272 {
273         float i;
274         entity e;
275         for(i = 0; i < maxclients; ++i)
276         {
277                 e = playerslots[i];
278                 if(GetPlayerName(i) == "")
279                 {
280                         if(e.sort_prev)
281                         {
282                                 // player disconnected
283                                 SetTeam(e, -1);
284                                 RemovePlayer(e);
285                                 e.sort_prev = world;
286                                 //e.gotscores = 0;
287                         }
288                 }
289                 else
290                 {
291                         if (!e.sort_prev)
292                         {
293                                 // player connected
294                                 if (!e)
295                                         playerslots[i] = e = spawn();
296                                 e.sv_entnum = i;
297                                 e.ping = 0;
298                                 e.ping_packetloss = 0;
299                                 e.ping_movementloss = 0;
300                                 //e.gotscores = 0; // we might already have the scores...
301                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
302                                 RegisterPlayer(e);
303                                 HUD_UpdatePlayerPos(e);
304                         }
305                 }
306         }
307         self.nextthink = time + 0.2;
308 }
309
310 void Porto_Init();
311 void TrueAim_Init();
312 void PostInit(void)
313 {
314         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
315
316         entity playerchecker;
317         playerchecker = spawn();
318         playerchecker.think = Playerchecker_Think;
319         playerchecker.nextthink = time + 0.2;
320
321         Porto_Init();
322         TrueAim_Init();
323
324         postinit = true;
325 }
326
327 float button_zoom;
328
329 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
330 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
331 // All keys are in ascii.
332 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
333 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
334 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
335 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
336 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
337 {
338         float bSkipKey;
339         bSkipKey = false;
340
341         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
342                 return true;
343
344         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
345                 return true;
346
347         if(menu_visible && menu_action)
348                 if(menu_action(bInputType, nPrimary, nSecondary))
349                         return TRUE;
350
351         return bSkipKey;
352 }
353
354 // END REQUIRED CSQC FUNCTIONS
355 // --------------------------------------------------------------------------
356
357 // --------------------------------------------------------------------------
358 // BEGIN OPTIONAL CSQC FUNCTIONS
359 void Ent_RemoveEntCS()
360 {
361         entcs_receiver[self.sv_entnum] = world;
362 }
363 void Ent_ReadEntCS()
364 {
365         float sf;
366         InterpolateOrigin_Undo();
367
368         self.classname = "entcs_receiver";
369         sf = ReadByte();
370
371         if(sf & 1)
372                 self.sv_entnum = ReadByte();
373         if(sf & 2)
374         {
375                 self.origin_x = ReadShort();
376                 self.origin_y = ReadShort();
377                 self.origin_z = ReadShort();
378                 setorigin(self, self.origin);
379         }
380         if(sf & 4)
381         {
382                 self.angles_y = ReadByte() * 360.0 / 256;
383                 self.angles_x = self.angles_z = 0;
384         }
385         if(sf & 8)
386                 self.healthvalue = ReadByte() * 10;
387         if(sf & 16)
388                 self.armorvalue = ReadByte() * 10;
389
390         entcs_receiver[self.sv_entnum] = self;
391         self.entremove = Ent_RemoveEntCS;
392         self.iflags |= IFLAG_ORIGIN;
393
394         InterpolateOrigin_Note();
395 }
396
397 void Ent_Remove();
398
399 void Ent_RemovePlayerScore()
400 {
401         float i;
402
403         if(self.owner)
404         {
405                 SetTeam(self.owner, -1);
406                 self.owner.gotscores = 0;
407                 for(i = 0; i < MAX_SCORE; ++i)
408                         self.owner.(scores[i]) = 0; // clear all scores
409         }
410 }
411
412 void Ent_ReadPlayerScore()
413 {
414         float i, n;
415         float isNew;
416         entity o;
417
418         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
419         // (no I've never heard of M-x replace-string, sed, or anything like that)
420         isNew = !self.owner; // workaround for DP bug
421         n = ReadByte()-1;
422
423 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
424         if(!isNew && n != self.sv_entnum)
425         {
426                 //print("A CSQC entity changed its owner!\n");
427                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
428                 isNew = true;
429                 Ent_Remove();
430                 self.enttype = ENT_CLIENT_SCORES;
431         }
432 #endif
433
434         self.sv_entnum = n;
435
436         if (!(playerslots[self.sv_entnum]))
437                 playerslots[self.sv_entnum] = spawn();
438         o = self.owner = playerslots[self.sv_entnum];
439         o.sv_entnum = self.sv_entnum;
440         o.gotscores = 1;
441
442         //if (!o.sort_prev)
443         //      RegisterPlayer(o);
444         //playerchecker will do this for us later, if it has not already done so
445
446         float sf, lf;
447 #if MAX_SCORE <= 8
448         sf = ReadByte();
449         lf = ReadByte();
450 #else
451         sf = ReadShort();
452         lf = ReadShort();
453 #endif
454         float p;
455         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
456                 if(sf & p)
457                 {
458                         if(lf & p)
459                                 o.(scores[i]) = ReadInt24_t();
460                         else
461                                 o.(scores[i]) = ReadChar();
462                 }
463
464         if(o.sort_prev)
465                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
466
467         self.entremove = Ent_RemovePlayerScore;
468 }
469
470 void Ent_ReadTeamScore()
471 {
472         float i;
473         entity o;
474
475         self.team = ReadByte();
476         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
477
478         float sf, lf;
479 #if MAX_TEAMSCORE <= 8
480         sf = ReadByte();
481         lf = ReadByte();
482 #else
483         sf = ReadShort();
484         lf = ReadShort();
485 #endif
486         float p;
487         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
488                 if(sf & p)
489                 {
490                         if(lf & p)
491                                 o.(teamscores[i]) = ReadInt24_t();
492                         else
493                                 o.(teamscores[i]) = ReadChar();
494                 }
495
496         HUD_UpdateTeamPos(o);
497 }
498
499 void Ent_ClientData()
500 {
501         float f;
502         float newspectatee_status;
503
504         f = ReadByte();
505
506         scoreboard_showscores_force = (f & 1);
507
508         if(f & 2)
509         {
510                 newspectatee_status = ReadByte();
511                 if(newspectatee_status == player_localnum + 1)
512                         newspectatee_status = -1; // observing
513         }
514         else
515                 newspectatee_status = 0;
516
517         spectatorbutton_zoom = (f & 4);
518
519         if(f & 8)
520         {
521                 angles_held_status = 1;
522                 angles_held_x = ReadAngle();
523                 angles_held_y = ReadAngle();
524                 angles_held_z = 0;
525         }
526         else
527                 angles_held_status = 0;
528
529         if(newspectatee_status != spectatee_status)
530         {
531                 // clear race stuff
532                 race_laptime = 0;
533                 race_checkpointtime = 0;
534         }
535         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
536         {
537                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
538                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
539                 )
540                         prev_p_health = -1;
541                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
542                         prev_health = -1;
543         }
544         spectatee_status = newspectatee_status;
545
546         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
547 }
548
549 void Ent_Nagger()
550 {
551         float nags, i, j, b, f;
552
553         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
554
555         if(!(nags & 4))
556         {
557                 if(vote_called_vote)
558                         strunzone(vote_called_vote);
559                 vote_called_vote = string_null;
560                 vote_active = 0;
561         }
562         else
563         {
564                 vote_active = 1;
565         }
566
567         if(nags & 64)
568         {
569                 vote_yescount = ReadByte();
570                 vote_nocount = ReadByte();
571                 vote_needed = ReadByte();
572                 vote_highlighted = ReadChar();
573         }
574
575         if(nags & 128)
576         {
577                 if(vote_called_vote)
578                         strunzone(vote_called_vote);
579                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
580         }
581
582         if(nags & 1)
583         {
584                 for(j = 0; j < maxclients; ++j)
585                         if(playerslots[j])
586                                 playerslots[j].ready = 1;
587                 for(i = 1; i <= maxclients; i += 8)
588                 {
589                         f = ReadByte();
590                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
591                                 if (!(f & b))
592                                         if(playerslots[j])
593                                                 playerslots[j].ready = 0;
594                 }
595         }
596
597         ready_waiting = (nags & 1);
598         ready_waiting_for_me = (nags & 2);
599         vote_waiting = (nags & 4);
600         vote_waiting_for_me = (nags & 8);
601         warmup_stage = (nags & 16);
602 }
603
604 void Ent_RandomSeed()
605 {
606         float s;
607         prandom_debug();
608         s = ReadShort();
609         psrandom(s);
610 }
611
612 void Ent_ReadAccuracy(void)
613 {
614         float sf, f, w, b;
615         sf = ReadInt24_t();
616         if(sf == 0)
617         {
618                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
619                         weapon_accuracy[w] = -1;
620                 return;
621         }
622
623         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
624         {
625                 if(sf & f)
626                 {
627                         b = ReadByte();
628                         if(b == 0)
629                                 weapon_accuracy[w] = -1;
630                         else if(b == 255)
631                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
632                         else
633                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
634                 }
635                 if(f == 0x800000)
636                         f = 1;
637                 else
638                         f *= 2;
639         }
640 }
641
642 void Spawn_Draw(void)
643 {
644         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
645 }
646
647 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
648 {
649         float teamnum = (ReadByte() - 1);
650         vector spn_origin;
651         spn_origin_x = ReadShort();
652         spn_origin_y = ReadShort();
653         spn_origin_z = ReadShort();
654
655         if(is_new)
656         {
657                 self.origin = spn_origin;
658                 setsize(self, PL_MIN, PL_MAX);
659                 droptofloor();
660
661                 /*if(autocvar_cl_spawn_point_model) // needs a model first
662                 {
663                         self.mdl = "models/spawnpoint.md3";
664                         self.colormod = Team_ColorRGB(teamnum);
665                         precache_model(self.mdl);
666                         setmodel(self, self.mdl);
667                         self.drawmask = MASK_NORMAL;
668                         //self.movetype = MOVETYPE_NOCLIP;
669                         //self.draw = Spawn_Draw;
670                 }*/
671                 if(autocvar_cl_spawn_point_particles)
672                 {
673                         if((serverflags & SERVERFLAG_TEAMPLAY))
674                         {
675                                 switch(teamnum)
676                                 {
677                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
678                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
679                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
680                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
681                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
682                                 }
683                         }
684                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
685
686                         self.draw = Spawn_Draw;
687                 }
688         }
689
690         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
691 }
692
693 void Ent_ReadSpawnEvent(float is_new)
694 {
695         // If entnum is 0, ONLY do the local spawn actions
696         // this way the server can disable the sending of
697         // spawn origin or such to clients if wanted.
698         float entnum = ReadByte();
699
700         if(entnum)
701         {
702                 self.origin_x = ReadShort();
703                 self.origin_y = ReadShort();
704                 self.origin_z = ReadShort();
705
706                 if(is_new)
707                 {
708                         float teamnum = GetPlayerColor(entnum - 1);
709
710                         if(autocvar_cl_spawn_event_particles)
711                         {
712                                 switch(teamnum)
713                                 {
714                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
715                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
716                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
717                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
718                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
719                                 }
720                         }
721                         if(autocvar_cl_spawn_event_sound)
722                         {
723                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
724                         }
725                 }
726         }
727
728         // local spawn actions
729         if(is_new && (!entnum || (entnum == player_localentnum)))
730         {
731                 zoomin_effect = 1;
732                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
733
734                 if(autocvar_cl_unpress_zoom_on_spawn)
735                 {
736                         localcmd("-zoom\n");
737                         button_zoom = FALSE;
738                 }
739         }
740
741         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
742 }
743
744 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
745 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
746 void Ent_RadarLink();
747 void Ent_Init();
748 void Ent_ScoresInfo();
749 void CSQC_Ent_Update(float bIsNewEntity)
750 {
751         float t;
752         float savetime;
753         t = ReadByte();
754
755         if(autocvar_developer_csqcentities)
756                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
757
758         // set up the "time" global for received entities to be correct for interpolation purposes
759         savetime = time;
760         if(servertime)
761         {
762                 time = servertime;
763         }
764         else
765         {
766                 serverprevtime = time;
767                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
768                 time = serverprevtime + serverdeltatime;
769         }
770
771 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
772         if(self.enttype)
773         {
774                 if(t != self.enttype || bIsNewEntity)
775                 {
776                         //print("A CSQC entity changed its type!\n");
777                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
778                         Ent_Remove();
779                         clearentity(self);
780                         bIsNewEntity = 1;
781                 }
782         }
783         else
784         {
785                 if(!bIsNewEntity)
786                 {
787                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
788                         bIsNewEntity = 1;
789                 }
790         }
791 #endif
792         self.enttype = t;
793         switch(t)
794         {
795                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
796                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
797                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
798                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
799                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
800                 case ENT_CLIENT_LASER: Ent_Laser(); break;
801                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
802                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
803                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
804                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
805                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
806                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
807                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
808                 case ENT_CLIENT_INIT: Ent_Init(); break;
809                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
810                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
811                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
812                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
813                 case ENT_CLIENT_WALL: Ent_Wall(); break;
814                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
815                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
816                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
817                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
818                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
819                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
820                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
821                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
822                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
823                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
824                 case ENT_CLIENT_TURRET: ent_turret(); break;
825                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
826                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
827                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
828                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
829                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
830                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
831
832                 default:
833                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
834                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
835                         break;
836         }
837
838         time = savetime;
839 }
840 // Destructor, but does NOT deallocate the entity by calling remove(). Also
841 // used when an entity changes its type. For an entity that someone interacts
842 // with others, make sure it can no longer do so.
843 void Ent_Remove()
844 {
845         if(self.entremove)
846                 self.entremove();
847
848         if(self.skeletonindex)
849         {
850                 skel_delete(self.skeletonindex);
851                 self.skeletonindex = 0;
852         }
853
854         if(self.snd_looping > 0)
855         {
856                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
857                 self.snd_looping = 0;
858         }
859
860         self.enttype = 0;
861         self.classname = "";
862         self.draw = menu_sub_null;
863         self.entremove = menu_sub_null;
864         // TODO possibly set more stuff to defaults
865 }
866 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
867 void CSQC_Ent_Remove()
868 {
869         if(autocvar_developer_csqcentities)
870                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
871
872         if(wasfreed(self))
873         {
874                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
875                 return;
876         }
877         if(self.enttype)
878                 Ent_Remove();
879         remove(self);
880 }
881
882 void Gamemode_Init()
883 {
884         if (!isdemo())
885         {
886                 if(!(calledhooks & HOOK_START))
887                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
888                 calledhooks |= HOOK_START;
889         }
890 }
891 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
892 void CSQC_Parse_StuffCmd(string strMessage)
893 {
894         if(autocvar_developer_csqcentities)
895                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
896
897         localcmd(strMessage);
898 }
899 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
900 void CSQC_Parse_Print(string strMessage)
901 {
902         if(autocvar_developer_csqcentities)
903                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
904
905         print(ColorTranslateRGB(strMessage));
906 }
907
908 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
909 void CSQC_Parse_CenterPrint(string strMessage)
910 {
911         if(autocvar_developer_csqcentities)
912                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
913
914         centerprint_hud(strMessage);
915 }
916
917 string notranslate_fogcmd1 = "\nfog ";
918 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
919 void Fog_Force()
920 {
921         // TODO somehow thwart prvm_globalset client ...
922
923         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
924                 { localcmd("\nr_drawfog 0\n"); }
925         else if(forcefog != "")
926                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
927 }
928
929 void Gamemode_Init();
930 void Ent_ScoresInfo()
931 {
932         float i;
933         self.classname = "ent_client_scores_info";
934         gametype = ReadInt24_t();
935         HUD_ModIcons_SetFunc();
936         for(i = 0; i < MAX_SCORE; ++i)
937         {
938                 scores_label[i] = strzone(ReadString());
939                 scores_flags[i] = ReadByte();
940         }
941         for(i = 0; i < MAX_TEAMSCORE; ++i)
942         {
943                 teamscores_label[i] = strzone(ReadString());
944                 teamscores_flags[i] = ReadByte();
945         }
946         HUD_InitScores();
947         Gamemode_Init();
948 }
949
950 void Ent_Init()
951 {
952         self.classname = "ent_client_init";
953
954         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
955
956         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
957         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
958         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
959         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
960         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
961         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
962         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
963         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
964
965         if(forcefog)
966                 strunzone(forcefog);
967         forcefog = strzone(ReadString());
968
969         armorblockpercent = ReadByte() / 255.0;
970
971         g_balance_grenadelauncher_bouncefactor = ReadCoord();
972         g_balance_grenadelauncher_bouncestop = ReadCoord();
973         g_balance_electro_secondary_bouncefactor = ReadCoord();
974         g_balance_electro_secondary_bouncestop = ReadCoord();
975
976         vortex_scope = !ReadByte();
977         rifle_scope = !ReadByte();
978
979         serverflags = ReadByte();
980
981         minelayer_maxmines = ReadByte();
982
983         hagar_maxrockets = ReadByte();
984
985         g_trueaim_minrange = ReadCoord();
986         g_balance_porto_secondary = ReadByte();
987
988         if(!postinit)
989                 PostInit();
990 }
991
992 void Net_ReadRace()
993 {
994         float b;
995
996         b = ReadByte();
997
998         switch(b)
999         {
1000                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1001                         race_checkpoint = ReadByte();
1002                         race_time = ReadInt24_t();
1003                         race_previousbesttime = ReadInt24_t();
1004                         if(race_previousbestname)
1005                                 strunzone(race_previousbestname);
1006                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1007
1008                         race_checkpointtime = time;
1009
1010                         if(race_checkpoint == 0 || race_checkpoint == 254)
1011                         {
1012                                 race_penaltyaccumulator = 0;
1013                                 race_laptime = time; // valid
1014                         }
1015
1016                         break;
1017
1018                 case RACE_NET_CHECKPOINT_CLEAR:
1019                         race_laptime = 0;
1020                         race_checkpointtime = 0;
1021                         break;
1022
1023                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1024                         race_laptime = ReadCoord();
1025                         race_checkpointtime = -99999;
1026                         // fall through
1027                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1028                         race_nextcheckpoint = ReadByte();
1029
1030                         race_nextbesttime = ReadInt24_t();
1031                         if(race_nextbestname)
1032                                 strunzone(race_nextbestname);
1033                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1034                         break;
1035
1036                 case RACE_NET_CHECKPOINT_HIT_RACE:
1037                         race_mycheckpoint = ReadByte();
1038                         race_mycheckpointtime = time;
1039                         race_mycheckpointdelta = ReadInt24_t();
1040                         race_mycheckpointlapsdelta = ReadByte();
1041                         if(race_mycheckpointlapsdelta >= 128)
1042                                 race_mycheckpointlapsdelta -= 256;
1043                         if(race_mycheckpointenemy)
1044                                 strunzone(race_mycheckpointenemy);
1045                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1046                         break;
1047
1048                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1049                         race_othercheckpoint = ReadByte();
1050                         race_othercheckpointtime = time;
1051                         race_othercheckpointdelta = ReadInt24_t();
1052                         race_othercheckpointlapsdelta = ReadByte();
1053                         if(race_othercheckpointlapsdelta >= 128)
1054                                 race_othercheckpointlapsdelta -= 256;
1055                         if(race_othercheckpointenemy)
1056                                 strunzone(race_othercheckpointenemy);
1057                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1058                         break;
1059
1060                 case RACE_NET_PENALTY_RACE:
1061                         race_penaltyeventtime = time;
1062                         race_penaltytime = ReadShort();
1063                         //race_penaltyaccumulator += race_penaltytime;
1064                         if(race_penaltyreason)
1065                                 strunzone(race_penaltyreason);
1066                         race_penaltyreason = strzone(ReadString());
1067                         break;
1068
1069                 case RACE_NET_PENALTY_QUALIFYING:
1070                         race_penaltyeventtime = time;
1071                         race_penaltytime = ReadShort();
1072                         race_penaltyaccumulator += race_penaltytime;
1073                         if(race_penaltyreason)
1074                                 strunzone(race_penaltyreason);
1075                         race_penaltyreason = strzone(ReadString());
1076                         break;
1077
1078                 case RACE_NET_SERVER_RECORD:
1079                         race_server_record = ReadInt24_t();
1080                         break;
1081                 case RACE_NET_SPEED_AWARD:
1082                         race_speedaward = ReadInt24_t();
1083                         if(race_speedaward_holder)
1084                                 strunzone(race_speedaward_holder);
1085                         race_speedaward_holder = strzone(ReadString());
1086                         break;
1087                 case RACE_NET_SPEED_AWARD_BEST:
1088                         race_speedaward_alltimebest = ReadInt24_t();
1089                         if(race_speedaward_alltimebest_holder)
1090                                 strunzone(race_speedaward_alltimebest_holder);
1091                         race_speedaward_alltimebest_holder = strzone(ReadString());
1092                         break;
1093                 case RACE_NET_SERVER_RANKINGS:
1094                         float pos, prevpos, del;
1095                         pos = ReadShort();
1096                         prevpos = ReadShort();
1097                         del = ReadShort();
1098
1099                         // move other rankings out of the way
1100                         float i;
1101                         if (prevpos) {
1102                                 for (i=prevpos-1;i>pos-1;--i) {
1103                                         grecordtime[i] = grecordtime[i-1];
1104                                         if(grecordholder[i])
1105                                                 strunzone(grecordholder[i]);
1106                                         grecordholder[i] = strzone(grecordholder[i-1]);
1107                                 }
1108                         } else if (del) { // a record has been deleted by the admin
1109                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1110                                         if (i == RANKINGS_CNT-1) { // clear out last record
1111                                                 grecordtime[i] = 0;
1112                                                 if (grecordholder[i])
1113                                                         strunzone(grecordholder[i]);
1114                                                 grecordholder[i] = string_null;
1115                                         }
1116                                         else {
1117                                                 grecordtime[i] = grecordtime[i+1];
1118                                                 if (grecordholder[i])
1119                                                         strunzone(grecordholder[i]);
1120                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1121                                         }
1122                                 }
1123                         } else { // player has no ranked record yet
1124                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1125                                         grecordtime[i] = grecordtime[i-1];
1126                                         if(grecordholder[i])
1127                                                 strunzone(grecordholder[i]);
1128                                         grecordholder[i] = strzone(grecordholder[i-1]);
1129                                 }
1130                         }
1131
1132                         // store new ranking
1133                         if(grecordholder[pos-1] != "")
1134                                 strunzone(grecordholder[pos-1]);
1135                         grecordholder[pos-1] = strzone(ReadString());
1136                         grecordtime[pos-1] = ReadInt24_t();
1137                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1138                                 race_myrank = pos;
1139                         break;
1140                 case RACE_NET_SERVER_STATUS:
1141                         race_status = ReadShort();
1142                         if(race_status_name)
1143                                 strunzone(race_status_name);
1144                         race_status_name = strzone(ReadString());
1145         }
1146 }
1147
1148 void Net_TeamNagger()
1149 {
1150         teamnagger = 1;
1151 }
1152
1153 void Net_ReadPingPLReport()
1154 {
1155         float e, pi, pl, ml;
1156         e = ReadByte();
1157         pi = ReadShort();
1158         pl = ReadByte();
1159         ml = ReadByte();
1160         if (!(playerslots[e]))
1161                 return;
1162         playerslots[e].ping = pi;
1163         playerslots[e].ping_packetloss = pl / 255.0;
1164         playerslots[e].ping_movementloss = ml / 255.0;
1165 }
1166
1167 void Net_WeaponComplain()
1168 {
1169         complain_weapon = ReadByte();
1170
1171         if(complain_weapon_name)
1172                 strunzone(complain_weapon_name);
1173         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1174
1175         complain_weapon_type = ReadByte();
1176
1177         complain_weapon_time = time;
1178         weapontime = time; // ping the weapon panel
1179
1180         switch(complain_weapon_type)
1181         {
1182                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1183                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1184                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1185         }
1186 }
1187
1188 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1189 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1190 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1191 float CSQC_Parse_TempEntity()
1192 {
1193         float bHandled;
1194                 bHandled  = true;
1195         // Acquire TE ID
1196         float nTEID;
1197                 nTEID = ReadByte();
1198
1199         if(autocvar_developer_csqcentities)
1200                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1201
1202                 // NOTE: Could just do return instead of break...
1203         switch(nTEID)
1204         {
1205                 case TE_CSQC_TARGET_MUSIC:
1206                         Net_TargetMusic();
1207                         bHandled = true;
1208                         break;
1209                 case TE_CSQC_PICTURE:
1210                         Net_MapVote_Picture();
1211                         bHandled = true;
1212                         break;
1213                 case TE_CSQC_RACE:
1214                         Net_ReadRace();
1215                         bHandled = true;
1216                         break;
1217                 case TE_CSQC_VORTEXBEAMPARTICLE:
1218                         Net_ReadVortexBeamParticle();
1219                         bHandled = true;
1220                         break;
1221                 case TE_CSQC_TEAMNAGGER:
1222                         Net_TeamNagger();
1223                         bHandled = true;
1224                         break;
1225                 case TE_CSQC_ARC:
1226                         Net_ReadArc();
1227                         bHandled = true;
1228                         break;
1229                 case TE_CSQC_PINGPLREPORT:
1230                         Net_ReadPingPLReport();
1231                         bHandled = true;
1232                         break;
1233                 case TE_CSQC_WEAPONCOMPLAIN:
1234                         Net_WeaponComplain();
1235                         bHandled = true;
1236                         break;
1237                 case TE_CSQC_VEHICLESETUP:
1238                         Net_VehicleSetup();
1239                         bHandled = true;
1240                         break;
1241                 case TE_CSQC_SVNOTICE:
1242                         cl_notice_read();
1243                         bHandled = true;
1244                         break;
1245                 case TE_CSQC_SHOCKWAVEPARTICLE:
1246                         Net_ReadShockwaveParticle();
1247                         bHandled = true;
1248                         break;
1249                 default:
1250                         // No special logic for this temporary entity; return 0 so the engine can handle it
1251                         bHandled = false;
1252                         break;
1253         }
1254
1255         return bHandled;
1256 }
1257
1258 string getcommandkey(string text, string command)
1259 {
1260         string keys;
1261         float n, j, k, l = 0;
1262
1263         if (!autocvar_hud_showbinds)
1264                 return text;
1265
1266         keys = db_get(binddb, command);
1267         if (keys == "")
1268         {
1269                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1270                 for(j = 0; j < n; ++j)
1271                 {
1272                         k = stof(argv(j));
1273                         if(k != -1)
1274                         {
1275                                 if ("" == keys)
1276                                         keys = keynumtostring(k);
1277                                 else
1278                                         keys = strcat(keys, ", ", keynumtostring(k));
1279
1280                                 ++l;
1281                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1282                                         break;
1283                         }
1284
1285                 }
1286                 if (keys == "")
1287                         keys = "NO_KEY";
1288                 db_put(binddb, command, keys);
1289         }
1290
1291         if (keys == "NO_KEY") {
1292                 if (autocvar_hud_showbinds > 1)
1293                         return sprintf(_("%s (not bound)"), text);
1294                 else
1295                         return text;
1296         }
1297         else if (autocvar_hud_showbinds > 1)
1298                 return sprintf(_("%s (%s)"), text, keys);
1299         else
1300                 return keys;
1301 }